APPEND BIMOEN2
	IF ~Global("MRAlignLaw","LOCALS",0)
	InPartySlot(LastTalkedToBy,0) 
		!StateCheck(Player1,CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		GlobalGT("Chapter","GLOBAL",%bg2_chapter_3%)
		InParty("Imoen2")
		See(Player1)
		!ActuallyInCombat()~ THEN BEGIN MRLawChaAlignTalk
		SAY ~Y'know, I was wondering...~
		IF ~OR(3)
			Alignment(Player1,LAWFUL_GOOD)
			Alignment(Player1,LAWFUL_NEUTRAL)
			Alignment(Player1,LAWFUL_EVIL)~
		DO ~SetGlobal("MRAlignLaw","LOCALS",1)~ GOTO MRLawChaLaw
		IF ~OR(3)
			Alignment(Player1,NEUTRAL_GOOD)
			Alignment(Player1,NEUTRAL)
			Alignment(Player1,NEUTRAL_EVIL)~
		DO ~SetGlobal("MRAlignLaw","LOCALS",1)~ GOTO MRLawChaNeu
		IF ~OR(3)
			Alignment(Player1,CHAOTIC_GOOD)
			Alignment(Player1,CHAOTIC_NEUTRAL)
			Alignment(Player1,CHAOTIC_EVIL)~
		DO ~SetGlobal("MRAlignLaw","LOCALS",1)~ GOTO MRLawChaCha
	END

	IF ~~ THEN BEGIN MRLawChaLaw
		SAY ~You're always like 'the rules this' and 'the law' that. After growin' up with a bunch of stuffy monks, I'd thought you'd want to live a little!~
		IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Laws and rules are important. They protect those who can't protect themselves. Having fun isn't worth hurting others.~ GOTO MRLawChaLawGood
		IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~If we didn't have laws, society would fall apart. There'd be no order to anything - nations, kingdoms, and even cities would simply cease to exist.~ GOTO MRLawChaLawNeu
		IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Laws are convenient. They're a tool like any other, and if you know how to use them right, you can get anything you want.~ GOTO MRLawChaLawEvil
		++ ~Well, that's just what you do! You follow the rules and obey the laws. That's what they're there for.~ GOTO MRLawChaLawDumb
	END
END

CHAIN BIMOEN2 MRLawChaNeu
~Whatcha think about rules and laws and stuff like that?~
==BIMOEN2 IF ~OR(2)InParty("Keldorn") InParty("Anomen")~ THEN ~(She casts a meaningful glance at Keldorn) Like our knight in shining armor there, he practically worships the damn things.~
==BIMOEN2 IF ~!InParty("Keldorn") !InParty("Anomen") InParty("Korgan") ~ THEN ~But then you've got people like Korgan...~
==BIMOEN2 IF ~!InParty("Keldorn") !InParty("Anomen") !InParty("Korgan") InParty("Nalia")~ THEN ~But there's plenty of good people who don't follow the rules, like Nalia.~
==BIMOEN2 IF ~!InParty("Keldorn") !InParty("Anomen") !InParty("Korgan") !InParty("Nalia")~ THEN ~I mean, there's plenty of good people who don't follow the rules, I'm sure.~
END BIMOEN2 MRLawChaNeuNext

APPEND BIMOEN2
IF ~~ THEN BEGIN MRLawChaNeuNext
 SAY ~But laws hafta be good for something, right? Otherwise there wouldn't be so many.~
	IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Laws and rules are important. They protect those who can't protect themselves. Having fun isn't worth hurting others.~ GOTO MRLawChaLawGood
	IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~If we didn't have laws, society would fall apart. There'd be no order to anything - nations, kingdoms, and even cities would simply cease to exist.~ GOTO MRLawChaLawNeu
	IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Laws are convenient. They're a tool like any other, and if you know how to use them right, you can get anything you want.~ GOTO MRLawChaLawEvil
	++ ~Well, that's just what you do! You follow the rules and obey the laws. That's what they're there for.~ GOTO MRLawChaLawDumb
	IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Could be. They meant well, but too many rules and laws suck the spirit dry. People become more obsessed with what's legal instead of what's right.~ GOTO MRLawChaChaGood
	IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Perhaps. Rules and laws have their place, but you have to give people some room to be themselves.~ GOTO MRLawChaChaNeu
	IF ~ CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Definitely! You couldn't *breathe* without consulting this or that prophecy! Gods, I am glad I'm out of that place. ~ GOTO MRLawChaChaNeu2
	IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~Candlekeep's rules were a joke. I do what I want, when I want, period.~ GOTO MRLawChaChaEvil1
	IF ~ Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~Candlekeep's rules were a joke. I do what I want, when I want, period.~ GOTO MRLawChaChaEvil2
	IF ~~ THEN REPLY ~I like doing what I want, when I want. It's more fun that way!~ GOTO MRLawChaChaDumb
END

IF ~~ THEN BEGIN MRLawChaCha
		SAY ~D'ya think the reason we're both kinda... well, anti-authority, is 'cause of all the rules and stuff we got saddled with at Candlekeep?~
		IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Could be. They meant well, but too many rules and laws suck the spirit dry. People become more obsessed with what's legal instead of what's right.~ GOTO MRLawChaChaGood
		IF ~CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Perhaps. Rules and laws have their place, but you have to give people some room to be themselves.~ GOTO MRLawChaChaNeu
		IF ~ CheckStatGT(Player1,10,WIS)~ THEN REPLY ~Definitely! You couldn't *breathe* without consulting this or that prophecy! Gods, I am glad I'm out of that place. ~ GOTO MRLawChaChaNeu2
		IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~Candlekeep's rules were a joke. I do what I want, when I want, period.~ GOTO MRLawChaChaEvil1
		IF ~ Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~Candlekeep's rules were a joke. I do what I want, when I want, period.~ GOTO MRLawChaChaEvil2
		++ ~Uh... I thought it was just because it's more fun that way.~ GOTO MRLawChaChaDumb
	END

	IF ~~ THEN BEGIN MRLawChaLawGood
		SAY ~Pfeh, they sure don't seem to work all that well. How many people've come crying to us for help 'cause the local guards wouldn't help?~
		IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaLawNeu
		SAY ~Riiiight. 'Cause obviously in big cities like Baldur's Gate and Athkatla, there's never any crime or anything? (She rolls her eyes.)~
		IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaLawEvil
		SAY ~(She chuckles) Sounds like you, alright. You drove Mister G nuts!~
	IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaLawDumb
		SAY ~"That's just what you do"? You've never thought about it?~ 
		IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaChaGood
		SAY ~Exactly! Finally someone who gets it.~
		IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaChaNeu
		SAY ~Haha, yeah, tell me about it! Ol' Puffguts tried really hard to keep me in line, but y'know *that* never worked...~
		IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaChaEvil1
		SAY ~Aww, c'mon, it wasn't *that* bad. Mister G really loved you, y'know. Even if you were a little mean-hearted jerk sometimes.~
		IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaChaEvil2
		SAY ~Aww, c'mon, it wasn't *that* bad. Mister G really loved you. You *are* pretty loveable, y'know. Even if you were a little mean-hearted jerk sometimes.~
		IF ~~ THEN GOTO MRLawChaLaw2
	END


	IF ~~ THEN BEGIN MRLawChaChaGood2
		SAY ~You forgot to mention *fun*! I mean, take magic for example. Or sneakin' around and stealing stuff. That's tons of fun, and they're *both* illegal in Athkatla.~
		=
		~Well, thieving's illegal in most places, actually, but still...~ 
		IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaChaNeu2
		SAY ~Exactly! But you forgot to mention the most important thing: fun!~
		=
		~I mean, take magic for example. Or sneakin' around and stealing stuff. That's tons of fun, and they're *both* illegal in Athkatla.~
		=
		~Well, thieving's illegal in most places, actually, but still!~
		IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaChaEvil
		SAY ~Geez, be a sourpuss, why don't ya? Y'know what? Sometimes you're too busy being all "look at me, I'm the high and mighty Bhaalspawn" to remember the most important thing...~
		=
		~Having fun!~
		=
		~I mean, take magic for example. Or sneakin' around and stealing stuff. That's tons of fun, and they're *both* illegal in Athkatla.~
		=
		~Well, thieving's illegal in most places, actually, but still!~
		IF ~~ THEN GOTO MRLawChaLaw2
	END

	IF ~~ THEN BEGIN MRLawChaChaDumb
		SAY ~Well it *is* more fun, silly! But I dunno... don't you ever kinda wonder about things like that?~
		IF ~~ THEN GOTO MRLawChaLaw2
	END


	IF ~~ THEN BEGIN MRLawChaLaw2
		SAY ~If *I* made the rules, things'd be a lot different around here. (She holds up her fingers and starts counting them off.)~
		=
		~Everyone'll have to wear pink at *least* once a week. Cookies aren't allowed to make you fat - oh, and they're free to redheads...~
		++ ~It's cute how you think I care.~ + MRLawChaLawStuffy
		++ ~And everyone has to call you Her Royal Highness?~ + MRLawChaLawPlay
		IF ~OR(3)
			!Alignment(Player1,CHAOTIC_GOOD)
			!Alignment(Player1,CHAOTIC_NEUTRAL)
			!Alignment(Player1,CHAOTIC_EVIL)
			~ THEN REPLY ~You shouldn't trivialize this, Imoen. Laws aren't something to make up on a whim.~ GOTO MRLawChaLawStuffy
		IF ~Gender(Player1,MALE)~ THEN REPLY ~Who said you'll make the rules? I'm going to be the king of the world, not you.~ GOTO MRLawChaLawOther
		IF ~Gender(Player1,FEMALE)~ THEN REPLY ~ Who said you'll make the rules? I'm going to be the queen of everything, not you.~ GOTO MRLawChaLawOther
		IF ~OR(3)
			!Alignment(Player1,LAWFUL_GOOD)
			!Alignment(Player1,LAWFUL_NEUTRAL)
			!Alignment(Player1,LAWFUL_EVIL)
		~ THEN REPLY ~Rules, smules. It's time for some anarchy, baby! YEAH!~ GOTO MRLawChaChaPlay
	END
END

CHAIN BIMOEN2 MRLawChaLawStuffy
~D'ya always have to be such a spoilsport? Geez.~
==BIMOEN2 IF ~Gender(Player1,MALE)~ THEN ~Fine, Mr. Stick-in-the-Mud. Let's go do something "interesting"... like walking, I guess.~
=~(She sniffs indignantly and continues on. You hear her mutter as she leaves) Why the heck don't we buy some horses? Or even *see* any horses? Is there some stupid Amnish law against convenient transportation?~
==BIMOEN2 IF ~Gender(Player1,FEMALE)~ THEN ~Fine, Miss Stick-in-the-Mud. Let's go do something "nteresting... like walking, I guess.~
~(She sniffs indignantly and and continues on. You hear her mutter as she leaves) Why the heck don't we buy some horses? Or even *see* any horses? Is there some stupid Amnish law against convenient transportation?~
EXIT

CHAIN BIMOEN2 MRLawChaLawOther
~(She laughs and pats your arm) Sure you will, sure you will.~
==BIMOEN2 IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~Keep dreaming there, little <PRO_BROTHERSISTER>.~
==BIMOEN2 IF ~ Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~(She laughs and pats your arm) Sure you will, sure you will. Keep dreaming there, lover.~
END BIMOEN2 MRLawChaLawEnd


APPEND BIMOEN2
	IF ~~ THEN BEGIN MRLawChaLawPlay
		SAY ~"Her Royal Highness"... hmm. Well, I was gonna go with "Your Imoency". Or maybe "Her Fabulous Greatness". but yours has a nice ring to it.~
		IF ~~ THEN GOTO MRLawChaLawEnd
	END

	IF ~~ THEN BEGIN MRLawChaChaPlay
		SAY ~Haha! Whoa there <PRO_GIRLBOY>! (She grins at you happily) I'm not sure I trust you with *total* anarchy, you nut.~
		=
		~I still wanna be 'Her Royal Highness' for at least a day...~
		IF ~~ THEN GOTO MRLawChaLawEnd
	END

	IF ~~ THEN BEGIN MRLawChaLawEnd
		SAY ~ I guess we should get going, though. Seems like all we ever do is walk.~
		=
		~(You hear her mutter as she carries on forward) Why the heck don't we buy some horses? Or even *see* any horses? Is there some stupid Amnish law against convenient transportation?~
		IF ~~ THEN EXIT
	END
END
