APPEND P#SALOB

//NPC-Initiated Flirts

IF ~Global("P#SalomeyaFlirtEarly","GLOBAL",2)~ THEN BEGIN P#SalomeyaFlirt0
SAY @0 /* ~(Salomeya is a beautiful, elegant, often distant and merciless woman. But sometimes she's playful. Her moods are difficult to predict.)~ */
IF ~RandomNum(72,1)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.1
IF ~RandomNum(72,2)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.2
IF ~RandomNum(72,3)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.3
IF ~RandomNum(72,4)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.4
IF ~RandomNum(72,5)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.5
IF ~RandomNum(72,6)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.6
IF ~RandomNum(72,7)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.7
IF ~RandomNum(72,8)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.8
IF ~RandomNum(72,9)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.9
IF ~RandomNum(72,10)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.10
IF ~RandomNum(72,11)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.11
IF ~RandomNum(72,12)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.12
IF ~RandomNum(72,13)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.13
IF ~RandomNum(72,14)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.14
IF ~RandomNum(72,15)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.15
IF ~RandomNum(72,16)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.16
IF ~RandomNum(72,17)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.17
IF ~RandomNum(72,18)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.18
IF ~RandomNum(72,19)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.19
IF ~RandomNum(72,20)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.20
IF ~RandomNum(72,21)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.21
IF ~RandomNum(72,22)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.22
IF ~RandomNum(72,23)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.23
IF ~RandomNum(72,24)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.24
IF ~RandomNum(72,25)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.25
IF ~RandomNum(72,26)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.26
IF ~RandomNum(72,27)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.27
IF ~RandomNum(72,28)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.28
IF ~RandomNum(72,29)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.29
IF ~RandomNum(72,30)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.30
IF ~RandomNum(72,31)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.31
IF ~RandomNum(72,32)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.32
IF ~RandomNum(72,33)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.33
IF ~RandomNum(72,34)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.34
IF ~RandomNum(72,35)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.35
IF ~RandomNum(72,36)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.36
IF ~RandomNum(72,37)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.37
IF ~RandomNum(72,38)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.38
IF ~RandomNum(72,39)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.39
IF ~RandomNum(72,40)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.40
IF ~RandomNum(72,41)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.41
IF ~RandomNum(72,42)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.42
IF ~RandomNum(72,43)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.43
IF ~RandomNum(72,44)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.44
IF ~RandomNum(72,45)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.45
IF ~RandomNum(72,46)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.46
IF ~RandomNum(72,47)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.47
IF ~RandomNum(72,48)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.48
IF ~RandomNum(72,49)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.49
IF ~RandomNum(72,50)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.50
IF ~RandomNum(72,51)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.51
IF ~RandomNum(72,52)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.52
IF ~RandomNum(72,53)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.53
IF ~RandomNum(72,54)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.54
IF ~RandomNum(72,55)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.55
IF ~RandomNum(72,56)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.56
IF ~RandomNum(72,57)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.57
IF ~RandomNum(72,58)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.58
IF ~RandomNum(72,59)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.59
IF ~RandomNum(72,60)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.60
IF ~RandomNum(72,61)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.61
IF ~RandomNum(72,62)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.62
IF ~RandomNum(72,63)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.63
IF ~RandomNum(72,64)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.64
IF ~RandomNum(72,65)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.65
IF ~RandomNum(72,66)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.66
IF ~RandomNum(72,67)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.67
IF ~RandomNum(72,68)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.68
IF ~RandomNum(72,69)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.69
IF ~RandomNum(72,70)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.70
IF ~RandomNum(72,71)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.71
IF ~RandomNum(72,72)~ THEN DO ~SetGlobalTimer("P#SalomeyaFlirtEarlyTime","GLOBAL",587)  SetGlobal("P#SalomeyaFlirtEarly","GLOBAL",3)~ GOTO P#SalomeyaFlirt.72
END

IF ~~  P#SalomeyaFlirt.72
SAY @1 /* ~(She's balancing gracefully on one foot, shaking a stone out of her shoe.)~ */
= @2 /* ~Next time I set out adventuring it will be in a sedan chair carried by eight strong slaves.~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.71
SAY @3 /* ~Every one of my dance-masters told me that my feet were made for dancing. Though each of them named a different dance their favorite, of course. ~ */
= @4 /* ~The point, is that my beautiful legs are obviously wasted on walking.~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.70
SAY @5 /* ~(Salomeya lifts herself on tiptoe and draws a semi-circle in front of herself with one foot. A very small, neatly booted foot.)~ */
= @6 /* ~I bet that my foot could fit into your palm...~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.69
SAY @7 /* ~(One of the backpack straps ran under Salomeya's breasts pulling the fabric tight, and simultaneously lifting the soft, rounded mound.)~ */
= @8 /* ~Ah, so inappropriate! Will you help me straighten it out?~ */
++ @9 /* ~(Run the second strap under Salomeya's other breast, making her bosom appear quite perky.)~ */ + P#SalomeyaFlirt.69.1
++ @10 /* ~(Free Salomeya's breast out of the trap.)~ */ + P#SalomeyaFlirt.69.2
++ @11 /* ~No, you do it yourself.~ */ + P#SalomeyaFlirt.69.3
END

IF ~~ P#SalomeyaFlirt.69.3
SAY @12 /* ~(She does so in a deliberately tender manner, managing a caress with her thumb in the process.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.69.2
SAY @13 /* ~This is so much better! (She hugs herself with her arm, squeezing the breasts to be tighter and fuller under the silk.) Oops....~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.69.1
SAY @14 /* ~Hmm, I wouldn't have minded that, but I can't see my feet now.~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.68
SAY @15 /* ~(She fusses with a necklace. The shiny drop of stone finally slides to where Salomeya wants it to be - in the lovely cove between her breasts, touching one or another in turn, as the bard walks.)~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.67
SAY @16 /* ~(Salomeya runs her palm along your hip.)~ */
= @17 /* ~Strong legs are good in a man.~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.66
SAY @18 /* ~(Salomeya smoothes silk dress over her pleasantly round hip. You can now see the curve from her waist down. There's something of a lute in her shape.)~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.65
SAY @19 /* ~(Salomeya puts her arms on her hips. Strangely, she doesn't look like a goodwife about to upbraid her kids. She looks powerful and statuesque.)~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.64
SAY @20 /* ~(Salomeya pinches your nose slightly.) Don't put it too high in the air, darling. People expect modesty in their heroes, missing the obvious truth that only those who know their worth deserve fame.~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.63
SAY @21 /* ~(Salomeya wrinkles her pretty little nose.) Ah, if only more critters around here used soap and perfumes!~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.62
SAY @22 /* ~(Salomeya takes your face between her palms and looks into your eyes.)~ */
= @23 /* ~Careful maidens shouldn't do this, they risk losing their maidenheads. Luckily, I know how to handle boys with enticing eyes. Not that I'm concerned about my virginity, of course.~ */
++ @24 /* ~Maybe you're concerned about the different sort of virginity - that of your heart that no man ever took.~ */ + P#SalomeyaFlirt.62.1
++ @25 /* ~What are you concerned about then?~ */ + P#SalomeyaFlirt.62.2
++ @26 /* ~Heh, let's go, funny bard.~ */ EXIT
END

IF ~~ P#SalomeyaFlirt.62.2
SAY @27 /* ~Nothing. I'm not a careful maiden, and never was.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.62.1
SAY @28 /* ~You might be man enough for me to eventually open my legs for you, but not my heart.~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.61
SAY @29 /* ~(She musses up your hair and then pushes it out of your eyes.) I'll feel maternal any moment now....~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.60
SAY @30 /* ~Some things one can truly appreciate only when they're gone. (She closes her eyes for a moment. She's right: her face is still beautiful, but it lacks the emerald pools of her eyes.)~ */
++ @31 /* ~(Kiss her.)~ */ + P#SalomeyaFlirt.60.1
++ @32 /* ~Remember to keep your eyes open when we make love.~ */ + P#SalomeyaFlirt.60.2
++ @33 /* ~I don't need this reminder. I know how beautiful your eyes are.~ */ + P#SalomeyaFlirt.60.3
END

IF ~~  P#SalomeyaFlirt.60.3
SAY @34 /* ~Trust you to come up with a fitting platitude!~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.60.2
SAY @35 /* ~(She laughs long and merrily.)~ */
IF ~~ THEN EXIT
END

IF ~~  P#SalomeyaFlirt.60.1
SAY @36 /* ~(She avoids your kiss easily.) A skilled swordsman can fight in utter darkness. And I don't need to see to know I'm about to get kissed.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.59
SAY @37 /* ~Oh, Beshaba, the more time we spend here, the more I fear turning into a wild woman, running around in bits of still tastefully selected furs, my hair flowing behind me on the wind, my eyes burning bright with feral desires and singing feverish hymns to the vales and dales....~ */
= @38 /* ~I suspect some men would find that attractive.~ */
++ @39 /* ~He-he, yes, to be honest.~ */ +  P#SalomeyaFlirt.59.1
++ @40 /* ~Only if the wildling possesses a need for uninhibited, wild copulating... as a ritual, of course.~ */ +  P#SalomeyaFlirt.59.2
++ @41 /* ~I'm not that fond of twigs in my women's hair.~ */ +  P#SalomeyaFlirt.59.3
++ @42 /* ~No, I find it off-putting when a woman rips bloody carcasses apart with her teeth and nails and the like.~ */ +  P#SalomeyaFlirt.59.4
END

IF ~~ P#SalomeyaFlirt.59.4
SAY @43 /* ~I can see how something like that could subtract some pleasure from kissing... and all these women dreaming of a noble savage for a lover. Brr!~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.59.3
SAY @44 /* ~Or the bones of small birds... or maybe even whole birds? Beshaba, punish me however you wish, but not with messy hair!~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.59.2
SAY @45 /* ~Me praying this way could turn plenty of men pious.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.59.1
SAY @46 /* ~Oh, I can just see you thinking of it while your daddy lectured you about ladies' honor and similar nonsense.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.58
SAY @47 /* ~(Brushing a knot out of her hair.) Wonderful, I have the wind for a hairdresser! What's next? Bathing in a frozen creek instead of a tub? Ah, wait, we've already done that.~ */
= @48 /* ~(Sigh.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.57
SAY @49 /* ~(The waft throws a strand of Salomeya's hair into your face. It tickles you gently in passing and smells of something exquisitely bitter and outrageously expensive.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.56
SAY @50 /* ~(Salomeya writes something in her journal, then stops and stares at her quill.)~ */
= @51 /* ~No! You've got it all wrong! It sounded so much better in my head!~ */
= @52 /* ~(Looks around.) But even with your incompetence, the verse is still magnificent and so much better than anything else written nowadays.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.55
SAY @53 /* ~(Salomeya's nibbling the end of her quill, absentmindedly... )~ */
= @54 /* ~(...the wrong end of the quill. Before she's alerted to her mistake, dark ink stains her lips. Strangely, it doesn't spoil her bright, eye-catching beauty.) ~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.54
SAY @55 /* ~(Somewhere Salomeya picked up a bunch of bright white feathers from some northern bird and now she's braided it into a small tight braid crowning her head.) ~ */
= @56 /* ~(She looks at you critically, the feathers bright and proud.) I suppose that moss will do for you.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.53
SAY @57 /* ~(As she walks, Salomeya braids her hair into a lazy, thick braid. She releases it, and it hangs down swinging above her small round bottom like a pendulum. The hair is too thick for it to unwind.) ~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.52
SAY @58 /* ~(Salomeya purses her lips.)~ */
= @59 /* ~Tiresome clime, tiresome landscape, tiresome quest and... (a pointed glance in your direction) ...tiresome men.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.51
SAY @60 /* ~(Salomeya touches her upper lip with her tongue, then draws it back, leaving her mouth slightly open, ready for a kiss, for a few heartbeats.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.50
SAY @61 /* ~(Salomeya licks her lips with the tip of her tongue, slowly, as if her mouth is full of thick honey.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.49
SAY @62 /* ~(Salomeya throws the ends of her shawl back, so it covers her throat. Now a seductive white triangle of skin is visible between the edge of her shawl and the deep cut of her corsage.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.48
SAY @63 /* ~(She tugs at her shawl a few times, obviously nervous about something, then in one decisive move pulls it off her shoulders and ties it about her waist like a belt.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.47
SAY @64 /* ~(Salomeya spends quite some time arranging the shawl around her shoulders to her satisfaction. Finally, she settles on a loose draping that leaves her neck and one shoulder bare, but covers both arms to the elbow.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.46
SAY @65 /* ~My shoes, my poor, poor shoes! (While crestfallen on the account of ruined footwear, Salomeya doesn't forget to lift her skirts to the magic height that reveals just enough to titillate the spectator.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.45
SAY @66 /* ~(Salomeya lifts her skirts slightly). Could you massage my ankle, darling? All this glorious wandering has given me a cramp.~ */
++ @67 /* ~(Take her ankle and give it a massage.)~ */ +  P#SalomeyaFlirt.45.1
++ @68 /* ~(Stroke the nice, smooth ankle.)~ */ +  P#SalomeyaFlirt.45.2
++ @69 /* ~Only if you promise to wash my feet in return!~ */ +  P#SalomeyaFlirt.45.3
END

IF ~~ P#SalomeyaFlirt.45.3
SAY @70 /* ~Will that be with my hair? If you want to make a fool out of yourself, at least be imaginative about it.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.45.2
SAY @71 /* ~(Salomeya kicks you lightly in the chest, but manages to upset your balance enough for you to let go off her foot, and almost fall down.)~ */
= @72 /* ~Next time you dare disobey me, you *will* end up on your face, darling.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.45.1
SAY @73 /* ~Ah, very good, darling, very good.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.44
SAY @74 /* ~(Salomeya clasps her hands behind her back, stretching her shoulders, offering you a side view of her torso and her bosom over it like a sail filled with wind.).~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.43
SAY @75 /* ~(Salomeya stretches languidly, presenting you with a view of her arching back, the waist that looks even narrower when she stretches upward, and a slow fall of the heavy waves of her red hair as she leans her head back to stretch her neck.).~ */
IF ~~ THEN EXIT
END


IF ~~ P#SalomeyaFlirt.42
SAY @76 /* ~Pocket change and trinkets. Feh, I am starting to think that the profitability of adventuring is strongly exaggerated. After all, I've heard one can win a *fortune* adventuring.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.41
SAY @77 /* ~(She leans onto you and whispers into your ear.) Don't worry, oh legend in making. Yes, yet again we've killed everyone and it served other people's interests, not your own. They say that the third time's the charm. For men like you they make accommodations, like hundredth time the charm, or even thousandth….~ */
= @78 /* ~So one of these days you'll understand that you should turn the situation to your advantage. ~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.40
SAY @79 /* ~(She gives you a critical look.) You're becoming manlier, boy. Keep it up, and perhaps I will stop looking for someone to wet-nurse you. ~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.39
SAY @80 /* ~(She passes her fingers along a raised cheekbone, then down her jaw to her chin.) I think that the suffering and cruel need gave me a bit of a martyr look. ~ */
= @81 /* ~I remember it suited me, but alas, it's so passé. ~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.38
SAY @82 /* ~(She touches her temple lightly.) I have such a headache….~ */
= @83 /* ~But nothing that cannot be cured by a luxurious scented bath and a few exotic slaves dancing for my pleasure… just not singing. I can't abide pathetic attempts to outdo me.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.37
SAY @84 /* ~(Salomeya removes one of her earrings.) Ouf, that's so much better. Do massage my earlobe, darling.~ */
++ @85 /* ~(Softly pinch her earlobe between your fingers and massage.)~ */ + P#SalomeyaFlirt.37.1
++ @86 /* ~(Take the earlobe between your lips and suck on it gently.) ~ */ + P#SalomeyaFlirt.37.2
++ @87 /* ~Just wear lighter earrings, woman. You don't really need to store pounds of gold and precious stones there.~ */ + P#SalomeyaFlirt.37.3
++ @88 /* ~Leave me be.~ */ EXIT
END

IF ~~ P#SalomeyaFlirt.37.3
SAY @89 /* ~So, you know nothing of fashion or rainy days, boy. Well, what else can one expect from a paladin's whelp?~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.37.2
SAY @90 /* ~Daaarling, but this is most unexpected of you. (She plays with your hair.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.37.1
SAY @91 /* ~Enough, enough! Oh, Beshaba, you didn't even know to wash your hands and scent them before touching my precious ears!~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.36
SAY @92 /* ~(She plays with her earrings. Or, to be more precise, she shows off the lovely shape of her little ear, the elegance of her fingers and the perfect white of her neck.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.35
SAY @93 /* ~(She looks directly at you.) I so adore handsome men….~ */
= @94 /* ~Too bad there are none around.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.34
SAY @95 /* ~(She taps you on the shoulder with a brightly painted and polished nail.)~ */
= @96 /* ~Darling, I think I could use a bonus. Jewelry, if you don't mind. *Valuable* jewelry.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.33
SAY @97 /* ~I will have to cover the story of those who follow you as well.~ */
= @98 /* ~Hmm, at least I have a good start: 'A gloriously beautiful and incredibly talented bard, thrown in with a gang of misfits by the cruel hand of destiny- etc, etc, etc.' I want the audience to *weep* with pity for me and cheer my every accomplishment and….~ */
= @99 /* ~Ah, yes… yes.  I forgot again: it's your story, your story, your story!~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.32
SAY @100 /* ~I'm starting to think that a good love story will be beneficial to my saga. Now, I just need to figure out how to describe you falling in love.~ */
= @101 /* ~Here, lean toward me and look into my eyes… yes, like this. I think I am starting to see something interesting there… ~ */
= @102 /* ~Yes, you must be getting hungry!~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.31
SAY @103 /* ~I think I am starting a trend… a trend for bards to throw in their lot with novice adventurers and go save the world.~ */
= @104 /* ~That would take care of the rivals nicely. I just need to make sure that the market is over-saturated with accounts like that by the time they start returning.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.30
SAY @105 /* ~I can't quite decide if I want to present you as a hero or as an anti-hero. Of course, an anti-hero is an easier sell, because, let's face it, people believe they are original, but then again, it's a hero, pure white hero that *is* original… or at least it was the month I left Waterdeep.~ */
= @106 /* ~For all I know, the courts are teeming with bards singing the praises of pristine, flawless heroes…. (Sigh).~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.29
SAY @107 /* ~Oh, Beshaba, you *slouch*! I have heard about blind heroes, deaf heroes, one-handed heroes, hells, for all I know there were headless heroes, but slouching is so completely un-heroic. Hmm, maybe we should disembody you and carry your head as a symbolic thing?~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.28
SAY @108 /* ~Yo, paladin's son! Is world-saving proceeding on schedule? ~ */
= @109 /* ~Oh, don't wrack your little brain for a reply. Obviously the point was asking the question, not getting an answer.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.27
SAY @110 /* ~Why does saving the world always have to happen in dirty dungeons, dark caves, stinky bogs and other unappealing places? I suppose it's living in a hellhole like this that makes evil overlords want to conquer the world, but still….~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.26
SAY @111 /* ~(A petulant little yawn.) I couldn't sleep at all last night, thanks to you. ~ */
= @112 /* ~The moment I closed my beautiful eyes, I saw the same nightmare: you having to save the world. How the world could stoop so low still puzzles me.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.25
SAY @113 /* ~(Salomeya examines her skirts squarely in front of you.) The hem is muddy.~ */
= @114 /* ~(Her pretty face takes on an expression of saintly patience and forbearance.)  Of course it's not your fault, with you dragging us here. Why, how could it be?!~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.24
SAY @115 /* ~(Salomeya bites into a piece of a stale bread, pouts prettily and directs an accusing glance towards you.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.23
SAY @116 /* ~(A silvery laughter drifts towards you. You know instinctively that Salomeya has shared a private joke with someone.)~ */
= @117 /* ~(The joke is as likely to be about you, as completely innocent but intended to make you sweat thinking that she's laughing at you behind your back.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.22
SAY @118 /* ~(Salomeya flashes you a smile demonstrating even pearl-like teeth between coral lips.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.21
SAY @119 /* ~(Salomeya looks at you, then chuckles delicately covering her mouth with her hand. Then whatever amused her about you gains more and more hold on her, until finally she's laughing something fierce, not making any effort to shield her mouth.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.20
SAY @120 /* ~(Salomeya is trying some complex tune on her lute. She keeps messing up in the same place.~ */
= @121 /* ~Oh, Beshaba, they are like glass in this cold! (Despite her irritation she carefully puts the lute down, and then breathes on her fingers.)~ */
++ @122 /* ~Allow me….~ */ +  P#SalomeyaFlirt.20.1
++ @123 /* ~(Observe further.)~ */ +  P#SalomeyaFlirt.20.2
++ @124 /* ~Keep trying. They say practice makes perfect….~ */ +  P#SalomeyaFlirt.20.3
END

IF ~~ P#SalomeyaFlirt.20.3
SAY @125 /* ~If I wanted anything at all to be said just now, I assure you it was not the platitude you just uttered!~ */
= @126 /* ~(This time the melody progresses past the tripping point and comes to its conclusion safely. The wide smile plays on Salomeya's lips, almost triumphant. She gives you a disdainful gaze.) ~ */
= @127 /* ~If it was not for your idiocy, I'd have had it right the first time.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.20.2
SAY @128 /* ~(This time the melody progresses past the tripping point and comes to its conclusion safely. The wide smile plays on Salomeya's lips, and unexpectedly she kisses your cheek, which seems to leave her surprised and taken aback.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.20.1
SAY @129 /* ~(You take Salomeya's icy fingers between your palms and breathe on them while watching her. As the fingers become warmer, the impatience becomes increasingly transparent upon the bard's face.)~ */
= @130 /* ~That's enough. (She pulls her hands away from you and reaches for her lute.)~ */
IF ~~ THEN GOTO P#SalomeyaFlirt.20.2
END

IF ~~ P#SalomeyaFlirt.19
SAY @131 /* ~(Salomeya is tuning her lute, embracing the yellow curve of the instrument with more tenderness than you have ever seen in her.)~ */
= @132 /* ~(The strings sing this note or that, in the plaintive voice of one plucked string.)~ */
= @133 /* ~I always thought that the way to sing solitude is by cutting all strings but one. Of course it's not something that you'd expect an average listener to understand.~ */
++ @134 /* ~I do.~ */ + P#SalomeyaFlirt.19.1
++ @135 /* ~I don't like this… whining. Give me some jovial tune!~ */ + P#SalomeyaFlirt.19.2
++ @136 /* ~(Shrug.)~ */ EXIT
END

IF ~~ P#SalomeyaFlirt.19.2
SAY @137 /* ~Of course. Why would someone like you choose to exercise what little taste and refinement he's got? Here we go, this one is suitable for peasants and paladin's sons.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.19.1
SAY @138 /* ~You're hardly an average listener, boy.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.18
SAY @139 /* ~The battle cries make me hoarse. Mmgh, I wonder.…~ */
= @140 /* ~Kiss me tenderly, in the even
when the lights go out
on a moonless night.
Kiss me, kiss me… deeeeeeply….~ */
= @141 /* ~(She sings in a lower, sultry, smoky voice, slightly hoarse, slightly breathy, and endlessly erotic.)~ */ 
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.17
SAY @142 /* ~(Salomeya coughs) Oh, no, no! A healing spell, quickly! This horrible cold will be the death of my voice, oh Beshaba, why did I have to come here?!~ */
+ ~OR(2) Class(Player1,CLERIC_ALL) Class(Player1,DRUID_ALL)~  + @143 /* ~I'll heal you, don't worry. You'll sound better than ever, I promise.~ */ + P#SalomeyaFlirt.17.1
++ @144 /* ~Please, grab a potion, songstress. I can't stand the thought of you losing your gift.~ */ + P#SalomeyaFlirt.17.2
++ @145 /* ~Oh, please! It's just a little cough.~ */ + P#SalomeyaFlirt.17.3
++ @146 /* ~Ha! I'd love to see you lose the only two things you truly have - your voice and your beauty. What would you do then? ~ */ + P#SalomeyaFlirt.17.4
END

IF ~~ P#SalomeyaFlirt.17.4
SAY @147 /* ~I'll beg by the palaces of the great if I don't have my own by that time, you fool. Everything should be done in style.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.17.3
SAY @148 /* ~I'm a singer you tone-deaf lout. If you can't possibly comprehend how ruinous it is for me, think about your own skinny behind, and the disastrous consequences of me going hoarse in the middle of my wondrous battle song.~ */ 
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.17.2
SAY @149 /* ~You can't *afford* it, you mean.~ */
= @150 /* ~Ah, where is that potion already?!~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.17.1
SAY @151 /* ~You can do that? Really? (For a short moment she looks vulnerable, childlike and grateful.)~ */
= @152 /* ~Well, what are you waiting for?! I'm suffering, and that cannot be tolerated.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.16
SAY @153 /* ~La-la-laaaa… la-laaa-la….~ */
= @154 /* ~(The singing exercise does not have words that would distract your attention from Salomeya's clear, melodious, powerful voice. It rises and falls with the unknown tune, and when it grows stronger, it truly carries. It's almost like a river swelling in flood in those moments….)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.15
SAY @155 /* ~I miss Waterdeep's continuous buzz and bustle. The silence here… it's dead and deafening.~ */
= @156 /* ~However, my divine voice stands out better.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.14
SAY @157 /* ~(Salomeya takes off all of her rings and arranges them in her lap. Then she holds up her palms for you to inspect.)~ */
= @158 /* ~I can't decide whether they are so beautiful that they do not need any adornments, or if they are so beautiful that only the most precious gems deserve the right to be worn by them.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.13
SAY @159 /* ~My rings are too large for my nervous fingers…. My eyes… look into my eyes!~ */
= @160 /* ~They are greener than ever with the haze of longing…. (She is right. Her eyes *are* impossibly green.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.12
SAY @161 /* ~(Salomeya twists the ring around her slender finger. She must have lost a bit of weight because the ring is too loose.)~ */
= @162 /* ~(If you think about it, you've seen her pass up food absentmindedly of late.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.11
SAY @163 /* ~(Salomeya looks at you, her eyes half-hooded, and her head cocked to one shoulder. )~ */
++ @164 /* ~One copper for your thoughts, Miss.~ */ + P#SalomeyaFlirt.11.1
++ @165 /* ~(Smile at her.)~ */ + P#SalomeyaFlirt.11.2
++ @166 /* ~(Make a little dance.) Does that help?~ */ + P#SalomeyaFlirt.11.2
++ @167 /* ~(Ignore her.)~ */ EXIT
END

IF ~~ P#SalomeyaFlirt.11.4
SAY @168 /* ~Mmgh….~ */
= @169 /* ~Perhaps I will tell you some other time, when you are ready to hear it.~ */
IF ~~ THEN DO ~GiveGoldForce(-1)~ EXIT
END

IF ~~ P#SalomeyaFlirt.11.3
SAY @170 /* ~Yours surely don't.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.11.2
SAY @171 /* ~I'm busy with very important bard things.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.11.1
SAY @172 /* ~My thoughts, unlike yours, are worth their weight in gold.~ */
++ @173 /* ~Meaning that they are worth nothing, because the thoughts have no weight.~ */ + P#SalomeyaFlirt.11.3
++ @174 /* ~Oooh. All right, a gold piece for your thoughts! ~ */ + P#SalomeyaFlirt.11.4
++ @167 /* ~(Ignore her.)~ */ EXIT
END

IF ~~ P#SalomeyaFlirt.10
SAY @175 /* ~(A small shiver creeps up your spine. You are certain that someone's watching you…)~ */
= @176 /* ~(It's Salomeya, and she incinerates you with the green flame of her eyes. If looks could kill, you'd be dead, though the why is left uncertain.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.9
SAY @177 /* ~(Salomeya gives you a smoldering look from under her long, dark eyelashes. )~ */
= @178 /* ~(It's a wonder that metal objects on your persona don't start melting.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.8
SAY @179 /* ~(Salomeya doesn't walk, rather she glides along, with a noticeable sway of her hips.)~ */
= @180 /* ~(You're nearly certain that this sway intensifies when she senses your glance.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.7
SAY @181 /* ~(She's spent quite some time trying to rhyme your name with something or other in three different languages. So far, judging by the rhymes, the resulting poem is not exactly flattering.)~ */
++ @182 /* ~Salomeya, how about… (You suggest a flattering rhyme.)~ */ + P#SalomeyaFlirt.7.1
++ @183 /* ~Heh, why don't you try… (You suggest an insulting rhyme.)~ */ + P#SalomeyaFlirt.7.2
++ @184 /* ~Bring it on! I can take it! ~ */ + P#SalomeyaFlirt.7.3
++ @185 /* ~Oh, stop it, you horrible, horrible woman. ~ */ + P#SalomeyaFlirt.7.4
+~OR(2) Global("P#SalomeyaSnake","GLOBAL",0) GlobalTimerExpired("P#SalomeyaBadJoke","GLOBAL")~ + @186 /* ~Well, I'm not sure about my name, but I think that Salomeya rhymes with a 'snake' perfectly!~ */ DO ~SetGlobal("P#SalomeyaSnake","GLOBAL",1)  ~ + P#SalomeyaFlirt.7.5
+ ~ Global("P#SalomeyaSnake","GLOBAL",1) !GlobalTimerExpired("P#SalomeyaBadJoke","GLOBAL")~ + @186 /* ~Well, I'm not sure about my name, but I think that Salomeya rhymes with a 'snake' perfectly!~ */ + P#SalomeyaFlirt.7.7
++ @187 /* ~If you need to rhyme my name with something, rhyme it with Salomeya.~ */ + P#SalomeyaFlirt.7.6
END

IF ~~ P#SalomeyaFlirt.7.7
SAY @188 /* ~(You have a vivid vision of an avalanche swallowing you whole.)~ */
IF ~~ THEN DO ~SetGlobalTimer("P#SalomeyaBadJoke","GLOBAL",20000)~ EXIT
END

IF ~~ P#SalomeyaFlirt.7.6
SAY @189 /* ~What a quaint suggestion and so 1190's… that it could actually… no, it couldn't.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.7.5
SAY @190 /* ~(Clap, clap, clap.) I hope you're done with being witty for today. Tell another joke at your own risk.~ */
IF ~~ THEN DO ~SetGlobalTimer("P#SalomeyaBadJoke","GLOBAL",20000)~ EXIT
END

IF ~~ P#SalomeyaFlirt.7.4
SAY @191 /* ~Darling, if there is one good thing about this… tundra, it is its vastness. Go find yourself a corner, it shouldn't be difficult.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.7.3
SAY @192 /* ~I'd appreciate *less* interruptions.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.7.2
SAY @193 /* ~I will try to account for you seeing yourself this way, darling.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.7.1
SAY @194 /* ~You have yet to deserve this being put in the same verse as your name.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.6
SAY @195 /* ~(Salomeya is carrying snow in a silver basin for her ritual morning bathing. Silver, snow and her skin all seem to shine white.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.5
SAY @196 /* ~(Salomeya touches two immaculate fingers with coral-red nails to her coral-red lips and sends you a kiss. Tender, exaggerated, mocking… mystifying. )~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.4
SAY @195 /* ~(Salomeya is carrying snow in a silver basin for her ritual morning bathing. Silver, snow and her skin all seem to shine white.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.3
SAY @197 /* ~Ah, I keep forgetting! I must show you how stylish gents wear helmet nowadays at the tournaments. (Salomeya puts a helmet on your head sideways, in a decidedly impractical, but swaggering way.)~ */
++ @198 /* ~I don't need it at all. (Pull the helmet off.)~ */ + P#SalomeyaFlirt.3.1
++ @199 /* ~I'd rather not look like a fool. Especially not a dead fool. (Set the helmet properly.)~ */ + P#SalomeyaFlirt.3.2
++ @200 /* ~Risking my life for the sake of looks and the lady's pleasure? I'm in!~ */ + P#SalomeyaFlirt.3.3
END

IF ~~ P#SalomeyaFlirt.3.3
SAY @201 /* ~Not yet, but if you continue to show promise… perhaps, perhaps… (She smoothes her skirt over her hip.)~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.3.2
SAY @202 /* ~Beauty demands sacrifices. Maybe this will help you stay alive against goblins, but I *guarantee* that the fashionable crowds are going to eat you alive if you show up like that.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.3.1
SAY @203 /* ~Then do bother yourself with some semblance of a hairstyle, darling.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.2
SAY @204 /* ~When… or if we should come together to a civilized place, like Waterdeep for example, please, do me a favor and try to make sure that your equipment is neither too shiny-perfect, nor shabby and covered in little pieces of…~ */
= @205 /* ~(What is this? Goblin brains?) ~ */
= @206 /* ~…goblin brains for example.~ */
= @207 /* ~The former makes people think that you are a pretend hero, who spends his days polishing his armor, and the latter makes a hero look barbaric and witless.~ */
IF ~~ THEN EXIT
END

IF ~~ P#SalomeyaFlirt.1
SAY @208 /* ~(Murmurs to herself.) No, darling, I have no desire whatsoever to look at this matter or any other from your perspective. I'm too perfect to want to view the world through any eyes but my own.~ */
= @209 /* ~Ah, yes, perfect….~ */
IF ~~ THEN EXIT
END

END

