/*Irenicus dungeon first talk */
APPEND IMOEN2J

	IF ~Global("MRLeaveDungeon","GLOBAL",2)~ THEN BEGIN MRLeaveDungeon
	 SAY ~<CHARNAME>...~ [MRImRom5] 
	 IF ~~ THEN REPLY ~Yes?~ DO ~SetGlobal("MRLeaveDungeon","GLOBAL",3)~ GOTO MRLeaveDungeonNext
	 IF ~~ THEN REPLY ~What do you want *now*?~ DO ~SetGlobal("MRLeaveDungeon","GLOBAL",3)~ GOTO MRLeaveDungeonNext
	 ++ ~Be quiet, Imoen.~ DO ~SetGlobal("MRLeaveDungeon","GLOBAL",3)~ + MRLeaveDungeonQuiet
        END
        
        IF ~~ THEN BEGIN MRLeaveDungeonQuiet
           SAY ~Alright... okay. Sorry.~
           IF ~~ THEN EXIT
        END

	IF ~~ THEN BEGIN MRLeaveDungeonNext
	 SAY ~I can't stand this pain anymore. It's just too much, my head hurts so bad... I only want to leave this place.~
	 IF ~~ THEN REPLY ~Don't worry, Imoen. I'll get us out of here as soon as I can, hang on just a bit longer. Do you think you can do it?~ GOTO MRLeaveDungeonAche
	 IF ~IfValidForPartyDialogue("Jaheira")~ THEN REPLY ~Don't worry, Jaheira will say some healing prayers for you. It'll tide you over until we reach the surface.~ GOTO MRLeaveDungeonAche
	 IF ~~ THEN REPLY ~Come here. (Bring Imoen into a hug.)~ GOTO MRLeaveDungeonHug
	 IF ~~ THEN REPLY ~You know I can't do anything about that for now. It's best if you cope in silence. It won't be much longer.~ GOTO MRLeaveDungeonSilence
	END

	IF ~~ THEN BEGIN MRLeaveDungeonHug
	 SAY ~(Imoen trembles under your touch. It's a wonder she's stayed composed throughout your escape.)~
	 IF ~~ THEN GOTO MRLeaveDungeonHug2
	END

	IF ~~ THEN BEGIN MRLeaveDungeonHug2
	 SAY ~<CHARNAME>, I... some-- something is inside my head, I can feel it. It's no normal ache, it's like... a clamp around my head. Like small needles stabbing my thoughts.~
	 IF ~~ THEN REPLY ~That bastard will pay for this. Is there something I can do to alleviate the pain?~ GOTO MRLeaveDungeonClose
	 IF ~~ THEN REPLY ~We must get to the surface at once.~ GOTO MRLeaveDungeonClose
	 IF ~~ THEN REPLY ~I won't leave until I find this man and make him suffer for what he has done to us both.~ GOTO MRLeaveDungeonDeath
	 IF ~~ THEN REPLY ~You know I can't do anything about that for now. It's best if you cope in silence. It won't be much longer.~ GOTO MRLeaveDungeonSilence
	END

	IF ~~ THEN BEGIN MRLeaveDungeonAche
	 SAY ~I don't know. It's no normal ache, it's like... a clamp around my head. Like small needles stabbing my thoughts.~
	 IF ~~ THEN REPLY ~That bastard will pay for this. Is there something I can do to alleviate the pain?~ GOTO MRLeaveDungeonClose
	 IF ~~ THEN REPLY ~We must get to the surface at once.~ GOTO MRLeaveDungeonClose
	 IF ~~ THEN REPLY ~I won't leave until I find this man and make him suffer for what he has done to us both.~ GOTO MRLeaveDungeonDeath
	 IF ~~ THEN REPLY ~You know I can't do anything about that for now. It's best if you cope in silence. It won't be much longer.~ GOTO MRLeaveDungeonSilence
	END

	IF ~~ THEN BEGIN MRLeaveDungeonClose
	 SAY ~Actually, yes. It's... it's weird, but the closer I am to you, the better I feel. It's like your presence makes it a bit better. A little bit.~
         = ~So I'd be grateful if we don't get too far from one another. This pain is just... it's killing me. Please?~
         IF ~~ THEN REPLY ~Of course. Don't be afraid, I won't move from your side. I promise.~ GOTO MRLeaveDungeonPromise
	 IF ~~ THEN REPLY ~I'll do what I can, but I won't hesitate to split up if I feel it's necessary.~ GOTO MRLeaveDungeonSplit
	 IF ~~ THEN REPLY ~That's simply not possible, Imoen.~ GOTO MRLeaveDungeonSilence
	 IF ~~ THEN REPLY ~You are becoming a burden, Imoen. If you can't be useful to me, get lost.~ GOTO MRLeaveDungeonBurden
	END

	IF ~~ THEN BEGIN MRLeaveDungeonPromise
	 SAY ~Alright...~
	 IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRLeaveDungeonSilence
	 SAY ~(She sighs) Alright, I... I can do that. I can. Don't worry about it.~
	 IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRLeaveDungeonSplit
	 SAY ~(Imoen sighs) Alright, well... that's better than nothing.~
	 IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRLeaveDungeonDeath
	 SAY ~No, no, let's just leave this place and don't look back, <CHARNAME>! I don't wanna see that man again, he...~
         = ~He's death itself.~
	 IF ~~ THEN GOTO MRLeaveDungeonDeath2
	END

	IF ~~ THEN BEGIN MRLeaveDungeonDeath2
	 SAY ~Let's go on, this place gives me the creeps.~
	 IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRLeaveDungeonBurden
	 SAY ~(There's fear in Imoen's eyes) I'll make myself useful. Please don't leave me here alone. I'll get busy right away...~
	 IF ~~ THEN EXIT
	END



	 /* second talk */

	IF ~Global("MRAtExit","GLOBAL",1)~ THEN BEGIN MRLeaveDungeon2
	 SAY ~Finally! I can just smell it, the surface at last...~ [MRImRom4]
	 IF ~~ THEN DO ~SetGlobal("MRAtExit","GLOBAL",2) ActionOverride("TALKERMR",DestroySelf())~ GOTO MRLeaveDungeon2next
	END

	IF ~~ THEN BEGIN MRLeaveDungeon2next
	 SAY ~Wait. There's a fight goin' on. And... and that voice. (Imoen shudders.)~
	 = ~It's him! Why is he at the exit? It's not fair! We can't go out there now. We can't.~
	 IF ~~ THEN REPLY ~Don't be afraid, Imoen. I am here to protect you.~ GOTO MRLeaveDungeon2Anger
	 IF ~~ THEN REPLY ~It's the only way out, and we can't stay in here forever.~ GOTO MRLeaveDungeon2Leave
	 IF ~~ THEN REPLY ~I don't really care about what you want. Now I shall have my revenge.~ GOTO MRLeaveDungeon2Revenge
	END


	IF ~~ THEN BEGIN MRLeaveDungeon2Anger
	 SAY ~(Imoen stares at you) Just like you protected me before? Some damn hero you were when they took us down and dragged us into a torture chamber!~
	 = ~(She bites back her anger, regret showing on her features almost immediately) I'm sorry. It wasn't your fault. I'm just... hurt, and angry and frustrated. There's... there's no other way out of here, is there. (Imoen looks ahead once more) The only way out is through him.~
	 = ~I don't even care. I need to get out this place. Let's do it.~
	 IF ~~THEN EXIT
	END

	IF ~~ THEN BEGIN MRLeaveDungeon2Leave
	 SAY~I *know*! Urrgh, I can't stand being here anymore. I don't care what I find out there, as long as we are *out there*.~
	 =~C'mon, this place stinks. Let's do this.~
	 IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRLeaveDungeon2Revenge
	 SAY ~Oh yeah? What in the nine hells makes you think it'll be any different than the last time? Don't you remember his *goons* took us down and dragged us into his torture chamber?~
	 = ~But hey, by all means, run head first into Irenicus. Just don't expect me to save your sorry arse when he's turning your flesh inside out!~
	 IF ~~ THEN EXIT
	END
END