BEGIN d_gBFlov //The Loviatan, Loviatan Dialogue

IF ~PartyHasItem("RING05")~ THEN BEGIN 0
	SAY @12000 /* Have you come to suffer? */
	++ @12001 /* I have this invisibility ring from Eloran for you. They’ll help you hide from the paladins and the Fist. */ GOTO missionDo
	++ @12002 /* Shouldn’t you be trying to convince me to spare you? */ GOTO spareYou
	++ @12003 /* No, but you’re about to. */ GOTO fightingWords
END

IF ~~ THEN BEGIN missionDo
	SAY @12004 /* Eloran? I know she’s not one of the Ilmateri here. Who is she and why does she think to give me this ring? */
	++ @12005 /* She’s a fool, is what she is. Now, are you going to take the ring or not? */ GOTO eloFool
	++ @12006 /* She’s a Lathanderite and has taken pity on your plight. */ GOTO eloPity
	++ @12007 /* She’s a Lathanderite, though to be honest, I’m not sure why she’d do this either. */ GOTO eloIDK
END

IF ~~ THEN BEGIN eloFool
	SAY @12008 /* Then you are a fool for listening to her. But I'll take the ring. I doubt you'll see me again. */IF ~~ THEN DO ~
   SetGlobal("gBFq13","GLOBAL",2) TakePartyItem("RING05")  EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN eloPity
	SAY @12009 /* I don’t need anyone’s pity, and certainly not from–nevermind. I'll take the ring. I doubt you'll see me again. */IF ~~ THEN DO ~
   SetGlobal("gBFq13","GLOBAL",2) TakePartyItem("RING05") EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN eloIDK
	SAY @12010 /* 	Then I don’t know why you’d listen to her, but I’ll take the ring. I doubt you'll see me again. */IF ~~ THEN DO ~
   SetGlobal("gBFq13","GLOBAL",2) TakePartyItem("RING05") EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN spareYou
	SAY @12011 /* You expected a Loviatan - I’m playing my part in this, as you surely will. Go on, do what heroes are supposed to do. */
	++@12012 /* I just wanted to talk to you. I heard you’d repented. How does a Loviatan end up making amends with Ilmater? */ GOTO backstory
	++ @12013 /* I'll just kill you then. */ GOTO fightingWords
END

IF ~~ THEN BEGIN backstory
	SAY @12014 /* I was a slave in Dambrath and gained Loviatar’s favor through my ability to suffer without flinching. It was a useful skill for a slave. Eventually, I was able to flee. Along the way, I met a group of monks. They…. They treated me like a person. They were Ilmateri, and treated me well, despite my faith in Loviatar. Life is suffering, but I didn’t really realize that there were gods out there to alleviate suffering rather than inflict it and teach you to shoulder it. I feel guilty for my service to Loviatar, but is not guilt a form of psychological pain? Am I still serving a god I no longer worship? I don’t know. And I want to speak with the Ilmateri here, perhaps find answers. Are you satisfied? */
	++ @12015 /* I have this invisibility ring from Eloran for you. It'll help you hide from the paladins and the Fist. */ GOTO missionDo
	++ @12016 /* No. I'm going to kill you. */ GOTO fightingWords
END

IF ~~ THEN BEGIN fightingWords
	SAY @12017 /* As I expected. I don’t know why I thought - never mind that. I'll die here, but not before I make you bleed. */ IF ~~ THEN DO ~
	ActionOverride("g_lovi",Enemy()) ~ EXIT
END

