// *** PARTY COMPLAINTS / COMMENTS ABOUT THE INVOLVEMENT - Set 1 ***

/* These comments can only occur a few days (game time) after Imoen and PC sleep together (MRSleptImoen = 1). However, soem of them have additional conditions (written in the dialog itself) regarding if it occurs before or after the romance is resolved. */


//** Keldorn - Complete**//

APPEND KELDORJ
	IF ~
		Global("MRKeldornReaction","GLOBAL",1)~ THEN BEGIN MRKelReact
	SAY ~<CHARNAME>. (Keldorn slowly alternates his gaze between you and Imoen. An unfathomable expression masks his face and you cannot begin to guess his thoughts.)~
	=
	~We have long known that Imoen was your childhood friend. Now we have discovered that she is your 'sister' as well, although I do not believe that being Bhaalspawn implies that you are natural siblings.~
	=
	~I am not blind. And I am aware of what you two have been going through. But I had never thought that you would become... 'involved' in this way.~
	IF ~IsValidForPartyDialog("Imoen2")~ THEN DO ~SetGlobal("MRKeldornReaction","GLOBAL",2)~ EXTERN IMOEN2J MRKelReact
	IF ~!IsValidForPartyDialog("Imoen2")~ THEN DO~SetGlobal("MRKeldornReaction","GLOBAL",2)~ GOTO MRKelReact2
	END
	
	IF ~~ THEN BEGIN MRKelReact2
	SAY ~Have you anything to say for yourself?~
		IF ~IsValidForPartyDialog("Imoen2")~ THEN REPLY ~She's right, Keldorn. We're not involved.~ GOTO MRKelReact3
		IF ~!IsValidForPartyDialog("Imoen2")~ THEN REPLY ~We're not 'involved', Keldorn.~ GOTO MRKelReact3
		++ ~Life is full of surprises, isn't it?~ GOTO MRKelReact3Surprise
		++ ~Not now, Keldorn. I'm in no mood for a lecture.~ GOTO MRKelReact3PreNo
		++ ~I love her. That says enough.~ GOTO MRKelReact3Love
	END
	
	IF ~~ THEN BEGIN MRKelReact3
		SAY ~A fine and easy answer... but I am neither blind nor a fool.~
		IF ~~ THEN GOTO MRKelReact4
	END
	
	IF ~~ THEN BEGIN MRKelReact3PreNo
		SAY ~Avoiding the issue will not solve it, <CHARNAME>.~
			++ ~I don't care what you think.~ GOTO MRKelReact3No
			IF ~IsValidForPartyDialog("Imoen2")~ THEN REPLY ~She's right, Keldorn. We're not involved.~ GOTO MRKelReact3
			++ ~We're not 'involved', Keldorn.~ GOTO MRKelReact3
			++ ~I *said* not now! You aren't here to be my moral guidance, paladin. Don't waste my time with your musings.~ GOTO MRKelReact3No
			++ ~I love her. And that is not an 'issue.'~ GOTO MRKelReact3Love
 END
	
	IF ~~ THEN BEGIN MRKelReact3Love
		SAY ~A fine and easy answer, <CHARNAME>. But it is not that simple.~
			++ ~I think it is. And if you truly are the man I think you are, you will realize it sooner or later.~ GOTO MRKelReact4
			++ ~I know it isn't, Keldorn. But I trust your common sense, and your wisdom. Someday you will see that I speak the truth.~ GOTO MRKelReact4
			++ ~Keldorn, you are married, and you truly love your wife. You should understand this better than anyone.~ GOTO MRKelReact4
			++ ~I don't care what you think.~ GOTO MRKelReact3No
			++ ~Leave me be! You aren't here to be my moral guidance, paladin. Don't waste my time with your musings.~ GOTO MRKelReact3No
	END
	
	IF ~~ THEN BEGIN MRKelReact3No
		SAY ~Very well. If you do not wish to listen to reason, then we will continue this conversation later.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRKelReact3Surprise
		SAY ~A fine and easy answer, <CHARNAME>. But it is not that simple.~
			++ ~I don't care what you think.~ GOTO MRKelReact3No
			++ ~I think it is. The gods work in mysterious ways, wouldn't you agree?~ GOTO MRKelReact3Surprise2
			++ ~What, you've never been surprised by life? Never had an unexpected blessing fall into your lap?~ GOTO MRKelReact3Surprise2
			++ ~Look, leave me be! You aren't here to be my moral guidance, paladin. Don't waste my time with your musings.~ GOTO MRKelReact3No
	END

	IF ~~ THEN BEGIN MRKelReact3Surprise2
		SAY ~To attribute this to the will of the gods is dangerous, <CHARNAME>. Be careful with your words.~
			++ ~You may be a paladin, Keldorn, but I am half-divine. I think I know a bit more about what the gods are capable of than you do.~ GOTO MRKelReactSurpriseBhaal
			++ ~Is that a threat? Perhaps *you* should be careful with your words... before you regret them.~ GOTO MRKelReact3No
			++ ~And who are you to say what the gods do or do not want for me? Has Torm whispered in your ear that I am doomed?~ GOTO MRKelReact4
	END

	IF ~~ THEN BEGIN MRKelReactSurpriseBhaal
		SAY ~We both know who where your divine parentage comes from - and it is hardly a glowing endorsement on your feelings of what is right or wrong.~
		IF ~~ THEN GOTO MRKelReact4
	END

	IF ~~ THEN BEGIN MRKelReact4
	SAY ~I find your... 'relationship'... a very polarizing one. I do try to understand you two, and to be tolerant. However, my feelings as a man are in conflict with the vows I have taken as a paladin of the Most Noble Order of the Radiant Heart.~
		IF ~IsValidForPartyDialog("Imoen2")~THEN EXTERN IMOEN2J MRKelReact4
		IF ~~ THEN GOTO MRKelReact5
	END	
	
	IF ~~ THEN BEGIN MRKelReact5
		SAY ~I only ask that you give deep consideration to the path you are treading, <CHARNAME>. You are not playing with some summer fling, but with the sanctity of your very being.~
		IF ~~ THEN EXIT
	END
END

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRKelReact
		SAY ~(Imoen briefly glances at you) We are not 'involved'. In *any* way.~
		IF ~~ THEN EXTERN KELDORJ MRKelReact2
	END
	
	IF ~~ THEN BEGIN MRKelReact4
		SAY ~There isn't a relationship! Just- just stop talking about it already!~
		IF ~~ THEN EXTERN KELDORJ MRKelReact5
	END
END
	

// *** Aerie - Complete ***
APPEND AERIEJ
	IF ~Global("MRAerieReaction","GLOBAL",1)  GlobalLT("LoveTalk","LOCALS",17) 
		~ THEN BEGIN MRAerReact
		SAY ~(Aerie giggles as she looks at you and Imoen) I... I'm glad to see you together, <CHARNAME>. You are perfect for each other!~ 
		IF ~IsValidForPartyDialog("Imoen2")~ THEN DO ~SetGlobal("MRAerieReaction","GLOBAL",2)~ GOTO MRAerReact2
	END
END

CHAIN AERIEJ MRAerReact2
~And Imoen, why didn't you tell me you had a crush on <PRO_HIMHER>?~
==IMOEN2J IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Gah, just quit it, you. I had no idea what I wanted. Whatever feelings I had, it took me some time to admit it. Y'know, with the whole... uh... well...~
==AERIEJ ~Oh, Imoen, you're blushing!~
=~I really hope you'll stay together forever. You make such a wonderful couple!~
EXIT

CHAIN
IF ~Global("MRAerieReaction","GLOBAL",1) GlobalGT("LoveTalk","LOCALS",16) Global("AerieRomanceActive","GLOBAL",3)~ THEN AERIEJ MRAerImConflict
~(Aerie looks both nervous and troubled. Her eyes go from Imoen to you, from you to Imoen, and back to you again.)~
DO ~SetGlobal("MRAerieReaction","GLOBAL",2)~
== IMOEN2J ~Aerie... stop looking at me like that, please.~
== AERIEJ ~(Aerie is startled by Imoen's sudden interruption of her thoughts) I- excuse me?~
== IMOEN2J ~Don't act all innocent, you know what I'm talkin' about.~
== IMOEN2J ~Look Aerie... I'd like to have some words with ya. I know you don't like me much right now.~
== AERIEJ ~I... why- why do you think that?~
== IMOEN2J ~You think I don't know 'bout what happened between <CHARNAME> and you? You hate me because you think I stole <PRO_HIMHER> from you.~
== AERIEJ ~(Aerie's cheeks redden slightly) What? No, I- I would never think that! And I would never hate you for something that is not your fault, either.~
= ~<CHARNAME> and I just... just didn't work together. I... I *did* have this strange hope that we would overcome it and be together again but... it's obvious it won't be like that.~
= ~But I don't blame you or <PRO_HIMHER> for it, these are just... th- things that happen. Yesterday <PRO_HESHE> loved me, today it is you. Who knows what will happen tomorrow?~
== IMOEN2J ~Ah, so ya still hope <PRO_HESHE>'ll come back to ya, huh? (Aerie's words seem to anger Imoen, at first. Then Imoen seems to reconsider and puts out her hands in a conciliatory gesture.)~
== AERIEJ ~B-but I don't-~
== IMOEN2J ~No, no, look, I understand why you'd feel that way. That's why I wanted to clear the air between us.~
= ~I like you a great deal, Aerie. Yer one of the most decent people we've ever come across, and I really don't want this whole thing to drive us apart. In fact, I'd love it if we could... maybe become friends?~
== AERIEJ ~My... friend?~
== IMOEN2J ~I know all this is hard for ya... I know what you've been through, an' the last thing ya deserve is traveling with Miss Bitterness and <PRO_LADYLORD> Scornful Glares by your side, if y'know what I mean.~
= ~And the last thing *I'd* like is having you glaring at me all the time. Like you were doing just a moment ago - and don't try denyin' it.~
== AERIEJ ~S-sorry. Sorry. It's just... difficult.~
== IMOEN2J ~Yer super nice, Aerie. I wouldn't expect to be able to reason like this with anyone else. I'd much rather have a friend in you - (Imoen chuckles) rather than a witch who's always plotting my downfall! For what I've seen, you'd be one tough adversary.~
== AERIEJ ~Oh, Imoen, I don't hate you or- or have vengeful thoughts towards you or anything like that! It's only that... when I look at you two together, all those brief happy moments I had with <CHARNAME> stir in my mind and... and I can't help feeling sad, and bitter, and... and, well, and... lonely.~
== IMOEN2J ~Aaww... y'know, yer quite cute too. But I'm sure ya knew that already, hah. You could have anyone you like with those big round eyes of yours.~
== AERIEJ ~(A smile appears on Aerie's lips) You are just flattering me now.~
== IMOEN2J ~Yeah, did it work?~
== AERIEJ ~Maybe. If you say it a couple times again.~
== IMOEN2J ~(Both women giggle) Aw, just imagine all the gossip we can share. This is going to be great, Aerie. Mark this moment, it's the beginning of a beautiful friendship!~
== AERIEJ ~I... I really hope so, Imoen. And I *truly* hope you will be happy with <CHARNAME>.~
== IMOEN2J ~Thanks, Aerie. I truly hope so, too.~
EXIT

	
// *** Viconia - Complete ***


APPEND VICONIJ
	IF ~Global("MRViconiaReaction","GLOBAL",1)
		~ THEN BEGIN MRVicReact
		SAY ~So, you and the girl are finally together. How... appropriate.~
		IF ~Gender(Player1,MALE)~ THEN DO ~SetGlobal("MRViconiaReaction","GLOBAL",2)~ GOTO MRVicReactMale
		IF ~Gender(Player1,FEMALE)~ THEN DO ~SetGlobal("MRViconiaReaction","GLOBAL",2)~ GOTO MRVicReactFemale
	END

	IF ~~ THEN BEGIN MRVicReactMale
		SAY ~I knew there was some manner of attraction between you two. It was only a matter of time before you succumbed to your primal desires.~
		IF ~~ THEN GOTO MRVicReact2
	END

	IF ~~ THEN BEGIN MRVicReactFemale
		SAY ~I had never imagined you had such... tastes. Had I known that you lusted after the bodies of other women, then perhaps...~
		=
		~(She approaches you and looks lingeringly over your body.)~
		=
		~Perhaps if I would have given you a try... who knows?~
		IF ~~ THEN GOTO MRVicReact2
	END

	IF ~~ THEN BEGIN MRVicReact2
		SAY ~Tell me, <CHARNAME> - how does it feel to have sex with your own sister?~
		IF ~!IsValidForPartyDialog("Imoen2")~ THEN GOTO MRVicReact3
		IF ~IsValidForPartyDialog("Imoen2")~THEN EXTERN IMOEN2J MRVicReact2
	END
END

CHAIN IMOEN2J MRVicReact2
~What kinda sick question is that? And why in Faerun do you think <CHARNAME> would even answer you?~
==VICONIJ ~Because I am asking it, girl. Now hold your tongue and let the adults have their peace.~
==IMOEN2J ~(Imoen scowls but falls silent - but as Viconia turns her attention back to you, you can see Imoen making faces at the drow's back.)~
END VICONIJ MRVicReact3

APPEND VICONIJ
	IF ~~ THEN BEGIN MRVicReact3
		SAY ~Satisfy my curiosity, <CHARNAME>. I am intrigued.~
		IF ~IsValidForPartyDialog("Imoen2")~ THEN REPLY ~Whether we're related is debatable, Viconia. Bhaal was no ordinary 'father', after all. Sorry to disappoint you.~ GOTO MRVicReactExitBoring
		IF ~!IsValidForPartyDialog("Imoen2")~ THEN REPLY ~Viconia, you have understood nothing. We don't see each other as siblings anymore, so I can't answer your question.~ GOTO MRVicReactExitBoring
		++ ~I won't answer that, Viconia.~ GOTO MRVicReactExitBoring
		IF ~IsValidForPartyDialog("Imoen2")~ THEN REPLY ~(You can't help but laugh at Imoen's antics.)~ GOTO MRVicReact3Caught
		++ ~It's not like that at all, Viconia. What I feel for Imoen is based on affection and love, not just physical attraction.~ EXTERN IMOEN2J MRVicReactLove
		++ ~Um. It's okay, I guess.~ EXTERN IMOEN2J MRVicReact3Hey
		++ ~Actually, it's a good question. Let me tell you this: every time I get ahold of her t-~ EXTERN IMOEN2J MRVicReact3Hey
		++ ~That is absolutely uncalled for, Viconia. Apologize to both of us!~ GOTO MRVicReact3Sorry
	END

	IF ~~ THEN BEGIN MRVicReact3Caught
		SAY ~What? What is- (She looks back to see Imoen wearing the most ridiculous of faces.)~
		=
		~(Viconia frowns, glaring at both of you) It is no wonder why you two ended up together. One is as childish and pathetic as the other.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRVicReact3Sorry
		SAY ~(She narrows her dark eyes at you) I would not apologize even to Shar, <CHARNAME>. And do not presume to give me orders.~
		IF ~~ THEN EXIT
	END


	IF ~~ THEN BEGIN MRVicReactExitBoring
		SAY ~I will never understand you, kivvil. Not that there is much cause for regret in that.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRVicReact3Trained
		SAY ~Hah! She has you well trained, dog. Perhaps I have underestimated you, Imoen.~
		IF ~~ THEN EXTERN IMOEN2J MRVicReact3Dog
	END
END 

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRVicReactLove
	SAY ~(Imoen stops mocking Viconia and smiles brightly.)~
	=
	~That was beautiful, <CHARNAME>.~
	=
	~(She approaches you, hugs you and kisses your lips with all the love she can gather.)~
	IF ~~ THEN EXTERN VICONIJ MRVicReactExitBoring
	END

	IF ~~ THEN BEGIN MRVicReact3Hey
	SAY ~<CHARNAME>!~
	++ ~Uhh, I meant... err... that's none of your business!~ EXTERN VICONIJ MRVicReact3Trained
	++ ~What? I was just answering...~ EXTERN VICONIJ MRVicReact3Trained
	END
	
	IF ~~ THEN BEGIN MRVicReact3Dog
	SAY ~Yeah, that's true, look at this! Hey <CHARNAME>, bark for us, I'll give you some biscuits!~
	++ ~(Scowl at her.)~ GOTO MRVicReact3DogNo
	++ ~(Raise an eyebrow quizzically.)~ GOTO MRVicReact3DogNo
	++ ~(Play along and bark.)~ GOTO MRVicReact3DogYes
	END

	IF ~~ THEN BEGIN MRVicReact3DogNo
	SAY ~Hahah, c'mon, just poking some fun at you, that's all!~
	IF ~~ THEN EXTERN VICONIJ MRVicReactExitBoring
	END

	IF ~~ THEN BEGIN MRVicReact3DogYes
	SAY ~(Imoen is quite surprised. She didn't actually think you'd play along.)~
	= ~Aww, my doggie!~
	= ~(She pets your head playfully, but the look in her eyes tells you that when the rest of the party beds down for the night, you'll be getting more than just a biscuit...)~
	IF ~~ THEN EXTERN VICONIJ MRVicReactExitBoring
	END
END

/* Jaheira - Complete (see NPC banter file) */
APPEND JAHEIRAJ
	IF ~Global("MRJaheiraReaction","GLOBAL",1)~ THEN BEGIN JTMR1
		SAY~<CHARNAME>, I know what has been going on between you and Imoen. I have been waiting to see the outcome of it all...~
		=
		~And now that it has progressed to this point, I just wanted you to know that I personally disapprove such a relationship.~
		IF ~Gender(Player1,MALE)~ THEN DO ~SetGlobal("MRJaheiraReaction","GLOBAL",2) ~ GOTO JTMR2
		IF ~Gender(Player1,FEMALE)~ THEN DO ~SetGlobal("MRJaheiraReaction","GLOBAL",2)~ GOTO JTMR3
	END

	IF ~~ THEN BEGIN JTMR2
		SAY ~And not only because a sentimental relationship of such nature, when there is so much at stake, isn't a wise thing to get involved in...~
		IF ~~ THEN GOTO JTMR4
	END

	IF ~~ THEN BEGIN JTMR3
		SAY ~Especially, since you are a woman. I find it an unnatural thing, but in that matter everyone should choose freely.~
		IF ~~ THEN GOTO JTMR4
	END

	IF ~~ THEN BEGIN JTMR4
		SAY ~Mainly, I disapprove it because you two were raised, have behaved and in sum have *been* like siblings all these years; and now, you have discovered you *are* siblings, and Bhaalspawn no less.~
		IF ~~ THEN GOTO JTMR4a
	END

	IF ~~ THEN BEGIN JTMR4a
		SAY ~I don't know how Imoen has fallen into this pit of corruption you dare to call 'love'. Such actions go against the laws of nature.~
		IF ~!IsValidForPartyDialog("Imoen2")~ THEN GOTO JTMR5
		IF ~IsValidForPartyDialog("Imoen2")~ THEN EXTERN IMOEN2J JTMR4acha
	END
END

CHAIN IMOEN2J JTMR4acha
~I fell nowhere, Jaheira. I chose to do what my heart longed for. I understood that being Bhaalspawn is completely irrelevant. Why won't you?~
DO ~ActionOverride(Player1,SetDialog("Player1"))~
==JAHEIRAJ ~Because I serve Balance, Imoen. However, I was questioning <CHARNAME>, not you.~
END JAHEIRAJ JTMR5

APPEND JAHEIRAJ
	IF ~~ THEN BEGIN JTMR5
		SAY ~I still respect you, both of you, do not misunderstand. And it's because you are both my friends that I am saying this: your relationship is a mistake and an affront to the natural order.~
		IF ~~ THEN REPLY ~I would have never expected such prejudices from someone like you.~ GOTO JTMR11
		IF ~~ THEN REPLY ~Imoen means more to me than my own life, Jaheira. I truly love her.~ GOTO JTMR11
		IF ~~ THEN REPLY ~I have never cared for what you have to say, and I'm not about to start now.~ GOTO JTMR11
		IF ~~ THEN REPLY ~I respect your opinion, Jaheira, but it is settled already.~ GOTO JTMR11
		IF ~!IsValidForPartyDialog("Imoen2")~ THEN REPLY ~I have been asking myself that question again and again... is this right? Isn't this a huge mistake?...I think your right.~ GOTO JTMR12
		IF ~IsValidForPartyDialog("Imoen2")~ THEN REPLY ~I have been asking myself that question again and again... is this right? Isn't this a huge mistake?...I think your right.~  EXTERN IMOEN2J JTMR10acha
	END

	IF ~~ THEN BEGIN JTMR11
		SAY ~(Jaheira simply stares at you.)~
		=
		~Whatever you say, <CHARNAME>. I will not enter into an argument with you about this, despite the wrongness of your words. I still think that two Bhaalspawn fornicating undoubtedly offend the principles of nature. I only wanted you to know that.~
		IF ~~ THEN EXIT
	END


	IF ~~ THEN BEGIN JTMR12
		SAY ~You have made the right choice. It's good to see you still have some common sense left.~
		IF ~~ THEN DO ~ActionOverride(Player1,SetDialog("Player1"))~ EXTERN PLAYER1 JTMRGoOn
	END	
END

APPEND PLAYER1
	IF ~~ THEN BEGIN JTMRGoOn
		SAY~(You go on with your quest; Imoen simply ignores you. Things between you two would have never worked anyway...)~
		IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4)~
		EXIT
	END

END

CHAIN IMOEN2J JTMR10acha
	~What? And that's all? After all we've been through, after all we've told each other... it's over, just like that, because Jaheira says so?~
	=
	~This... this is a load of horseshit. (Tears already stream down her face. Imoen runs away from you.)~
	== JAHEIRAJ
	 ~Don't go after her, <CHARNAME>, leave her for a while. It might be painful, but it is best for everyone.~
END JAHEIRAJ JTMR12

/* Jan - Complete */

CHAIN
IF ~Global("MRJanReaction","GLOBAL",1)~ THEN JANJ MRJanReact
	~You know, you two remind me of my third cousin Gertie's babysitter's half-brother, Barker.~
	DO ~SetGlobal("MRJanReaction","GLOBAL",2)~
	== IMOEN2J ~Huh? Who? What?~
	== JANJ ~You and <CHARNAME>. You see, Barker-~
	== IMOEN2J ~Barker? That's a silly name.~
	== JANJ ~Well, he was a werewolf, you see. And Barker-~
	== IMOEN2J ~But if his parents named him Barker, wouldn't that mean he was born as a werewolf? That's not even possible.~
	== JANJ ~Barker wasn't his birth name, Imoen! Before his unfortunate encounter, he was good ol' Poindexter Whifflepot.~
	== IMOEN2J ~I can see why he went by Barker.~
	== JANJ ~Exactly. So anyways, Barker fell in love with his sister Marcia. Oh, the family was furious! Their father, Dunkirk, absolutely refused to hear of it. Such scandal had never been heard of in all the years of Dwerpthorp Village, not since Old Man Nump had stolen the prize statue for the annual turnip growing contest and hid it in Miss Delly's knickers. She wasn't wearing them at the time, of course.~
	== IMOEN2J ~Of course. And yeah, me 'n <CHARNAME> have gotten a lot of flack for the whole 'I'm <PRO_HISHER> sister' thing, too.~
	== JANJ ~Oh, they weren't upset because they were brother and sister.~
	== IMOEN2J ~They weren't?~
	== JANJ ~Dear me, of course not. But Dunkirk was allergic to dog hair, and Mrs. Whifflepot had always had more of a fancy for kittens.~
	== IMOEN2J ~Kittens?~
	== JANJ ~Instead of puppies. Oh, they were adorable! They had all had Barker's little black nose!~
EXIT

/* Nalia - Complete */

APPEND NALIAJ
	IF ~Global("MRNaliaReaction","GLOBAL",1)
	OR(2)
	Global("ImoenRomanceActive","GLOBAL",1)
	Global("ImoenRomanceActive","GLOBAL",2)
	Global("MRSleptImoen","GLOBAL",1)
	OR(5)
		InParty("Keldorn")
		InParty("Anomen")
		InParty("Jaheira")
		InParty("Korgan")
		InParty("Valygar")~ THEN BEGIN MRNalReact
		SAY ~<CHARNAME>, could I talk to you for a moment?~
		IF ~~ THEN REPLY ~Sure. What's on your mind?~ DO ~SetGlobal("MRNaliaReaction","GLOBAL",2)~ GOTO MRNalReact2
		IF ~~ THEN REPLY ~Now isn't a good time.~ DO ~SetGlobal("MRNaliaReaction","GLOBAL",2)~ GOTO MRNalReactImportant
	END

	IF ~~ THEN BEGIN MRNalReactImportant
		SAY ~It will only take a minute.~
		++ ~Well, okay.~ GOTO MRNalReact2
		++ ~What part of 'no' do you not understand?~ GOTO MRNalReactEnd
		++ ~Sounds important. Is everything alright, Nalia?~ GOTO MRNalReact2
	END

	IF ~~ THEN BEGIN MRNalReactEnd
		SAY ~Okay, okay. There's no need to get hostile about it.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRNalReact2
		SAY ~(Nalia motions you a few feet further from the group) I've heard certain people talking...~
		= ~And I just wanted to tell you that I see nothing wrong with it. Nobility have a long tradition of marrying cousins, and being with your sister isn't so incredibly different.~
		IF ~Gender(PLAYER1,FEMALE)~ THEN GOTO MRNalReact2Woman
		IF ~Gender(PLAYER1,MALE)~ THEN REPLY ~Uh. Thanks.~ GOTO MRNalReact3
		IF ~Gender(PLAYER1,MALE)~ THEN REPLY ~Who's been talking? Tell me!~ GOTO MRNalReact2Tell
		IF ~Gender(PLAYER1,MALE)~ THEN REPLY ~I don't care about "certain people's" opinions - and I don't care about yours.~ GOTO MRNalReact3
		IF ~Gender(PLAYER1,MALE)~ THEN REPLY ~Thank you, Nalia. It's good to have a friend who understands.~ GOTO MRNalReact3Friends
	END
	
	IF ~~ THEN BEGIN MRNalReact2Woman
		SAY ~That you're both women... well, that *is* a bit bizarre, I'll admit, but they'll get over it.~
		++ ~Uh. Thanks.~ GOTO MRNalReact3
		++ ~Who's been talking? Tell me!~ GOTO MRNalReact2Tell
		++ ~I don't care about "certain people's" opinions - and I don't care about yours.~ GOTO MRNalReact3
		++ ~Thank you, Nalia. It's good to have a friend who understands.~ GOTO MRNalReact3Friends
	END
		
	IF ~~ THEN BEGIN MRNalReact2Tell
		SAY ~Oh, please. Like you don't know.~
		IF ~~ THEN GOTO MRNalReact3
	END

	IF ~~ THEN BEGIN MRNalReact3Friends
		SAY ~You're welcome. Too many people with small minds have big mouths. But anyone can see how much you love Imoen... and that's all that should matter.~
		= ~That's all I really wanted to say. Thanks for listening... and good luck.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRNalReact3
		SAY ~All I'm saying is that you shouldn't listen to small minds with big mouths. Anyone can see how much you love Imoen... and that is all that should matter.~
		= ~That's all I wanted to say. Thanks for listening... and good luck.~
		IF ~~ THEN EXIT
	END
END


/* Cernd - Complete*/

APPEND CERNDJ

	IF ~Global("MRCerndReaction","GLOBAL",1)~ THEN BEGIN MRCerReact1
		SAY ~(Cernd whistles, oblivious to the tension you and Imoen have created within the group.)~
		IF ~InParty("Jaheira") Global("MRJaheiraReaction","GLOBAL",2)~ THEN REPLY ~You are also a druid, Cernd - do you agree with Jaheira? About Imoen and me?~ DO ~SetGlobal("MRCerndReaction","GLOBAL",2)~ GOTO MRCerReactJah
		IF ~OR(2)!InParty("Jaheira") !Global("MRJaheiraReaction","GLOBAL",2)~ THEN REPLY ~You're a druid, Cernd -- a guardian of nature and balance. What do you think about Imoen and me?~ DO ~SetGlobal("MRCerndReaction","GLOBAL",2)~ GOTO MRCerReact
	END
	
	IF ~~ THEN BEGIN MRCerReactJah //* Only if Jaheira's in the part, see above *//
		SAY ~Jaheira is a wise woman, but Nature holds many paths for Her children. What is natural for the spring blossom is not natural for the winter fox.~
			++ ~So you don't agree?~ GOTO MRCerReact
			++ ~Gah. Nevermind. I forgot how annoying it is to talk to you!~ EXIT
			++ ~So you agree?~ GOTO MRCerReact
	END

	IF ~~ THEN BEGIN MRCerReact
		SAY ~Many animals will take mates among their own family, if other mates are not available.~
		= ~People look at you and see a <PRO_RACE>, but that is not what you are. You are Bhaalspawn, and it is your nature to seek out your own kind, just as all Nature's creatures do.~
		= ~That you have taken Imoen as your mate is anything but unnatural.~
		++ ~Why haven't you spoken of this before now?~ GOTO MRCerReactSpeak
		++ ~You are a wise man, my friend. Thank you.~ GOTO MRCerReactEnd
		++ ~What a bunch of troll turds!~ GOTO MRCerReactTroll
	END

	IF ~~ THEN BEGIN MRCerReactSpeak
		SAY ~Why should I have? Who you choose as your partner has no bearing on me.~
		IF ~Gender(PLAYER1,MALE)~ THEN REPLY ~Even if we someday have children? Doesn't that concern you?~ GOTO MRCerReactChildren
		IF ~Gender(PLAYER1,FEMALE)~ THEN REPLY ~Even though we are both women? Doesn't that concern you?~ GOTO MRCerReactWomen
		++ ~Good point! Thanks, Cernd.~ GOTO MRCerReactEnd
	END

	IF ~~ THEN BEGIN MRCerReactChildren
		SAY ~Of course not. Do you really think that a single generation will turn your children into monsters? Does this happen with the sheep that are bred for thicker wool, or cattle for a certain color? Nature desires life - She does not let it so easily be warped and destroyed.~
		++ ~What a bunch of troll turds!~ GOTO MRCerReactTroll
		++ ~Thank you, Cernd. You've put my mind at ease.~ GOTO MRCerReactEnd
	END

	IF ~~ THEN BEGIN MRCerReactWomen
		SAY ~Of course not. I have lived in Nature's bosom and devoted my life to Her creatures. Do you think I have not seen buck pair with buck or two peahens tend a single nest? Such things happen. It, too, is natural.~
		++ ~What a bunch of troll turds!~ GOTO MRCerReactTroll
		++ ~Thank you, Cernd. You've put my mind at ease.~ GOTO MRCerReactEnd
	END

	IF ~~ THEN BEGIN MRCerReactTroll
		SAY ~Hah! From the foulest filth springs the fairest flower.~
		= ~Disagree with me as you will, <CHARNAME>. It makes no difference in the grand cycle of life.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRCerReactEnd
		SAY ~You are welcome, <CHARNAME>. I care for all of Nature's children... including you.~
		IF ~~ THEN EXIT
	END
END

/* Anomen - Complete */

APPEND ANOMENJ
	IF ~Global("MRAnomenReaction","GLOBAL",1) Gender(PLAYER1,MALE)~ THEN BEGIN MRAnoReactMale
		SAY ~Try as I might, I cannot believe what I see.~
		=~A perversion - a brother and a sister - pawing at each other with all the decency of two slavering dogs!~
		IF ~IsValidForPartyDialog("Imoen2")~ THEN DO ~SetGlobal("MRAnomenReaction","GLOBAL",2)~ EXTERN IMOEN2J MRAnoReact
	END

	IF ~Global("MRAnomenReaction","GLOBAL",1) Gender(PLAYER1,FEMALE)~ THEN BEGIN MRAnoReactFemale
		SAY ~Try as I might, I cannot believe what I see.~
		= ~A perversion - two siblings, two women no less - pawing at each other with all the decency of two slavering dogs!~
		IF ~IsValidForPartyDialog("Imoen2")~ THEN DO ~SetGlobal("MRAnomenReaction","GLOBAL",2)~ EXTERN IMOEN2J MRAnoReact
	END

	IF ~~ THEN BEGIN MRAnoReact2
		SAY ~If you have any shred of righteousness in your heart, <CHARNAME>, you will cease this depravity before it goes any further.~
		++ ~Righteousness? Not an ounce. Now shut up and leave us alone.~ GOTO MRAnoReact3
		++ ~This is uncalled for, Anomen, and it's none of your business.~ GOTO MRAnoReact3
		++ ~My heart *is* righteous - and I am not depraved.~ GOTO MRAnoReact3
	END

	IF ~~ THEN BEGIN MRAnoReact3
		SAY ~You do not know what you are saying. Mark my words, <CHARNAME>... This path will lead to your ruin.~
		IF ~~ THEN EXIT
	END
END

CHAIN IMOEN2J MRAnoReact
	~(Imoen shoots you a dark glare) Thanks for telling the whole damn continent, <CHARNAME>! Every last buffoon knows about us, it seems.~
	== ANOMENJ IF ~Global("AnomenIsKnight","GLOBAL",1)~ THEN ~<PRO_HESHE> said nothing, Imoen. But what has happened is obvious to anyone.~
	== ANOMENJ IF ~Global("AnomenIsNotKnight","GLOBAL",1)~ THEN ~<PRO_HESHE> said nothing, girl. But it is plain enough to see your sickness!~
END ANOMENJ MRAnoReact2



/* Valygar - Complete */

APPEND VALYGARJ
	IF ~Global("MRValygarReaction","GLOBAL",1)~ THEN BEGIN MRValSilent
		SAY ~(Valygar has kept his silence throughout the party's reaction to you and Imoen.)~
		IF ~~ THEN REPLY ~You are one of the few who have not voiced an opinion on Imoen and I.~ DO ~SetGlobal("MRValygarReaction","GLOBAL",2)~ GOTO MRValReact
		IF ~~ THEN REPLY ~(That's just as well. You've had enough opinions to last you a lifetime.)~ DO ~SetGlobal("MRValygarReaction","GLOBAL",2)~ EXIT
	END

	IF ~~ THEN BEGIN MRValReact
		SAY ~Some things are better left unsaid.~
			++ ~And that means what, exactly?~ GOTO MRValReact2
			++ ~You're right, they are. So let's keep it that way.~ EXIT
			++ ~Perhaps, but a friend wouldn't shy from sharing his thoughts.~ GOTO MRValReact2
	END

	IF ~~ THEN BEGIN MRValReact2
		SAY ~What do you wish me to say, <CHARNAME>? That I approve of such things?~
			IF ~OR(6)
				Class(PLAYER1,MAGE)
				Class(PLAYER1,FIGHTER_MAGE)
				Class(PLAYER1,FIGHTER_MAGE_THIEF)
				Class(PLAYER1,MAGE_THIEF)
				Class(PLAYER1,CLERIC_MAGE)
				Class(PLAYER1,FIGHTER_MAGE_CLERIC)~ THEN REPLY ~Do you not? Speak your mind, Valygar.~ GOTO MRValReact3Mages
			IF ~OR(6)
				Class(PLAYER1,MAGE)
				Class(PLAYER1,FIGHTER_MAGE)
				Class(PLAYER1,FIGHTER_MAGE_THIEF)
				Class(PLAYER1,MAGE_THIEF)
				Class(PLAYER1,CLERIC_MAGE)
				Class(PLAYER1,FIGHTER_MAGE_CLERIC)~ THEN REPLY ~Do you not? Speak your mind, Valygar.~ GOTO MRValReact3Mage
			++ ~Never you mind. Let's keep things private.~ EXIT
	END

	IF ~~ THEN BEGIN MRValReact3Mages
		SAY ~A pair of witches, cursed by the gods, consorting with each other? Do you truly think I could ever gaze upon that with anything more than contempt?~
		IF ~~ THEN GOTO MRValReact3Plural
	END
	
	IF ~~ THEN BEGIN MRValReact3Mage
		SAY ~A pair of witches, cursed by the gods, consorting with each other? Do you truly think I could ever gaze upon that with anything more than contempt?~
		IF ~~ THEN GOTO MRValReact3Imoen
	END

	IF ~~ THEN BEGIN MRValReact3Imoen
		SAY ~I know that Imoen is your sister, but she is also a witch - and deep inside, as twisted as any other.~
		= ~Perhaps worse, now that we know that she is also Bhaal's offspring.~
		IF ~IsValidForPartyDialog("Imoen2")~THEN EXTERN IMOEN2J MRValReact
		IF ~!IsValidForPartyDialog("Imoen2")~ THEN REPLY ~That's your objection? That she's a mage?~ GOTO MRValReact4
		IF ~!IsValidForPartyDialog("Imoen2")~ THEN REPLY ~You cannot compare Imoen to people like the Cowled Wizards and Irenicus!~ GOTO MRValReact2ImoenCowled
		IF ~!IsValidForPartyDialog("Imoen2")~ THEN REPLY ~That is quite possibly the dumbest thing I've ever heard.~ GOTO MRValReactDumb
			++ ~I don't quite care. Let's keep things private.~ EXIT
	END

	IF ~~ THEN BEGIN MRValReact3Imoen2	
		SAY ~It is nothing personal, Imoen. You are a kind and loving girl - but magic warps even the most noble souls. If you continue to embrace it, it will corrupt you as well.~
			++ ~That's your objection? That she's a mage?~ + MRValReact4
			IF ~Gender(PLAYER1,FEMALE)~ THEN REPLY ~Hrm... he has a point, Imoen. Maybe you should go back to your thieving ways.~ EXTERN IMOEN2J MRValReact2Female
			IF ~Gender(PLAYER1,MALE)~ THEN REPLY ~Hrm... he has a point, Imoen. Maybe you should go back to your thieving ways.~ EXTERN IMOEN2J MRValReact2Male
			++ ~That is quite possibly the dumbest thing I've ever heard.~ GOTO MRValReactDumb
			++ ~Never mind. Let's drop the issue.~ EXIT
	END

	IF ~~ THEN BEGIN MRValReact3Imoen3
		SAY ~Do you see? She is unwilling to hear even the thought of giving up such power.~
			++ ~This is quite possibly the dumbest thing I've ever heard.~ + MRValReactDumb
			++ ~Seriously? That's your objection? That she's a mage?~ + MRValReact4
			++ ~Never mind. Let's drop the issue.~ EXIT
	END

	IF ~~ THEN BEGIN MRValReact2ImoenCowled
		SAY ~It is nothing personal... but magic warps even the most noble souls. If she continues to embrace it, it will corrupt her as well.~
			++ ~This is quite possibly the dumbest thing I've ever heard.~ GOTO MRValReactDumb
			++ ~Seriously? That's your objection? That she's a mage?~ + MRValReact4
			++ ~Never mind. Let's drop the issue.~ EXIT
	END

	IF ~~ THEN BEGIN MRValReact3Plural
		SAY ~You walk a dangerous path already, <CHARNAME>. I do not see why you would wish to tempt Fate even more.~
			++ ~Hey now, no need to get rude about things.~ GOTO MRValReact3Plural1
			++ ~This is quite possibly the dumbest thing I've ever heard.~ GOTO MRValReactDumb
			++ ~Wait... your objection is that we use magic? Seriously?~ GOTO MRValReact4
			++ ~Never mind. Let's drop the issue.~ EXIT
	END

	IF ~~ THEN BEGIN MRValReact3Plural1
		SAY ~It is nothing personal... but magic warps even the most noble souls. If you continue to embrace it, it will corrupt you as well.~
			++ ~Wait... your objection is that we use magic? Seriously?~ GOTO MRValReact4
			++ ~This is quite possibly the dumbest thing I've ever heard.~ GOTO MRValReactDumb
	END

	IF ~~ THEN BEGIN MRValReactDumb
		SAY ~I am not surprised that you disagree with me. And now you know why I found it wiser to keep my opinion to myself.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRValReact4
		SAY ~It is not my only objection, but it is my strongest.~ 
		IF ~~ THEN GOTO MRValReactDumb
	END
END

	
APPEND IMOEN2J
	IF ~~ THEN BEGIN MRValReact
		SAY ~Hey! That's not nice at all! What'd I ever do to you, stuffypants?~
		IF ~~ THEN EXTERN VALYGARJ MRValReact3Imoen2
	END

	IF ~~ THEN BEGIN MRValReact2Female
		SAY ~(Imoen rolls her eyes and walks away, leaving you and Valygar to your discussion) Yeah, right. Like I'm gonna listen to two buffleheads like you guys tell me about magic.~
		IF ~~ THEN DO ~RunAwayFrom(Player1,45)~ EXTERN VALYGARJ MRValReact3Imoen3
	END

	IF ~~ THEN BEGIN MRValReact2Male
		SAY ~(Imoen rolls her eyes and walks away, leaving you and Valygar to your discussion) You guys are just a couple of stupid boys. What do you know 'bout magic anyways?~
		IF ~~ THEN DO ~RunAwayFrom(Player1,45)~ EXTERN VALYGARJ MRValReact3Imoen3
	END
END
	

/* Korgan - */

/* He only comments if you're both women, 'cause he's a lowlife perv */

APPEND KORGANJ
	IF ~Global("MRKorganReaction","GLOBAL",1)~ THEN BEGIN MRKorReact
		SAY ~'Ey lass - make this bloody walk worthwhile. Take a break an' kiss up yer sister.~
			IF ~OR(2) CheckStatLT(PLAYER1,12,CHR) Race(PLAYER1,HALFORC)~ THEN DO ~SetGlobal("MRKorganReaction","GLOBAL",2)~EXTERN IMOEN2J MRKorReactUgly
			IF ~CheckStatGT(PLAYER1,11,CHR) !Race(PLAYER1,HALFORC)~ THEN DO ~SetGlobal("MRKorganReaction","GLOBAL",2)~ EXTERN IMOEN2J MRKorReactCute
	END
END

CHAIN IMOEN2J MRKorReactUgly
~'Take a break and...' What in the Nine Hells is that supposed to mean?~
== KORGANJ IF ~OR(2) CheckStatLT(PLAYER1,12,CHR) Race(PLAYER1,HALFORC)~ THEN ~<CHARNAME> ain't much ta look at, but after all this bloody marchin' me standards ain't too high.~
== IMOEN2J IF ~OR(2) CheckStatLT(PLAYER1,12,CHR) Race(PLAYER1,HALFORC)~ THEN ~Look, Korgan - we're not dancing girls or prostitutes, okay? So keep your eyes to yourself!~
== KORGANJ IF ~OR(2) CheckStatLT(PLAYER1,12,CHR) Race(PLAYER1,HALFORC)~ THEN ~If ye don't wanna be looked at, ye shouldn't be smoochin' an' pawin' and gigglin' everywhere.~
== IMOEN2J IF ~OR(2) CheckStatLT(PLAYER1,12,CHR) Race(PLAYER1,HALFORC)~ THEN ~Oh yeah? Well how 'bout I solve that problem for ya?~
END
IF ~~ THEN DO ~ActionOverride("Imoen2",ForceSpell("Korgan",WIZARD_BLINDNESS))~ EXIT

CHAIN IMOEN2J MRKorReactCute
~'Take a break and...' What in the Nine Hells is that supposed to mean?~
== KORGANJ ~Ye daft, lass? All ye smoochin' an' pawin' an' gigglin' - it makes me heart swell.~
== VICONIJ IF ~IsValidForPartyDialog("Viconia")~ THEN ~That is not all I have seen swell, jalluk.~
== NALIAJ IF ~!IsValidForPartyDialog("Viconia") IsValidForPartyDialog("Nalia")~ THEN ~I doubt that's the only thing that swells. Disgusting.~
== KELDORJ IF ~!IsValidForPartyDialog("Viconia") !IsValidForPartyDialog("Nalia") IsValidForPartyDialog("Keldorn")~ THEN ~Do not subject these women to your filth, Korgan. Leave them be.~
== IMOEN2J IF ~!IsValidForPartyDialog("Viconia") !IsValidForPartyDialog("Nalia") !IsValidForPartyDialog("Keldorn")~ THEN ~Ew. Seriously, seriously ew!~
END
IF ~~ THEN DO ~ActionOverride("Imoen2",ForceSpell("Korgan",WIZARD_BLINDNESS)) ActionOverride("Imoen2",ForceSpell("Korgan",WIZARD_BLINDNESS))~ EXTERN IMOEN2J MRKorReactCuteEnd

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRKorReactCuteEnd
		SAY ~There. I feel better!~
		IF ~~ THEN EXIT
	END
END
	
/* These people don't comment directly on the relationship: Mazzy, Minsc, Edwin, Haer'Dalis */
