BEGIN ~B2#Aeri~

IF ~NumTimesTalkedTo(0)
~ THEN BEGIN 0
  SAY @0
  IF ~~ THEN REPLY @1 GOTO 1
  IF ~~ THEN REPLY @2 GOTO 1
  IF ~~ THEN REPLY @3 GOTO 3
END

IF ~~ THEN BEGIN 1
  SAY @4
  IF ~~ THEN GOTO 1a
END

IF ~~ THEN BEGIN 1a
  SAY @5
  IF ~~ THEN REPLY @6 GOTO 2
  IF ~~ THEN REPLY @7 GOTO 3
  IF ~~ THEN REPLY @8 GOTO 4
END

IF ~~ THEN BEGIN 2
  SAY @9
  IF ~~ THEN REPLY @11 GOTO 5
END

IF ~~ THEN BEGIN 3
  SAY @10
  IF ~~ THEN REPLY @11 GOTO 5
END

IF ~~ THEN BEGIN 4
  SAY @12
  IF ~~ THEN DO ~SetGlobal("B2#AeriMET","GLOBAL",1)
MoveToPoint([2355.3082])
~ EXIT
END

IF ~~ THEN BEGIN 5
  SAY @13
  = @14
  = @15
  IF ~~ THEN REPLY @16 GOTO 6
  IF ~~ THEN REPLY @17 GOTO 7
  IF ~~ THEN REPLY @8 GOTO 4
END

IF ~~ THEN BEGIN 6
  SAY @18
  IF ~~ THEN DO ~SetGlobal("B2#AeriMET","GLOBAL",1)
MoveToPoint([2355.3082])
~ EXIT
END

IF ~~ THEN BEGIN 7
  SAY @19
  IF ~~ THEN DO ~SetGlobal("B2#AeriMET","GLOBAL",1)
MoveToPoint([2355.3082])
~ EXIT
END

IF ~Dead("BENTHA")
~ THEN BEGIN 13
  SAY @20
  IF ~~ THEN DO ~
EscapeArea()
~ EXIT
END

IF ~Global("B2#BENTHASAFE","GLOBAL",1)
~ THEN BEGIN 14
  SAY @21
  = @22
  = @23
  IF ~~ THEN REPLY @24 GOTO 15
  IF ~~ THEN REPLY @25 GOTO 16
  IF ~~ THEN REPLY @26 GOTO 17
  IF ~~ THEN REPLY @27 GOTO 18
END

IF ~~ THEN BEGIN 15
  SAY @28
  IF ~~ THEN REPLY @29 GOTO 19
  IF ~~ THEN REPLY @30 GOTO 20
  IF ~~ THEN REPLY @31 GOTO 21
  IF ~~ THEN REPLY @32 GOTO 22
  IF ~~ THEN REPLY @27 GOTO 18
END

IF ~~ THEN BEGIN 19
  SAY @33
  IF ~~ THEN GOTO 23
END

IF ~~ THEN BEGIN 20
  SAY @34
  IF ~~ THEN GOTO 23
END

IF ~~ THEN BEGIN 21
  SAY @35 
  IF ~~ THEN GOTO 23
END

IF ~~ THEN BEGIN 22
  SAY @36
  IF ~~ THEN GOTO 23
END

IF ~~ THEN BEGIN 23
  SAY @37
  IF ~~ THEN REPLY @24 GOTO 15
  IF ~~ THEN REPLY @25 GOTO 16
  IF ~~ THEN REPLY @26 GOTO 17
  IF ~~ THEN REPLY @27 GOTO 18
END

IF ~~ THEN BEGIN 16
  SAY @38
  = @39
  = @40
  = @41
  IF ~~ THEN GOTO 23
END

IF ~~ THEN BEGIN 17
  SAY @42
  = @43
  IF ~~ THEN GOTO 23
END

IF ~~ THEN BEGIN 18
  SAY @44
  IF ~~ THEN DO ~SetGlobal("B2#AeriSTO","GLOBAL",1) StartStore("B2#4906",LastTalkedToBy)
SetGlobal("B2#BENTHASAFE","GLOBAL",2)
~ EXIT
END

IF ~InParty("Quayle") Global("B2#AeriSTO","GLOBAL",1) Global("B2#QuaAer","GLOBAL",0)
~ THEN BEGIN B2#QuaAer
  SAY @121
  IF ~~ THEN GOTO 33
END

IF ~~ THEN BEGIN B2#QuaAer2
  SAY @132
  IF ~~ THEN DO ~SetGlobal("B2#QuaAer","GLOBAL",1)
~ EXIT
END

IF ~Global("B2#AeriSTO","GLOBAL",1)
~ THEN BEGIN 24
  SAY @45
  IF ~~ THEN REPLY @24 GOTO 25
  IF ~~ THEN REPLY @46 GOTO 26
  IF ~Global("B2#AeriQST","GLOBAL",0)~ THEN REPLY @47 GOTO AQ1
  IF ~Global("B2#AeriQST","GLOBAL",1) PartyHasItem("B2#BTSA")~ THEN REPLY @48 GOTO AQ16
  IF ~~ THEN REPLY @26 GOTO 27
  IF ~~ THEN REPLY @27 GOTO 28
END

IF ~~ THEN BEGIN 25
  SAY @28
  IF ~~ THEN REPLY @29 GOTO 29
  IF ~~ THEN REPLY @30 GOTO 30
  IF ~~ THEN REPLY @31 GOTO 31
  IF ~GlobalLT("B2#AeriQST","GLOBAL",2)~ THEN REPLY @49 GOTO 32
  IF ~Global("B2#AeriQST","GLOBAL",2)~ THEN REPLY @49 GOTO 32a
END

IF ~~ THEN BEGIN 29
  SAY @33
  IF ~~ THEN GOTO 33
END

IF ~~ THEN BEGIN 30
  SAY @34
  IF ~~ THEN GOTO 33
END

IF ~~ THEN BEGIN 31
  SAY @35 
  IF ~~ THEN GOTO 33
END

IF ~~ THEN BEGIN 32
  SAY @36
  IF ~~ THEN GOTO 33
END

IF ~~ THEN BEGIN 32a
  SAY @50
  IF ~~ THEN GOTO 33
END

IF ~~ THEN BEGIN 33
  SAY @37
  IF ~~ THEN REPLY @24 GOTO 25
  IF ~~ THEN REPLY @46 GOTO 26
  IF ~Global("B2#AeriQST","GLOBAL",0)~ THEN REPLY @47 GOTO AQ1
  IF ~Global("B2#AeriQST","GLOBAL",1) PartyHasItem("B2#BTSA")~ THEN REPLY @48 GOTO AQ16
  IF ~~ THEN REPLY @26 GOTO 27
  IF ~~ THEN REPLY @27 GOTO 28
END

IF ~~ THEN BEGIN 26
  SAY @38
  = @39
  = @40
  = @41
  IF ~~ THEN GOTO 33
END

IF ~~ THEN BEGIN 27
  SAY @42
  = @43
  IF ~~ THEN GOTO 33
END

IF ~~ THEN BEGIN 28
  SAY @44
  IF ~~ THEN DO ~StartStore("B2#4906",LastTalkedToBy)
~ EXIT
END

IF ~Dead("ZORDRAL")
~ THEN BEGIN 34
  SAY @51
  = @52
  = @53
  = @54
  = @55
  IF ~~ THEN DO ~GiveItem("SCRLPET",LastTalkedToBy) SetGlobal("B2#BENTHASAFE","GLOBAL",1) 
EscapeAreaMove("%NashkelCarnival_ZordralsTent%",318,205,3)
~ EXIT
END

IF ~Global("B2#AeriMET","GLOBAL",1)
~ THEN BEGIN 35
  SAY @56
  IF ~~ THEN REPLY @57 GOTO 36
  IF ~~ THEN REPLY @58 GOTO 37
  IF ~~ THEN REPLY @59 GOTO 38
END

IF ~~ THEN BEGIN 36
  SAY @60
  = @61
  = @62
  IF ~~ THEN DO ~
~ EXIT
END

IF ~~ THEN BEGIN 37
  SAY @63
  = @62
  IF ~~ THEN DO ~
~ EXIT
END

IF ~~ THEN BEGIN 38
  SAY @64
  = @65
  IF ~~ THEN DO ~
~ EXIT
END

IF ~~ THEN BEGIN AQ1
  SAY @66
  IF ~~ THEN REPLY @67 GOTO AQ2
  IF ~~ THEN REPLY @68 GOTO AQ3
  IF ~~ THEN REPLY @69 GOTO AQ4
END

IF ~~ THEN BEGIN AQ2
  SAY @70
  IF ~~ THEN GOTO AQ5
END

IF ~~ THEN BEGIN AQ3
  SAY @71
  IF ~~ THEN GOTO AQ5
END

IF ~~ THEN BEGIN AQ4
  SAY @72
  IF ~~ THEN GOTO AQ5
END

IF ~~ THEN BEGIN AQ5
  SAY @73
  IF ~~ THEN REPLY @74 GOTO AQ6
  IF ~~ THEN REPLY @75 GOTO AQ7
  IF ~~ THEN REPLY @76 GOTO AQ15
END

IF ~~ THEN BEGIN AQ6
  SAY @77
  IF ~~ THEN REPLY @78 GOTO AQ7
  IF ~~ THEN REPLY @76 GOTO AQ15
END

IF ~~ THEN BEGIN AQ7
  SAY @79
  IF ~~ THEN REPLY @80 GOTO AQ8
  IF ~~ THEN REPLY @81 GOTO AQ9
  IF ~~ THEN REPLY @76 GOTO AQ15
END

IF ~~ THEN BEGIN AQ8
  SAY @82
  IF ~~ THEN REPLY @83 GOTO AQ9
  IF ~~ THEN REPLY @76 GOTO AQ15
END

IF ~~ THEN BEGIN AQ9
  SAY @84
  IF ~~ THEN REPLY @85 GOTO AQ10
END

IF ~~ THEN BEGIN AQ10
  SAY @86
  IF ~~ THEN REPLY @87 GOTO AQ11
END

IF ~~ THEN BEGIN AQ11
  SAY @88
  IF ~~ THEN REPLY @89 GOTO AQ12
END

IF ~~ THEN BEGIN AQ12
  SAY @90
  IF ~~ THEN REPLY @91 GOTO AQ13
END

IF ~~ THEN BEGIN AQ13
  SAY @92
  IF ~~ THEN REPLY @93 GOTO AQ14
END

IF ~~ THEN BEGIN AQ14
  SAY @94
  = @95
  IF ~~ THEN DO ~SetGlobal("B2#AeriQST","GLOBAL",1)
~ EXIT
END

IF ~~ THEN BEGIN AQ15
  SAY @96
  IF ~~ THEN GOTO 33
END

IF ~~ THEN BEGIN AQ16
  SAY @97
  IF ~~ THEN REPLY @98 GOTO AQ17
END

IF ~~ THEN BEGIN AQ17
  SAY @99
  IF ~~ THEN REPLY @100 GOTO AQ18
END

IF ~~ THEN BEGIN AQ18
  SAY @101
  = @102 
  = @103
  = @104
  = @105
  IF ~~ THEN REPLY @106 GOTO AQ19
  IF ~~ THEN REPLY @107 GOTO AQ20
END

IF ~~ THEN BEGIN AQ19
  SAY @108
  = @109
  IF ~~ THEN DO ~SetGlobal("B2#AeriQST","GLOBAL",2)
TakePartyItem("B2#BTSA")
GiveItemCreate("B2#RNG1",LastTalkedToBy,1,0,0)
AddexperienceParty(300)
SetGlobalTimer("B2#Ash","GLOBAL",TWO_DAYS)
~ EXIT
END

IF ~~ THEN BEGIN AQ20
  SAY @110
  = @111
  IF ~~ THEN DO ~SetGlobal("B2#AeriQST","GLOBAL",2)
TakePartyItem("B2#BTSA")
AddexperienceParty(300)
SetGlobalTimer("B2#Ash","GLOBAL",TWO_DAYS)
~ EXIT
END

// INTERJECTIONS

INTERJECT B2#Aeri 1 B2#ImnAeri
  == %IMOEN_JOINED% IF ~IsValidForPartyDialog("%IMOEN_DV%")~ THEN 
    @112
  == B2#Aeri IF ~IsValidForPartyDialog("%IMOEN_DV%")~ THEN
    @113
  == %IMOEN_JOINED% @114
  == B2#Aeri @115
  == %IMOEN_JOINED% @116
  == B2#Aeri @117
  == %IMOEN_JOINED% @118
  = @119
  == B2#Aeri @120
END B2#Aeri 3

INTERJECT B2#Aeri B2#QuaAer B2#QuaAer1
  == QUAYLJ IF ~IsValidForPartyDialog("QUAYLE")~ THEN
    @122
  == B2#Aeri IF ~IsValidForPartyDialog("QUAYLE")~ THEN
    @123
  = @124
  == QUAYLJ @125
  == B2#Aeri @126
  == QUAYLJ @127
  == B2#Aeri @128
  == QUAYLJ @129
  == B2#Aeri @130
  == QUAYLJ @131
END B2#Aeri B2#QuaAer2