APPEND IMOEN2J  //// Changes: Basic punctuation

	IF ~Global("MRDragonKillTalk","GLOBAL",1)~ THEN BEGIN MRDragonSlayer
		SAY ~Holy-! WOW! <CHARNAME>! We just killed a DRAGON! (Imoen bounces where she stands, clapping her hands together in excitement.)~
		= ~I feel so awesome right now! Imoen the DragonSlayer! Wait... no, no 'Slayer' stuff. The Dragonstomper! Oooh! Imoen the Dragonfryer! But that sounds like I'm cooking it... hmm.~
		= ~The Dragonkiller? Nah, too plain... (She wanders off, tapping a fingertip against her chin, muttering to herself) Dragonsmasher? Dragonlady?~
		IF ~~ THEN DO ~SetGlobal("MRDragonKillTalk","GLOBAL",2)~ EXIT
	END
	
	IF ~Global("MRDragonKillTalk","GLOBAL",3)~ THEN BEGIN MRDragonSlayer2
		SAY ~Y'know, after the third or fourth dragon, this whole 'dragon-slayer' thing is a lot less impressive.~
		IF ~~ THEN DO ~SetGlobal("MRDragonKillTalk","GLOBAL",4)~ EXIT
	END
END

ADD_TRANS_TRIGGER COWENF2 0 ~OR(2) !IsValidForPartyDialog("Imoen2") !Global("MRImoenCowl","GLOBAL",0)~ DO 0
ADD_TRANS_TRIGGER COWENF2 0 ~OR(2) !IsValidForPartyDialog("Imoen2") !Global("MRImoenCowl","GLOBAL",0)~ DO 1

EXTEND_BOTTOM COWENF2 0
  IF ~IsValidForPartyDialog("Imoen2") Global("MRImoenCowl","GLOBAL",0)~ THEN DO ~SetGlobal("MRImoenCowl","GLOBAL",2)~ EXTERN IMOEN2J MRCowledWizards
END

ADD_TRANS_TRIGGER COWENF2 1 ~OR(2) !IsValidForPartyDialog("Imoen2") !Global("MRImoenCowl","GLOBAL",0)~ DO 0

EXTEND_BOTTOM COWENF2 1
  IF ~IsValidForPartyDialog("Imoen2") Global("MRImoenCowl","GLOBAL",0)~ THEN DO ~SetGlobal("MRImoenCowl","GLOBAL",2)~ EXTERN IMOEN2J MRCowledWizards
END

ADD_TRANS_TRIGGER COWENF2 2 ~OR(2) !IsValidForPartyDialog("Imoen2") !Global("MRImoenCowl","GLOBAL",0)~ DO 0

EXTEND_BOTTOM COWENF2 2
  IF ~IsValidForPartyDialog("Imoen2") Global("MRImoenCowl","GLOBAL",0)~ THEN DO ~SetGlobal("MRImoenCowl","GLOBAL",2)~ EXTERN IMOEN2J MRCowledWizards
END

/* #2 - Running into the Cowled Wizards in Athkatla, after being rescued from Spellhold */
/* Triggers if the Cowled Wizards show up because you're doing unauthorized magic, or you meet Tolgerias in the Government District */
/* after they speak their first lines (so, interjecting after them). We need a CHAIN here between Imoen and the wizard (whoever that is) */

/* Not Tolgerias */
CHAIN IMOEN2J MRCowledWizards
~You! You're one of the guys who locked me up in Spellhold!~
== COWENF2 ~Was I? Doubtlessly you deserved to be there. And seeing as how you've escaped, it is simple enough to send you back.~
== IMOEN2J IF ~!IsValidForPartyDialog("Aerie") !IsValidForPartyDialog("Minsc") !IsValidForPartyDialog("Jaheira") !IsValidForPartyDialog("Korgan")~ THEN ~(Her eyes narrow dangerously) Lay a finger on me and you're a dead man.~
== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~You won't t-touch her. She's done nothing wrong!~
== MINSCJ IF ~ IsValidForPartyDialog("Minsc")~ THEN ~Boo says that I should stick my sword in your rear for threatening her so!~
== MINSCJ IF ~ IsValidForPartyDialog("Minsc")~ THEN ~I do not understand why this is better than your head, but Boo is always right!~
== JAHEIRAJ IF ~ IsValidForPartyDialog("Jaheira")~ THEN ~Do not threaten us, mage. You would not live to regret it.~
== KORGANJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Look, ye troll-faced long-legged sewer rat! I've chased the lass across the ocean once already. If ye be wantin' that I do it twice, then you an' me axe got some talkin' to do.~
END COWENF2 cowattack

APPEND COWENF2
	IF ~~ THEN cowattack
	SAY ~Enough of these idle threats!~
	 IF ~~ THEN DO ~IncrementGlobal("CowledWarning","GLOBAL",1)
	CreateCreatureObject("MAGE16C",Myself,0,0,0)
	CreateCreatureObject("MAGE18A",Myself,0,0,0)
	CreateCreatureObject("MAGE18Z",Myself,0,0,0)
	Enemy()
	~ EXIT
	END
END

/* Tolgerias, in the Government District */

CHAIN 
IF ~Global("MRImoenCowl","GLOBAL",1)~ THEN IMOEN2J MRCowledWizards2
~You! You're one of the guys who locked me up in Spellhold!~
DO ~SetGlobal("MRImoenCowl","GLOBAL",2)~
== TOLGER ~Was I? Doubtlessly you deserved to be there. And seeing as how you've escaped, it is simple enough to send you back.~
== IMOEN2J IF ~!IsValidForPartyDialog("Aerie") !IsValidForPartyDialog("Minsc") !IsValidForPartyDialog("Jaheira") !IsValidForPartyDialog("Korgan")~ THEN ~(Her eyes narrow dangerously) Lay a finger on me and you're a dead man.~
== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~You won't t-touch her. She's done nothing wrong!~
== MINSCJ IF ~IsValidForPartyDialog("Minsc")~ THEN ~Boo says that I should stick my sword in your rear for threatening her so!~
== MINSCJ IF ~IsValidForPartyDialog("Minsc")~ THEN ~I do not understand why this is better than your head, but Boo is always right!~
== JAHEIRAJ IF ~IsValidForPartyDialog("Jaheira")~ THEN ~Do not threaten us, mage. You would not live to regret it.~
== KORGANJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Look, ye troll-faced long-legged sewer rat! I've chased the lass across the ocean once already. If ye be wantin' that I do it twice, then you an' me axe got some talkin' to do.~
== TOLGER ~Enough! That is not why you are here, and I have more pressing matters at hand!~
EXIT


/* #3 - When you return the acorns to the Dryads in Windspear Hills */
/* After you give the acorns back and the dryads re-appear, and if you don't have Imoen's soul back yet */

INTERJECT_COPY_TRANS2 VAELASA 6 MRDryadQuest
== IDRYAD1 IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Sister! You escaped his clutches as well, but... you are different now.~
== IMOEN2J IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Sister? Me? Uh, well...~
== IDRYAD1 IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Do not worry. Life will always prevail.~
== IDRYAD2 IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Just as we have.~
== IDRYAD3 IF ~IsValidForPartyDialog("Imoen2")~ THEN ~So shall you.~
== IMOEN2J IF ~IsValidForPartyDialog("Imoen2")~ THEN ~I- I guess. It's good to see that you have your freedom again. No one deserves a fate like that.~
== VAELASA IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Enough, sisters. The time of mourning is past; the future brings rejoicing!~
== VAELASA IF ~IsValidForPartyDialog("Imoen2")~ THEN ~Thank you again, mortals, for your graciousness. We will not forget it.~
END

/* #5 -- Meeting Drizzt */
APPEND IMOEN2J
	IF ~Global("MRMeetDrizzt","GLOBAL",1)~ THEN BEGIN MRDrizzt
		SAY ~Wow. I can't believe I met Drizzt Do'Urden. He's like... practically famous!~
		= ~Aww, man! I should've asked for his autograph!~
		IF ~~ THEN DO ~SetGlobal("MRMeetDrizzt","GLOBAL",2)~ EXIT
	END
END

INTERJECT_COPY_TRANS C6DRIZZ2 0 MRDrizzt2
== IMOEN2J IF ~IsValidForPartyDialog("Imoen2")~ THEN
~Uh, wait. Before we go in there and risk none of us coming out alive...~
= ~Drizzt, can I get your autograph?~
== C6DRIZZ2 IF ~IsValidForPartyDialog("Imoen2")~ THEN
~Now is not really the time, I'm afraid. Is everyone prepared for battle?~
== IMOEN2J IF ~IsValidForPartyDialog("Imoen2")~ THEN
 ~(She mutters sourly under her breath) Figures.~
END

/* #6 - The Druid Grove, if Jaheira duels Falon for control and wins */
ADD_TRANS_TRIGGER JAHEIRAJ 94 ~OR(3) !See("Imoen2") !InParty("Imoen2") StateCheck("Imoen2",CD_STATE_NOTVALID)~ DO 0

EXTEND_BOTTOM JAHEIRAJ 94
 IF ~See("Imoen2") InParty("Imoen2") !StateCheck("Imoen2",CD_STATE_NOTVALID)~ THEN DO ~SetGlobal("MRJahFaldorn","GLOBAL",1)~ EXTERN ~CEFALDOR~ 12
END 

CHAIN 
IF ~Global("MRJahFaldorn","GLOBAL",2)~ THEN IMOEN2J MRDruidDuel
~Wow. I mean, I always knew that Jaheira could kick butt, but that was some serious butt-kicking!~
DO ~SetGlobal("MRJahFaldorn","GLOBAL",3)~
==MINSCJ IF ~IsValidForPartyDialog("Minsc")~ THEN ~Did you say butt-kicking? BUTT-KICKING FOR GOOD-~
==IMOEN2J IF ~IsValidForPartyDialog("Minsc")~ THEN ~We know, Minsc! We know!~
==IMOEN2J IF ~!IsValidForPartyDialog("Minsc")~ THEN ~And oddly fascinating...~
EXIT
	
	
/* #7 - The Circus, when you see the circus tent (not sure how to code this -- perhaps when you see the guard or something?) ~ */
APPEND IMOEN2J
	IF ~Global("MRCircus","GLOBAL",1)~ THEN BEGIN MRCircus
			SAY ~<CHARNAME>! A circus!~
			= ~(Imoen grabs your arm, gives you her very best puppy-dog-eyes, and bounces up and down in excitement.)~
			= ~Can we go in? Can we, can we, can we, PLEASE?~
			IF ~~ THEN DO ~SetGlobal("MRCircus","GLOBAL",2)~ EXIT
	END
	
	IF ~Global("MRCircus","GLOBAL",3)~ THEN BEGIN MRCircus2
	SAY ~(Sighs) This circus sucks.~
	IF ~~ THEN DO ~SetGlobal("MRCircus","GLOBAL",4)~ EXIT
	END
END

/* #8 - Planar Sphere -- when subduing Lavok -- so, after he is defeated and gives his speech about getting a demon heart and returning to the Material Plane */
APPEND IMOEN2J
	IF ~Global("MRLavok","GLOBAL",1)~ THEN BEGIN MRLavok
	SAY ~See? This is why I'm really starting to hate insane semi-immortal mages.~
	IF ~~ THEN DO ~SetGlobal("MRLavok","GLOBAL",2)~ EXIT
	END
END


/* #9 - Unseeing Eye -- triggered after hearing Gaal's diatribe about the eyes */
INTERJECT_COPY_TRANS CSGAAL 10 MRUnseeingEye
== IMOEN2J IF ~IsValidForPartyDialog("Imoen2")~ THEN
~Y'know, Amnish people have a whole new level of crazy, dontcha think?~
END


// *** Gong quest ***

INTERJECT_COPY_TRANS LOUT 20 MRGongQuest
== IMOEN2J IF ~IsValidForPartyDialog("Imoen2")~ THEN
~Hah. You really know how to have fun, <CHARNAME>! To the sewers! Let's go find this gong and kobold!~
== LOUT IF ~IsValidForPartyDialog("Imoen2")~ THEN
~He nay be a kobold, my Lady... I- I think...~
END

INTERJECT_COPY_TRANS2 ROGER 13 MRGongQuest2
== IMOEN2J IF ~IsValidForPartyDialog("Imoen2")~ THEN
~Behold, the great Bhaalspawn <CHARNAME> - lugging around a dung-covered gong all through the Realms! What's next, cleaning golden pantaloons? Gimme a break...~
== JAHEIRAJ IF ~IsValidForPartyDialog("Imoen2") IsValidForPartyDialog("Jaheira")~ THEN
~I cannot believe we did that back then. As I can't believe what we are doing now.~
END