// This is a brief conversation on marriage initiated through PID by the protagonist. Only available if Imoen is romanced.
//Available after first of Senda/Abazigal dead and solar talk
// Global toward epilogues: IRTWantsMarriage = 0,1

// Trigger global: IRTMarriageTalk = 1
/*
PID option:
+ ~GlobalGT("IRTLoveMeter","GLOBAL",7) Global("IRTMarriageTalk","GLOBAL",1) Gender(Player1,MALE)~ + ~Would you ever want to marry, Imoen?~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRTMarriageTalk","GLOBAL",2)~ GOTO Mar1
+ ~GlobalGT("IRTLoveMeter","GLOBAL",7) Global("IRTMarriageTalk","GLOBAL",1) Gender(Player1,FEMALE)~ + ~Would you ever want to marry, Imoen?~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRTMarriageTalk","GLOBAL",2)~ GOTO MarF
+ ~!GlobalGT("IRTLoveMeter","GLOBAL",7) Global("IRTMarriageTalk","GLOBAL",1)~ + ~Would you ever want to marry, Imoen?~ DO ~SetGlobal("IRTMarriageTalk","GLOBAL",2)~ GOTO MarTooLow
*/


APPEND IMOEN25J
IF ~~ MarTooLow
   SAY ~(Imoen quirks an eyebrow, lips pursed.)~
   = ~The way things have been lately? No, I don't think so. Can't say I've been feelin' the spark we used to have...~
   ++ ~I understand what you mean. I'm sorry, Imoen. I'll do better.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",2)~ + MarLow4
   ++ ~There's a lot on my plate. I can't give you all of my attention right now. I thought you'd understand.~ + MarLow3
   ++ ~There goes Selfish Imoen again, thinking of no-one but herself. Is anyone surprised?~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-2)~ + MarLow2
   ++ ~I don't want to argue. Let's move on.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-1)~ + MarLow1
END

IF ~~ MarLow1
   SAY ~Yeah. We better do that.~
   IF ~~ THEN EXIT
END

IF ~~ MarLow2
   SAY ~(She rolls her eyes.) Yup, sure, whatever. I don't wanna argue right now, so let's just move on.~
   IF ~~ THEN EXIT
END

IF ~~ MarLow3
   SAY ~I *do* understand, is why I haven't said a thing. But you asked me a question, and I answered honestly.~
   = ~I really don't wanna argue right now. You know where I stand. Let's leave it at that.~
   IF ~~ THEN EXIT
END

IF ~~ MarLow4
   SAY ~Hey, no, I get it. Yer dealing with some heavy stuff right now, I can't expect things between us to be rainbows and cotton candy all the time.~
   = ~I appreciate the thought, though. It's great to know that you care.~
   IF ~~ THEN EXIT
END


IF ~~ MarF
   SAY ~Marry? As in, the two of us? Is that a thing that can happen? I didn't think it was an option.~
   = ~I mean, who in the world would marry us? What with the ladyparts an' all.~
   ++ ~I'm sure we can find someone. A priest of Sune, maybe.~ + MarFVague
   + ~InParty("Aerie")~ + ~Aerie is a priestess. She can officiate.~ + MarFAerie
   + ~InParty("Jaheira")~ + ~Jaheira is a druid. She has the authority.~ + MarFJaheira
   + ~InParty("Viconia")~ + ~Viconia could do it. She's a priestess.~ + MarFViconia
   + ~InParty("Anomen")~ + ~Anomen is a cleric. He could officiate.~ + MarFAnomen
   + ~InParty("Keldorn")~ + ~I believe Keldorn has the authority, as Paladin of the Most Noble Order of the Radiant Heart.~ + MarFKeldorn
   ++ ~I'm sure there will be an amenable civil servant somewhere.~ + MarFVague
   ++ ~Don't worry about that. Let's say we could. Would you?~ + Mar1
   ++ ~That's a good point. Never mind, then.~ + MarFNvrMnd
END

IF ~~ MarFVague
   SAY ~Eeh, if you say so. I wouldn't count on it.~
   IF ~~ THEN GOTO Mar1N
END

IF ~~ MarFNvrMnd
   SAY ~Duuuuuuhr, I'm <CHARNAME> and I ask questions without thinking them through, dduuuuhhhhrrr!~
   IF ~~ THEN EXIT
END
END

CHAIN IMOEN25J MarFAerie
	~Oh Gods, I sure hope she didn't hear you say that.~
	== AERIE25J IF ~IsValidForPartyDialog("Aerie")~ THEN ~(Aerie clasps her hands together, bouncing in place.) Yes! Yes, that would be wonderful! I'd be honored to do this for you.~
	== IMOEN25J IF ~IsValidForPartyDialog("Aerie")~ THEN ~Ah, crap. Now she's never gonna stop buggin' me about it.~
	== IMOEN25J IF ~!IsValidForPartyDialog("Aerie")~ THEN ~(Imoen looks in Aerie's direction.) Oh good, she didn't. If she had, she'd get all excited and never stop buggin' me about it.~
END IMOEN25J Mar1WifeWife

CHAIN IMOEN25J MarFJaheira
	~Pff, yeah, right! Haven't you been listening to everything she says about us?~
	= ~Wait, of course you haven't. Neither have I, hah!~
	== JAHEI25J IF ~IsValidForPartyDialog("Jaheira")~ THEN ~I've made peace with your union, Imoen, <CHARNAME>. And yet, I must admit I'm reluctant to the idea of officiating for you. I trust you understand.~
END IMOEN25J Mar1WifeWife

CHAIN IMOEN25J MarFViconia
	~What? And become wife and wife, with *Shar* as our witness? Are you nuts?~
	== VICON25J IF ~IsValidForPartyDialog("Viconia")~ THEN ~This might be the one time I agree with something you say, girl. Shar is not the one to beseech with such trifling matters.~
END IMOEN25J Mar1WifeWife

CHAIN IMOEN25J MarFAnomen
	~Oh boy, wouldn't that be the most fun of all weddings, with Mister Annoyance frowning upon us the whole time.~
	== ANOME25J IF ~IsValidForPartyDialog("Anomen")~ THEN ~You need not worry, for I would never agree to endorse such a perverted union.~
END IMOEN25J Mar1WifeWife

CHAIN IMOEN25J MarFKeldorn
	~Could he? Can't say I've ever looked into paladins doin' that kinda stuff...~
	== KELDO25J IF ~IsValidForPartyDialog("Keldorn")~ THEN ~I could, and I would. It required some time and much thought, but I see wisdom in endorsing your union. Love is a rare thing in the lives we carry, and so it should be celebrated - regardless of how it chooses to manifest.~
	== IMOEN25J IF ~IsValidForPartyDialog("Keldorn")~ THEN ~That's a mighty roundabout and long-winded way to say we were right all along, isn't it? Have you married anyone before?~
	== KELDO25J IF ~IsValidForPartyDialog("Keldorn")~ THEN ~I can't say I have. But I have witnessed several comrades perform the ceremony.~
	== IMOEN25J IF ~IsValidForPartyDialog("Keldorn")~ THEN ~Y'know what? Yer an alright fellow.~
END IMOEN25J Mar1WifeWife

APPEND IMOEN25J
IF ~~ Mar1
   SAY ~(Imoen quirks an eyebrow, lips pursing in amusement.) Is that a proposal, <PRO_LADYLORD> <CHARNAME>?~
   IF ~Gender(Player1,FEMALE)~ THEN GOTO Mar1WifeWife
   IF ~Gender(Player1,MALE)~ THEN GOTO Mar1N
END

IF ~~ Mar1WifeWife
   SAY ~Might be worth doing just for the looks I'll get when I refer to you as "my wife"...~
   IF ~~ THEN GOTO Mar1N
END

IF ~~ Mar1N
   SAY ~Can't say it matters to me a whole lot, to be honest. I always found the idea... stifling.~
   = ~I could be talked into it, I guess, if it's important to you. Just don't ask me to get excited about it.~
   ++ ~Really? Personally, I can't imagine the future without you as my wife.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1)~ + MarYes
   ++ ~I feel the same way. I don't need a priest or civil servant to validate our love.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1)~ + MarNo
   + ~Gender(Player1,MALE)~ + ~It doesn't matter to you? But marriage is every young girl's dream!~ + MarDreamM
   + ~Gender(Player1,FEMALE)~ + ~It doesn't matter to you? But marriage is every young girl's dream!~ + MarDreamF
   ++ ~I was only curious. Thanks for being honest.~ + MarEnd
   ++ ~Oh. If you're not all that interested, then never mind.~ + MarDisappoint
END

IF ~~ MarEnd
   SAY ~Hey, of course. If we can't tell each other what we want out of life, then what's the point?~
   = ~Well, then, so there is that. (She arches her brow, adopting a haughty tone. She sounds just like Jaheira.) I am glad we have settled this matter to mutual satisfaction. If there is no other issues to discuss, I suggest we move on.~
   IF ~~ THEN EXIT
END

IF ~~ MarDisappoint
   SAY ~Well, it's just not my thing. What's so great about it? A big stuffy ceremony, some priest telling me things I already know, a bunch of people starin' at me like I'm some kind of circus freak...~
   = ~All for what gain? A public promise or a piece of paper won't make me any more committed to you. I'm already all in, so... (Imoen shrugs.)~
   = ~If you don't care about it, I don't care about it.~
   IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1)~ EXIT
END

IF ~~ MarDreamF
   SAY ~Pfah! Yours included, I take it? We never *once* talked about big frilly dresses and flowers and decorations, ya know. I've always been kind of a tomboy about such things and you... well, you're you.~
   ++ ~I knew you'd only get bored out of your mind, but I've always dreamed about it.~ + MarDreamF3
   ++ ~I *tried* talking to you about these things, and fashion, and makeup, but you were always too focused on the next big prank, or getting out of doing chores so you could skulk around the keep, up to no good.~ + MarDreamF2
   ++ ~True. I was only teasing. I don't quite care, honestly.~ + MarNo
END
END

CHAIN IMOEN25J MarDreamF2
   ~Aw, jeez, sorry! All that stuff is just... not my thing. Well, I do appreciate nicely cut robes, that much I do. Won't say no to more enchanted jewelry, either. Hint hint hint.~
   = ~Hey, wait! I tried kohl around my eyes, once. Remember? Winthrop flat-out laughed in my face, and Dreppin said I looked like a raccoon. Jerks.~
   == IMOEN25J IF ~Global("IRTPlayerIsMagicUser","GLOBAL",1)~ THEN ~Anyway... I'm sorry I'm so blah about this. It's hard to be a mighty kick-ass witch AND a girly girl at the same time, I dunno how you do it. I never daydreamed about the perfect wedding.~
   == IMOEN25J IF ~Global("IRTPlayerIsMagicUser","GLOBAL",0)~ THEN ~Anyway... I'm sorry I'm so blah about this. It's hard to be a mighty kick-ass witch AND a girly girl at the same time, y'know? I dunno how you pull it off while bein' the Hero of the Ages. I never daydreamed about the perfect wedding.~
END IMOEN25J MarHappy

APPEND IMOEN25J
IF ~~ MarDreamF3
   SAY ~Aww, that's... kind of adorable, love. I'm sorry I'm so blah about this. It's just not my thing, y'know?~
   IF ~~ THEN GOTO MarHappy
END

IF ~~ MarDreamM
   SAY ~Pfah! Not *every* young girl, because it was never mine. Y'know what I'd dream about? Seeing the world, from corner to corner. Visit every dot on the map, free to roam as I please and do as I please. Not terribly surprising, considering our chronic imprisonment in Candlekeep.~
   = ~Funny part is, now that I'm doing just that - well, kind of - it's every bit as I'd imagined! Uh, except for the torture, that part I could've skipped. And sleeping accommodations, sometimes. We should stop at posh inns more often. And by more often I mean all the time, please.~
   = ~Anyway, yeah, no frilly dresses or stuffy ceremonies in my dreams. Sorry! It's just... not my thing, y'know?~
   ++ ~Well, it is *my* dream to see you in that dress, take your hand and declare my love for you in front of everyone.~ + MarDreamM3
   ++ ~It doesn't have to be like that. It can be quiet, intimate and informal.~ + MarDreamM2
   ++ ~Ah. My mistake, then. Thank you for your honesty. Consider the matter settled.~ + MarEnd
   ++ ~You're no fun, Imoen.~ + MarDreamM1
END

IF ~~ MarDreamM1
   SAY ~Aww, c'mon, I'm *loads* of fun! It's just such a hassle, and for what gain, really? A public promise or a piece of paper won't make my love for you any more real.~
   IF ~~ THEN GOTO MarHappy
END

IF ~~ MarDreamM2
   SAY ~Aw. Really? That'd be... nice, I guess. It'd still be a hassle, though. I just don't see the gain, y'know? A big solemn promise or a piece of paper won't make my love for you any more real than it already is.~
   IF ~~ THEN GOTO MarHappy
END

IF ~~ MarDreamM3
   SAY ~Aw, jeez... when you put it like that, it's hard to argue against it. I just don't see the gain, y'know? A public promise or a piece of paper won't make my love for you any more real than it already is.~
   IF ~~ THEN GOTO MarHappy
END

IF ~~ MarNo
   SAY ~Then we're on the same page! I'm so glad to hear it. I'm already all in with us, love. A public promise or a piece of paper won't make it any more official. All I need is this.~
   = ~(Imoen leans in and softly kisses your mouth, lingering for a little while. She gives you another brief kiss after your lips part, for good measure.)~
   = ~(She smiles, entangles her fingers with yours and remains close for a while.)~
   IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",4)~ EXIT
END

IF ~~ MarYes
   SAY ~Aw, jeez, that's so darn sweet of you. If you put it like that, it doesn't sound so bad.~
   = ~It's just not my thing, y'know? The big frilly dresses, the stuffy ceremony, everybody looking at us like we just came out of a circus... yeugh.~
   IF ~~ THEN GOTO MarHappy
END

IF ~~ MarHappy
   SAY ~But if it'd make you happy...~
   ++ ~It would make me the happiest <PRO_MANWOMAN> alive. (Get down on one knee, take her hand.) Imoen of Candlekeep: I would ask you to marry me.~ + MarHappy4
   ++ ~It would, yes. But we can discuss the details later. Let's focus on surviving, for now.~ + MarHappy3
   ++ ~No, don't worry about it. If you're not excited about the idea, there is no point.~ + MarHappy2
   ++ ~You make a lot of sense, actually. We don't need it. We only need each other.~ + MarHappy1
END

IF ~~ MarHappy1
   SAY ~Hah! Vindicated yet again. Imoen, always right about everything!~
   = ~(She leans in and softly kisses your mouth, lingering for a little while. She gives you another brief kiss after your lips part, for good measure.)~
   = ~I'm already all in with us, love. All I need is this. (She smiles, entangles her fingers with yours and remains close for a while.)~
   IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",3)~ EXIT
END

IF ~~ MarHappy2
   SAY ~But there is no point *anyway*, y'see? I'm already all in with us, love.~
   = ~(She leans in and softly kisses your mouth, lingering for a little while. She gives you another brief kiss after your lips part, for good measure.)~
   = ~All I need is this. (She smiles, entangles her fingers with yours and remains close for a while.)~
   IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",2)~ EXIT
END

IF ~~ MarHappy3
   SAY ~That works fine and dandy for me. Who knows, we might just die today and then we won't have to worry about catering, huh? Aah, all worries gone, all problems solved.~
   = ~We better make it count while we can. (Imoen leans in and softly kisses your mouth, then gives you another, more brief kiss after your lips part.)~
   IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",2) SetGlobal("IRTWantsMarriage","GLOBAL",1)~ EXIT
END

IF ~~ MarHappy4
   SAY ~(Imoen freezes in place for a moment, eyes wide. Then she tilts her head to the side, as if waiting for something. A half-smile creeps onto her lips.)~
   = ~Well?~
   = ~Where's the ring, then?~
   ++ ~Um... I didn't have the chance to get one. I thought the question would be enough.~ + MarHappy4c
   ++ ~(You are prepared. From your pocket you produce the amethyst-studded gold ring you were saving for this occasion. She always liked purple.)~ + MarHappy4d
   ++ ~You need a ring? I didn't think you'd care.~ + MarHappy4b
   ++ ~Well, this is awkward. I call for a do-over.~ + MarHappy4a
END

IF ~~ MarHappy4a
   SAY ~Hah hah, a do-over? No no no no, only one chance to get it right, and you blew it big time.~
   IF ~~ THEN GOTO MarHappyEnd
END

IF ~~ MarHappyEnd
   SAY ~(Imoen pulls on your hand, dragging you into a hug. Her features are full of amusement.)~
   = ~Of course I'll marry you, silly. I wanna make you happy. Something tells me I'll find ways to enjoy myself with this whole ceremony thing.~
   = ~(She leans in for a kiss, soft and caring. You can feel her chest swell in your arms, her lips smile against yours. She lovingly looks into your eyes as you part.)~
   = ~We better get done with all this nasty business in our hands, so we can get on with the rest of your lives.~
   = ~I can't wait...~
   IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",5) SetGlobal("IRTWantsMarriage","GLOBAL",1)~ EXIT
END

IF ~~ MarHappy4b
   SAY ~But of course I care! It's the *most* important thing! There's NO WAY I'd go for it without a ring on my finger, who do you think I am?~
   IF ~~ THEN GOTO MarHappyEnd
END

IF ~~ MarHappy4c
   SAY ~What? No no no no, that will just not do. I *must* have a ring to even *consider* going for this. Who do you think I am?~
   IF ~~ THEN GOTO MarHappyEnd
END

IF ~~ MarHappy4d
   SAY ~(Imoen's mouth is agape with delighted surprise. She incredulously looks at you as the band slips past the bony joint of her ring finger.)~
   = ~Yer such a stinker! When did ya get a chance to get this? Oh, look at that, it's so pretty!~
   = ~(Imoen pulls on your hand, dragging you into a hug.) Of course I'll marry you, silly! I was only teasing, I didn't expect you'd have an actual ring.~
   = ~(She leans in for a kiss, soft and caring. You can feel her chest swell in your arms, her lips smile against yours. She lovingly looks into your eyes as you part.)~
   = ~I wanna make you happy. Something tells me I'll find ways to enjoy myself with this whole ceremony thing. It'll be fun. We better get done with all this nasty business in our hands, so we can get on with the rest of your lives.~
   = ~I can't wait...~
   IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",5) SetGlobal("IRTWantsMarriage","GLOBAL",1)~ EXIT
END
END


