// Resisted the Taint

APPEND IMOEN25J
IF ~~ THEN HowResist
	SAY ~Eh. (Imoen shrugs.) There's good days. There's bad days. There's days I wanna stab everyone. The usual.~
	= ~I wouldn't say it's gotten much worse since that last time, though. I dunno, it feels... manageable, for the most part. Not that I wouldn't love for it to go wring lemons somewhere else and leave me well alone already.~
	= ~How about you? How ya doin' with all that?~
	++ ~I'm just fine. I think I'm past that stage.~ + HowRes1
	++ ~It's always going to remain tough, no matter how long I deal with it.~ + HowRes2
	++ ~I don't even notice it anymore.~ + HowRes3
	++ ~It's nightmarish. I feel like I've been slowly losing my mind all this time.~ + HowRes4
	++ ~"Go wring lemons somewhere else"? What kind of expression is that?~ + HowRes5
END

IF ~~ THEN HowRes1
	SAY ~Oh, that must be nice. Though you probably have worse things to worry about now.~
	= ~At least I have something to look forward to. Anyway, I'm doin' alright. Not much else to say, sorry!~
	IF ~~ THEN EXIT
END

IF ~~ THEN HowRes2
	SAY ~Oh, yay. I'm so happy to hear that. At least we're not alone with it, huh? Misery loves company an' all that.~
	= ~Anyway, I'm doin' alright. Not much else to say, sorry!~
	IF ~~ THEN EXIT
END

IF ~~ THEN HowRes3
	SAY ~Oh, hah. That's kinda sad, isn't it? Guess you can imagine the Taint as a grumpy old man, mumbling to itself in the background, being a general nuisance that you tune out.~
	= ~Hope I get there too. Right now it's more like a kid that won't shut up. A really obnoxious, disturbing kid.~
	= ~Anyway, I'm doin' alright, all things considered. Thanks for asking, please come again.~
	IF ~~ THEN EXIT
END

IF ~~ THEN HowRes4
	SAY ~Oh Gods, you and me both. In a way I'm glad to hear you say that. Sometimes I wonder if there's much of my old self left.~
	= ~Sorry, I shouldn't be like that. Misery loves company, I guess. At least we can remind each other of what we used to be like.~
	= ~Anyway... thanks for asking. Hold on to yer marbles, for all our sakes.~
	IF ~~ THEN EXIT
END

IF ~~ THEN HowRes5
	SAY ~I dunno. It's what came to my head. Imoen works in mysterious ways.~
	= ~What I meant to say is that the Taint can bugger off and stop being a pain in my butt any day now, thank you very much. I think I'd sooner have that Noober guy following us around again.~
	= ~Anyway, thanks for askin'. I'll be alright, don't worry about me.~
	IF ~~ THEN EXIT
END	

// Controlled the Slayer

IF ~~ THEN HowSlay
	SAY ~(Imoen takes a moment to consider her response.)~
	= ~It's like... a polymorph spell jacked up on every potion under the sun. Everything is warped and twisted, like seen through the eyes of a predator. It also feels like I'm holding hands with a demon. Sometimes it pulls this way, and I push *this* way, and we end up somewhere in the middle. I thoroughly loathe it and I still want nothing but to be rid of it.~  
	= ~A different part of me, though... (she fidgets a bit.) I can't ignore how thrilling it is. The heightened senses and the raw power, it's like an altered state where nothing can get to ya. I can see how it could become... addictive. For someone not as repulsed by the Taint as I am, that is.~
	= ~How is it for you?~
	++ ~You just described it word for word.~ + HowSlay2
	++ ~It's different for me. I can't quite explain it.~ + HowSlay3
	++ ~I bribe the Slayer with bags full of candy, so we usually have a good time.~ + HowSlay4
	++ ~It's different for me. I basically give up on what makes me who I am and give in to the rage.~ + HowSlay5
	++ ~It's nothing like that. I become a God among mortals, fully in control and ready to slaughter my enemies.~ + HowSlay6 
END	
	
IF ~~ THEN HowSlay2
	SAY ~(Imoen nods.) It's a rough deal we got. Maybe it'll all become far easier when we don't have to resort to violence so often.~
	IF ~~ THEN GOTO HowSlayEnd
END

IF ~~ THEN HowSlayEnd
	SAY ~... That's, you know, when we die, probably. Hah.~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN HowSlay3
	SAY ~(Imoen nods.) Everyone's built differently. None of the Bhaalspawn we've fought so far seem to turn into the Slayer. I guess we're similar, but not identical. Maybe it'll all become far easier when we don't have to resort to violence so often.~
	IF ~~ THEN GOTO HowSlayEnd
END
	
IF ~~ THEN HowSlay4
	SAY ~Pfft! If with "bags full of candy" ya mean "meatsacks full of organs", then I get where yer coming from, 'cuz I do that all the time.~
	= ~Yeesh. That was a bit dark, wasn't it.~
	= ~Anyway, it wouldn't be so bad if we didn't have to resort to violence all the time. Kinda hard to ignore the urges when everyone's threatening to kill you.~
	= ~Maybe we should just lie down and die already, huh? We're too damn stubborn, <CHARNAME>. We should work on our people skills.~
	IF ~~ THEN EXIT
END

IF ~~ THEN HowSlay5
	SAY ~Huh. After you talked me so hard into controlling this thing, *that's* how you go about it? Okay...~
	= ~Guess you were makin' sure I didn't make your same mistakes. Not that I'm judging ya or nothin', this would all be a lot easier if we didn't have to resort to violence so often.~
	IF ~~ THEN GOTO HowSlayEnd
END

IF ~~ THEN HowSlay6
	SAY ~Yikes. I think I'll keep my version, thanks. I'd rather not start thinking that way, who knows where I'd end up.~
	= ~Not that I'm judging ya or nothin'. This would all be a lot easier if we didn't have to resort to violence all the time.~
	IF ~~ THEN GOTO HowSlayEnd
END
	
// Became the Ravager

IF ~~ THEN HowAss
	SAY ~(Imoen fidgets a bit.) Well, I don't so much *become* it as I just let it take over for a while. All the violence and aggression builds up, and when the moment comes I let it loose. Hopefully directed at our enemies.~
	= ~While it's happening, my brain just... disconnects. I don't remember much of what happens - but when I come back, it's like a huge burden off my chest. Like my lungs were full of lead, and I breathed all that garbage out.~
	= ~And sure enough, soon they start filling back up, and the awful cycle continues. (She fakes a smile.) Isn't it wonderful?~
	= ~You were right, though. There's no other choice for me. I am what I am, I see that now.~
	= ~Why'd ya ask?~
	++ ~Just making sure you're doing alright.~ + HowAss2
	++ ~Just making sure you're not having second thoughts.~ + HowAss2
	++ ~Just curious.~ + HowAss2
	++ ~I wanted to compare your experiences to mine.~ + HowAss2
	++ ~I was bored.~ + HowAss2
END
	
IF ~~ THEN HowAss2
	SAY ~(Imoen nods in understanding, then suddenly frowns.)~
	= ~Y'know what? I just lied to you. I don't completely disconnect. I'm aware of what's happening, but I just let it happen, because... because it feels good - and I know that's all kinds of messed up, but I find myself caring less and less.~
	= ~And y'know the worst part? What I just said, it used to scare me witless. Now it's more like... well, jeez, that's too bad, isn't it, a damn shame, but what can you do?~
	= ~Can we maybe not talk about it? I'd rather not talk about it.~
	IF ~~ THEN DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",3)~ EXIT
END
END
