// Here go all the small interjections and very brief dialogues scattered throughout the game

/* Table of contents:
// Imoen takes special interest in retrieving Lazarus Librarus's book
// You killed the merchant after leaving Saradush
// Imoen interjects to Peltje in Saradush about finding vampires
// Extending Imoen's interjection to a gnome bhaalspawn in Saradush
// Comments to Farielle, a priestess in Saradush that might give you the key to the sewers
// Viconia's "you should be his/her slave" banter with Imoen needs to be changed to account for the romance
// Haer'Dalis cheesy come-on
// Keldorn and his ring
// Imoen and the vampire tramp/man-whore
// Imoen and the n00b trollop in Saradush
// Imoen interjects to Saemon in Amkethran
// Imoen saves Asana in Amkethran if you do nothing
// Imoen greets Lazarus Librarus in Amkethran
//Extend Volo imoen comment
*/


// Imoen takes special interest in retrieving Lazarus Librarus's book

// 1st Comment - Lazarus

EXTEND_BOTTOM 25SPELL 0
  IF ~InParty("Imoen2") IsValidForPartyDialog("Imoen2") Global("IRTLazGreeting1","GLOBAL",0)~ THEN DO ~SetGlobal("IRTLazGreeting1","GLOBAL",1)~EXTERN IMOEN25J MRLaz1
END

APPEND IMOEN25J
 IF ~~ THEN MRLaz1
	SAY ~Oooh, new bookshelves, how I missed them. Can't wait to browse through this stuff.~
	IF ~Global("lazarus","GLOBAL",0)~ THEN EXTERN 25SPELL 8
	IF ~Global("lazarus","GLOBAL",3)~ THEN EXTERN 25SPELL 1
 END
END


I_C_T2 25SPELL 8 IRTIntLazarus2
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2")~ THEN
	~What?~
END

I_C_T 25SPELL 13 IRTIntLazarus3
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") !Global("IRTPlayerIsMagicUser","GLOBAL",1)~ THEN ~Yes, yes <CHARNAME>, let's help this man. I was ever so excited to get new spells and now it's like they took all my candy away.~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") Global("IRTPlayerIsMagicUser","GLOBAL",1)~ THEN ~Yes, yes <CHARNAME>, let's help this man. I was ever so excited to get new spells and now it's like they took all my candy away. C'mon, I'm sure you wanna get some for yourself too!~
	== 25SPELL IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Witnessing your enthusiasm for the art brings joy to this old mage's heart, Lady Imoen.~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2")~ THEN ~You know my name?~
	== 25SPELL IF ~IsValidForPartyDialog("Imoen2") OR(2) Global("ImoenRomanceActive","GLOBAL",2) GlobalGT("ImoenRomanceActive","GLOBAL",3)~ THEN ~You are mighty <CHARNAME>'s childhood friend and most stalwart companion. Your name is almost as well known, my dear.~
	== 25SPELL IF ~IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",2) !GlobalGT("ImoenRomanceActive","GLOBAL",3)~ THEN ~You are mighty <CHARNAME>'s Bhaalspawn sister. Your name is almost as well known, my dear.~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") !ReputationGT(Player1,6)~ THEN ~Hah. How about that. Dunno if it's a good thing, with the kind of reputation our group has...~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") ReputationGT(Player1,6)~ THEN ~Hah. Almost as famous as you, <CHARNAME>. How about that.~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Anyway, let's go look for that spellbook, hmm?~
	== 25SPELL IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Oh, oh yes my good <PRO_LADYLORD>. Help me with this, I beg of you.~
END	

I_C_T 25SPELL 3 IRTIntLazarus4
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Phooey. You're no fun.~
END

// 2nd Comment - Hectan

I_C_T SARTHF1 8 IRTIntHectan1
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Oh, for crying out loud. Don't you think the man would've been long gone if he had a means to get out of here? How about we give you two hundred gold pieces instead so you can go buy yourself a brain?~
	== SARTHF1 IF ~IsValidForPartyDialog("Imoen2")~ THEN ~I don't care what you have to say. Get me that scroll, or no deal.~
END

// 3rd Comment - Restored book

I_C_T2 25SPELL 17 IRTIntLazarus5
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Yay!~
	== 25SPELL IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Excellent, no damage to the cover or binding, everything is exactly as it was. I feared the book might have been damaged in the care of that brute.~ // Lazarus is meant to say this
END


// You killed the merchant after leaving Saradush, North Forest guy
//  Triggers after combat is over

ADD_TRANS_ACTION HGKAR01
BEGIN 10 END
BEGIN 0 END
~SetGlobal("IRTKilledForestMerchant","GLOBAL",1)~ // Sets a global right as the merchant dies.

APPEND IMOEN25J
IF WEIGHT #0 ~Global("IRTKilledForestMerchant","GLOBAL",2)~ THEN Mer1
	SAY ~Wow.~
	IF ~~ THEN DO ~SetGlobal("IRTKilledForestMerchant","GLOBAL",3) IncrementGlobal("IRTLoveMeter","GLOBAL",-2)~ + Mer2
END

IF ~~ THEN Mer2
	SAY ~Was that really necessary?~
	++ ~No. That's the whole point, haha!~ + Mer3
	++ ~He has valuables. I want them. Seems a natural course of action to me.~ + Mer4
	++ ~No, no it wasn't... I don't know what happened. My vision clouded and I acted without thinking. The poor man didn't deserve that.~ + Mer5
	++ ~You didn't notice the way he was looking at me? He deserved to be punished.~ + Mer6
	++ ~Mind your own business, Imoen.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-1)~ + Mer7
END

IF ~~ THEN Mer3
	SAY ~Oh.~
	= ~That's not a sane thing to do, <CHARNAME>. You realize that, yes?~
	= ~A stranger's life is worth so little these days...~
	IF ~~ THEN EXIT
END

IF ~~ THEN Mer4
	SAY ~(Imoen shakes her head.) A stranger's life is worth so little these days...~
	IF ~~ THEN EXIT
END

IF ~~ THEN Mer5
	SAY ~No. He didn't.~
	= ~I'll bet killing him "by mistake" won't stop us from looting his corpse. A stranger's life is worth so little these days...~
	IF ~~ THEN EXIT
END

IF ~~ THEN Mer6
	SAY ~If... you say so. I didn't notice anything, but okay.~
	IF ~~ THEN EXIT
END

IF ~~ THEN Mer7
	SAY ~(Imoen purses her lips.)~
	= ~I'm so grossed out by you right now.~
	IF ~~ THEN EXIT
END
END

// Imoen interjects to Peltje in Saradush about finding vampires

I_C_T SARPEL01 5 IRTIntPeltje
== IMOEN25J IF ~InParty("Imoen2")~ THEN ~Eew, vampires? I'm SO sick of vampires...~
END


// Replacing Imoen's interjection to a gnome bhaalspawn in Saradush

ADD_TRANS_TRIGGER IMOEN25J 12 ~Global("ImoenRomanceActive","GLOBAL",0)~ DO 0 1

EXTEND_BOTTOM IMOEN25J 12
  IF ~!Global("ImoenRomanceActive","GLOBAL",0)~ THEN REPLY ~What do you mean? How have you learned to deal with it?~ GOTO 12Ext
		IF ~!Global("ImoenRomanceActive","GLOBAL",0)~ THEN REPLY ~We've all had a hard time accepting it.~ EXTERN SARBHA02 12ExtEnd
		IF ~!Global("ImoenRomanceActive","GLOBAL",0)~ THEN REPLY ~I honestly never understood what's the big deal.~ EXTERN SARBHA02 12ExtEnd
END


CHAIN IMOEN25J 12Ext
	~Huh?~
	= ~Well, don't know, I guess I was just- (Another catapult strike interrupts her words. She throws wary glances at the walls of the sieged stronghold.) Just helpin' the conversation along so we can get back under cover, honestly. Whatcha think about that, little fella?~
END SARBHA02 12ExtEnd

CHAIN SARBHA02 12ExtEnd
	~Just leave me alone. I can't tell you anything, I'm just a simple farmer! All I want is my normal life back - damn this cursed immortal lineage!~ DO ~RunAwayFrom(LastTalkedToBy,60)~
	== IMOEN25J ~Yeesh, where are manners these days?~
EXIT

// Comments to Farielle, a priestess in Saradush that might give you the key to the sewers

I_C_T2 SARTEM01 21 IRTIntFar
	== IMOEN25J IF ~InParty("Imoen2") Range("Imoen2",11)~ THEN ~Way to go. Blackmailing well-meaning priests must be in the top ten Not-Nice Things to Do, <CHARNAME>.~
	== SARTEM01 IF ~InParty("Imoen2") Range("Imoen2",11)~ THEN ~Poor creature. I sense the good in you stifled in this <PRO_MANWOMAN>'s shadow, my sister. The reason why one such as you would follow this monster escapes my understanding.~
	== IMOEN25J IF ~InParty("Imoen2") Range("Imoen2",11)~ THEN ~That's fine, 'cuz I don't think that's any of yer business. Look, if you give us the key, it will help you in the end - regardless of <CHARNAME>'s, uh... priorities.~
END



I_C_T SARTEM01 22 Farielle
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") IsValidForPartyDialog("Edwin")~ THEN ~I love your people skills. It's as if you have an "I'm SO evil" sign plastered on your forehead. Why don't you let *me* talk to her, hmm?~
	== EDWIN25J IF ~IsValidForPartyDialog("Edwin") IsValidForPartyDialog("Imoen2")~ THEN ~And what will you do, brat? Cry and grovel at her feet until she gives you the key out of disgust? Perhaps you should let ME have some... "words" with the wench, <CHARNAME>. I would be most... convincing. (Yes, I believe my skills will suit her body quite nicely.)~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") IsValidForPartyDialog("Edwin")~ THEN ~You realize she probably heard all that, right?~
	== SARTEM01 IF ~IsValidForPartyDialog("Edwin") IsValidForPartyDialog("Imoen2")~ THEN ~Yes, I did.~
	== EDWIN25J IF ~IsValidForPartyDialog("Edwin") IsValidForPartyDialog("Imoen2")~ THEN ~It was meant to be heard!~
END

I_C_T SARTEM01 17 IRTIntFar2
	== IMOEN25J IF ~IsValidForPartyDialog("Edwin") IsValidForPartyDialog("Imoen2")~ THEN ~Well, that was rude. Why don't you let *me* talk to her, hmm?~
	== EDWIN25J IF ~IsValidForPartyDialog("Edwin") IsValidForPartyDialog("Imoen2")~ THEN ~And what will you do, brat? Cry and grovel at her feet until she gives you the key out of disgust? Perhaps you should let ME have some... "words" with the wench, <CHARNAME>. I would be most... convincing. (Yes, I believe my skills will suit her body quite nicely.)~
	== IMOEN25J IF ~IsValidForPartyDialog("Edwin") IsValidForPartyDialog("Imoen2")~ THEN ~You realize she probably heard all that, right?~
	== SARTEM01 IF ~IsValidForPartyDialog("Edwin") IsValidForPartyDialog("Imoen2")~ THEN ~Yes, I did.~
	== EDWIN25J IF ~IsValidForPartyDialog("Edwin") IsValidForPartyDialog("Imoen2")~ THEN ~It was meant to be heard!~
END


// Viconia's "you should be his/her slave" banter with Imoen needs to be changed to account for the romance
ADD_TRANS_TRIGGER BVICON25 26 ~OR(3) Global("ImoenRomanceActive","GLOBAL",1) Global("ImoenRomanceActive","GLOBAL",0) Global("ImoenRomanceActive","GLOBAL",4) !Global("IRTQuarrelDue","GLOBAL",1) !Global("IRTCooldownDue","GLOBAL",1)~ DO 0

EXTEND_BOTTOM BVICON25 26
    IF ~Global("ImoenRomanceActive","GLOBAL",2) !Global("IRTQuarrelDue","GLOBAL",1) !Global("IRTCooldownDue","GLOBAL",1)~ THEN EXTERN BIMOEN25 VicBan1
	IF ~Global("ImoenRomanceActive","GLOBAL",3) !Global("IRTQuarrelDue","GLOBAL",1) !Global("IRTCooldownDue","GLOBAL",1)~ THEN EXTERN BIMOEN25 VicBan2
	IF ~Global("ImoenRomanceActive","GLOBAL",5) !Global("IRTQuarrelDue","GLOBAL",1) !Global("IRTCooldownDue","GLOBAL",1)~ THEN EXTERN BIMOEN25 VicBan3
	IF ~OR(2) Global("IRTQuarrelDue","GLOBAL",1) Global("IRTCooldownDue","GLOBAL",1)~ THEN EXTERN BIMOEN25 NotInTheMood
END

CHAIN BIMOEN25 NotInTheMood
	~I'm not in the mood to talk right now, Viconia. Leave me be.~
	== BVICON25 ~I see. I am aware of your little quarrel. It is so revolting to see how dependent on <PRO_HIMHER> you are.~
	== BIMOEN25 ~You don't have a damn clue what's really going on, so shut your mouth already.~
	== BVICON25 ~You are pathetic. Go ahead, keep letting <PRO_HIMHER> step on you like a lowly worm. You owe <PRO_HIMHER> as much.~
	== BIMOEN25 ~Whatever.~
EXIT

CHAIN BIMOEN25 VicBan1
	~I'd like to think I give <PRO_HIMHER> something better than that. <PRO_HESHE> can find a slave anywhere. The bond we share... it's far more precious. <PRO_HESHE> knows that no matter what's happening all around us, I'll be at <PRO_HISHER> side, sharing the burden, giving <PRO_HIMHER> all of my love and support.~
	== BVICON25 ~(Viconia grimaces.) Already I regret initiating this conversation.~
	== BIMOEN25 ~Oh, really? I would die for <PRO_HIMHER>, Viconia. I mean, not *lightly*, but if it meant saving <PRO_HIMHER>, I would. I'd give up the soul that <PRO_HESHE> rescued for me.~
	== BVICON25 ~Which is the least you owe <PRO_HIMHER>, girl.~
		== BIMOEN25 ~It's not about debt, but speaking of, it kind of reminds me of a certain someone. A poor helpless drow that would've burned at the stake if <CHARNAME> hadn't shown up at the right time...~
END BIMOEN25 108

CHAIN BIMOEN25 VicBan2
	~<CHARNAME> hates me, Viconia. I'm still here because I'm useful somehow, and I do owe <PRO_HIMHER> - but you can't get me drunk enough to stretch loyalty *that* far.~
	== BVICON25 ~And so you fail to repay your debt. Without <CHARNAME>, you would be nothing.~
	== BIMOEN25 ~Oh yeah? I know the way <PRO_HESHE> found you, y'know. You'd be a pile of dirty ashes if <PRO_HESHE> hadn't stepped in, but I don't see you groveling at <PRO_HISHER> feet, fetching <PRO_HISHER> snacks and licking <PRO_HISHER> boots.~
	== BVICON25 ~I would sooner embrace death than give myself to servitude. However, I had presumed it would come as second nature to you, given your feeble sensibilities and needy behavior.~
	== BIMOEN25 ~Gee. Thanks, Viconia. Thanks a lot for that.~
EXIT

CHAIN BIMOEN25 VicBan3
	~I already felt like that sometimes. That's why we're not together anymore.~
	== BVICON25 ~It is baffling that you would rebel against <PRO_HISHER> wishes so. I wouldn't have been so merciful with you, had I been in <PRO_HISHER> place. You belonged to <PRO_HIMHER>, after all. You still do.~
	== BIMOEN25 ~Oh, please. I'm still gonna stick by <PRO_HIMHER> through thick and thin, y'know. Regardless of what happened between us, <PRO_HESHE>'s been like my other half since we left Candlekeep. I'd still die for <PRO_HIMHER> and give up my soul if it meant keeping <PRO_HIMHER> safe.~
	= ~Makes me wonder, would you go that far?~
	== BVICON25 ~(Viconia frowns.) What could you mean by that?~
END BIMOEN25 109

// Haer'Dalis cheesy come-on
ADD_TRANS_TRIGGER BHAERD25 28 ~!Global("ImoenRomanceActive","GLOBAL",2) !Global("IRTQuarrelDue","GLOBAL",1) !Global("IRTCooldownDue","GLOBAL",1)~ DO 0

EXTEND_BOTTOM BHAERD25 28
   IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN EXTERN BIMOEN25 HaerBanExt1
	  IF ~!Global("ImoenRomanceActive","GLOBAL",2) OR(2) Global("IRTQuarrelDue","GLOBAL",1) Global("IRTCooldownDue","GLOBAL",1)~ THEN EXTERN BIMOEN25 HaerBanExt2
END


CHAIN BIMOEN25 HaerBanExt1
	~Uh-huh. You seem real confident that <CHARNAME> isn't a jealous <PRO_MANWOMAN>. <PRO_HESHE> might be about to stab you in the spleen for that.~
	== BHAERD25 ~Ah, but this is most innocent flattery, my wildflower, as most assuredly <CHARNAME> knows. I know of your relationship and certainly would not dream of becoming an obstacle for such beautiful a thing.~
	== BIMOEN25 ~Right. Anyway, about my grace, you were saying?~
	== BHAERD25 ~Hah hah! I was saying your grace is only comparable to your wit, my precious blackbird.~
	== BIMOEN25 ~Oh yeah? Well, carry on then, don't let me stop ya. I'm sure you can use the practice.~
	== BHAERD25 ~Alas, I do fear I overstep my bounds. Perhaps I should leave be for the time being, lest your radiance addle my senses.~
	== BIMOEN25 ~Gee. You're good. We should talk more often.~
END BHAERD25 32

CHAIN BIMOEN25 HaerBanExt2
	~Uh-huh. I'm not in the mood for this, sorry. If you'll excuse me...~
	== BHAERD25 ~But of course, my sweet Imoen. 'Tis been a lack of tact on my part, accept my apologies.~
EXIT

// Imoen mentions in a banter with Cernd that she was 8 years old and stole a watch from Winthrop, but the official timeline says she arrived at Candlekeep when she was 10.
// Here it's changed to "wee girl"

REPLACE BIMOEN25
IF ~~ THEN BEGIN 40
	SAY ~Actually, yes. I was still a wee girl and Winthrop had this big gold chain hanging out of the back pocket of his robes all day, staring me in the face. I just couldn't help myself.~
	IF ~~ THEN EXTERN BCERND 35
END
END

// Keldorn and his ring
ADD_TRANS_TRIGGER BKELDO25 39 ~!Global("ImoenRomanceActive","GLOBAL",2)~ DO 0

EXTEND_BOTTOM BKELDO25 39
   IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN EXTERN ~BIMOEN25~ 39Keldorn
END 

CHAIN BIMOEN25 39Keldorn
	~Oh, I know that you're married and I'm with <CHARNAME> and all that, Keldorn... but do you have *any* idea how good you look? I... I can't help myself, I just want to touch you all the time!~
	== BKELDO25 ~Imoen! I... I have a daughter that is the same age as you!~
	== BIMOEN25 ~I don't know what it is, Keldorn... maybe it's the Bhaal essence in me. I just want to run my fingers through your hair and nibble on your ears! Oh, Keldorn, you drive me so wild!~
	== BKELDO25 ~But I thought you were in love with <CHARNAME>! I can't allow this to happen!~
	== BIMOEN25 ~<PRO_HESHE> can't satisfy me anymore. (She takes Keldorn's hand in hers as she bites her lower lip.) What I really need is a mature, experienced man who knows how to treat a woman...~
	== BKELDO25 ~By Torm, no! (He withdraws his hand in shock.) This is terrible! I... I had no idea I had this effect on you...~
	== BIMOEN25 ~Oh, get over yourself already, Keldorn! Sheesh. (Imoen giggles.) Here's your ring back. I won't take it again, I promise.~
EXIT


// Imoen and the vampire tramp/man-whore in Saradush

ADD_TRANS_TRIGGER SARPROVF 0 ~!Global("ImoenRomanceActive","GLOBAL",2)~ DO 0
ADD_TRANS_TRIGGER SARPROVM 0 ~!Global("ImoenRomanceActive","GLOBAL",2)~ DO 0


EXTEND_BOTTOM SARPROVF 0
	+ ~IsValidForPartyDialog("Imoen2") Global("ImoenRomanceActive","GLOBAL",2) PartyGoldGT(49) !Global("ToldVampires","GLOBAL",1)~ + ~Sounds good to me!~ EXTERN IMOEN25J spvf1
END
EXTEND_BOTTOM SARPROVM 0
	+ ~IsValidForPartyDialog("Imoen2") Global("ImoenRomanceActive","GLOBAL",2) PartyGoldGT(49) !Global("ToldVampires","GLOBAL",1)~ + ~Sounds good to me!~ EXTERN IMOEN25J spvf2
END

APPEND IMOEN25J
IF ~~ THEN spvf1
	SAY ~You better keep Captain Wood inside yer pants the whole time if you know what's best for ya, darling.~
	IF ~~ THEN EXTERN SARPROVF 1
END

IF ~~ THEN spvf2
	SAY ~You better keep all yer clothes on the whole time if you know what's best for ya, darling.~
	IF ~~ THEN EXTERN SARPROVM 1
END
END

// Imoen and the n00b trollop in Saradush


ADD_TRANS_TRIGGER SARPRO01 11 ~!Global("ImoenRomanceActive","GLOBAL",2)~ DO 0

EXTEND_BOTTOM SARPRO01 11
	+ ~IsValidForPartyDialog("Imoen2") Global("ImoenRomanceActive","GLOBAL",2)~ + ~Sounds good. Let's go.~ EXTERN IMOEN25J sarpro1
END

APPEND IMOEN25J
IF ~~ THEN sarpro1
  SAY ~Ha ha, that's real funny. Reeeeal funny, I'm crackin' up here.~
	= ~Look at the poor girl, she's trembling! You haven't done this before, have ya.~
	IF ~~ THEN EXTERN SARPRO01 3
END
END

// Imoen interjects to Saemon in Amkethran

I_C_T amsaemon 4 IRTIntSae
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Imoen2")~ THEN ~Saemon, you dirty two-timing vermin! You know as well as we do that we haven't seen you since you *betrayed us* in Amn!~
	== AMSAEMON IF ~IsValidForPartyDialog("Imoen2") See("Imoen2")~ THEN ~Such silliness. The two hundred gold pieces that exchanged hands yesterday prove you wrong, I'm afraid.~
END

// Imoen saves Asana in Amkethran if you do nothing
//this is a special case we DONT WANT THE NORMAL DO's to happen as it contains cutscenes etc
INTERJECT AMMERC04 2 IRTAsanaInt
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Stop! I won't sit back and let this happen.~
END AMMERC03 AsanInter1

CHAIN AMMERC03 AsanInter1
	~This woman is a thief, and she will pay for her crimes!~
	== IMOEN25J ~She just wanted to feed her starving family! Have you never been hungry? Or are you too damn dense to understand empathy?~
	== AMMERC04 ~Insolent wench! There is no excuse for this. We are guests in this town, and the daughter of the Mayor dares take our gold! This is an insult which must be repaid in blood!~
	== AMMERC03 ~Now stand aside and let justice prevail, or face the consequences!~
	== IMOEN25J ~What consequences? Your blood on my clothes?~
	== AMMERC04 ~You little whore! How dare you threaten us? You will make good sparring practice!~
	== IMOEN25J ~(Imoen's voice is harsh with seething scorn.) Have you even looked at us, little man? The gear we carry, the weapons we wield? You haven't even bothered to look at our faces, have you. We slaughtered Yaga-Shura, the Fire Giant - only the last entry on a long list of death and destruction. You presume to harm us? Your sword would never come ten feet from my person. Not even your entire army of imbeciles could defeat us!~
	== IMOEN25J ~So here's your choice, rot-for-brains. You can forget this whole incident and walk away alive, or you can explode in tiny little bits. It's a real hard choice, so think carefully about it.~
	== AMMERC03 ~(The mercenaries stare at the archmage. Though they burn with hatred, Imoen's words seem to make them pay attention to whom they're truly dealing with. It doesn't take them long to realize just how much your power surpasses their own.)~
	== AMMERC03 ~This is not over. Mark my words.~ DO ~ActionOverride("ammerc04",EscapeArea()) EscapeArea()~
	== AMASANA ~Thank you, my Lady. I cannot repay you for saving my life, though my father might have some small reward for you. Please excuse me now... this has been most upsetting.~ DO ~SetGlobal("IRTImoenHero","GLOBAL",1) SetGlobal("AsanaPlot","GLOBAL",3) EscapeArea() ActionOverride("Imoen2",StartDialog("IMOEN25J",Player1))~ 
EXIT

APPEND IMOEN25J
IF WEIGHT #1 ~Global("IRTImoenHero","GLOBAL",1)~ THEN ImoenHero
  SAY ~(Imoen remains tense until everyone goes out of sight. Then she takes a deep breath and exhales in relief.)~
  ++ ~I hope you realize that, had they attacked, you'd have been on your own.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-10) SetGlobal("IRTImoenHero","GLOBAL",2)~ + IH4
  ++ ~I'd never seen this side of you, Imoen. I like it.~ DO ~SetGlobal("IRTImoenHero","GLOBAL",2)~ + IH1
  ++ ~This is direct insubordination. I cannot tolerate this.~ DO ~SetGlobal("IRTImoenHero","GLOBAL",2)~ + IH3
  ++ ~(You shrug and move on, uncaring.)~ DO ~SetGlobal("IRTImoenHero","GLOBAL",2)~ EXIT
  ++ ~I guess that was the right thing to do. I'm sorry I didn't intervene.~ DO ~SetGlobal("IRTImoenHero","GLOBAL",2)~ + IH1
  ++ ~I don't approve of what you just did, but... well played.~ DO ~SetGlobal("IRTImoenHero","GLOBAL",2)~ + IH1
END

IF ~~ THEN IH1
  SAY ~(She glances at you, indifference in her eyes.) Whatever, <CHARNAME>.~
  IF ~~ THEN EXIT
END

IF ~~ THEN IH3
  SAY ~(She glances at you, indifference in her eyes.) Do as you may, I don't care.~
  IF ~~ THEN EXIT
END

IF ~~ THEN IH4
  SAY ~(She glances at you, indifference in her eyes.) Then I guess I'd have killed them all myself.~
  IF ~~ THEN EXIT
END
END

// Imoen greets Lazarus Librarus in Amkethran

INTERJECT 25SPELL 5 IRTIntLazAmk
	== IMOEN25J IF ~AreaCheck("AR5502") IsValidForPartyDialog("Imoen2")~ THEN ~Lazarus, you're alive! I was hoping you'd make it out of Saradush in time...~
END 25SPELL 6


//Volo comment on imoen
ADD_TRANS_TRIGGER IMOEN25J 32 ~!Global("ImoenRomanceActive","GLOBAL",2)~ DO 0

EXTEND_BOTTOM IMOEN25J 32
   IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN EXTERN SARVOLO Imvolo
END

CHAIN 
IF ~~ THEN SARVOLO Imvolo
~Actually, milady, I was not finished.~
==IMOEN25J ~Aw. Sorry. Go for it.~
==SARVOLO ~*Ahem* ... at her command. Her close friendship with <CHARNAME> grew into something much deeper, and bards across Faerun will sing of their undying love for centuries to come.~
==IMOEN25J ~Yeah, okay, sounds good. Aaand?~
==SARVOLO ~And... her beauty knew no match among mortal kin.~
==IMOEN25J ~Yay!~
EXIT