IF
	Delay(5)
	Global("Roach","GLOBAL",0)
THEN
	RESPONSE #100
		ForceSpell(Myself,SUCCUBUS_ETHEREAL)
		SetGlobal("Roach","GLOBAL",1)
		Continue()
END

IF
	Exists(NearestEnemyOf(Myself))
	Range(NearestEnemyOf(Myself),60)
	!Range(NearestEnemyOf(Myself),1)
	Global("Roach","GLOBAL",1)
THEN
	RESPONSE #100
		Shout(4)
		ForceSpell(NearestEnemyOf(Myself),TRAP_FIREBALL)
		Wait(2)
		ForceSpell(NearestEnemyOf(Myself),GATE_LESSER_DEMONS)
		ForceSpell(NearestEnemyOf(Myself),TANARI_SILENCE)
		SetGlobal("Roach","GLOBAL",2)
		Continue()
END

IF
	See(NearestEnemyOf(Myself))
	Range(NearestEnemyOf(Myself),10)
	!Range(NearestEnemyOf(Myself),1)
	Global("Roach","GLOBAL",2)
THEN
	RESPONSE #100
		ForceSpell(NearestEnemyOf(Myself),SUCCUBUS_ENERGY_DRAIN)
		EquipMostDamagingMelee()
		AttackOneRound(NearestEnemyOf(Myself))
		ForceSpell(NearestEnemyOf(Myself),PAIN)
		AttackReevaluate(LastAttackerOf(Myself),10)
		SetGlobal("Roach","GLOBAL",3)
		Continue()
END

IF
	See(NearestEnemyOf(Myself))
	HPPercentLT(Myself,50)
	Global("Roach","GLOBAL",3)
THEN
	RESPONSE #100
		ForceSpell(NearestEnemyOf(Myself),TANARI_VAMPIRIC_TOUCH)
		SmallWait(5)
		ForceSpell(NearestEnemyOf(Myself),TANARI_DEATH_GAZE)
		SmallWait(5)
		SetGlobal("Roach","GLOBAL",4)
		EquipMostDamagingMelee()
		AttackReevaluate(NearestEnemyOf(Myself),10)
		Continue()
END

IF
	See(NearestEnemyOf(Myself))
	HPPercentLT(Myself,50)
	!Global("Roach","GLOBAL",3)
THEN
	RESPONSE #100
		ForceSpell(NearestEnemyOf(Myself),TRAP_FIREBALL)
		SmallWait(5)
		SetGlobal("Roach","GLOBAL",4)
		EquipMostDamagingMelee()
		AttackReevaluate(NearestEnemyOf(Myself),10)
		Continue()
END

IF
	!HPPercentLT(Myself,25)
	Global("Roach","GLOBAL",4)
THEN
	RESPONSE #100
		ReallyForceSpell(NearestEnemyOf(Myself),TANARI_VAMPIRIC_TOUCH)
		SetGlobal("Roach","GLOBAL",2)
		Continue()
END


