/*the idea is that this is to be compiled with romanceContent, pidtree, qualityimes, bitalk */
APPEND IMOEN2J
	IF ~~ THEN BEGIN MRResolution1
				SAY ~Good, we're alone.~
			= ~<CHARNAME>, what happened between us... I've been thinking about it a lot.~ [ MRImRom1 ]
			= ~I- I think it was wrong. A huge mistake. We've both been through so much together, and with everything that's happened... we were just caught up in the moment.~
			IF ~!Global("JaheiraRomanceActive","GLOBAL",2)
				!Global("AerieRomanceActive","GLOBAL",2)
				!Global("AnomenRomanceActive","GLOBAL",2)
				!Global("ViconiaRomanceActive","GLOBAL",2)
				!Global("RasaadRomanceActive","GLOBAL",2)
				!Global("DornRomanceActive","GLOBAL",2)
				!Global("HexxatRomanceActive","GLOBAL",2)
				!Global("NeeraRomanceActive","GLOBAL",2)~ GOTO MRResolution1noConflict
			IF ~OR(8) Global("JaheiraRomanceActive","GLOBAL",2)
					Global("AerieRomanceActive","GLOBAL",2)
					Global("AnomenRomanceActive","GLOBAL",2)
					Global("ViconiaRomanceActive","GLOBAL",2)
					Global("RasaadRomanceActive","GLOBAL",2)
					Global("DornRomanceActive","GLOBAL",2)
					Global("HexxatRomanceActive","GLOBAL",2)
					Global("NeeraRomanceActive","GLOBAL",2)~ THEN GOTO MRRomanceConflict2
		END
END
APPEND IMOEN2J
	//conflict line
	
	IF ~~ THEN BEGIN MRRomanceConflict2
    SAY ~(Imoen looks away, her voice dropping to a whisper) I don't want to lose our friendship over this. Can't we just... forget it ever happened?~
	= ~This could get real complicated. We... we can go back to how things used to be. I won't ever mention it again, to anyone.~
	++ ~There's no way we could pretend. If we don't talk about what happened - about what *is* happening between us - we'll lose our minds.~ GOTO MRRomanceConflict-Explode
	++ ~Stop lying to yourself, Imoen! We must do something about it, dammit!~ GOTO MRRomanceConflict-Aggressive
	++ ~I love you, Imoen.~ GOTO MRRomanceConflict-Love
	++ ~Very well. Tell me that you don't love me, and I will forget about that thing which "didn't happen".~ GOTO MRRomanceConflict-Cha
	++ ~Friends? I'm done with you. Don't talk to me again.~ GOTO MRResolutionDoneWithYou
	END

	IF ~~ THEN BEGIN MRRomanceConflict-Love
		SAY ~Hah. You *love* me? Really? You have the nerve to say that to my face?~
			++ ~What do you mean? Do you think I'm lying?~ GOTO MRRomanceConflict-Explain
			++ ~Yes, I do! And you should believe me!~ GOTO MRRomanceConflict-Explain
			++ ~Well, okay, you got me - I don't love you at all.~ GOTO MRRomanceConflict-No
	END

	IF ~~ THEN BEGIN MRRomanceConflict-Cha
		SAY ~Of course I love you, dumb-ass. You're my best friend. That's why I'm willing to put this behind us. Do you think this is a game? Are you playing with me right now?~
			++ ~What do you mean? I'm not playing at all!~ GOTO MRRomanceConflict-Explain
			++ ~So you love me, but you don't want to be with me?~ GOTO MRRomanceConflict-Explain
			++ ~Well, okay, you got me - I don't care for you at all.~ GOTO MRRomanceConflict-No
	END

	IF ~~ THEN BEGIN MRRomanceConflict-Aggressive
		SAY ~'Do something about it'? That's a laugh. You've already 'done something about it'. That ship sailed a long time ago.~
			++ ~Huh? What do you mean?~ GOTO MRRomanceConflict-Explain
			++ ~I haven't done anything. You refuse to talk to me!~ GOTO MRRomanceConflict-Explain
			++ ~Well, okay, you got me - I don't love you at all.~ GOTO MRRomanceConflict-No
	END

	IF ~~ THEN BEGIN MRRomanceConflict-Explode
	SAY ~Hah! That's rich. There's nothing between us, and there never will be. You think I'm stupid or something?~
			++ ~Huh? What do you mean?~ GOTO MRRomanceConflict-Explain
			++ ~No, but you sure are stubborn!~ GOTO MRRomanceConflict-Explain
			++ ~Well, okay, you got me - I don't love you at all.~ GOTO MRRomanceConflict-No
	END

	IF ~~ THEN BEGIN MRRomanceConflict-No
		SAY ~Yeah, obviously. At least you're honest. Like I said, I'm gonna pretend this never happened, and you can go back to courting whoever you please.~
		IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3)~ EXIT
	END
END

CHAIN IMOEN2J MRRomanceConflict-Explain
~Hah!~
DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3)~
== IMOEN2J IF ~Global("AerieRomanceActive","GLOBAL",2)~ THEN ~You think I don't see what's going on between you and Aerie? Don't insult my intelligence.~
== IMOEN2J IF ~Global("ViconiaRomanceActive","GLOBAL",2)~ THEN ~You think I don't see what's going on between you and Viconia? Don't insult my intelligence.~
== IMOEN2J IF ~Global("JaheiraRomanceActive","GLOBAL",2)~ THEN ~You think I don't see what's going on between you and Jaheira? Don't insult my intelligence.~
== IMOEN2J IF ~Global("AnomenRomanceActive","GLOBAL",2)~ THEN ~You think I don't see what's going on between you and Anomen? Don't insult my intelligence.~

== IMOEN2J IF ~Global("RasaadRomanceActive","GLOBAL",2)~ THEN ~You think I don't see what's going on between you and Rasaad? Don't insult my intelligence.~
== IMOEN2J IF ~Global("DornRomanceActive","GLOBAL",2)~ THEN ~You think I don't see what's going on between you and Dorn? Don't insult my intelligence.~
== IMOEN2J IF ~Global("HexxatRomanceActive","GLOBAL",2)~ THEN ~You think I don't see what's going on between you and Hexxat? Don't insult my intelligence.~
== IMOEN2J IF ~Global("NeeraRomanceActive","GLOBAL",2)~ THEN ~You think I don't see what's going on between you and Neera? Don't insult my intelligence.~

== IMOEN2J ~I shoulda seen it earlier, but I was so caught up with everything that I didn't notice until it was too late.~
END
++ ~Only a distraction. No-one else means anything to me, Imoen. I am in love with you.~ EXTERN IMOEN2J MRRomanceConflict-Explain2
++ ~I didn't realize how I felt about you until our night together...~ EXTERN IMOEN2J MRRomanceConflict-Explain2
++ ~I guess the game is up, then. Yes, I played you for a fool - but you were a great lay!~ EXTERN IMOEN2J MRRomanceConflict-Jerk


CHAIN IMOEN2J MRRomanceConflict-Explain2
~I don't believe you! How *can* I believe you, when I've seen you two flirting, whispering things, touching each other's hands?~
= ~What we did was a mistake, and it should've never happened. I was just weak and desperate, wishing for my dreams to come true.~
= ~But not anymore. I'm not gonna let you lead me on with pretty words and lies about how I'm your one true love.~
==IMOEN2J IF ~OR(5) Global("AerieRomanceActive","GLOBAL",2) Global("ViconiaRomanceActive","GLOBAL",2) Global("JaheiraRomanceActive","GLOBAL",2) Global("HexxatRomanceActive","GLOBAL",2) Global("NeeraRomanceActive","GLOBAL",2)~ THEN ~(She tilts her head, motioning back towards the rest of the group) If I were, you wouldn't be with *her*.~
==IMOEN2J IF~OR(3) Global("AnomenRomanceActive","GLOBAL",2) Global("DornRomanceActive","GLOBAL",2) Global("RasaadRomanceActive","GLOBAL",2)~ THEN ~(She tilts her head, motioning back towards the rest of the group) If I were, you wouldn't be with *him*.~
EXIT

CHAIN IMOEN2J MRRomanceConflict-Jerk
~What?!~
==IMOEN2J IF ~Gender(PLAYER1,FEMALE)~ THEN ~You- you- you self-centered, ignorant, gutter-whoring BITCH!~
==IMOEN2J IF ~Gender(PLAYER1,MALE)~ THEN ~You- you- you self-centered, ignorant, troll-buggering BASTARD!~
==IMOEN2J ~(Her hands ball into angry fists at her sides; every muscle in her body is rigid as she struggles not to give you the slap you so richly deserve.)~
=~(It's a losing battle; her hand flashes out and leaves a bright red mark where it connects with your cheek.)~
END
IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3) LeaveParty() EscapeArea()~ EXIT