APPEND ACSILVER


IF ~~ THEN BEGIN 25PLOT.2
SAY @8
++ @9 + 25PLOT.6
++ @10 + 25PLOT.4
++ @11 + 25PLOT.5
END

IF ~~ THEN BEGIN 25PLOT.3
SAY @12 = @13
IF ~~ THEN DO ~SetGlobal("ACBREBROKE","GLOBAL",1)SetGlobal("ACBREEXISTS","GLOBAL",2)ActionOverride("ACBRE",LeaveParty())ActionOverride("ACBRE",ReallyForceSpell(Myself,DRYAD_TELEPORT))ReallyForceSpell(Myself,DRYAD_TELEPORT)~ EXIT
END

IF ~~ THEN BEGIN 25PLOT.4
SAY @14
IF ~Global("ACBREBIO","GLOBAL",2)Global("ACFORRESDEAD","GLOBAL",0)~ THEN DO ~SetGlobal("AC25PLOT","GLOBAL",5)ClearAllActions()StartCutSceneMode()StartCutScene("ACCUT_15")~ UNSOLVED_JOURNAL @10055 EXIT
IF ~Global("ACBREBIO","GLOBAL",2)Global("ACFORRESDEAD","GLOBAL",1)~ THEN DO ~SetGlobal("AC25PLOT","GLOBAL",5)ClearAllActions()StartCutSceneMode()StartCutScene("ACCUT15X")~ UNSOLVED_JOURNAL @10055 EXIT
IF ~Global("ACBREBIO","GLOBAL",3)Global("ACFORRESDEAD","GLOBAL",0)~ THEN DO ~SetGlobal("AC25PLOT","GLOBAL",5)ClearAllActions()StartCutSceneMode()StartCutScene("ACCUT15Y")~ UNSOLVED_JOURNAL @10055 EXIT
IF ~Global("ACBREBIO","GLOBAL",3)Global("ACFORRESDEAD","GLOBAL",1)~ THEN DO ~SetGlobal("AC25PLOT","GLOBAL",5)ClearAllActions()StartCutSceneMode()StartCutScene("ACCUT15Z")~ UNSOLVED_JOURNAL @10055 EXIT
END

IF ~~ THEN BEGIN 25PLOT.4a
SAY @14
IF ~~ THEN DO ~SetGlobal("AC25PLOT","GLOBAL",5)ClearAllActions()StartCutSceneMode()StartCutScene("ACCUT15A")~ EXIT
END

IF ~~ THEN BEGIN 25PLOT.5
SAY @15
IF ~~ THEN DO ~SetGlobal("AC25PLOT","GLOBAL",4)~ EXIT
END

IF ~~ THEN BEGIN 25PLOT.6
SAY @16
++ @17 + 25PLOT.4
++ @11 + 25PLOT.5
END

IF ~Global("ACLASTPLOT","GLOBAL",0)Global("AC25PLOT","GLOBAL",4)~ THEN BEGIN 25PLOT.7
SAY @18
++ @19 + 25PLOT.4
++ @11 + 25PLOT.5
END

IF ~Global("ACLASTPLOT","GLOBAL",0)Global("AC25PLOT","GLOBAL",5)~ THEN BEGIN 25PLOT.8
SAY @20
++ @21 + 25PLOT.4a
++ @11 + 25PLOT.5
END

IF ~Global("ACLASTPLOT","GLOBAL",1)See("ACBRE")!See(PLAYER1)~ THEN BEGIN LAST.1
SAY @22
IF ~~ THEN EXIT
END

IF ~Global("ACLASTPLOT","GLOBAL",1)!See("ACBRE")See(PLAYER1)~ THEN BEGIN LAST.2
SAY @23
IF ~~ THEN EXIT
END

IF ~Global("ACLASTPLOT","GLOBAL",1)!See("ACBRE")!See(PLAYER1)~ THEN BEGIN LAST.3
SAY @24
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN LAST.5
SAY @25
IF ~~ THEN GOTO LAST.11
END

IF ~~ THEN BEGIN LAST.6
SAY @26
IF ~~ THEN GOTO LAST.11
END

IF ~~ THEN BEGIN LAST.7
SAY @27
IF ~~ THEN GOTO LAST.11
END

IF ~~ THEN BEGIN LAST.8
SAY @28
IF ~~ THEN GOTO LAST.11
END

IF ~~ THEN BEGIN LAST.9
SAY @29
IF ~~ THEN GOTO LAST.11
END

IF ~~ THEN BEGIN LAST.10
SAY @30
IF ~~ THEN GOTO LAST.11
END

IF ~~ THEN BEGIN LAST.11
SAY @31
++ @32 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",3)~ + LAST.12
++ @33 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",2)~ + LAST.12
++ @34 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",1)~ + LAST.12
++ @35 DO ~SetGlobal("ACBREDESCIDES","GLOBAL",1)~ + LAST.12
END

END



CHAIN
IF ~Global("ACLASTPLOT","GLOBAL",0)Global("AC25PLOT","GLOBAL",3)GlobalGT("ACBREBIO","GLOBAL",1)~ THEN ACSILVER 25PLOT.START
@89 = @90
==ACBRE25J @91
==ACSILVER @92
==ACBRE25J @93
==ACSILVER @94
==ACBRE25J IF ~Global("ACFORRESDEAD","GLOBAL",1)~ THEN @95
==ACBRE25J IF ~!Global("ACFORRESDEAD","GLOBAL",1)~ THEN @96
==ACSILVER IF ~Global("ACFORRESDEAD","GLOBAL",1)~ THEN @97
==ACSILVER IF ~!Global("ACFORRESDEAD","GLOBAL",1)~ THEN @98
==ACBRE25J @99 = @100
END
++ @101 + 25PLOT.1
++ @102 + 25PLOT.2
++ @103 + 25PLOT.3

CHAIN
IF ~~ THEN ACSILVER 25PLOT.1
@104
==ACBRE25J @105
END
++ @106 + 25PLOT.2
++ @103 + 25PLOT.3

CHAIN
IF ~Global("ACLASTPLOT","GLOBAL",0)Global("AC25PLOT","GLOBAL",10)
InParty("ACBRE") 
See("ACBRE") 
!StateCheck("ACBRE",CD_STATE_NOTVALID)~ THEN ACSILVER 25PLOT.END
@107 DO ~SetGlobal("AC25PLOT","GLOBAL",11) EraseJournalEntry(@10055) EraseJournalEntry(@10056)
EraseJournalEntry(@10057) EraseJournalEntry(@10058) EraseJournalEntry(@10059) EraseJournalEntry(@10060) EraseJournalEntry(@10061) EraseJournalEntry(@10062) EraseJournalEntry(@10063) EraseJournalEntry(@10064) EraseJournalEntry(@10065) EraseJournalEntry(@10066) EraseJournalEntry(@10067) EraseJournalEntry(@10068) EraseJournalEntry(@10069) EraseJournalEntry(@10070) EraseJournalEntry(@10071) AddJournalEntry(@10072,QUEST_DONE)~
==ACBRE25J @75
==ACSILVER @108
==ACSILVER IF ~OR(2) PartyHasItem("ACAXE2") PartyHasItem("c!ax45")~ THEN @109
END
IF ~OR(2) PartyHasItem("ACAXE2") PartyHasItem("c!ax45") GlobalLT("CHAPTER","GLOBAL",%bg2_chapter_9%)~ THEN DO ~AddXPObject(PLAYER1,20000)AddXPObject(PLAYER2,20000)AddXPObject(PLAYER3,20000)AddXPObject(PLAYER4,20000)AddXPObject(PLAYER5,20000)AddXPObject(PLAYER6,20000)ClearAllActions()StartCutSceneMode()StartCutScene("ACCUT_14")~ EXIT
IF ~OR(2) PartyHasItem("ACAXE2") PartyHasItem("c!ax45") GlobalGT("CHAPTER","GLOBAL",%bg2_chapter_8%)~ THEN DO ~AddXPObject(PLAYER1,20000)AddXPObject(PLAYER2,20000)AddXPObject(PLAYER3,20000)AddXPObject(PLAYER4,20000)AddXPObject(PLAYER5,20000)AddXPObject(PLAYER6,20000)ClearAllActions()StartCutSceneMode()StartCutScene("ACCUT14A")~ EXIT
IF ~!PartyHasItem("ACAXE2") !PartyHasItem("c!ax45")~ THEN DO ~AddXPObject(PLAYER1,20000)AddXPObject(PLAYER2,20000)AddXPObject(PLAYER3,20000)AddXPObject(PLAYER4,20000)AddXPObject(PLAYER5,20000)AddXPObject(PLAYER6,20000)ClearAllActions()StartCutSceneMode()StartCutScene("ACCUT_17")~ EXIT

CHAIN
IF ~Global("ACLASTPLOT","GLOBAL",1)See("ACBRE")See(PLAYER1)~ THEN ACSILVER LAST.4
@110 DO ~SetGlobal("ACLASTPLOT","GLOBAL",2)~
==ACBRE25J @111
==ACSILVER IF ~!Race(PLAYER1,DWARF)~ THEN @112 = @113
==ACSILVER IF ~Race(PLAYER1,DWARF)~ THEN @112 = @114
==ACBRE25J @115 
==ACSILVER @116
==ACBRE25J @117
==ACBRE25J IF ~ReputationLT(PLAYER1,9)~ THEN @118 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",1)~
==ACBRE25J IF ~ReputationGT(PLAYER1,8)ReputationLT(PLAYER1,14)~ THEN @118 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",2)~
==ACBRE25J IF ~ReputationGT(PLAYER1,13)~ THEN @119 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",3)~
==ACBRE25J IF ~Alignment(PLAYER1,MASK_GOOD)~ THEN @120 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",3)~
==ACBRE25J IF ~Alignment(PLAYER1,MASK_GENEUTRAL)~ THEN @121 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",2)~
==ACBRE25J IF ~Alignment(PLAYER1,MASK_EVIL)~ THEN @122 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",1)~
==ACBRE25J IF ~Alignment(PLAYER1,MASK_LAWFUL)~ THEN @123 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",3)~
==ACBRE25J IF ~Alignment(PLAYER1,MASK_LCNEUTRAL)~ THEN @124 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",2)~
==ACBRE25J IF ~Alignment(PLAYER1,MASK_CHAOTIC)~ THEN @125 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",1)~
==ACBRE25J @126
==ACSILVER @127
==ACSILVER IF ~GlobalLT("ACBREDESCIDES","GLOBAL",5)~ THEN @128
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",4)GlobalLT("ACBREDESCIDES","GLOBAL",7)~ THEN @129
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",6)~ THEN @130
END
++ @131 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",3)~ + LAST.5
++ @132 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",2)~ + LAST.6
++ @133 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",1)~ + LAST.7
++ @134 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",3)~ + LAST.8
++ @135 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",2)~ + LAST.9
++ @136 DO ~IncrementGlobal("ACBREDESCIDES","GLOBAL",1)~ + LAST.10

CHAIN
IF ~~ THEN ACSILVER LAST.12
@137
==ACBRE25J @138
==ACSILVER @139
==ACBRE25J IF ~GlobalLT("ACBREDESCIDES","GLOBAL",10)~ THEN @140 DO ~SetGlobal("ACBreBroke","GLOBAL",1)SetGlobal("ACBREEXISTS","GLOBAL",2)SetGlobal("ACBREINPARTY","GLOBAL",3)LeaveParty()Enemy()~
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)GlobalLT("ACBREDESCIDES","GLOBAL",13)~ THEN @141
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",12)~ THEN @142
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)~ THEN @143
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)GlobalLT("ACBREDESCIDES","GLOBAL",13)~ THEN @144 = @145
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)GlobalLT("ACBREDESCIDES","GLOBAL",13)~ THEN @146
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)GlobalLT("ACBREDESCIDES","GLOBAL",13)~ THEN @147
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",12)~ THEN @148
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",12)~ THEN @149
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",12)~ THEN @150
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",12)~ THEN @151
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",12)~ THEN @152
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)~ THEN @153
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)GlobalLT("ACBREDESCIDES","GLOBAL",13)~ THEN @154
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",12)~ THEN @155
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)~ THEN @156
==ACBRE25J IF ~GlobalGT("ACBREDESCIDES","GLOBAL",12)~ THEN @157
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",12)~ THEN @158
==ACSILVER IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)~ THEN @159
END
IF ~GlobalLT("ACBREDESCIDES","GLOBAL",10)~ THEN EXIT
IF ~GlobalGT("ACBREDESCIDES","GLOBAL",9)~ THEN DO ~AddXPObject(PLAYER1,20000)AddXPObject(PLAYER2,20000)AddXPObject(PLAYER3,20000)AddXPObject(PLAYER4,20000)AddXPObject(PLAYER5,20000)AddXPObject(PLAYER6,20000)ForceSpell(Myself,DRYAD_TELEPORT)~ EXIT