APPEND ~KELDDA~

IF WEIGHT #4 ~PartyHasItem("NTBLUN06")
Global("wyvernp","GLOBAL",1)
Global("BassilusDead","GLOBAL",2)
InParty("Will")
GlobalGT("Chapter","GLOBAL",4)~ THEN BEGIN Tells
  SAY @0
  IF ~!Global("KelddatTalkNewBlunt","GLOBAL",1)~ THEN REPLY @1 GOTO TellsMore
  IF ~Global("KelddatTalkNewBlunt","GLOBAL",1)~ THEN REPLY @2 GOTO TellsAid
  IF ~~ THEN REPLY @3 GOTO TellsMore
END

IF ~~ THEN BEGIN TellsMore
  SAY @4
  IF ~~ THEN REPLY @5 DO ~SetGlobal("KelddatTalkNewBlunt","GLOBAL",1)~ EXIT
  IF ~PartyHasItem("MISC45")
PartyHasItem("NTBLUN06")
~ THEN REPLY @6 GOTO Tells1
END

IF ~~ THEN BEGIN Tells1
  SAY @7
  IF ~~ THEN REPLY @8 DO ~SetGlobal("KelddatTalkNewBlunt","GLOBAL",1)
~ EXIT
  IF ~~ THEN REPLY @9 GOTO Tells2
END

IF ~~ THEN BEGIN Tells2
  SAY @10
  IF ~~ THEN DO ~TakePartyItem("MISC45")
TakePartyItem("NTBLUN06")
~ GOTO Tells3
END

IF ~~ THEN BEGIN Tells3
  SAY @11
  IF ~~ THEN GOTO Tells4
END

IF ~~ THEN BEGIN Tells4
  SAY @12
  IF ~~ THEN DO ~SetGlobal("KelddatMakesNewBlunt","GLOBAL",1)
SetGlobal("KelddatTalkNewBlunt","GLOBAL",2)
DestroyItem("MISC45")
DestroyItem("NTBLUN06")
SmallWait(5)
ForceSpell(Myself,CLERIC_DRAW_UPON_HOLY_MIGHT)
SmallWait(5)
GiveItemCreate("NTBLUN07",LastTalkedToBy,0,0,0)
~ EXIT
END

IF ~~ THEN BEGIN TellsAid
  SAY @13
  IF ~~ THEN REPLY @14 DO ~StartStore("tem3402",LastTalkedToBy(Myself))~ EXIT
  IF ~~ THEN REPLY @15 EXIT
END

END