// ~~ New Imoen summoning: romance Imoen easy way ~~
//replace the old summoning dialogue from IMOEN25A state 0


REPLACE IMOEN25A
	IF ~Global("ImoenSummoned","GLOBAL",1)~ THEN BEGIN 0
		SAY ~Sweet Tymora's unholy rack!~ [IRQUIET]
		IF ~~ THEN DO ~SetGlobal("ImoenSummoned","GLOBAL",2)~ GOTO Summon1
	END
END


CHAIN IF ~Global("ImoenSummoned","GLOBAL",1)~ THEN IMOEN25A Summon1
	 ~Uh... <CHARNAME>? Is that you? What the hell just happened?~
	= ~One moment I'm getting up from a nap, the next I'm... uh. Where in blazes am I?~
	== AERIE25J IF ~OR(2) GlobalGT("MRAerImFriend","GLOBAL",5) Global("IRTAerImFriend","GLOBAL",1) InParty("Aerie")~ THEN ~Imoen, hi! It is nice to see you again!~
	== IMOEN25A IF ~OR(2) GlobalGT("MRAerImFriend","GLOBAL",5) Global("IRTAerImFriend","GLOBAL",1) InParty("Aerie")~ THEN ~Oh, um, hi! Sorry, I'm all discombobulated...~
END
    +~Global("ImoenRomanceActive","GLOBAL",0)~+ ~My love, I've missed you terribly. Are you well?~ DO ~SetGlobal("ImoenRomanceActive","GLOBAL",2) SetGlobal("IRTLoveMeter","GLOBAL",5)~ GOTO Summon6
	++ ~It is good to see a friendly face. I've missed you. What have you been doing?~ DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4)~ GOTO Summon7
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~My love, I've missed you terribly. Are you well?~ DO ~ SetGlobal("IRTLoveMeter","GLOBAL",5)~ GOTO Summon6
	++ ~You are here because I called you. Join the group, I need you.~ GOTO Summon3anew
	++ ~You are wearing on my nerves already. Pipe down and do as I say or you will rot here for all eternity.~ DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3)~ GOTO Summon5
	++ ~I might need you later. Go wait somewhere around here.~ DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4) SetGlobal("IRTLoveMeter","GLOBAL",-1)~ GOTO Summon4

APPEND IMOEN25A
IF ~~ Summon3anew
	SAY ~Wow, wow, hold yer horses there. My head's still spinning. Not even a "how ya doing"? So impolite...~
	+~Global("ImoenRomanceActive","GLOBAL",0)~+ ~Yes, love, forgive my hastiness. Are you well?~ DO ~SetGlobal("ImoenRomanceActive","GLOBAL",2) SetGlobal("IRTLoveMeter","GLOBAL",5)~ GOTO Summon6
	++ ~I suppose it's the least I could ask a good friend. How are you doing?~ DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4)~ GOTO Summon7
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~Yes, love, forgive my hastiness. Are you well?~ DO ~SetGlobal("IRTLoveMeter","GLOBAL",5)~ GOTO Summon6
	++ ~You are wearing on my nerves already. Pipe down and do as I say or you will rot here for all eternity.~ DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3)~ GOTO Summon5
	++ ~Actually, I don't need you right now. Go wait somewhere around here.~ DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4) SetGlobal("IRTLoveMeter","GLOBAL",-1)~ GOTO Summon3anewAhead
END

IF ~~ Summon3anewAhead
	SAY ~Yes, well, as I was saying, some strange stuff has started happening to me. I've been having... odd dreams.~
	= ~It's not like after Irenicus had us, either. This is different. I... I didn't believe I was a Bhaalspawn. Not even after Irenicus said so, not really. But now I do.~
	= ~The feelings... it's... it's hard to describe. But you probably know all about it, huh? I don't know how you went through it, I really don't.~
	++ ~Come with me, then.~ DO ~SetGlobal("IRTJustJoined","GLOBAL",1) JoinParty() SetDialog("IMOEN25J")~ EXIT
	++ ~I didn't ask for your life story.~ GOTO Summon7a
	++ ~I need you to wait here for awhile. I'll deal with you later.~ GOTO Summon4
END
END

CHAIN IMOEN25A Summon4
	~Wow. Really? You dragged me here only to... h- hey, is that an imp over there?~
	== BOTSMITH ~I ams Cespenar. I ams butler of the Great One, oh yes!~
	== IMOEN25A ~Haha, what? How's it that Bhaal had *you* as a butler?~
	== BOTSMITH ~Cespenar is good good butler! Cespenar finds things, Cespenar makes Shiny ones! Cespenar cooks, too. Yummy yummy food, oh yes!~
	== IMOEN25A ~Ooh, is that so? 'Cuz I'm super hungry. Let me see what you got...~ DO ~MoveToObject("BOTSMITH")~ 
EXIT

APPEND IMOEN25A
IF ~~ Summon5
	SAY ~Agh. You jerk, why did you even call me here? I can't believe I'm *still* glad to see you again.~
	= ~'Cause, y'know, some strange stuff has started happening to me. I've been having... odd dreams.~
	= ~It's not like after Irenicus had us, either. This is different. I... I didn't really believe I was a Bhaalspawn. Not even after Irenicus said so, not really. But now I do.~
	= ~The feelings... it's... it's hard to describe. But you probably know all about it, huh? I don't know how you went through it, I really don't.~
	= ~I, uh... sorry. I'll be quiet now.~
	++ ~Come with me, then.~ DO ~SetGlobal("IRTJustJoined","GLOBAL",1) JoinParty() SetDialog("IMOEN25J")~ EXIT
	++ ~No, wait. I'm sorry. You're my sister now, we need to get along. Friends?~ DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4)~ GOTO Summon5a
	++ ~I need you to wait here for awhile. I'll deal with you later.~ GOTO Summon4
END

IF ~~ THEN Summon5a
	SAY ~(Imoen gives you a bright smile.) Really? Yes, of course! I promise not to drive you too crazy. Ooh, it's gonna be just like old times!~
	IF ~~ THEN DO ~SetGlobal("IRTJustJoined","GLOBAL",1) JoinParty() SetDialog("IMOEN25J")~ EXIT
END

IF ~~ THEN Summon6
	SAY ~(Imoen smiles brightly and gives you a tight hug.) I've missed you SO much. Wish you hadn't talked me into leaving... but it doesn't matter now. We're back together, yay! It's felt like an eternity without you. And not just because I was bored out of my mind.~
	= ~Some strange stuff started happening to me, though. I've been having... odd dreams. Y'know, I... I didn't *really* believe I was a Bhaalspawn. Not even when Irenicus said so, not entirely. But... now I do.~
	= ~The feelings... it's... it's hard to describe. But you probably know all about it, huh? I don't know how you went through it, I really don't.~
	++ ~Don't worry. Come with me, and we'll deal with it together.~ GOTO Summon6a
	++ ~Imoen, I didn't ask for your life story.~ GOTO Summon7a
	++ ~I need you to wait here for a while, actually. It's hard to part ways again, but it's really important.~ GOTO Summon4
	++ ~Fine. Wait here.~ GOTO Summon4
END

IF ~~ THEN Summon6a
	SAY ~Oh boy. I'm ready... (She raises her eyebrows suggestively) and willing.~
	IF ~~ THEN DO ~SetGlobal("IRTJustJoined","GLOBAL",1) JoinParty() SetDialog("IMOEN25J")~ EXIT
END
END

APPEND IMOEN25A
IF ~~ THEN Summon7
	SAY ~Oh, I haven't been doing anything special. Dealing with my problems, mostly. But some strange stuff started happening recently. I've been having... odd dreams.~
	= ~It's not like after Irenicus had us, either. This is different. I... I didn't believe I was a Bhaalspawn. Not even after Irenicus said so, not really. But now I do.~
	= ~The feelings... it's... it's hard to describe. But you probably know all about it, huh? I don't know how you went through it, I really don't.~
	++ ~Come with me, then.~ DO ~SetGlobal("IRTJustJoined","GLOBAL",1) JoinParty() SetDialog("IMOEN25J")~ EXIT
	++ ~I didn't ask for your life story.~ GOTO Summon7a
	++ ~I need you to wait here for awhile. I'll deal with you later.~ GOTO Summon4
END

IF ~~ THEN Summon7a
	SAY ~(Imoen gives you a playful shove.) Jerk.~
	= ~Let's get going before I change my mind about helping you...~
	IF ~~ THEN DO ~SetGlobal("IRTJustJoined","GLOBAL",1) JoinParty() SetDialog("IMOEN25J")~ EXIT
END
END

// ~~ Greetings for everyone after being Summoned ~~


CHAIN IF WEIGHT #100 ~Global("IRTJustJoined","GLOBAL",2)~ THEN IMOEN25J SummonHeya
	~Heya all, people! Looks like we're traveling together again.~ DO ~SetGlobal("IRTJustJoined","GLOBAL",3)~

	== SAREV25J IF ~InParty("Sarevok")~ THEN ~Oh, joy. Just what we needed, a screaming brat pouting about every single eventuality we come across.~
	== IMOEN25J IF ~InParty("Sarevok")~ THEN ~Sarevok! What the hell?~
	== SAREV25J IF ~InParty("Sarevok")~ THEN ~Exactly, my "dear sister". Hell is what has brought us back together. Although, this time, we fight on the same side. Much to my regret, I must say.~
	== IMOEN25J IF ~InParty("Sarevok")~ THEN ~(Imoen's scowl is dark enough to be threatening.) How so?~
	== SAREV25J IF ~InParty("Sarevok")~ THEN ~Your fellow <PRO_BROTHERSISTER> here gave up an insignificant portion of <PRO_HISHER> divine essence to bring me back to life. In exchange, <PRO_HESHE> has my lifelong services.~
	== SAREV25J IF ~InParty("Sarevok") Global("SarevokOath","GLOBAL",1)~ THEN ~But fear not, little girl. I am bound by an unholy Oath not to betray <CHARNAME> and, by extension, anyone who travels with <PRO_HIMHER>.~
	== SAREV25J IF ~InParty("Sarevok") !Global("SarevokOath","GLOBAL",1)~ THEN ~I offered an Oath of fealty, but <CHARNAME>... declined. The reason of which still escapes me.~  // Oops, there was a ! missing.
	== SAREV25J IF ~InParty("Sarevok")~ THEN ~In any case, I pose no threat. (Certain acrimony wraps Sarevok last words.)~
	== IMOEN25J IF ~InParty("Sarevok")~ THEN ~Hrm. You better. I'm watchin' ya, that's for sure. You don't wanna die a third time, do ya? Hm, wait, is it the fourth? I've lost count already, you've eaten dust so many times by our hands...~
	== SAREV25J IF ~InParty("Sarevok")~ THEN ~I cower in fear.~
	== IMOEN25J IF ~NumInPartyGT(3) InParty("Sarevok")~ THEN ~(She huffs.) Just stay away from me...~
	== IMOEN25J IF ~!NumInPartyGT(3) InParty("Sarevok")~ THEN ~(She huffs.) Just stay away from me. I can't believe yer our only companion. We're gonna have so much fun.~

	== AERIE25J IF ~Global("IRTAerImFriend","GLOBAL",1) InParty("Aerie")~ THEN ~I missed you a lot, Imoen.~
	== IMOEN25J IF ~Global("IRTAerImFriend","GLOBAL",1) InParty("Aerie")~ THEN ~I missed you too, Aerie. It's good to be with ya again. Now we can continue making fun of <CHARNAME> together!~
	== AERIE25J IF ~Global("IRTAerImFriend","GLOBAL",1) InParty("Aerie")~ THEN ~Hee hee, I can't wait...~
	== AERIE25J IF ~!Global("IRTAerImFriend","GLOBAL",1) InParty("Aerie")~ THEN ~Hello, Imoen.~
	== IMOEN25J IF ~!Global("IRTAerImFriend","GLOBAL",1) InParty("Aerie")~ THEN ~Heya! How ya doin', Aerie?~
	== AERIE25J IF ~!Global("IRTAerImFriend","GLOBAL",1) InParty("Aerie")~ THEN ~I am well. It is great to see you.~

	== JAN25J IF ~InParty("Jan")~ THEN ~I tell you, young lass, your sudden poofing into this place reminded me of that one time cousin Fiddlefingers drank his Improved Turnip Juice of True Vision.~
	== IMOEN25J IF ~InParty("Jan")~ THEN ~Oh boy. What happened to him, Jan?~
	== JAN25J IF ~InParty("Jan")~ THEN ~Well, he claimed it would grant him extra-planar vision, allowing him to see all the wonders of the multiverse from the comfort of his own chair. And so he drank it... vanishing into thin air! We thought he was literally gone to other planes, you see, but soon he started yelling. He had clearly turned invisible, which was quite the disappointment for him. He blamed us for the entire thing, saying our foul auras had interfered with the magicks at work. If you ask me, he shouldn't have chosen red turnip as the base component. Too tart.~
	== JAN25J IF ~InParty("Jan")~ THEN ~But the potion worked! Well, not in the way he had intended, but it did make you invisible. Quite the wonder! And so we have invisibility potions today. Such a hidden genius, cousin Fiddlefingers. Too bad about the overdose...~
	== IMOEN25J IF ~InParty("Jan")~ THEN ~Fascinating story, Jan.~

	== JAHEI25J IF ~InParty("Jaheira")~ THEN ~It is good to have you with us again, child.~
	== IMOEN25J IF ~InParty("Jaheira")~ THEN ~I'm so happy yer still alive, mom!~
	== JAHEI25J IF ~InParty("Jaheira")~ THEN ~(Jaheira smiles.) I didn't say you were *my* child. Just *a* child.~
	== IMOEN25J IF ~InParty("Jaheira")~ THEN ~Gee whiz. Way to disown me, just like that.~
	== IMOEN25J IF ~InParty("Jaheira")~ THEN ~But seriously, it's great to see you, Jaheira. Haughty eyebrows and all.~


	== MINSC25J IF ~InParty("Minsc")~ THEN ~Minsc is happy to see Imoen again. What? (Minsc lifts his rodent to his ear and smiles.) Boo says he is happy, too! Good Imoen always knows how to do good buttkicking with her magicks!~
	== IMOEN25J IF ~InParty("Minsc")~ THEN ~Minsc, will you teach me some day to understand what Boo says?~
	== MINSC25J IF ~InParty("Minsc")~ THEN ~I, ah... you do not understand what he says?~
	== IMOEN25J IF ~InParty("Minsc")~ THEN ~Oh, y-yeah, of course! Haha. Gotcha!~
	== IMOEN25J IF ~InParty("Minsc")~ THEN ~Traveling with you never gets old, Minsc.~

	== VICON25J IF ~InParty("Viconia")~ THEN ~It was strange not having your insipid chatter distract us all the time, dalhar.~
	== IMOEN25J IF ~InParty("Viconia")~ THEN ~Ha! I knew you'd miss me. I look forward to your mean and unprovoked abuse, Vic.~
	== VICON25J IF ~InParty("Viconia")~ THEN ~I will not disappoint.~

	== IMOEN25J IF ~InParty("Korgan")~ THEN ~It is *such* a pleasure to smell ya again, Korgan.~
	== KORGA25J IF ~InParty("Korgan")~ THEN ~What ye be meanin' by that, ye long-limbed lass? Mayhaps ye be wantin' a closer sniff?~
	== IMOEN25J IF ~InParty("Korgan")~ THEN ~NO! Um, no. Just praising your most unique personal hygiene.~
	== KORGA25J IF ~InParty("Korgan")~ THEN ~Ha! This be how *real* dwarfs smell.~

	== IMOEN25J IF ~InParty("Nalia")~ THEN ~Whew, Nalia, you look... mighty. Somehow.~
	== NALIA25J IF ~InParty("Nalia")~ THEN ~I'll take that as a compliment. Somewhat.~
	== IMOEN25J IF ~InParty("Nalia")~ THEN ~No, really! You have this... aura about ya. Intimidating!~
	== NALIA25J IF ~InParty("Nalia")~ THEN ~Well, that's good, isn't it?~
	== IMOEN25J IF ~InParty("Nalia")~ THEN ~Sure! It'll be nice to talk magic with ya.~

	== MAZZY25J IF ~InParty("Mazzy")~ THEN ~Greetings, Imoen.~
	== IMOEN25J IF ~InParty("Mazzy")~ THEN ~Hi, um. How ya doin'?~
	== MAZZY25J IF ~InParty("Mazzy")~ THEN ~Aside from being in a foul hell dimension where evil can literally be felt on your skin, I don't see much room for complaint.~
	== IMOEN25J IF ~InParty("Mazzy")~ THEN ~Gee. In a bad mood?~
	== MAZZY25J IF ~InParty("Mazzy")~ THEN ~Hm. It was an attempt at humor, actually.~
	== IMOEN25J IF ~InParty("Mazzy")~ THEN ~Oh! Then... well done?~
	== MAZZY25J IF ~InParty("Mazzy")~ THEN ~Thank you.~

	== KELDO25J IF ~InParty("Keldorn")~ THEN ~A true pleasure to have you with us again, Imoen.~
	== IMOEN25J IF ~InParty("Keldorn")~ THEN ~Aw, thanks Keldorn! You have a funny beard!~
	== KELDO25J IF ~InParty("Keldorn")~ THEN ~I... alright.~
	== KELDO25J IF ~InParty("Keldorn")~ THEN ~Welcome back indeed.~

	== CERND25J IF ~InParty("Cernd")~ THEN ~Welcome back to the fold, friend. You return to us as the stray lamb finds its way back to the flock.~
	== IMOEN25J IF ~InParty("Cernd")~ THEN ~Oh, um... yer so familiar. I... can't seem to place your name, though.~
	== CERND25J IF ~InParty("Cernd")~ THEN ~Cernd, a humble servant and loyal defender of Nature.~
	== IMOEN25J IF ~InParty("Cernd")~ THEN ~Oh, yeah! Nice to meet you again, I guess.~

	== IMOEN25J IF ~InParty("Valygar")~ THEN ~And isn't that one stern, silent ranger I'm seeing.~
	== VALYG25J IF ~InParty("Valygar")~ THEN ~Well, isn't that one chirpy, hyperactive mage addressing me.~
	== IMOEN25J IF ~InParty("Valygar")~ THEN ~Oh my, more than four words strung together! Yer a box full of surprises, Val.~
	== VALYG25J IF ~InParty("Valygar")~ THEN ~Thanks. I try.~

	== HAERD25J IF ~InParty("HaerDalis")~ THEN ~Ah, the blackbird has returned to the raven's wake at last!~
	== IMOEN25J IF ~InParty("HaerDalis")~ THEN ~Mmm-hmm. Nice to see ya too, um, pigeon.~
	== HAERD25J IF ~InParty("HaerDalis")~ THEN ~And with her wit as sharp as ever. This sparrow will enjoy our travels, rest assured!~

	== ANOME25J IF ~InParty("Anomen")~ THEN ~Well met, Imoen.~
	== IMOEN25J IF ~InParty("Anomen")~ THEN ~Why, well met indeed, Anomen! How're things goin' for ya?~
	== ANOME25J IF ~InParty("Anomen")~ THEN ~I presume they go as well as they could, considering the circumstances.~
	== IMOEN25J IF ~InParty("Anomen")~ THEN ~That's one smart answer!~

	== IMOEN25J IF ~InParty("Edwin") Gender("Edwin",MALE)~ THEN ~Hey, doesn't my favorite evil red wizard have anything to say to me?~
	== IMOEN25J IF ~InParty("Edwin") Gender("Edwin",FEMALE)~ THEN ~Hey, doesn't my favorite evil witch have anything to say to me?~
	== EDWIN25J IF ~InParty("Edwin")~ THEN ~Are you addressing me, girl? Are you not aware yet that you are beneath my station?~
	== IMOEN25J IF ~InParty("Edwin")~ THEN ~Right, uh... I guess you're of noble blood or something? 'Cause I happen to have a bit of a lineage, myself.~
	== EDWIN25J IF ~InParty("Edwin")~ THEN ~A *simian* is above your station, you smart-mouthed wench. Know your place and leave me be.~
	== IMOEN25J IF ~InParty("Edwin") Gender("Edwin",FEMALE)~ THEN ~But of course, m'Lady. I'd never presume to be as refined and graceful as you.~
	== EDWIN25J IF ~InParty("Edwin") Gender("Edwin",FEMALE)~ THEN ~Yes, indeed. A magically-transgendered man is far more elegant and beautiful than you. I hope that you are proud.~
	== IMOEN25J IF ~InParty("Edwin") Gender("Edwin",FEMALE)~ THEN ~... Point taken.~

	== IMOEN25J ~Oh well... let's hit the road!~
EXIT
