IF
    Clicked([ANYONE])
    Range(LastTrigger,9)
    Global("Tele1","AR0602",0)
THEN
    RESPONSE #100
        SetGlobal("Tele1","AR0602",1)
        DisplayString(Myself,@0) // "Warning! This area is currently unstable, you will not be able to return. Only exit if you have completed all your tasks."
END

IF
    Clicked([ANYONE])
    Range(LastTrigger,9)
    GlobalGT("Tele1","AR0602",0)
THEN
    RESPONSE #100
        SaveGame(0)
        SetGlobal("Char59","GLOBAL",1)
        DisplayStringHead(Myself,@1) // "Warning! Emergency shutdown in progress. Please proceed to the nearest exit."
        ScreenShake([3854.2462],10)
        ScreenShake([3003.609],10)
        FadeToColor([20.0],0)
        PlaySound("EFF_M28")
        FadeFromColor([20.0],0)
        Wait(3)
        MultiPlayerSync()
        ActionOverride(Player1,LeaveAreaLUAPanic("AR1608","",[186.220],14))
        ActionOverride(Player1,LeaveAreaLUA("AR1608","",[186.220],14))
        ActionOverride(Player2,LeaveAreaLUA("AR1608","",[220.201],14))
        ActionOverride(Player3,LeaveAreaLUA("AR1608","",[152.200],14))
        ActionOverride(Player4,LeaveAreaLUA("AR1608","",[189.182],14))
        ActionOverride(Player5,LeaveAreaLUA("AR1608","",[121.172],14))
        ActionOverride(Player6,LeaveAreaLUA("AR1608","",[152.156],14))
        ActionOverride(Player1,MultiPlayerSync())
END

IF
    Clicked([ANYONE])
    !Range(LastTrigger,9)
THEN
    RESPONSE #100
        DisplayString(Myself,14702) // You are too far away to use that.
END


