IF
    Clicked([ANYONE])
    Range(LastTrigger,5)
    Global("Tele4","AR2806",0)
THEN
    RESPONSE #100
        SetGlobal("Tele4","AR2806",1)
        SetGlobal("Tele3","GLOBAL",1)
        DisplayString(Myself,@0) // This landing cage will take me back to the Spelljammer. Fortunately the controls of the Spelljammer has also been set to return me from whence I came. However I will not be able to return here.
END

IF
    Clicked([ANYONE])
    Range(LastTrigger,5)
    GlobalGT("Tele4","AR2806",0)
THEN
    RESPONSE #100
        SaveGame(0)
        FadeToColor([20.0],0)
        PlaySound("EFF_M28")
        Wait(1)
        MultiPlayerSync()
        ActionOverride(Player1,LeaveAreaLUAPanic("AR2200","",[3213.2140],14))
        ActionOverride(Player1,LeaveAreaLUA("AR2200","",[3213.2140],14))
        ActionOverride(Player2,LeaveAreaLUA("AR2200","",[3247.2177],14))
        ActionOverride(Player3,LeaveAreaLUA("AR2200","",[3177.2166],14))
        ActionOverride(Player4,LeaveAreaLUA("AR2200","",[3206.2144],14))
        ActionOverride(Player5,LeaveAreaLUA("AR2200","",[3151.2129],14))
        ActionOverride(Player6,LeaveAreaLUA("AR2200","",[3174.2118],14))
        ActionOverride(Player1,MultiPlayerSync())
END

IF
    Clicked([ANYONE])
    !Range(LastTrigger,5)
THEN
    RESPONSE #100
        DisplayString(Myself,14702) // You are too far away to use that.
END


