

// ********************************************************************************* //

/* The Imoen-Aerie Friendship */

/* We need to set the "MRAerieFriendshipTimer" when Aerie and Imoen meet in Spellhold... but only
if there's no opportunity for the Aerie-Imoen Romance Conflict above. So only set it if Aerie's
LoveTalks never got above 16, I guess?

We also need to set an "MRAerImFriend" global so we can track things.
Set this regardless of anything -- just set it automatically when they meet in Spellhold, and set it to 0
*/


/* The beginning of the actual friendship */

/* Triggers if the MRAerieFriendshipTimer has expired and MRAerImFriend == 0 */

CHAIN
IF ~Global("MRAerImFriend","GLOBAL",1)~ THEN AERIEJ MRAerImFriend
~Imoen?~
DO ~SetGlobal("MRAerImFriend","GLOBAL",2) RealSetGlobalTimer("MRAerieFriendshipTimer","GLOBAL",1200)~
== IMOEN2J ~Yeah? Y'need something from me, Aerie?~
== AERIEJ ~W-well, I just... <CHARNAME> didn't tell me much about you. I-I was wondering--~
== IMOEN2J ~Ah, so you wanna get to know the cunning and mysterious Imoen of legend, right?~
== AERIEJ ~Haha, y-yes, sort of. I'm simply curious. But it's alright if you'd rather not talk to me right now, of course.~
== IMOEN2J ~Oh, no, please, I always enjoy talking about myself!~
== IMOEN2J ~Anything ya wanna know in particular? Or you'd rather get the full Imoen bio?~
== AERIEJ ~Well, you could start with that, and then we can continue from there, alright?~
== IMOEN2J~(Imoen grins) Aerie, I think you an' I will get along just fine.~
== AERIEJ ~Oh, I... I hope so. I'm glad you feel that way.~
== IMOEN2J ~My, but you blush so easily. This is gonna be fun.~
== IMOEN2J ~(Imoen clears her throat) It all began long ago, when knights soared through the skies atop dragons and dreadful wizards terrorized the realm...~
== AERIEJ ~(Aerie laughs and continues to listen. They talk mainly about Imoen's childhood, and very sparsely about Aerie's past.)~
= ~(And when their voices drop to whispers and giggles, it's clear Imoen is having fun at your expense by telling embarrassing childhood stories about you.)~
EXIT
// ******************************************************************

CHAIN
IF ~Global("MRAerImFriend","GLOBAL",3)~ THEN IMOEN2J MRAerImFriend3
~Hey Aerie, you okay? Are you crying?~
DO ~SetGlobal("MRAerImFriend","GLOBAL",4) RealSetGlobalTimer("MRAerieFriendshipTimer","GLOBAL",1200)~
== AERIEJ ~W-what? N-no, no, of course not. (Aerie quickly wipes her face with the back of her hand.)~
== IMOEN2J ~Aw, don't be ashamed, it's alright. C'mon, tell me what's botherin' you.~
== AERIEJ ~Oh, it's just... it's only... oh, I feel so childish, but I can't help it.~
= ~I-I was lost in memories, of my time as an Avariel...~
== IMOEN2J ~It must be very painful for you.~
== AERIEJ ~Yes, yes it is! I can't stand it, tied to the ground like this, when I could be soaring above buildings, through the clouds!~
= ~I feel miserable every time I bathe, every time I change clothes, whenever I feel these... these monstrosities on my back!~
== IMOEN2J ~Oh, Aerie, I'm sorry.~
== AERIEJ ~No... no, *I'm* sorry, Imoen, I apologize for my weakness, you don't deserve my whining. No one deserves it.~
== IMOEN2J ~Aerie, c'mon, don't be so-~
== AERIEJ ~(Aerie begins to sob) No, I don't deserve your compassion. I'm a wretch, I'm a disgrace to the Avariel! I have no pride. I've no reason to live.~
= ~I should just... just sit and rot here where I am.~

== IMOEN2J IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~(Imoen frowns) Aerie.~
== IMOEN2J IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~Aerie, look at me. Look into my eyes. What do you see?~
== AERIEJ IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~I... I don't...~
== IMOEN2J IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~You see nothing. That's what's left inside me, nothing. Just memories of hours and hours of torture, of horrible torment.~
== IMOEN2J IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~They took my soul, ripped it off me against my will. I hope you'll never know what it is to feel this... hollow. It grows with every passing day. It feels like it'll swallow me whenever I close my eyes.~
== AERIEJ IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~Oh Imoen... I... I didn't know-~
== IMOEN2J IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~Look, I know you can't get your wings back. I... I know I'll never be the same, either, no matter what I do. So we're kind of the same, aren't we? All we can do is... work to get new wings.~
== AERIEJ IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~B-- but I... what... what do you mean?~

== IMOEN2J IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~Well, that sounds rather extreme, dontcha think?~
== AERIEJ IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~It's just... just so hard to see the point of carrying on sometimes.~
== IMOEN2J IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~Hey, believe me, I can relate. Y'know, with all the endless torture and getting my soul stripped off me an' all? That sure was something, alright.~
== AERIEJ IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~Y-yes, but... but you got your soul back, you're whole again. I will never-~
== IMOEN2J IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~(Aerie is interrupted by Imoen's laughter. It's a joyless thing, steeped in acrimony.)~
== IMOEN2J IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~Oh, oh wow, that's precious, Aerie. Yeah, I'm whole again, sure thing. Same ol' Imoen, right as rain.~
== AERIEJ IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~What... I'm sorry, did I...~
== IMOEN2J IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~Crumple up a paper, go ahead and try to smooth out the wrinkles, see how far you get. Break a porcelain vase, good luck putting it back together. Some things just can't be made whole again. No matter how hard you try.~
== IMOEN2J IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~Look, I know you can't get your wings back. I don't think I'll ever be the same, either. You and I, Aerie... we just gotta carry on, make do with what we've got. We fell off the sky, and now we have to get new wings. How's that for a metaphor?~
== AERIEJ IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~I... I don't know.~

== IMOEN2J ~It's simple, really. Find in this new life you've been forced into *something* that keeps you going. Just like everyone else does. It's not so bad if we're still alive.~
= ~You look at it like life as an Avariel is over, but it's gotta be the other way around. Your life as a "normal" elf has just started. Whatcha gonna do with it?~
== AERIEJ ~(Aerie blinks, deep in troubled thoughts.)~
= ~I...~
= ~Please, let me think... let me think for a while.~
== IMOEN2J ~Of course, Aerie. Just... start gathering feathers.~
==AERIEJ ~(Aerie nods agreeably, a sad half-smile on her lips.)~
EXIT

// *****************************************************************

CHAIN
IF ~Global("MRAerImFriend","GLOBAL",5)~ THEN AERIEJ MRAerImFriend7
~Imoen, I'm sorry.~
== IMOEN2J ~Huh? Why?~
== AERIEJ ~F-for being so self-centered. My wings were everything to me, and since they've been gone... I couldn't imagine anyone else having problems as bad as mine.~
= ~And-and also, thanks you for talking to me and caring about me. It... it means a lot.~
== IMOEN2J ~Yer just adorable, you know that? I was feeling kinda bad about the way I talked to ya. You've been so serious ever since, I was thinking of apologizing myself, imagine that!~
= ~But I guess you were just thinking about the whole thing, huh?~
== AERIEJ ~Yes, yes I was. That's why I want to thank you so much, Imoen. You have opened my eyes. I-I don't know what to live for, but... what's lost is gone forever, and I can't change that. There is no point in dwelling.~
== IMOEN2J ~I'm glad you feel that way.~
== AERIEJ ~(Aerie nods) Everyone around me was born without wings, and that doesn't stop them from enjoying life, from working toward something. And that has made me wonder...~
= ~What... what's your goal in life, Imoen? What's your dream?~
== IMOEN2J ~Uh, my dream? Umm, I can't decide between having a pet chinchilla, or being offensively rich and powerful. Maybe I'll go wild and choose both!~
== AERIEJ ~(Aerie purses her lips) Oh Imoen, I'm trying to be serious.~
== IMOEN2J ~Oh, alright, alright... honestly, I don't know. I haven't had the time to really think about it. Just... get <CHARNAME> out of trouble, I guess. Which, I'm sure you can tell, is a life-long endeavor.~
= ~Tellya what, I'll come up with something I'd love to do when I have a quiet life of my own, and you do the same. How's that sound?~
== AERIEJ ~(Aerie thinks on it briefly and then smiles) Alright. It's a deal.~
==IMOEN2J ~Good!~
END
	IF ~~ THEN DO ~RealSetGlobalTimer("MRAerieFriendshipTimer","GLOBAL",1200) SetGlobal("MRAerImFriend","GLOBAL",6)~ EXIT

// ******************************************************************************
CHAIN
IF ~Global("MRAerImFriend","GLOBAL",7)~ THEN IMOEN2J MRAerImFriend9
~Oh no!~
DO ~SetGlobal("MRAerImFriend","GLOBAL",8)~
== AERIEJ ~What's the matter, Imoen?~
== IMOEN2J ~Ooh, this is all my fault. Oh, <CHARNAME> is gonna kill me. Ohh, oh no.~
== AERIEJ ~What happened? What did you do?~
== IMOEN2J ~The jar's broken! Robbie escaped and turned all my stuff to jelly!~
== AERIEJ ~Robbie?~
== IMOEN2J ~Oh no, it's even worse. It had babies! Look at this, it's oozing all over the place.~
== AERIEJ ~Yuck, what is that! Is that a monstrous *ooze*?~
== IMOEN2J ~I thought I could keep it as a pet and teach it tricks and stuff, okay? Don't judge me!~
== AERIEJ ~You *what*?~
== IMOEN2J ~It escaped during the night... who knows where it went before getting back. You... you might want to check your things.~
== AERIEJ ~My things? (Aerie looks inside her pack.) Eek! When did this happen!~
END IMOEN2J MRAerImPrank

APPEND IMOEN2J
IF ~~ THEN BEGIN MRAerImPrank
 SAY ~Uh oh. (Imoen makes shifty eyes. She notices you looking at her and gives you a nervous smile.) Oh, hey, <CHARNAME>. Ha ha, fancy seein' you here, hahah, ah.~
 ++ ~Alright, what's going on here?~ + MRAerImPrank1
 ++ ~What in the world are you up to now, Imoen?~ + MRAerImPrank1
 ++ ~Whatever you two are talking about, I want you to shut up about it.~ + MRAerImPrankShut
END

IF ~~ THEN BEGIN MRAerImPrank1
 SAY ~Nothing, nothing at all, do go back to being awesome, <CHARNAME>, don't mind us.~
 IF ~~ THEN EXTERN AERIEJ MRAerImPrank1Ae
END

IF ~~ THEN BEGIN MRAerImPrankShut
 SAY ~Yeesh.~
 IF ~~ THEN EXTERN AERIEJ MRAerImPrank1Ae
END
END

APPEND AERIEJ
IF ~~ THEN BEGIN MRAerImPrank1Ae
 SAY ~Imoen! All my things are ruined! There's just this gross ooze all over the place!~
 = ~You might want to check your pack, <CHARNAME>. I fear the worst.~
 IF ~~ THEN EXTERN IMOEN2J MRAerImPrank1Im
END

IF ~~ THEN BEGIN MRAerImPrankPreCheckAer
 SAY ~Stop it, Imoen! This is serious, it could set us back a great deal!~
 IF ~~ THEN EXTERN IMOEN2J MRAerImPrankPreCheckIm
END
END

APPEND IMOEN2J
IF ~~ THEN BEGIN MRAerImPrank1Im
 SAY ~Gulp.~
 ++ ~This doesn't sound good. (Check your pack.)~ + MRAerImPrankCheck
 ++ ~Everything was fine last time I checked.~ + MRAerImPrankPreCheck
 IF ~OR(2) CheckStatGT(Player1,13,INT) CheckStatGT(Player1,13,WIS)~ THEN REPLY ~Sorry, I'm not falling for it, you two. (Hand your pack to Imoen) I've no idea how you pulled it off, but I want this clean and just the way it was. Now.~ GOTO MRAerImPrankSmart
 ++ ~(Narrow your eyes and check your belongings. There'll be Hell to pay if something is amiss.)~ + MRAerImPrankCheck
END

IF ~~ THEN BEGIN MRAerImPrankCheck
 SAY ~(Imoen fidgets as you take a look at your pack. Already you can tell something isn't right by the dark purple goop seeping from its pockets.)~
 = ~(Inside, there is nothing but a jelly-like substance, almost liquid but cohesive enough not to drip or stain through. All of your belongings are gone.)~
 = ~I'm so, so screwed.~
 ++ ~My stuff! My precious, precious things! What have you done!~ EXTERN AERIEJ MRAerImPrankReveal
 ++ ~Just... keep calm. What do we do now? There must be something we can do about this.~ EXTERN AERIEJ MRAerImPrankReveal
 ++ ~Imoen, I'm going to spank you until your whole back side is one big, fat bruise.~ EXTERN AERIEJ MRAerImPrankReveal
 ++ ~A pet ooze? Are you insane, Imoen? Look at this. We're ruined. Are you happy now?~ EXTERN AERIEJ MRAerImPrankReveal
 + ~OR(2) CheckStatGT(Player1,11,INT) CheckStatGT(Player1,11,WIS)~ + ~I'm honestly impressed. How did you pull this off, Imoen? Most elaborate prank yet.~ + MRAerImPrankSmartNice
 + ~OR(2) CheckStatGT(Player1,11,INT) CheckStatGT(Player1,11,WIS)~ + ~(Sigh) I don't know how you did this or why Aerie agreed to help you, but here. Clean it up, put my things back, and let's get going already.~ + MRAerImPrankSmart
END
END

CHAIN
AERIEJ MRAerImPrankReveal
~(Aerie's pressed-together lips suddenly burst in giggles.)~
DO ~SetGlobal("MRAerImFriend","GLOBAL",9) RealSetGlobalTimer("MRAerieFriendshipTimer","GLOBAL",1200)~
== IMOEN2J ~Nooo, it was goin' so well! (Her voice breaks into laughter, joining the Avariel.)~
== AERIEJ ~I'm sorry, I'm so sorry, I'm just, <CHARNAME>'s face, ooh!~
END IMOEN2J MRAerImPrankEnd

APPEND IMOEN2J
IF ~~ THEN BEGIN MRAerImPrankEnd
 SAY ~That face never gets old!~
 ++ ~Hah, I knew it. You two are too much, you got me good!~ EXTERN AERIEJ MRAerImPrankEndSport
 ++ ~I saw this coming from a mile away. It isn't that funny, you know.~ + MRAerImPrankEndMiffed
 ++ ~How did you even do this without me noticing? And where are my things?~ + MRAerImPrankEndHow
 ++ ~Imoen, you'll never grow up. And you, Aerie, should know better than to get pulled into her childish games.~ + MRAerImPrankEndMiffed
 ++ ~What a stupid waste of my time. I'm one step away from kicking you out. Clean this up right now so we can get going.~ + MRAerImPrankEndMad
 ++ ~Wow, that's a new one, you having fun at my expense. Ha-ha, ho-ho, what a jolly good time.~ + MRAerImPrankEndMiffed
END
END

CHAIN
IMOEN2J MRAerImPrankEndMiffed
~(Predictably enough, your reaction only makes Imoen laugh harder.)~
== AERIEJ ~Oh, please don't be angry! It was... it was just a silly joke. I'm so sorry to have upset you.~
== IMOEN2J ~Ha ha! What? What kind of attitude is that? Upsetting <PRO_HIMHER> is half the fun! Keeps <HIMHER> grounded!~
== AERIEJ ~No, no, I didn't mean for <PRO_HIMHER> to take offense. I... I shouldn't have listened to you.~
== IMOEN2J ~Aw, c'mon, lighten up, everyone. Yeesh. I'll get all the stuff, we'll clean up in no time. No harm done.~
== AERIEJ ~You're a terrible influence, Imoen.~
== IMOEN2J ~And right proud of it!~
EXIT

CHAIN
IMOEN2J MRAerImPrankEndMad
~(Imoen can tell your anger is dead serious. It sobers her up fairly quickly.)~
= ~Wow, um. Sorry, I thought... hey, I didn't mean to make you mad like that. I'm sorry. We'll fix everything right away, no harm done, alright?~
== AERIEJ ~(Aerie has paled considerably. She gets to work cleaning without delay, and soon everything is back to normal.)~
EXIT

CHAIN
IMOEN2J MRAerImPrankEndHow
~Oh, but that would be telling!~
== AERIEJ ~Come on, Imoen, I think we went far enough. I hope you feel all this cleanup was worth the trouble.~
== IMOEN2J ~Aww, you don't think it was?~
== AERIEJ ~(Aerie simply keeps her head down and gets busy cleaning. Though she tries to hide it, laughter plays on her lips.)~
== IMOEN2J ~It totally was.~
EXIT

CHAIN
AERIEJ MRAerImPrankEndSport
~You were right, Imoen, <HESHE>'s such a great sport. I was so nervous you'd get mad, <CHARNAME>. But Imoen is so persuasive....~
== IMOEN2J ~Yeah, try to put it all on me now, why dontcha.~
== AERIEJ ~It was *your* idea!~
== IMOEN2J ~Mm-hmm.~
== AERIEJ ~It was! It-it really was, <CHARNAME>!~
== IMOEN2J ~You keep saying that, <PRO_HESHE>'ll totally believe ya.~
== AERIEJ ~I would never think of doing something like this, and <CHARNAME> knows that!~
== IMOEN2J ~You sure are one devious little elf, arentcha. For shame, Aerie. For shame.~
== AERIEJ ~Urrgh! I'm never listening to you again. Here, *you* clean up this mess.~
= ~(Aerie hands her pack to Imoen and stomps off, possibly to the spot where they stashed all the equipment.)~
== IMOEN2J ~(Imoen gets busy cleaning. She laughs to herself all the way through.)~
EXIT

APPEND IMOEN2J
IF ~~ THEN BEGIN MRAerImPrankPreCheck
 SAY ~Yeah, ha ha, no need to check, no need. Let's keep going!~
 IF ~~ THEN EXTERN AERIEJ MRAerImPrankPreCheckAer
END

IF ~~ THEN BEGIN MRAerImPrankPreCheckIm
 SAY ~I'm so screwed.~
 ++ ~This can't be that bad. (Check your pack.)~ + MRAerImPrankCheck
 IF ~OR(2) CheckStatGT(Player1,13,INT) CheckStatGT(Player1,13,WIS)~ THEN REPLY ~Look, I'm not falling for it. (Hand your pack to Imoen) I've no idea how you pulled it off, but I want this clean and just the way it was. Now.~ GOTO MRAerImPrankSmart
 ++ ~(Narrow your eyes and check your belongings. There'll be Hell to pay if something is amiss.)~ + MRAerImPrankCheck
END
END


CHAIN
IMOEN2J MRAerImPrankSmart
~(Imoen looks back at you, lips pursed in disappointment) You're such a bore, you know that, <CHARNAME>?~
DO ~SetGlobal("MRAerImFriend","GLOBAL",9) RealSetGlobalTimer("MRAerieFriendshipTimer","GLOBAL",1200)~
== AERIEJ ~Ooh, I knew I'd tipped my hand somehow.~
== IMOEN2J ~Please, you were flawless! It's my fault, <PRO_HESHE>'s been the butt of too many pranks by now. <PRO_HESHE> knows me too well, I'm getting predictable!~
== AERIEJ ~Oh, Imoen, it-it's alright. (Aerie gives her an impish smile) Maybe we'll just have to work harder next time.~
== IMOEN2J ~Yes! Yes, we better get to work right now. That spoilsport know-it-all will never see us coming.~
= ~Um, after we're done cleanin' this mess, that is. Way to ruin the fun, <CHARNAME>!~
EXIT

CHAIN
IMOEN2J MRAerImPrankSmartNice
~(Imoen looks back at you, amusement and disappointment mixing in her expression) Aww, what gave me away?~
DO ~SetGlobal("MRAerImFriend","GLOBAL",9) RealSetGlobalTimer("MRAerieFriendshipTimer","GLOBAL",1200)~
== AERIEJ ~Ooh, I knew I'd tipped my hand somehow.~
== IMOEN2J ~No, please, you were flawless! It's my fault, <PRO_HESHE>'s been the butt of too many pranks by now. <PRO_HESHE> knows me too well, I'm getting predictable!~
== AERIEJ ~Oh, Imoen, it-it's alright. (Aerie gives her an impish smile) Maybe we'll just have to work harder next time.~
== IMOEN2J ~Yes! Yes, we better get to work right now. That spoilsport know-it-all will never see us coming.~
= ~Um, after we're done cleaning this mess, that is. Way to ruin the fun, <CHARNAME>!~
EXIT


// *********************************************************************************************

CHAIN
IF ~Global("MRAerImFriend","GLOBAL",10)~ THEN IMOEN2J MRAerImFriend15
~Hey, Aerie, can I ask ya somethin'?~
DO ~SetGlobal("MRAerImFriend","GLOBAL",11)~
== AERIEJ ~I-I guess so. Go ahead.~
== IMOEN2J ~It's about yer past, though. It might stir up some tough memories. Y'sure?~
== AERIEJ ~I... I'll be alright. Like you said, they're just memories.~
== IMOEN2J ~Right! Well, here goes. What was it like to fly?~
== AERIEJ ~(Aerie keeps silent for a moment, her brow knit thoughtfully.)~
= ~It was like... it was...~
= ~Freedom. It was simple, utter freedom.~
= ~I could go anywhere I pleased, any time I wanted. It was so exhilarating to see everything from above; mountains, forests, rivers, even cities sometimes, though they told us not to go so far. Everything so tiny, it seemed they would all fit in the palm of my hand.~
= ~And the wind, ohh, the wind. (She shivers in remembrance) Like a lover's arms embracing you, keeping you aloft, holding you so gently, buffeting your hair. It was... marvelous.~
== IMOEN2J ~Wow. It sure sounds great.~
== AERIEJ ~(Aerie smiles bitterly) You understand why I put so much of myself in my wings, don't you?~
== IMOEN2J ~Oh, I do. I'm kinda jealous, honestly.~
== AERIEJ ~What? J-jealous? Why would anyone be jealous of... of an Avariel without wings?~
== IMOEN2J ~Are you serious? There's people out there that would kill to have that kinda memories. *I* would, for one. Well, depends who I'd have to kill, though. I'm picky about who I kill, you see.~
= ~So, yeah, who wouldn't be a little jealous of you?~
== AERIEJ ~Huh.~
= ~I... I hadn't put it under that light before.~
== IMOEN2J ~That's 'cuz yer a downer, Aerie-head. I'm gonna start calling you Xan now.~
== AERIEJ ~Who's Xan?~
== IMOEN2J ~Only the greatest wizard to ever lie down and die. It's not important -- thanks for answering, anyway. Curiosity, sated!~
== AERIEJ ~So you say. Next time, I might just be too "airy-headed" to remember my healing prayers for you.~
== IMOEN2J ~Okay, alright, I take it back, jeez...~
END
	IF ~~ THEN DO ~RealSetGlobalTimer("MRAerieFriendshipTimer","GLOBAL",1200)~ EXIT

// *****************************************************************************

APPEND PLAYER1
	IF ~Global("MRAerImFriend","GLOBAL",12)~ THEN BEGIN MRAerImFriend18
		SAY ~(You hear Imoen and Aerie giggle, again. They've been talking a lot lately, often in hushed tones so as to not be overheard.)~
		=
		~(They seem to be a bit careless about it this time, however. If you were subtle enough, you could probably eavesdrop.)~
		++ ~(You've been terribly curious. Approach them discreetly.)~ DO ~ActionOverride(Player1,SetDialog("Player1")) SetGlobal("MRAerImFriend","GLOBAL",13)~ GOTO MRAerImFriend19
		++ ~Hey you two, what are you talking about?~ DO ~ActionOverride(Player1,SetDialog("Player1")) SetGlobal("MRAerImFriend","GLOBAL",13)~ GOTO MRAerImFriend18Hey
		++ ~(You couldn't care less about their pointless smalltalk. Keep going in silence.)~ DO ~ActionOverride(Player1,SetDialog("Player1")) SetGlobal("MRAerImFriend","GLOBAL",13)~ GOTO MRAerImFriend18Lame
		++ ~(Respect their privacy.)~ DO ~ActionOverride(Player1,SetDialog("Player1")) SetGlobal("MRAerImFriend","GLOBAL",13)~ GOTO MRAerImFriend18Private
	END

	IF ~~ THEN BEGIN MRAerImFriend18Lame
		SAY ~(You get as far from them as you can. They keep talking, not noticing you at all.)~
		IF ~~ THEN EXIT
	END


	IF ~~ THEN BEGIN MRAerImFriend18Private
		SAY ~(They giggle softly again. You put a bit more distance between you and them, letting them talk in private as they wish.)~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRAerImFriend18Hey
		SAY ~(Both are startled by your question; they reply at the same time.)~
		IF ~~ THEN EXTERN IMOEN2J MRAerImFriend18Hey2
	END

	IF ~~ THEN BEGIN MRAerImFriend18Hey4
		SAY ~(They both giggle again and then glance at each other with complicity.)~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRAerImFriend19
		SAY ~(You slow your pace until they are close enough, then casually maintain your stride.)~
		IF ~~ THEN EXTERN AERIEJ MRAerImFriend20
	END
END

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRAerImFriend18Hey2
		SAY ~Nothing!~
		IF ~~ THEN EXTERN AERIEJ MRAerImFriend18Hey3
	END

END


APPEND AERIEJ
	IF ~~ THEN BEGIN MRAerImFriend18Hey3
		SAY ~Nothing!~
		IF ~~ THEN EXTERN PLAYER1 MRAerImFriend18Hey4
	END

	IF ~~ THEN BEGIN MRAerImFriend20
		SAY ~Really?~
		IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN EXTERN IMOEN2J MRAerImFriend21Rom
		IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN EXTERN IMOEN2J MRAerImFriend21NoRom
	END
END

CHAIN
IMOEN2J MRAerImFriend21NoRom
~No kiddin'!~
== AERIEJ ~(Aerie giggles again, then sobers up) But I thought, with everything that's happened...~
== IMOEN2J ~Yeah. Yeah, it took a while. But I can't let all that stuff ruin me. With the whole soul issue settled, I kinda... drove myself to it. Glad I did, I'll tellya that much.~
== AERIEJ ~I've never... it never ocurred to me to do that.~
== IMOEN2J ~Really? Are you being serious right now?~
== AERIEJ ~Y-yes! Yes, I'm serious. You ask like I'm a freak.~
== IMOEN2J ~No, hey, no judgment, I just thought everyone did it. Now that I think about it, you... probably you never had much of a chance, huh.~
== AERIEJ ~No, not really, I suppose. And I figured... that's something you do with your partner. Eventually.~

== IMOEN2J IF ~Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Judging by what I've been hearing from your and Haer'Dalis' tent...~
== AERIEJ IF ~Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~(You hear Aerie's hushed titter) Oh, shush, you. It's all new to me. And my sweet lover, he can be so tender sometimes...~
== IMOEN2J IF ~Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Eugh, no mental images, please. Haer'Dalis ain't my thing - uh, no offense, I hope.~
== AERIEJ IF ~Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Well, I sure hope he's not your *thing*, Imoen, or I'll have to have some serious words with you!~
== IMOEN2J IF ~Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Haha, rest assured, Aerie. He's all yours. But, dunno, food for your thoughts. Maybe sometimes yer all in the mood and he's tired, and then what? Might be better with company, but solo isn't too shabby, if you catch my meaning.~

== IMOEN2J IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Yeah, right, well, "eventually" could be forever! The way things are going, we'll probably die two old maidens, wrinkled and crotchety, still waiting for their perfect knight in shining armor. I'd go insane if I went that long without takin' care of business.~
== AERIEJ IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Haha, that's just grim, Imoen. Somewhere out there, there is someone crazy enough to love you.~
== IMOEN2J IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Thanks, thanks for that, yer such a kind friend. Anyway, goin' by all the "secret" stuff I read in Candlekeep, it's way better with the right company. So the wait could be worth it, I guess?~

== AERIEJ ~So should I... do you think I should try?~
== IMOEN2J ~Oh Gods, Aerie, I've no clue. I don't even know if elves are supposed to do that stuff. On the other hand, plenty of elves in those novels I mentioned, so... you'd probably enjoy yerself. Put a pillow over yer head, though. Don't want the whole camp to hear ya.~
== AERIEJ ~That'd be so embarrassing!~
== IMOEN2J ~(Imoen pauses for a moment) Yeah, I'll say! Like all those times I caught <CHARNAME> doing things in the stables. Oh Gods, what I wouldn't give to scrub those images from my memory!~
== AERIEJ ~Oh my. Do I want to know?~
== IMOEN2J ~Probably not. I mean, the leather suit, the large rods, the clamps and all those animal noises! Eugh...~
== AERIEJ ~That... that's horrible!~
END IMOEN2J MRAerImFriendShockNoRom

CHAIN 
IMOEN2J MRAerImFriend21Rom
~No kiddin'!~
== AERIEJ ~(Aerie giggles again) But I thought <CHARNAME> and you...~
== IMOEN2J ~Well, yeah, d'uh. But sometimes <PRO_HESHE>'s tired, or I was tired when <PRO_HESHE> wasn't and then I'm not but it's too late, and sometimes I don't wanna bother <PRO_HIMHER>, so, y'know.~
== AERIEJ ~I've never... it never ocurred to me to do that.~
== IMOEN2J ~Really? Are you being serious right now?~
== AERIEJ ~Y-yes! Yes, I'm serious. You ask like I'm a freak.~
== IMOEN2J ~No, hey, no judgment, I just thought everyone did it. Now that I think about it, you... probably you never had much of a chance, huh.~
== AERIEJ ~No, not really, I suppose. And I figured... that's something you do with your partner. Eventually.~


== IMOEN2J IF ~Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Judging by what I've been hearing from your and Haer'Dalis' tent...~
== AERIEJ IF ~Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~(You hear Aerie's hushed titter) Oh, shush, you. Nothing I haven't heard from *your* and <CHARNAME>'s tent.~
== IMOEN2J IF ~Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~(There's laughter in Imoen's voice) Guilty as charged. What can I say, <PRO_HESHE>'s really good. Dontcha ever tell <PRO_HIMHER> I said that, though. <PRO_HISHER> head's big enough as it is.~
== AERIEJ IF ~Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~I won't if you won't.~


== IMOEN2J IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Well, I'll tell you this much, it *is* better with the right company...~
== AERIEJ IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Should I... do you think I should try?~
== IMOEN2J IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Oh Gods, Aerie, I've no clue. I don't even know if elves are supposed to do that stuff. On the other hand, going by all those "secret" novels I read in Candlekeep, you'd probably enjoy yerself. Put a pillow over yer head, though. Don't want the whole camp to hear ya.~
== AERIEJ IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~(You hear Aerie's hushed titter) Oh, shush, you. I'd get drowned out by what's coming from *your* and <CHARNAME>'s tent.~
== IMOEN2J IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~(There's laughter in Imoen's voice) Guilty as charged. What can I say, <PRO_HESHE>'s really good. Dontcha ever tell <PRO_HIMHER> I said that, though. <PRO_HISHER> head's big enough as it is.~
== AERIEJ IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~<PRO_HESHE>'s a hero, <PRO_HESHE> needs an ego to match.~
== IMOEN2J IF ~!Global("HaerDalisRomanceActive","GLOBAL",2)~ THEN ~Aww, guess that's true.~


== IMOEN2J ~(Imoen pauses for a moment) Though to tell the truth, <PRO_HESHE>'s into some stuff that's pretty disturbing. Bit of a shocker, honestly.~
== AERIEJ ~Oh my. Do I want to know?~
== IMOEN2J ~Probably not. It was bad enough when <PRO_HESHE> dressed up as a gnoll, asking me to wear "something furry". I drew the line at the actual pair of sheep <PRO_HESHE> brought into the tent.~
== AERIEJ ~That... that's horrible!~
END IMOEN2J MRAerImFriendShock

APPEND IMOEN2J
 IF ~~ THEN BEGIN MRAerImFriendShock
 SAY ~Yeah. Shoulda known somethin' was up after the leather suits came out.~
 ++ ~Woah, woah, I've never done anything like that!~ + MRAerImFriendKnewit
 ++ ~Imoen! You promised not to tell!~ + MRAerImFriendKnewit
 ++ ~Are these fantasies you've entertained, Imoen? Because that's never happened.~ + MRAerImFriendKnewit
 ++ ~I want this chatter to stop at once.~ + MRAerImFriendKnewit
 ++ ~(You know better than to say a damn thing. Casually walk away from them, pretending you haven't heard a word.)~ + MRAerImFriendWalk
 END
 
 IF ~~ THEN BEGIN MRAerImFriendShockNoRom
 SAY ~Tell me about it. I had nightmares for years.~
 ++ ~Woah, woah, I've never done anything like that!~ + MRAerImFriendKnewit
 ++ ~Imoen! You promised not to tell!~ + MRAerImFriendKnewit
 ++ ~Are these fantasies you've entertained, Imoen? Because that's never happened.~ + MRAerImFriendKnewit
 ++ ~I want this chatter to stop at once.~ + MRAerImFriendKnewit
 ++ ~(You know better than to say a damn thing. Casually walk away from them, pretending you haven't heard a word.)~ + MRAerImFriendWalk
 END
END

CHAIN
IMOEN2J MRAerImFriendKnewit
~Ogh, I knew it, I KNEW it! You little snivelin' snoop, you! Doin' like you're not listening!~
== AERIEJ ~(Aerie is blushing profusely.) <PRO_HESHE>... <PRO_HESHE> heard all that?~
== IMOEN2J ~No, <CHARNAME> heard *nothing* and will say *nothing else*, if <PRO_HESHE> knows what's good for <PRO_HIMHER>.~
== IMOEN2J IF ~Gender(Player1,MALE)~ THEN ~We'll talk later, Aerie. Clearly girls can't get some privacy around here without some troll-eared snoop getting all up in their business...~
== IMOEN2J IF ~Gender(Player1,FEMALE)~ THEN ~We'll talk later, Aerie. Clearly girlfriends can't get some privacy around here without some troll-eared snoop getting all up in their business...~
EXIT

CHAIN
IMOEN2J MRAerImFriendWalk
~Oh, there's a smart <PRO_GIRLBOY>. Keep walkin' and minding yer own business, <CHARNAME>, if you know what's good for ya!~
== AERIEJ ~Wait. <PRO_HESHE>... <PRO_HESHE> heard all that?~
== IMOEN2J ~No, <CHARNAME> heard *nothing* and will never say *anything*, if <PRO_HESHE> knows what's good for <PRO_HIMHER>.~
== IMOEN2J IF ~Gender(Player1,MALE)~ THEN ~We'll talk later, Aerie. Clearly girls can't get some privacy around here without some troll-eared snoop getting all up in their business...~
== IMOEN2J IF ~Gender(Player1,FEMALE)~ THEN ~We'll talk later, Aerie. Clearly girlfriends can't get some privacy around here without some troll-eared snoop getting all up in their business...~
EXIT




