// Here go all of Imoen's interactions with Sarevok.

/*
// Contents:
// Imoen mocks Sarevok's interjection when talking with the barkeep in Amkethran
// Interjection to Sarevok's proposal on becoming Lady/Lord of Murder
// Banter with Sarevok about the piece of soul of Imoen he has
// Extended meeting with Sarevok 
*/




// Imoen mocks Sarevok's interjection when talking with the barkeep in Amkethran

I_C_T SAREV25J 8 IRTIntSarevBar
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok")~ THEN ~Wow, such outstanding deduction there, Sarevok. Took an expert tactician to figure that one out, so glad you're with us.~
	== SAREV25J IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") ~ THEN ~Ah, yes, another constructive and helpful contribution by the company's token child. Do us all a favor and go play with your dolls while the grown-ups discuss important matters.~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok")~ THEN ~Oh yeah? Well... yer ugly and you smell. So there.~
END


// Interjection to Sarevok's proposal on becoming Lady/Lord of Murder
//this is random banter after you get sarevok's oath
// Sarevok's state 120, BSAREV25

// If You blow Sarevok off right away
I_C_T BSAREV25 121 IRTIntSarevProp1
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3)~ THEN
	 ~Good. Any proposition Sir Rotten Egghead here might've had for ya stinks of manipulative groveling and butt-kissin'.~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2")  !Global("ImoenRomanceActive","GLOBAL",3)~ THEN
	 ~<CHARNAME> is well aware of my personal agenda, little sister. I have learned through pain and death to submit my ambitions to <PRO_HISHER> will. Still, I have ambitions just the same... unlike you. What will you do once your sole reason to exist departs for godhood?~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3)~ THEN
	 ~(Imoen snorts.) Why, I'll tag along with my *other* dear Bhaalspawn sibling, of course! You and I, Sarevok, together for life. Wouldn't that be oodles of fun?~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3)~ THEN
	 ~Congratulations. You have just described the purest form of Hell.~
END

// You tell him that you have other plans
// --> None of your business | Doesn't matter what happens, you won't be involved
I_C_T BSAREV25 131 IRTIntSarevProp2
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~After all this time, one would expect ya to be out of get-rich-quick schemes, Sarevok.~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Hah. And what do you suggest, little sister? For me to retire to a tranquil cabin lakeside? I did not crawl my way back to life only to live out my years in obscurity. I still have ambitions... unlike you. What will you do once your sole reason to exist departs for godhood?~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3)~ THEN
	 ~(Imoen snorts.) Why, I'll tag along with my *other* dear Bhaalspawn sibling, of course! You and I, Sarevok, together for life. Wouldn't that be oodles of fun?~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3)~ THEN
	 ~Congratulations. You have just described the purest form of Hell.~
END


// --> I don't want what you want | Have you learned nothing? | Still want power and wealth? | None of that is important to me |
//  Doesn't mean I'll become evil | I do not seek to rule others:
// ----> I'm not going to discuss it with you <= Same as "None of your business"
// ----> There are better things than power, don't be a fool <= Imoen is satisfied with the outcome and doesn't say anything.
// ----> Goodie-two-shoes responses <= Depends on Sarevok's reaction to your words:
// ------> Sarevok changes
I_C_T BSAREV25 141 IRTIntSarevProp3
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Well, I'll be damned. That didn't sound like somethin' you'd say. You serious, Sarevok? C'mon, what are you really up to?~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~I suppose I have earned your suspicion. Be that as it may, I speak the truth. What did my old ways accomplish? I ended up in the Abyss, where I had to beg for a chance to cheat death. Perhaps this new life is the time for a different approach.~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Oh my. You answered me without sarcasm or spite. A new Sarevok has truly been born today!~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Spare me your mockery, little girl. Don't tempt me to do one last evil deed and drive my sword through your entrails. What a sweet farewell to malevolence that would be - I doubt it would be considered evil whatsoever, to rid the world of your incessant prattle.~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Uh... I'll be quiet now.~
END

// ------> Sarevok calls you a liar
I_C_T BSAREV25 139 IRTIntSarevProp4
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Yep. Couldn't expect any better. Why learn from past mistakes and listen to <CHARNAME>, when you can keep bull-rushin' the wall and accomplishing nothing?~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~I am not in the mood to humor your obnoxious intrusion. Mind your own business.~
END 

// ------> Sarevok is uncertain
I_C_T BSAREV25 138 IRTIntSarevProp5
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~If we didn't know any better, one would say that our Sarevok is going soft on us.~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~<CHARNAME> shapes the land on which <PRO_HESHE> sets foot. <PRO_HESHE> molds the fate of every soul <PRO_HESHE> touches. Perhaps, dear Sister, I am not immune to such powerful influence.~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Well, I'll be damned. That didn't sound like somethin' you'd say. Usually you'd be barkin' something awful at me right about now. C'mon, what are you really up to?~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~As much as I enjoy your impertinent gibberish, I would rather not discuss the matter with a five-year-old child.~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Whew... now that's more like it.~
END

// ~~ You plan on assuming your birthright without him ~~
// --> Still think he's not involved <= Same as "none of your business"
// --> You consider his involvement <= Same as "you tell him that it's a possibility" (below)

// ~~ You tell him that it's a possibility ~~
I_C_T BSAREV25 129 IRTIntSarevProp6
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~(Imoen sighs.) Sellin' the cow's milk without even buying the cow yet...~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Eavesdropping in our conversation, are you?~
	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Eavesdropping? You started talking while I was standing right here. I couldn't NOT hear your deranged schemes.~

// If Imoen isn't romanced
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",2) !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Hah! You don't fool anyone, dear Sister. The putrid stench of your jealousy is making my stomach churn.~
// If Imoen is romanced
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") Global("ImoenRomanceActive","GLOBAL",2) !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Hah! You don't fool anyone, dear Sister. The putrid stench of your jealousy is making my stomach churn. But worry not, child. I could bet <CHARNAME> has already made plans for <PRO_HISHER> consort, as well.~

	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Pfft! Oh yeah, sure, 'cause becoming some sort of divine wacko with a psychotic murder fetish has been my life-long dream.~

// If Sarevok doesn't have Imoen's soul
	== BSAREV25 IF ~!Global("ImoenGiveSoul","GLOBAL",2) See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~You may pretend to reject it, but your blood urges you towards the ultimate prize, as it once did to me. Yet instead of reveling in its strength, you feebly strive to ignore its call.~
// If Sarevok has Imoen's soul
	== BSAREV25 IF ~Global("ImoenGiveSoul","GLOBAL",2) See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~You forget our soulbound link, Imoen. You have secret urges you cannot deny. Pretend as you may, your blood urges you towards the ultimate prize, as it once did to me. The black depths of your heart want it. Yet instead of fully reveling in its strength, you feebly strive to ignore its call.~

	== IMOEN25J IF ~IsValidForPartyDialog("Imoen2") See("Sarevok") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~Yeah, well. Yer a freakin' nutcase and <CHARNAME> is as daft as you, so that's how confident I am in your crazy plans.~
	== BSAREV25 IF ~See("Imoen2") IsValidForPartyDialog("Imoen2") !Global("ImoenRomanceActive","GLOBAL",3) ~ THEN
	 ~We shall see.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1)~
END



// Banter with Sarevok about the piece of soul of Imoen he has
//no checks needed because it starts from a vanilla talk that checks if imoen and sarevok are around (didnt bother to find it)
ALTER_TRANS BIMOEN25
BEGIN 6 END
BEGIN 0 END
BEGIN
 "EPILOGUE" ~EXTERN BSAREV25 3Extended~ 
END

CHAIN BSAREV25 3Extended
	~How about the agony you felt as your soul was ripped from you? The despair at being left only with the cold voices of your tainted heart, discovering what was inside you all along? Your downfall to insanity, hiding away in a self-made prison until your hero came to your rescue?~
	== BSAREV25 IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~How about the hurt you keep deep down within, wondering if you weren't good enough for Gorion, wondering what he would say about what you've been doing in his ward's bedroll? All the longing and the guilt clawing-~
	== BSAREV25 IF ~!Global("ImoenRomanceActive","GLOBAL",2) GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~How about the hurt you keep deep down within, wondering if you weren't good enough for Gorion? Wondering why you're a Bhaalspawn? How about the loneliness... the unrequited longing-~
	== BSAREV25 IF ~!Global("ImoenRomanceActive","GLOBAL",2) !GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~How about the hurt you keep deep down within, wondering if you weren't good enough for Gorion? Wondering why you're a Bhaalspawn? How about the loneliness... the nascent longing for--~
END BIMOEN25 8


// Extended meeting with Sarevok 

// Little added option to scold Sarevok for snapping at Imoen
EXTEND_BOTTOM SAREV25A 68
   IF ~IsValidForPartyDialog("Imoen2")~ THEN REPLY ~Stay away from him, Imoen. Who knows what trick he has prepared this time.~ + 68a
END

APPEND SAREV25A
IF ~~ THEN 68a
	SAY ~Trick? Far from it, my dear <PRO_BROTHERSISTER>. I am in no condition to play tricks. I have done nothing but attempt to re-form myself since we last met.~
	IF ~~ THEN DO ~SetGlobal("TalkedToSarevok","GLOBAL",1)~  GOTO 3
END

END

// Sarevok finds out about their relationship
ADD_TRANS_TRIGGER SAREV25A 28 ~!Global("ImoenRomanceActive","GLOBAL",2)~ DO 0

EXTEND_BOTTOM SAREV25A 28
   IF ~Global("ImoenRomanceActive","GLOBAL",2)~ EXTERN IMOEN25J SarevSoul1
END


APPEND IMOEN25J
IF ~~ THEN BEGIN SarevSoul1
	SAY ~Nor would you get it! I... I don't know, <CHARNAME>. He doesn't deserve life. But... if it's important... I'll give up part of my soul. (She takes your hand in both of hers.) You know that I'd give my life for you. You saved my soul once from Bodhi, you shouldn't have to sacrifice yours.~
	++ ~If you're certain, then do it. This is important.~ EXTERN SAREV25A SarevSoul2
	++ ~You have been through enough. What if it hurts you in some way? I couldn't bear it.~ EXTERN SAREV25A SarevSoul2
	++ ~Your own sacrifice will not be forgotten, Imoen.~ EXTERN SAREV25A SarevSoul2
	++ ~You know that I would not ask for it if I didn't think it was necessary, right my dear?~ EXTERN SAREV25A SarevSoul2
	++ ~Forget it. Neither of us is giving Sarevok anything. I don't trust him.~ EXTERN SAREV25A SarevSoul2
END
END

CHAIN SAREV25A SarevSoul2
	~Wait. (Sarevok's image looks back and forth between you and Imoen. He seems suspicious, yet a smirk begins to appear on his hazy features.)~
	= ~Could it be? Am I imagining this? Are the pair of you truly bedding together?~
	== IMOEN25J ~Whoa, that's none of your business!~
	== SAREV25A IF ~Gender(Player1,MALE)~ THEN ~HA! Most unexpected, I must admit! The childhood friends that grew up together, now *sleep* together. Interbreeding among Bhaalspawn! I am willing to bet the sight of your child would not be pleasant.~
	== SAREV25A IF ~Gender(Player1,FEMALE)~ THEN ~HA! Most unexpected, I must admit! The childhood friends that grew up together, now *sleep* together. I wonder what your precious Gorion would have to say on the matter.~
	== IMOEN25J ~Shut your mouth, Sarevok. Do you want a piece of my soul or not?~
END SAREV25A SarevSoul3

APPEND SAREV25A
IF ~~ THEN BEGIN SarevSoul3
	SAY ~Yes, clearly. Let's get done with it, I grow impatient.~ 
	++ ~(Let Imoen give a fraction of her soul so that Sarevok may live again.)~ GOTO 29
	++ ~No. I will share a part of my soul with you, Sarevok, not her.~ EXTERN IMOEN25J 4
	++ ~Stop. No piece of our souls will be corrupted by your influence, Sarevok. Forget about it.~ GOTO 11
	++ ~Let's think about this. Maybe we can find a way out of here on our own.~ GOTO 32
END
END

ADD_TRANS_TRIGGER SAREV25A 29 ~!Global("ImoenRomanceActive","GLOBAL",3)~ DO 0

EXTEND_BOTTOM SAREV25A 29
    IF ~Global("ImoenRomanceActive","GLOBAL",3)~ THEN EXTERN IMOEN25J 3annoyedSarevSoul
END

APPEND IMOEN25J
	IF ~~ THEN BEGIN 3annoyedSarevSoul
		SAY ~I owe <PRO_HIMHER>, 'dear brother'. No matter how <PRO_HESHE>'s treated me, I still owe <PRO_HIMHER> my life, and my soul. I've a debt to repay.~
		IF ~~ THEN EXTERN SAREV25A 30
	END
END


ADD_TRANS_TRIGGER IMOEN25J 3 ~!Global("ImoenRomanceActive","GLOBAL",2)~ DO 0

EXTEND_BOTTOM IMOEN25J 3
    IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN EXTERN SAREV25A SarevSoul4
END


APPEND SAREV25A
	IF ~~ THEN BEGIN SarevSoul4
		SAY ~Yes, it is obvious that you have laid down *far* more than your soul before <CHARNAME>, sister...~
	IF ~~ THEN GOTO 30
	END
END

// Imoen gives her soul

ADD_TRANS_TRIGGER IMOEN25J 8 ~OR(3) !Global("ImoenGiveSoul","GLOBAL",2) !IsValidForPartyDialog("Aerie") !GlobalGT("IRTImAerTalks","GLOBAL",1)~ DO 0

EXTEND_BOTTOM IMOEN25J 8
    IF ~Global("ImoenGiveSoul","GLOBAL",2) IsValidForPartyDialog("Aerie") GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN EXTERN AERIE25J SarevSoul6
END


APPEND AERIE25J
	IF ~~ THEN BEGIN SarevSoul6
		SAY ~She... she could have died! How dare you put her at such risk!~
		IF ~~ THEN EXTERN SAREV25A 42
	END
END

I_C_T IMOEN25J 8 SarevokComment2MR
	== ANOME25J IF ~Global("ImoenGiveSoul","GLOBAL",2) IsValidForPartyDialog("Anomen")~ THEN ~Fiend! We should end your accursed existence now, once and for all! The risk you assumed on your own could have ended her life!~
	== VALYG25J IF ~Global("ImoenGiveSoul","GLOBAL",2) IsValidForPartyDialog("Valygar")~ THEN ~A risky ploy it was... a risk too high to assume on your own, indeed.~
END


