IF
    Clicked([ANYONE])
    Range(LastTrigger,2)
    Global("Tele2","AR2200",0)
THEN
    RESPONSE #100
        SetGlobal("Tele2","AR2200",1)
        SetGlobal("Tele3","GLOBAL",0)
        DisplayString(Myself,@0) // The controls on this Spelljammer has been automatically set to go to a certain destination. All you have to do is to press this button here...
END

IF
    Clicked([ANYONE])
    Range(LastTrigger,2)
    Global("Tele3","GLOBAL",1)
THEN
    RESPONSE #100
        SetGlobal("Tele2","AR2200",2)
        DisplayString(Myself,@1) // The device is of no further use to me. I have returned it.
END

IF
    Clicked([ANYONE])
    Range(LastTrigger,2)
    Global("Tele2","AR2200",1)
THEN
    RESPONSE #100
        SaveGame(0)
        FadeToColor([20.0],0)
        PlaySound("EFF_M28")
        Wait(1)
        MultiPlayerSync()
        ActionOverride(Player1,LeaveAreaLUAPanic("AR2806","",[1799.2065],2))
        ActionOverride(Player1,LeaveAreaLUA("AR2806","",[1799.2065],2))
        ActionOverride(Player2,LeaveAreaLUA("AR2806","",[1753.2062],2))
        ActionOverride(Player3,LeaveAreaLUA("AR2806","",[1826.2025],2))
        ActionOverride(Player4,LeaveAreaLUA("AR2806","",[1773.2010],2))
        ActionOverride(Player5,LeaveAreaLUA("AR2806","",[1839.1980],2))
        ActionOverride(Player6,LeaveAreaLUA("AR2806","",[1790.1963],2))
        ActionOverride(Player1,MultiPlayerSync())
END

IF
    Clicked([ANYONE])
    !Range(LastTrigger,2)
THEN
    RESPONSE #100
        DisplayString(Myself,14702) // You are too far away to use that.
END
