BEGIN d_gBF7st // Quest 7 Bandits and Thieves, Ex-Shadow Thief dialogue

IF ~True()~ THEN BEGIN 0
	SAY ~I left for a reason, and I’m not going back! You won’t take me alive!~
	++ ~Wait, what? Why don’t we talk first?~ GOTO letsTalk
	++ ~I don’t intend to.~ GOTO fightingWords
END

IF ~~ THEN BEGIN letsTalk
	SAY ~What? You mean… Mae’var didn’t send you? What are you doing here then?~
		++ ~Eloran, a Lathanderite cleric, sent me here to investigate Shadow Thief activity. Now, what are you doing here?~ GOTO eloExplain
		++ ~Oh, you know. Just going for a stroll.~ GOTO wiseGuy
END

IF ~~ THEN BEGIN wiseGuy
	SAY ~Don’t get smart with me. You’re here for me, aren’t you?~
	++ ~That depends. Eloran, a Lathanderite cleric, sent me here to investigate Shadow Thief activity. Now, what are you doing here?~ GOTO eloExplain
END

IF ~~ THEN BEGIN eloExplain
	SAY ~There aren’t any Shadow Thieves here. I wouldn’t be here if there were. I’m… I’m here to avoid the Shadow Thieves. I’m not stupid. I know that I can’t expect to be accepted after the things I’ve done, but I’m not going to sit around alone waiting for Mae’var’s dogs to find me. There’s safety in numbers, see? The bandits can’t be as bad as my old group, and if I stick with them, maybe my old associates will think twice about going after me, see?~
	++ ~Do you actually want to join the bandits, or are you just doing this because you feel you have no other choice?~ GOTO goodWords
	++ ~If the bandits are less bad, you must’ve done some heinous things. You deserve death for what you’ve done.~ GOTO fightingWords
END

IF ~~ THEN BEGIN goodWords
	SAY ~My choices are to join the bandits, or roll over and die. Don’t you dare presume to judge me!~
	++ ~There’s a third choice: go to the Temple of Lathander in Beregost and speak to Eloran. Repent, and become better than you were before.~ GOTO okFine	
END

IF ~~ THEN BEGIN okFine
	SAY ~A Lathanderite couldn’t be worse than the Shadow Thieves or these bandits.~
IF ~~ THEN DO ~
 SetGlobal("gBFq7","GLOBAL",2) EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN fightingWords
	SAY ~I won't go down easily!~ IF ~~ THEN DO ~
ActionOverride("g_thief",Enemy()) ~ EXIT
END

	

