/* The Bodhi 'Kidnap' Scene - COMPLETED*/

ADD_TRANS_TRIGGER BODHIAMB 6 ~OR(3) !InParty("Imoen2") !See("Imoen2") StateCheck("Imoen2",CD_STATE_NOTVALID)~ DO 0

EXTEND_BOTTOM BODHIAMB 6
 IF ~InParty("Imoen2") See("Imoen2") !StateCheck("Imoen2",CD_STATE_NOTVALID)~ THEN GOTO MRBodhi6
END

//the prior dialogue above has See because Bodhi is there, but she has dissapeared now so remove See
//conditions below
ADD_TRANS_TRIGGER BODHIAMB 7 ~OR(2) !InParty("Imoen2") StateCheck("Imoen2",CD_STATE_NOTVALID)~ DO 0

EXTEND_BOTTOM BODHIAMB 7
  IF ~InParty("Imoen2") !StateCheck("Imoen2",CD_STATE_NOTVALID)~ THEN DO ~ DialogueInterrupt(FALSE)
	CreateCreatureObject("VAMPIM01",Myself,0,0,0)
	CreateCreatureObject("VAMPIM01",Myself,0,0,0)
	CreateCreatureObject("VAMPIM01",Myself,0,0,0)
	CreateCreatureObject("VAMPIM01",Myself,0,0,0)
	ForceSpell(Myself,DRYAD_TELEPORT)
	Wait(1)
	SetGlobal("Deactivate0801","AR0800",3)
	DestroySelf()
	~ UNSOLVED_JOURNAL #16351 /* ~The final battle with Bodhi

	Bodhi has revealed herself to me, letting me know that she is aware of my pursuit... and in an attempt to dissuade me from entering her lair unleashed yet more of her undead creations upon me. She swears I will lose much more than my life if I continue to pursue her... although, in truth, I have little choice.~ */ EXTERN IMOEN2J MRBodhiGone
END


APPEND BODHIAMB
	IF ~~ THEN BEGIN MRBodhi6
		SAY ~And as for you, my dear, broken, empty Imoen...~
		IF ~OR(2) Global("ImoenRomanceActive","GLOBAL",1) Global("ImoenRomanceActive","GLOBAL",2)~ THEN GOTO MRBodhi6-1
		IF ~ GlobalGT("ImoenRomanceActive","GLOBAL",2)~ THEN GOTO MRBodhi6-2
	END

	IF ~~ THEN BEGIN MRBodhi6-1
		SAY ~I can see through your hollow carcass, child. I know of the doubts that torment you. I wonder...~
		=
		~How much simpler would things be for you if I killed <CHARNAME> right now?~
		IF ~~ THEN EXTERN IMOEN2J MRBodhi6-1a
	END

	IF ~~ THEN BEGIN MRBodhi6-1b
		SAY ~Ooh, how adorable for you to presume. Perhaps I should show you right now which of us is to wither and rot. (Bodhi leans forward, as if she is about to attack. Her dark eyes gleam with hunger as bloodlust takes over her expression.)~
		IF ~~ THEN GOTO MRBodhi6-4
	END

	IF ~~ THEN BEGIN MRBodhi6-2
		SAY ~You have come to retrieve what you think is yours... your power has grown stronger, even without your soul. I warn you; desist now, foolish girl.~
		=
		~Know that you would not stand a chance against me. But I wonder...~
		=
		~How far would you go, without the help of your companions?~
		=
		~I wonder, how far you would go if I killed <CHARNAME> right now?~
		IF ~~ THEN EXTERN IMOEN2J MRBodhi6-2a
	END


	IF ~~ THEN BEGIN MRBodhi6-4
		SAY ~I had considered turning you into one of us, little Imoen. One whom would blindly follow my orders. But then...~
		=
		~Why would I want your body... (she tilts her head to the left, showing Imoen her sharp teeth as she smiles wickedly at her.)~
		=
		~When I already have your soul?~
		IF ~~ THEN EXTERN IMOEN2J MRBodhi6-5a
	END

	IF ~~ THEN BEGIN MRBodhi6-6
		SAY ~(Bodhi turns to you.)~
		IF ~~ THEN GOTO 7
	END
END

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRBodhi6-1a
		SAY ~You... y-you won't touch a single hair on <CHARNAME>'s head while I still draw breath, you disgusting vampire!~
		IF ~~ THEN EXTERN BODHIAMB MRBodhi6-1b
	END

	IF ~~ THEN BEGIN MRBodhi6-2a
		SAY ~I'll have my soul back, or die in the attempt, vampire. I'll enjoy watching you wither and vanish when i stake your rotten heart.~
		IF ~~ THEN EXTERN BODHIAMB MRBodhi6-1b
	END

	IF ~~ THEN BEGIN MRBodhi6-5a
		SAY ~I...~
		IF ~~ THEN EXTERN BODHIAMB MRBodhi6-6	
	END

	IF ~~ THEN BEGIN MRBodhiGone
		SAY ~Whew.~
		IF ~~ THEN GOTO MRBodhiGone2
	END
END

CHAIN IMOEN2J MRBodhiGone2
~For a moment there I thought she was going to jump me!~
== NALIAJ IF ~IsValidForPartyDialog("Nalia")~ THEN ~I thought that too.~
== JANJ IF ~IsValidForPartyDialog("Jan")~ THEN ~Yes, it seemed likely to happen.~
== ANOMENJ IF ~IsValidForPartyDialog("Anomen")~ THEN ~I also thought that she'd take you by surprise, Imoen.~
== CERNDJ IF ~IsValidForPartyDialog("Cernd")~ THEN ~I saw you in her claws already.~
== EDWINJ IF ~IsValidForPartyDialog("Edwin")~ THEN ~I knew she wouldn't.~
== VICONIJ IF ~IsValidForPartyDialog("Viconia")~ THEN ~Rather unexpected, I would say.~
== HAERDAJ IF ~IsValidForPartyDialog("HaerDalis")~ THEN ~I am surprised she didn't take you with her, blackbird... I feared she would.~
== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~Oh, I'm so glad she didn't take you! I thought she'd attack you.~
== JANJ IF ~IsValidForPartyDialog("Jan")~ THEN ~Yes, yes, that is what everyone thought!~
== KELDORJ IF ~IsValidForPartyDialog("Keldorn")~ THEN ~I feared we had lost you already, Imoen.~
== KORGANJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Aye, ye were gone fer sure!~
== MAZZYJ IF ~IsValidForPartyDialog("Mazzy")~ THEN ~Thank Arvoreen... I thought that foul creature would attack you, Imoen!~
== VALYGARJ IF ~IsValidForPartyDialog("Valygar")~ THEN ~Me too...~
== IMOEN2J
~Glad she didn't. I doubt you'd make it to her if I'm not around to help, y'know. (She smiles in your direction.)~
=
~C'mon, let's kick some undead butt.~
EXIT
