IF
	GlobalLT("BansheeFight","GLOBAL",3)
	See(NearestEnemyOf(Myself))
	HPLT(Myself,20)
THEN
	RESPONSE #100
		SetGlobal("BansheeFight","GLOBAL",3)
		Wait(2)
		ForceSpell(NearestEnemyOf(Myself),WIZARD_CONFUSION)
		Wait(2)
		EquipMostDamagingMelee()
		PlaySound("Sirin04")
		Attack(NearestEnemyOf(Myself))
END

IF
	Global("BansheeFight","GLOBAL",0)
	See(NearestEnemyOf(Myself))
THEN
	RESPONSE #100
                PlaySound("EFF_M89")
	        ForceSpell(NearestEnemyOf(Myself),WIZARD_WAIL_OF_THE_BANSHEE)
		Wait(2)
		ForceSpell(NearestEnemyOf(Myself),WIZARD_CONFUSION)
		Wait(2)
		PlaySound("Sirin06")
		ForceSpell(Myself,SUCCUBUS_ETHEREAL)
		SetGlobal("BansheeFight","GLOBAL",1)
		RunAwayFromNoInterrupt(NearestEnemyOf(Myself),90)
END

IF
	Global("BansheeFight","GLOBAL",1)
	See(NearestEnemyOf(Myself))
THEN
	RESPONSE #50
		Wait(2)
		ForceSpell(NearestEnemyOf(Myself),WIZARD_CONFUSION)
		Wait(2)
		PlaySound("Sirin06")
		ForceSpell(Myself,SUCCUBUS_ETHEREAL)
		RunAwayFromNoInterrupt(NearestEnemyOf(Myself),90)
	RESPONSE #50
		Wait(2)
		ForceSpell(NearestEnemyOf(Myself),WIZARD_CONFUSION)
		Wait(2)
		PlaySound("Sirin06")
		ForceSpell(Myself,SUCCUBUS_ETHEREAL)
		SetGlobal("BansheeFight","GLOBAL",2)
		RunAwayFromNoInterrupt(NearestEnemyOf(Myself),90)
END

IF
	Global("BansheeFight","GLOBAL",2)
	See(NearestEnemyOf(Myself))
THEN
	RESPONSE #75
		EquipMostDamagingMelee()
		PlaySound("Sirin04")
		AttackOneRound(NearestEnemyOf(Myself))
		RunAwayFromNoInterrupt(NearestEnemyOf(Myself),60)
		AttackOneRound(NearestEnemyOf(Myself))
		RunAwayFromNoInterrupt(NearestEnemyOf(Myself),60)
		Wait(2)
		PlaySound("Sirin06")
		ForceSpell(Myself,SUCCUBUS_ETHEREAL)
		SetGlobal("BansheeFight","GLOBAL",1)
		RunAwayFromNoInterrupt(NearestEnemyOf(Myself),60)
	RESPONSE #25
		Wait(2)
		PlaySound("EFF_M89")
		ForceSpell(NearestEnemyOf(Myself),WIZARD_WAIL_OF_THE_BANSHEE)
		Wait(2)
		PlaySound("Sirin06")
		ForceSpell(Myself,SUCCUBUS_ETHEREAL)
		SetGlobal("BansheeFight","GLOBAL",1)
		RunAwayFromNoInterrupt(NearestEnemyOf(Myself),90)
END
