APPEND PLAYER1
	IF ~Global("MRRingSellImoen","GLOBAL",1)~ THEN BEGIN MRBracelet // from:
	 SAY ~(As you approach the Promenade's market, one voice stands out among the rest. It belongs to a corpulent woman that has set up shop above the Adventurer's Mart, hawking her wares at the top of her lungs.)~
         IF ~~ THEN DO ~ActionOverride(Player1,SetDialogue("Player1"))~ EXTERN MRWOMER MRWoman
	END
	
	IF ~~ THEN BEGIN MRBraceletGoAway
	   SAY ~(You do your best to ignore her obnoxious yelling, going about your business as usual.)~
	   IF ~~ THEN EXIT
        END

	IF ~~ THEN BEGIN MRBraceletApproach
	 SAY ~(Imoen has perked up as well. She tags along with you.)~
	 IF ~~ THEN DO ~ClearAllActions()
	StartCutSceneMode()
	StartCutScene("MrWoCut1")
	~ EXIT
	END

	IF ~~ THEN BEGIN MRBraceletApproach1 // from:
	 SAY ~(You come closer to the merchant, looking for something to buy to your sweetheart. Imoen joins you; her interest in the woman's wares is evident.)~ 
	 IF ~~ THEN DO ~ClearAllActions()
	StartCutSceneMode()
	StartCutScene("MrWoCut1")
	~ EXIT
	END


	IF ~~ THEN BEGIN MRBraceletPlan // from: 194.0 193.0
	 SAY ~(As you leave the woman's stall, Imoen flashes you a very mischievous grin.)~ 
	 IF ~~ THEN DO ~ClearAllActions() StartCutSceneMode() StartCutScene("MRWoCut2") ~ EXIT
	END
END

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRBraceletIm // from:
	 SAY ~Nah, just lookin', nevermind me. (Imoen's eyes gloss over the wares, not showing any real interest.)~
	 =~Not much to see, though...~
	 IF ~~ THEN EXTERN MRWOMER MRWomanAnnoyed
	END


	IF ~~ THEN BEGIN MRBraceletElbow // from:
	 SAY ~(You are interrupted by Imoen's elbow to your ribcage. She talks to you in a barely audible whisper, making sure the merchant can't hear.)~
	 = ~I think I see sumthin' good. (Her eyes gesture ever so slightly toward a glass case. Among gaudy accessories and trinkets, there is a strange, silvery bracelet. Myriad little carvings and symbols cover its surface.)~
	 IF ~~ THEN EXTERN MRWOMER MRWomanNotice
	END
	
	IF ~~ THEN BEGIN MRPurse
	SAY~(Imoen raises an eyebrow, clearly caught off-guard by the merchant's pin-sharp senses) Wouldn't call it the finest. Pretty ugly, if you ask me.~
	IF ~~ THEN EXTERN MRWOMER MRAfterPurse
	END

	IF ~~ THEN BEGIN MRWomanPrice // from:
	 SAY ~Nah, <PRO_HESHE> really isn't. We've got plenty of magical stuff, you wouldn't even know.~
         = ~All I came here for was to get me a new jade ring. I misplaced the one I had, and it really goes with this one outfit I like to wear. Might you have one?~
         IF ~~ THEN EXTERN MRWOMER MRWomanPriceJade
    END

	IF ~~ THEN BEGIN MRWomanBuyRing // from: 1864.0
	 SAY ~No, just plain jade, thanks. That one, right over there. It's pretty enough.~
         = ~Do ya mind getting it, <CHARNAME>? I think I left my purse at the inn.~
	 IF ~~ THEN REPLY ~Right, at the inn. I'll get it, of course.~ GOTO MRBraceletDemand2
	 IF ~~ THEN REPLY ~Aren't you Miss Proper today. Sure, why not.~ GOTO MRBraceletDemand2
	 IF ~OR(4)
	Global("AerieRomanceActive","GLOBAL",2)
	Global("JaheiraRomanceActive","GLOBAL",2)
	Global("ViconiaRomanceActive","GLOBAL",2)
	Global("AnomenRomanceActive","GLOBAL",2)
	!Global("ImoenRomanceActive","GLOBAL",2)
	~ THEN REPLY ~I don't want to buy you anything, Imoen. I want something for my beloved.~ GOTO MRBraceletDemand2
	 IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~I suppose it'll do as a gift for you.~ GOTO MRBraceletDemand2
	 IF ~~ THEN REPLY ~Can't say I want to, no.~ GOTO MRBraceletDemand2
	 IF ~~ THEN REPLY ~Forget about all this. Let's go.~ GOTO MRBraceletDemand2
	END
 END
        
CHAIN
IMOEN2J MRBraceletDemand2
 ~Wait, can I take a close look at - whoops! (Leaning over the display, Imoen loses her footing and slips onto the table, sending a handful of merchandise flying.)~
	 = ~Oh no, oh Gods, I'm so sorry!~
	 == MRWOMER ~(Mara's eyes are wide, her cheeks livid) My wares! How can you be so clumsy, girl? (She rushes to gather the items scattered over the Promenade steps, her considerable bulk impeding her progress somewhat.)~
	 == IMOEN2J ~I can't believe this happened again, I'm so embarrassed! Please, let me help you! (Imoen is already scrambling to gather everything she jostled out of place, her demeanor the picture of mortified apology.)~
	 == MRWOMER ~It's... it's fine, girl. It's fine. Just leave it there, I'll take care of it. Please step away from the stand and don't move anymore. Do you want that ring or not?~
	 == IMOEN2J ~No, no, I just... I really want to get out of here, I'm so embarrassed. Sorry, please, sorry, c'mon <CHARNAME>, let's just go...~
	 == IMOEN2J ~(She takes your arm and goes down a few steps. Imoen is leaning against you for support. She seems to be quite rattled by the humiliating experience.)~
	 == IMOEN2J ~<CHARNAME>...~
END IMOEN2J MRBraceletStole
 
 APPEND IMOEN2J
 IF ~~ THEN BEGIN MRBraceletStole
    SAY ~You might want to start running.~
    ++ ~What? Why? Are you alright?~ EXTERN MRWOMER MRHold
    ++ ~What in the world just happened, Imoen?~ EXTERN MRWOMER MRHold
    ++ ~I knew it, I just god-damn knew it!~ EXTERN MRWOMER MRHold
 END

IF ~~ THEN BEGIN MRHoldNot
   SAY ~(Imoen starts laughing) RUN!~
   = ~(She grabs you by the arm and drags you behind her as she runs.)~
	 IF ~NumInPartyGT(2)~ THEN GOTO MRBraceletParty
	 IF ~!NumInPartyGT(2)~ THEN DO ~ClearAllActions() StartCutSceneMode() StartCutScene("MRWoCut3")~ EXIT
	END

	IF ~~ THEN BEGIN MRBraceletParty
	 SAY ~(You just hope the rest of the party will be able to track you down again after you have disappeared from this place.)~ 
	 IF ~~ THEN DO ~ClearAllActions() StartCutSceneMode() StartCutScene("MRWoCut3") ~ EXIT
	END

	IF ~Global("MRRingSellImoen","GLOBAL",5)~ THEN BEGIN MRBraceletSuccess // from:
	 SAY ~(Imoen finally stops running and starts laughing uncontrollably - so much so, that she chokes and begins coughing.)~
	 IF ~~ THEN DO ~ActionOverride(Player1,GiveItemCreate("MRIMRIN1","Imoen2",0,0,0)) SetGlobal("MRRingSellImoen","GLOBAL",7) ActionOverride(Player1,SetDialogue("Player1"))~ GOTO MRBraceletSuccess2
	END

	IF ~~ THEN BEGIN MRBraceletSuccess2 // from: 1878.0
	 SAY ~Hahahah... did you... see... her face...? Oh... I missed this... I missed this... so much...~
	 IF ~!IfValidForPartyDialogue("Keldorn") !IfValidForPartyDialogue("Mazzy") !IfValidForPartyDialogue("Jaheira") !IfValidForPartyDialogue("Aerie") !IfValidForPartyDialogue("Anomen") !IfValidForPartyDialogue("Edwin")~ THEN GOTO MRBraceletSuccessAdmire
	 IF ~IfValidForPartyDialogue("Keldorn")
	~ THEN EXTERN ~KELDORJ~ MRBraceletSuccess
	 IF ~IfValidForPartyDialogue("Mazzy")
	~ THEN EXTERN ~MAZZYJ~ MRBraceletSuccess
	 IF ~IfValidForPartyDialogue("Jaheira")
	~ THEN EXTERN ~JAHEIRAJ~ MRBraceletSuccess
	 IF ~IfValidForPartyDialogue("Aerie")
	~ THEN EXTERN ~AERIEJ~ MRBraceletSuccess
	 IF ~IfValidForPartyDialogue("Anomen")
	~ THEN EXTERN ~ANOMENJ~ MRBraceletSuccess
	 IF ~IfValidForPartyDialogue("Edwin")
	~ THEN EXTERN ~EDWINJ~ MRBraceletSuccess
	END
END

CHAIN KELDORJ MRBraceletSuccess
~What happened, <CHARNAME>? Why did you run like that?~
==IMOEN2J ~Hahah... nothing, Keldorn... let's say that... we felt... like running free! (Imoen bursts out laughing again.)~
==KELDORJ ~I hope that doesn't mean what I think it does, child.~
END IMOEN2J MRBraceletSuccessAdmire

CHAIN MAZZYJ MRBraceletSuccess
~What happened, <CHARNAME>? Why did you run like that?~
==IMOEN2J ~Hahah... nothing, Mazzy... let's say that... we felt... like running free! (Imoen bursts out laughing again.)~
== MAZZYJ ~I really hope that doesn't mean what I think it does, Imoen.~
END IMOEN2J MRBraceletSuccessAdmire

CHAIN JAHEIRAJ MRBraceletSuccess
~What happened, <CHARNAME>? Why did you run like that?~
==IMOEN2J ~Hahah... nothing, Jaheira... let's say that... we felt... like running free! (Imoen bursts out laughing again.)~
==JAHEIRAJ ~I really hope that doesn't mean what I think it does, child.~
END IMOEN2J MRBraceletSuccessAdmire

CHAIN AERIEJ MRBraceletSuccess
~W-what happened, Imoen? Why did you run like that?~
==IMOEN2J ~Hahah... nothing, Aerie... let's say that... we felt... like running free! (Imoen bursts out laughing again.)~
==AERIEJ ~Oh? What does that mean? Oh, I hope it doesn't mean what I think it means...~
== IMOEN2J ~Oh don't be that... that uptight, Aerie! (Imoen turns to you.)~
END IMOEN2J MRBraceletSuccessAdmire

CHAIN ANOMENJ MRBraceletSuccess
 ~What happened, <CHARNAME>? Why did you run like that?~
==IMOEN2J ~Hahah... nothing, Annie... let's say that... we felt... like running free! (Imoen bursts out laughing again.)~
== ANOMENJ ~I really hope that doesn't mean what I think it does, Imoen.~
END IMOEN2J MRBraceletSuccessAdmire

CHAIN EDWINJ MRBraceletSuccess
 ~(Edwin pants) What in the hells happened?~
==IMOEN2J ~Hahah... nothing, Edwin... let's say that... we felt... like running free! (Imoen bursts out laughing again.)~
==EDWINJ ~Bah. Do you mongrels think a man of my station is to run through these streets like a booze-addled harlot? I have a reputation to maintain!~
== IMOEN2J ~Sure... sure, whatever... you say... (She turns to you.)~
END IMOEN2J MRBraceletSuccessAdmire

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRBraceletSuccessAdmire // from: 2366.0 2363.0 2361.0 1879.0
	 SAY ~(Still panting, Imoen pulls out a familiar piece of jewelry from under her belt. She slips her hand through the esoteric bracelet without a second thought.)~
         = ~Wow. Wow!~
	 = ~(She's looking at her arm with a mixture of pride and admiration) This is... wow. Totally worth it.~
	 IF ~~ THEN GOTO MRBraceletAdmire
	END

	IF ~~ THEN BEGIN MRBraceletAdmire // from: 1882.0
	 SAY ~Lucky break, huh? Who knows how much she was askin' for this. Lucky for you, Imoen's five-finger discount comes to the rescue!~
	 IF ~~ THEN REPLY ~I can't believe you. Let's go back right now, return that thing and apologize.~ GOTO MRBraceletRich
	 IF ~~ THEN REPLY ~What were you thinking? You could have set all of Athkatla's guards on our tail!~ GOTO MRBraceletGuards
	 IF ~~ THEN REPLY ~That was quite rash, but whatever. Looks like it was worth it.~ GOTO MRBraceletWorth
	 IF ~~ THEN REPLY ~I know I can always count on you for these things. I do wish you'd warned me, though.~ GOTO MRBraceletIdiot
	 IF ~~ THEN REPLY ~Great going! You should do that as often as you can from now on.~ GOTO MRBraceletEgg
	 IF ~~ THEN REPLY ~I'm baffled, here. You don't feel guilty about this? Not one bit?~ GOTO MRBraceletGuilt
	END

        IF ~~ THEN BEGIN MRBraceletGuilt
         SAY ~Oh, yeah, 'cuz she's really going to be living on the streets now, yep. Feel real bad for cutting into her profit margins.~
         = ~'Sides, what's more important? That woman's bottom line, or us saving the world from Irenicus?~
         ++ ~What's important is not breaking the law.~ + MRBraceletGuilt1
         ++ ~It's still a terrible thing to do, Imoen. There is no justifying it.~ + MRBraceletGuilt2
         ++ ~If you put it that way, I guess it's not so bad.~ + MRBraceletGuilt3
        END
        
        IF ~~ THEN BEGIN MRBraceletGuilt1
           SAY ~Pffhahaha! (It takes Imoen a moment to realize you're serious.)~
           = ~Oh, yeah, right, okay. Well... I'll try harder next time. How about that?~
           = ~In the mean time, I think I'm gonna find out exactly what this bracelet can do...~
           IF ~~ THEN EXIT
        END

        IF ~~ THEN BEGIN MRBraceletGuilt2
           SAY ~Well, I'm terribly sorry you feel that way. I'm undoing myself in apologies, here.~
           = ~I'll try to be a better person from now on, alright? Is that okay with you?~
           = ~In the mean time, I think I'm gonna find out exactly what this bracelet can do...~
           IF ~~ THEN EXIT
        END

        IF ~~ THEN BEGIN MRBraceletGuilt3
           SAY ~Hah, that's right! I knew you'd see it my way. It's all about perspective, y'see.~
           = ~Now, let's find out exactly what this bracelet can do...~
           IF ~~ THEN EXIT
        END

	IF ~~ THEN BEGIN MRBraceletEgg
	 SAY ~Woohoo, free rein to help myself to things! Score!~
	    = ~Just lemme know when ya want to try for my special discount again. At worst, we'll be in for another run, hah!~
            = ~In the mean time, I think I'm gonna find out exactly what this bracelet can do...~
           IF ~~ THEN EXIT
        END

	IF ~~ THEN BEGIN MRBraceletIdiot // from: 1883.3
	 SAY ~But then it wouldn't have been even *half* the fun!~
         = ~Yeah, alright, you have a point. We should work out a system. Secret hand signals or something.~
         = ~But in the mean time, I think I'm gonna find out exactly what this bracelet can do...~
           IF ~~ THEN EXIT
        END


	IF ~~ THEN BEGIN MRBraceletGuards // from: 1883.1
	 SAY ~Hah, right. Those bastions of virtue, they were so very eager to get moving. Which one do ya think woulda caught us, the one with the stains and the pot belly, or the one-eyed septuagenarian?~
         = ~C'mon, gimme more credit than that. If I'd thought they were a threat, I wouldn't have risked it.~
	 IF ~~ THEN REPLY ~That's besides the point. Let's go back right now, return that thing and apologize.~ GOTO MRBraceletRich
	 IF ~~ THEN REPLY ~It was just rash, Imoen. But at least it looks like it was worth it.~ GOTO MRBraceletWorth
	 IF ~~ THEN REPLY ~Alright, good to know had your eye out. I do wish you'd warned me, though.~ GOTO MRBraceletIdiot
	 IF ~~ THEN REPLY ~Ah. Well, then, maybe you should do that more often.~ GOTO MRBraceletEgg
	 IF ~~ THEN REPLY ~I'm just baffled, honestly. You don't feel guilty about this? Not one bit?~ GOTO MRBraceletGuilt
	END
	
	IF ~~ THEN BEGIN MRBraceletWorth
	SAY ~You don't have to say that twice! Can't wait to see what this really does. I tellya, it feels just... amazing. Like my step is lighter, and my thoughts are faster, and my boobs are bigger - no wait. Scratch that last part.~
	= ~I knew you'd be practical about this. We better get going though, dunno whether they're still on our trail...~
	IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRBraceletRich // from: 1884.0 1883.0
	SAY ~Pffhahaha! (It takes Imoen a moment to realize that you're serious.)~
	= ~Oh, yeah, right, okay. 'Cuz she's really going to be living on the streets now, yep. Feel real bad for cutting into her profit margins.~
        = ~Look, what's done is done. How about I promise not to do it again? Is that alright? Sure hope so, 'cause I'm not returning this thing.~
        = ~Yeesh. So damn uptight. Live a little!~
    IF ~~ THEN EXIT
    END

END