/* Reputation High/Low Dialogs - COMPLETED */

APPEND BIMOEN2
	IF ~ReputationGT(Player1,14) 
		Global("MRRepTalk","LOCALS",0)
		InPartySlot(LastTalkedToBy,0) 
		!StateCheck(Player1,CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		InParty("Imoen2")
		See(Player1)
		!ActuallyInCombat()
		GlobalGT("Chapter","GLOBAL",%bg2_chapter_5%) 
		AreaType(CITY)~ THEN BEGIN MRRepHigh
		SAY ~Y'know... a girl could get to enjoy this.~
		IF ~~ THEN REPLY ~Enjoy what?~ DO ~SetGlobal("MRRepTalk","LOCALS",1)~ GOTO MRRepHigh1
		IF ~~ THEN REPLY ~Not now, Imoen!~ DO ~SetGlobal("MRRepTalk","LOCALS",1)~ GOTO MRRepHighEnd
		IF ~IsValidForPartyDialog("Nalia") IsValidForPartyDialog("Keldorn")~ THEN REPLY ~(Ignore her.)~ DO ~SetGlobal("MRRepTalk","LOCALS",1)~ GOTO MRRepHighNPCGood
		IF ~IsValidForPartyDialog("Korgan") IsValidForPartyDialog("Viconia")~ THEN REPLY ~(Ignore her.)~DO ~SetGlobal("MRRepTalk","LOCALS",1)~ GOTO MRRepHighNPCEvil
		IF ~OR(2) !IsValidForPartyDialog("Nalia") !IsValidForPartyDialog("Keldorn") OR(2) !IsValidForPartyDialog("Korgan") !IsValidForPartyDialog("Viconia")~ THEN REPLY ~(Ignore her.)~ 
			DO ~SetGlobal("MRRepTalk","LOCALS",1)~ EXIT
	END

	IF ~~ THEN BEGIN MRRepHighEnd
		SAY ~(She rolls her eyes) Until you go and ruin it, of course.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepHigh1
		SAY ~Being famous! I mean, have you seen how people look at us? They love us!~
		++ ~I've seen how some of them look at *you*...~ GOTO MRRepHighJealous1
		IF ~!IsValidForPartyDialog("Nalia") !IsValidForPartyDialog("Aerie")~ THEN REPLY ~Like I care what these yokels think.~ GOTO MRRepHighEvil
		IF ~IsValidForPartyDialog("Nalia") !IsValidForPartyDialog("Aerie")~ THEN REPLY ~Like I care what these yokels think.~ EXTERN BNALIA MRRepHighEvil
		IF ~!IsValidForPartyDialog("Nalia") IsValidForPartyDialog("Aerie")~ THEN REPLY ~Like I care what these yokels think.~ EXTERN BAERIE MRRepHighEvil
		IF ~IsValidForPartyDialog("Nalia") IsValidForPartyDialog("Aerie")~ THEN REPLY ~ Like I care what these yokels think.~ EXTERN BAERIE MRRepHighEvil
		++ ~And they give us discounts and free stuff!~ GOTO MRRepHighGreedy
		++ ~It's not about being famous, Im.~ GOTO MRRepHighGood
	END

END

CHAIN BIMOEN2 MRRepHighJealous1
 ~Hah! Jealous much?~ 
==BIMOEN2 IF ~CheckStatLT(Player1,8,CHR)~ THEN ~I'm sure a few are looking at you. You're, ah... well, your personality makes up for your looks.~
	= ~Mostly.~
==BIMOEN2 IF ~CheckStatGT(Player1,13,CHR) Global("ImoenRomanceActive","GLOBAL",2)~THEN ~Betcha most of them are looking at you. In case you haven't noticed, you're kinda hot.~
==BIMOEN2 IF ~CheckStatGT(Player1,13,CHR) !Global("ImoenRomanceActive","GLOBAL",2) ~ THEN ~Betcha most of them are looking at you. You're hot.
	= Heck, even *I* think you're hot. In a very <PRO_BROTHERSISTER>ly way.~
==BIMOEN2 IF ~CheckStatGT(Player1,7,CHR) CheckStatLT(Player1,14,CHR)~ THEN ~I can't help it if I'm the cuter than you.~
END
	IF ~!IsValidForPartyDialog("Nalia") !IsValidForPartyDialog("Aerie")~ THEN REPLY ~Like I care what these yokels think.~ GOTO MRRepHighEvil
	IF ~IsValidForPartyDialog("Nalia") !IsValidForPartyDialog("Aerie")~ THEN REPLY ~Like I care what these yokels think. ~ EXTERN BNALIA MRRepHighEvil
	IF ~IsValidForPartyDialog("Aerie")~ THEN REPLY ~ Like I care what these yokels think. ~ EXTERN BAERIE MRRepHighEvil
	IF ~Gender(Player1,FEMALE)~ THEN REPLY ~Hopefully they're admiring us for our actions, not our cleavage.~ GOTO MRRepHighGood
	IF ~Gender(Player1,MALE)~ THEN REPLY ~Hopefully they're admiring us for our feats more than our faces.~ GOTO MRRepHighGood

APPEND BNALIA
	IF ~~ THEN BEGIN MRRepHighEvil
		SAY ~Just because they lack our wealth and power doesn't make these people any less deserving of dignity and respect, <CHARNAME>.~ 
	IF ~~ THEN EXTERN BIMOEN2 MRRepHighEvil2
	END
END

APPEND BAERIE
	IF ~~ THEN BEGIN MRRepHighEvil
		SAY ~That's c-c-cruel, <CHARNAME>. They need your h-help, not your hatred.~
	IF ~~ THEN EXTERN BIMOEN2 MRRepHighEvil2
	END
END


APPEND BIMOEN2
	IF ~~ THEN BEGIN MRRepHighGreedy
		SAY ~Yup! Although with the gold we come across it's not like we NEED to be cheap.~
		IF ~!IsValidForPartyDialog("Nalia") !IsValidForPartyDialog("Aerie")~ THEN REPLY ~They're lucky we pay for anything, the ignorant sheep.~ GOTO MRRepHighEvil
		IF ~IsValidForPartyDialog("Nalia") !IsValidForPartyDialog("Aerie")~ THEN REPLY ~They're lucky we pay for anything, the ignorant sheep.~ EXTERN BNALIA MRRepHighEvil
		IF ~IsValidForPartyDialog("Aerie")~ THEN REPLY ~They're lucky we pay for anything, the ignorant sheep.~ EXTERN BAERIE MRRepHighEvil
		++ ~We're not being cheap. They're simply expressing their gratitude for all the things we've done.~ GOTO MRRepHighGood
	END 

	IF ~~ THEN BEGIN MRRepHighGood
		SAY ~Yeah, yeah, goodness is it's own reward and all that. Still, isn't it just a little bit awesome to be so famous? Just a little bit?~
		++ ~Well... maybe a little.~ GOTO MRRepHighGoodLittle
		++ ~Vanity leads only to evil and corruption.~ GOTO MRRepHighGoodBad
	END

	IF ~~ THEN BEGIN MRRepHighGoodLittle
		SAY ~Hah! I knew it! <CHARNAME> and Imoen, the Charmers of Candlekeep! Saviors of the Sword Coast! Un-do-ers of Ust Natha!~
	=
	~Is 'un-do-ers' really a word, y'think?~
	++ ~Let's not get carried away here, Im.~ GOTO MRRepHighGoodEnd1
	++ ~And soon we will rule the world!~ GOTO MRRepHighGoodEndVolo
	++ ~If your ego gets any bigger you'll start getting stuck in doorways.~ GOTO MRRepHighGoodEnd1
	END

	IF ~~ THEN BEGIN MRRepHighGoodEnd1
		SAY ~Oh, c'mon, I was just teasin'. You gotta know me better than that by now!~
		=
		~But fine, have it your way. Let's go be modest somewhere, I guess.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepHighGoodEndVolo
		SAY ~You betcha! We'll have our own shelf in Candlekeep, and we'll be so famous that even Volo will know our names!~
		=
		~I think I should hush now. I'm starting to drool from all the awesomeness.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepHighGoodBad
		SAY ~Gah! You are such a stick in the mud!~
		=
		~Fine, I'll just be happy and excited and awesome without you! Hmph!~
		IF ~~ THEN EXIT
	END


	IF ~~ THEN BEGIN MRRepHighEvil
		SAY ~Looks like someone got out of the wrong side of the bedroll this morning.~
		=
		~Nevermind then, Grumpypants. Sheesh.~
		IF ~~ THEN EXIT
	END
END

CHAIN BIMOEN2 MRRepHighNPCGood
~Who'd've ever thought we'd be heroes, huh? Just makes me all warm and tingly inside.~
== BKELDOR
~I am surprised - pleasantly - by the way you and <CHARNAME> have handled yourselves. It seems my initial misgivings were unfounded.~
== BIMOEN2
~Initial misgivings? Oh. Bhaalspawn. Right.~
== BKELDOR
~For a paladin such as myself-~
==BIMOEN2
~It's really hard to imagine that me and <CHARNAME> might actually be normal, decent people who just wanna live normal, decent lives?~
==BKELDOR
~You needn't put words in my mouth, Imoen.~
==BNALIA
~She's right though, isn't she? The rich and righteous always assume that simply because someone is born in a less favorable circumstance, that they're morally flawed.~
==BKELDOR
~Perhaps your family believed that, Nalia, but I and my order certainly do not.~
==BNALIA
~Oh come on, Keldorn. We've ALL heard your concerns about Bhaalspawn.~
==BIMOEN2
~Repeatedly. Like, a lot.~
==BNALIA
~Imoen and <CHARNAME>'s parentage doesn't make them evil any more than your parentage makes you a paladin.~
==BKELDOR
~I agree. I was simply trying to express that I HAVE realized my mistake in assuming that they were doomed to follow their father's example.~
==BIMOEN2
~Well... thank you. Sorry I snapped, it's just - all the negative reactions get to me sometimes, y'know? Maybe I'm a little oversensitive.~
==BNALIA
~Imoen... you HAVE been a little touchy lately. Perhaps there is a more... feminine explanation for it?~
==BIMOEN2
~(glares) Hey! Magic fixes that problem, remember?~
==BKELDOR
~(Ahem) Perhaps we should move on.~
EXIT

CHAIN BIMOEN2 MRRepHighNPCEvil
~Who'd've ever thought we'd be heroes, huh? Just makes me all warm and tingly inside!~
== BKORGAN
~Heroes? Bah! If ye be wantin' warm an' tingly, lass, I'll show ye a better way than that.~
==BVICONI
~Just one, har'gluk? Your people are as lacking in imagination as they are stature.~
==BKORGAN
~Oi! Spend an hour with a dwarf - ye'll be singin' a different tune, drow.~
==BIMOEN2
~Just forget I said anything. Really. Let's keep going.~
==VICONI
~How could a shriveled wretch like you hope to satisfy a connoisseur of the darkest pleasures?~
==BKORGAN
~Me legs be short, drow - but me other parts be both long an' wide.~
==BIMOEN2
~EW! <CHARNAME>, shouldn't we be going? Like, RIGHT NOW? Please!~
EXIT

CHAIN BIMOEN2 MRRepHighEvil2
~Yeah, what she said!~
==BIMOEN2 IF ~IsValidForPartyDialog("Aerie") !IsValidForPartyDialog("Nalia")~ THEN ~How 'bout I go hang out with Aerie until you're done acting like a kobold's butt?~
= ~Sheesh.~
==BIMOEN2 IF ~!IsValidForPartyDialog("Aerie") IsValidForPartyDialog("Nalia")~ THEN ~How 'bout I go hang out with Nalia until you're done acting like a kobold's butt?~
= ~Sheesh.~
==BIMOEN2 IF ~IsValidForPartyDialog("Aerie") IsValidForPartyDialog("Nalia")~ THEN ~How 'bout we mage-girls go hang out until <CHARNAME>'s done acting like a kobold's butt?~
= ~Sheesh.~
EXIT

APPEND BIMOEN2
	IF ~ReputationLT(Player1,6) 
	    Global("MRRepTalk","LOCALS",0)
		InPartySlot(LastTalkedToBy,0) 
		!StateCheck(Player1,CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		InParty("Imoen2")
		See(Player1)
		!ActuallyInCombat()
		GlobalGT("Chapter","GLOBAL",%bg2_chapter_5%) 
		AreaType(CITY)
		~ THEN BEGIN MRRepLow
		SAY ~Y'know, when I left Candlekeep, this is totally NOT how I imagined I'd be spending my time.~
		++ ~What do you mean?~ DO ~SetGlobal("MRRepTalk","LOCALS",1)~ GOTO MRRepLow1
		IF ~!NumInPartyGT(2)~ THEN REPLY ~Shut up. I'm busy.~ DO ~SetGlobal("MRRepTalk","LOCALS",1)~ GOTO MRRepLowEnd1
		IF ~NumInPartyGT(2)~ THEN REPLY ~Shut up. I'm busy.~ DO ~SetGlobal("MRRepTalk","LOCALS",1)~ GOTO MRRepLowEnd2
		IF ~~ THEN REPLY ~(Ignore her.)~ DO ~SetGlobal("MRRepTalk","LOCALS",1)~ EXIT
	END

	IF ~~ THEN BEGIN MRRepLowEnd1
		SAY ~Traveling with a jerk like you. Hmph.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepLowEnd2
		SAY ~Traveling with bunch of jerks. Hmph.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepLow1
		SAY ~I always thought we'd be heroes! Y'know, steal from the rich, give to the poor. Help the downtrodden. Rescue kittens from trees!~
		=
		~Not robbing people blind, backstabbing, lying, killing...~
		=
		~I don't feel good about it. Do you?~
		++ ~No, but sometimes such things are necessary.~ GOTO MRRepLowGood
		++ ~I don't know. I don't really think about it much.~ GOTO MRRepLowNeu
		++ ~It doesn't bother me. Why should it?~ GOTO MRRepLowNeu
		++ ~Of course I feel good about it! Bring on the carnage - the God of Murder is back!~ GOTO MRRepLowBhaal
	END

	IF ~~ THEN BEGIN MRRepLowGood
		SAY ~Are they? Maybe if you tried a little charm and diplomacy instead of bashing in heads, y'think that might work? Heck, I can even just cast 'charm' - at least that'd be a little better.~
		++ ~It's not okay to lie to people, but it's okay to bewitch their minds?~ GOTO MRRepLowWicca
		IF ~!NumInPartyGT(2)
			 OR(7)
			Class(Player1,MAGE)
			Class(Player1,SORCERER)
			Class(Player1,CLERIC_MAGE)
			Class(Player1,FIGHTER_MAGE_CLERIC)
			Class(Player1,FIGHTER_MAGE)
			Class(Player1,FIGHTER_MAGE_THIEF)
			Class(Player1,MAGE_THIEF)~ THEN REPLY ~True, but I'd rather save your magical talent for emergencies.~ GOTO MRRepLowMagicDual
		IF ~!NumInPartyGT(2)
			!Class(Player1,MAGE)
			!Class(Player1,SORCERER)
			!Class(Player1,CLERIC_MAGE)
			!Class(Player1,FIGHTER_MAGE_CLERIC)
			!Class(Player1,FIGHTER_MAGE)
			!Class(Player1,FIGHTER_MAGE_THIEF)
			!Class(Player1,MAGE_THIEF)~
			THEN REPLY ~True, but I'd rather save your magical talent for emergencies.~ GOTO MRRepLowMagicSolo
		IF ~NumInPartyGT(2)
			OR(7)
			IsValidForPartyDialog("Nalia")
			IsValidForPartyDialog("Aerie")
			IsValidForPartyDialog("")
			IsValidForPartyDialog("Edwin")
			IsValidForPartyDialog("Jan")
			IsValidForPartyDialog("Cernd")
			IsValidForPartyDialog("Viconia")
			~ THEN REPLY ~True, but I'd rather save your magical talent for emergencies.~ GOTO MRRepLowMagicMulti
		++ ~Nah. I prefer a bit of the old ultra-violence.~ GOTO MRRepLowCW
	END

	IF ~~ THEN BEGIN MRRepLowMagicSolo
		SAY ~C'mon, it's just one little spell!~
		++ ~I'm not going to argue about this. The way we do things *works*. End of discussion.~ GOTO MRRepLowMagicDual2
		++ ~Fine, fine. Maybe we can try it your way. But if it doesn't work...~ GOTO MRRepLowMagicDual3
	END

	IF ~~ THEN BEGIN MRRepLowMagicDual
		SAY ~That's a load of crap. You can magic stuff just as well as I can; *one* of us can keep a 'Charm Person' or 'Mental Domination' memorized, just in case.~
		++ ~I'm not going to argue about this. The way we do things *works*. End of discussion.~ GOTO MRRepLowMagicDual2
		++ ~C'mon, Im, that's a complete waste of magical energy.~ GOTO MRRepLowMagicDual2
		++ ~Fine, fine. Maybe we can try it your way. But if it doesn't work...~ GOTO MRRepLowMagicDual3
	END

	IF ~~ THEN BEGIN MRRepLowMagicDual2
		SAY ~Well excuuuuuse me for having morals!~
		=
		~I'll try not to bother you with them again.~
		IF ~~ THEN EXIT
	END
END

CHAIN BIMOEN2 MRRepLowMagicDual3
 ~No, no, I get it, and I'm totally fine with that. I'd just like to avoid hurting people if I can, y'know?~
 ==BIMOEN2 IF ~Global("ImoenRomanceActive","GLOBAL",2) ~ THEN ~(She smiles happily and gives you a quick, soft kiss on the lips) Thanks for at least giving it a try.~
 ==BIMOEN2 IF ~!Global("ImoenRomanceActive","GLOBAL",2) ~ THEN ~(She smiles happily) Thanks for at least tryin'.~
 EXIT

APPEND BIMOEN2
	IF ~~ THEN BEGIN MRRepLowMagicMulti
		SAY ~ That's a load of crap. I'm not the only magic-user in the group, y'know - it's not like me dropping *one* spell in favor of 'charm person' is gonna make the difference between life and death.~
		++ ~I'm not going to argue about this. The way we do things *works*. End of discussion.~ GOTO MRRepLowMagicDual2
		++ ~It very well might, actually, and I'm not going to take that chance.~ GOTO MRRepLowMagicDual2
		++ ~Fine, fine. Maybe we can try it your way. But if it doesn't work...~ GOTO MRRepLowMagicDual3

	END

	IF ~~ THEN BEGIN MRRepLowWicca
		SAY ~(She crosses her arms defensively) Well, it's a lot less violent - and less permanent - than breaking their legs!~
		++ ~I thought magic was all about "And it harm none"?~ GOTO MRRepLowWicca3
		++ ~And still equally immoral.~ GOTO MRRepLowWicca3
		++ ~I guess that's true.~ GOTO MRRepLowWicca4
	END

	IF ~~ THEN BEGIN MRRepLowWicca3
		SAY ~Okay, well... well, we *do* have to get the information *somehow*, and okay, maybe zapping them with an enchantment spell isn't *exactly* ethical...~
		++ ~So you're saying I'm right?~ GOTO MRRepLowWicca5
		++ ~No, you're right, it *is* at least better than breaking legs.~ GOTO MRRepLowWicca4
		++ ~(Say nothing, just smirk.)~ GOTO MRRepLowWicca5
	END

	IF ~~ THEN BEGIN MRRepLowWicca5
		SAY ~Just... but... ooh, you always gotta RUIN it, dontcha?~
		=
		~So *maybe* my techniques aren't exactly paladin-pure. You don't gotta rub it in. Sheesh.~
		=
		~Quit grinning at me like that and just keep walkin', 'kay?~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepLowWicca4
		SAY ~See! I'm right.~
		=
		~I'm always right, y'know, it's one of those girl things.~
		IF ~Global("ImoenRomanceActive","GLOBAL",2) ~ THEN REPLY ~(sigh and smile patiently) Yes, dear.~ EXIT
		IF ~Gender(Player1,FEMALE)~ THEN REPLY ~I'm a girl, too, you know, so technically *I'm* always right.~ GOTO MRRepLowGirl
		++ ~Sure, Im, keep on believing that.~ EXIT
		++ ~(mutter) Anything to shut you up.~ EXIT
	END

	IF ~~ THEN BEGIN MRRepLowGirl
		SAY ~Pfft. Stop ruining my fun!~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepLowCW
		SAY ~Psht. Talking to you about morality is pointless.~
		=
		~And that movie sucks, by the way.~
		IF ~~ THEN EXIT
	END


	IF ~~ THEN BEGIN MRRepLowNeu
		SAY ~What? A lot of these people are totally innocent! And just 'cause someone doesn't get out of the way fast enough, or gives you a smartass answer about something, doesn't justify the stuff you do, y'know.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepLowNeu2
		SAY ~That is NOT funny! Gods, you are such a jerk sometimes.~
		=
	 ~Now be serious. Haven't you ever felt guilty about how you treat people?~
		++ ~Sure I have, but sometimes such things are necessary.~ GOTO MRRepLowGood
		++ ~I don't know. I don't really think about it much.~ GOTO MRRepLowNeu
		++ ~Of course not. Why should I?~ GOTO MRRepLowNeu
	END

	IF ~~ THEN BEGIN MRRepLowBhaal
		SAY ~Please tell me you're joking, <CHARNAME>.~
		IF ~CheckStatLT(Player1,13,CHR)~ THEN REPLY ~I don't joke about my power, Imoen. I revel in it.~ GOTO MRRepLowBhaal21
		IF ~CheckStatGT(Player1,13,CHR) CheckStatLT(Player1,17,CHR)~ THEN REPLY ~I don't joke about my power, Imoen. I revel in it.~ GOTO MRRepLowBhaal22
		IF ~CheckStatGT(Player1,16,CHR)~ THEN REPLY ~I don't joke about my power, Imoen. I revel in it.~ GOTO MRRepLowBhaal23
		++ ~Of course I'm kidding! But, in all seriousness, those things don't really bother me.~ GOTO MRRepLowNeu
		++ ~Haha yup! You should have seen your face.~ GOTO MRRepLowNeu2
	END

	IF ~~ THEN BEGIN MRRepLowBhaal21
		SAY ~(She purses her lips displeasedly, studying you with a vague expression of distaste mixed with worry... and perhaps even fear. Then, without saying anything, she abruptly turns away from you and walks off.)~
		IF ~~ THEN DO ~RunAwayFrom(Player1,45)~EXIT
	END

	IF ~~ THEN BEGIN MRRepLowBhaal22
		SAY ~You... you keep saying stuff like that! Why can't you just shut up and be *normal*?~
		IF ~!CheckStatGT(Player1,13,CHR)~ GOTO MRRepLowBhaal3
		IF ~CheckStatGT(Player1,13,CHR)~ GOTO MRRepLowBhaal4
	END

	IF ~~ THEN BEGIN MRRepLowBhaal23
		SAY ~You... you keep saying stuff like that...~ 
		IF ~~ THEN GOTO MRRepLowBhaal4
	END

	IF ~~ THEN BEGIN MRRepLowBhaal3
		SAY ~(Imoen turns away from you and stalks off; every line in her body is tense and angry. Apparently that was not the wisest thing to say to her.)~ 
		IF ~~ THEN DO ~RealSetGlobalTimer("MRLowBhaalTimer","GLOBAL",300) SetGlobal("MRRepLowBhaalWait","GLOBAL",1) RunAwayFrom(Player1,45)~ EXIT
	END

	IF ~~ THEN BEGIN MRRepLowBhaal4
		SAY ~(She purses her lips and regards you in silence for several moments. It appears to be anger at first, but beneath the surface there's a different, more conflicted emotion.)~
		=
		~(It is curiosity. But before you have a chance to say anything, the moment is over. She shakes her head, clearing out whatever thoughts had consumed her, and quickly walks away.)~ 
		IF ~~ THEN DO ~RunAwayFrom(Player1,45)~ EXIT
	END
END


APPEND IMOEN2J
	IF ~Global("MRRepLowBhaalWait","GLOBAL",2)~ THEN BEGIN MRRepLowBhaalContinue
		SAY ~<CHARNAME>... what you said about Bhaal, about reveling in your power... you don't really mean that, do you?~
			++ ~Of course not, Imoen. It was just a joke in bad taste.~ DO ~SetGlobal("MRRepLowBhaalWait","GLOBAL",3)~ GOTO MRRepLowBhaal-Joke
			++ ~Why do you ask?~ DO ~SetGlobal("MRRepLowBhaalWait","GLOBAL",3)~ GOTO MRRepLowBhaal-Why
			++ ~I do, actually. I have learned that our heritage is not a curse but a gift.~ DO ~SetGlobal("MRRepLowBhaalWait","GLOBAL",3)~ GOTO MRRepLowBhaal-Yes
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-Joke
		SAY ~Oh. Well, you shouldn't joke about things like that!~
		= ~Someone might take you seriously one of these days.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-Why
		SAY ~Why? Well, because! It's kinda important to me to know whether you're really buying into all this crazy Bhaal stuff, dontcha think?~
			++ ~Rest assured, Imoen, it was just a joke in bad taste. I don't buy into it at all.~ GOTO MRRepLowBhaal-Joke
			++ ~I believe it completely, and I meant every word of what I said.~ GOTO MRRepLowBhaal-Yes
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-Yes
		SAY ~But... but Bhaal is evil! The nightmares, the weird powers, everyone trying to kill us - even Alaundo's prophecy!~
		= ~How can you be a part of that? How can you *want* that?~
			++ ~Imoen... it's not a matter of wanting. It's a matter of *being*. We are what we are.~ GOTO MRRepLowBhaal-YesBeing
			++ ~Evil has its place in this world; do you think Ao would let Talona, Lloth, or Talos exist if it didn't?~ GOTO MRRepLowBhaal-YesPlace
			++ ~(Sigh) Not a morality lecture. I'm so sick of hearing everyone complain!~ + MRRepLowBhaal-YesStop
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-YesStop
		SAY ~Hey, sorry if I actually *care* what happens to you!~
		= ~Obviously you know what you're doing - or you think you do. So I'll just stay out of your way, 'kay?~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-YesPlace
		SAY ~Okay, you've a point. But... I dunno, <CHARNAME>. We grew up taught to be good people, to do good things.~
			++ ~Maybe we were taught wrong. What is fit for the masses may not be fit for demi-gods like us.~ GOTO MRRepLowBhaal-YesPlaceWrong
			++ ~Goodness is for the weak. The strong write their own rules and do as they wish.~ GOTO MRRepLowBhaal-YesPlaceStrong
			++ ~(Sigh) Not a morality lecture. I'm so sick of hearing everyone complain!~ GOTO MRRepLowBhaal-YesStop
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-YesBeing
		SAY ~So you're saying because our father was evil, we have to be, too? I don't buy that, <CHARNAME>.~
		= ~Gorion and Puffguts taught us to be good people, to do good things. They believed in us.~
			++ ~Maybe we were taught wrong. What is fit for the masses may not be fit for demi-gods like us.~ GOTO MRRepLowBhaal-YesPlaceWrong
			++ ~Goodness is for the weak. The strong write their own rules and do as they wish.~ GOTO MRRepLowBhaal-YesPlaceStrong
			++ ~(Sigh) Not a morality lecture. I'm so sick of hearing everyone complain!~ GOTO MRRepLowBhaal-YesStop	
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-YesPlaceWrong
		SAY ~(She sighs) I- I just can't accept that. Mister G an' all the monks, they loved us. They wanted what's best for us.~
			++ ~But they were only human, Im. They didn't *know* what was best for us.~ GOTO MRRepLowBhaal-YesWrongEnd
			++ ~They were idiots, trying to control what they did not understand.~ GOTO MRRepLowBhaal-YesSomeday
			++ ~You can't accept it now, perhaps - neither could I, at first. But in time, you will.~ GOTO MRRepLowBhaal-YesSomeday
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-YesPlaceStrong
		SAY ~If being strong means being a jerk and trampling on those less fortunate, I'm not interested.~
			++ ~Maybe right now you're not - I wasn't either, at first. But someday, you will be.~ GOTO MRRepLowBhaal-YesSomeday
			++ ~Someday you'll see: the difference between good and evil only depends on which people you kill.~ GOTO MRRepLowBhaal-YesSomeday
			++ ~Then stop trying to lecture me.~ GOTO MRRepLowBhaal-YesStop
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-YesSomeday
		SAY ~I hope you're wrong, <CHARNAME>. For both our sakes, I hope you're wrong.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRRepLowBhaal-YesWrongEnd
		SAY ~(She suddenly shivers, wrapping her arms around herself in a protective hug.)~
		= ~I don't want to talk about this anymore. Let's just go.~
		IF ~~ THEN EXIT
	END
END




