// ***Stealing***
// ***Ring of Gaxx***
APPEND BIMOEN2

	IF ~Global("MRStealGaxx","LOCALS",0)
	InPartySlot(LastTalkedToBy,0) 
		!StateCheck(Player1,CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		InParty("Imoen2")
		See(Player1)
		!ActuallyInCombat()
		GlobalGT("Chapter","GLOBAL",%bg2_chapter_5%)
		AreaType(CITY)
		HasItem("Player1","ring39")~ THEN BEGIN MRStealGaxx
		SAY ~<CHARNAME>...~ [ MRImRom3 ]
		IF ~~ THEN DO ~SetGlobal("MRStealGaxx","LOCALS",1)~ GOTO MRStealGaxx2
	END

	IF ~~ THEN BEGIN MRStealGaxx2
		SAY ~Could I talk to you about something?~
		++ ~Of course, Imoen. What troubles you?~ GOTO MRStealGaxx3
		++ ~What do you want?~ GOTO MRStealGaxx3
		++ ~Not now, Imoen. This is really an awful time.~ GOTO MRStealGaxxNo
		++ ~As long as you don't take too long.~ GOTO MRStealGaxxQuick
		++ ~No! Gods, I am SICK of your voice!~ GOTO MRStealGaxxYell
	END

	IF ~~ THEN BEGIN MRStealGaxxYell
		SAY ~Whoa! Easy there! Geez, sorry, forget I said anything.~
		=
		~Jerk...~
		IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3)~ EXIT
	END


	IF ~~ THEN BEGIN MRStealGaxxQuick
		SAY ~No, no, don't worry.~ 
		IF ~~ THEN GOTO MRStealGaxx3
	END

	IF ~~ THEN BEGIN MRStealGaxxNo
		SAY ~Aww, really? (she pouts) Fine, okay.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRStealGaxx3
		SAY ~Well, it's just... I've been thinking about something.~
		=
		~About all the effort you put into finding me and rescuing me, all the stuff you had to do to get into Spellhold and everything.~
		=
		~And I realized... well, I hadn't really thanked you properly. You know, for getting me out of there and all.~
		++ ~Please Imoen, you should know that's not necessary. You are a vital part of my life.~ GOTO MRStealGaxx4
		++ ~I only did what you would have done in my place, Imoen.~ GOTO MRStealGaxx4
		++ ~As always, I had no choice. I had to get into Spellhold to find you, and to find Irenicus.~ GOTO MRStealGaxx4
		++ ~I was chasing Irenicus, nothing more.~ GOTO MRStealGaxx4
		IF ~CheckStatGT(Player1,13,WIS)~ THEN REPLY ~Hmmm... you aren't trying to steal something from me, are you?~ GOTO MRStealGaxxCaught
		++ ~I wish I hadn't. I should have left you there to rot.~ GOTO MRStealGaxxRot
	END

	IF ~~ THEN BEGIN MRStealGaxxRot
		SAY ~Whoa, well, that came out of nowhere! How about I just leave you be until you calm down a bit?~
		=
		~Yeesh...~
		IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3) RunAwayFrom("Player1",45)~ EXIT
	END

	IF ~~ THEN BEGIN MRStealGaxxCaught
		SAY ~<CHARNAME>! Of course not - I'm being serious, for once!~
		++ ~Oh, alright. Sorry, it's just that it was so sudden.~ GOTO MRStealGaxx4
		++ ~Hmmm, I don't trust you. A serious Imoen only means a plotting Imoen.~ GOTO MRStealGaxxCaught2
	END

	IF ~~ THEN BEGIN MRStealGaxxCaught2
		SAY ~Oh, fine then! I was only trying to be grateful, but you're so paranoid you can't even appreciate it.~
		=
		~(She sighs and walks off, but you hear her whisper to herself) Damn... I'm gettin' too predictable!~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRStealGaxx4
		SAY ~Yeah, well, in any case... (She takes your hand in hers with affection, and gently kisses your cheek.)~
		=
		~Thanks, <CHARNAME>.~
		IF ~~ THEN DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRStealGaxxNotice
	END

	IF ~~ THEN BEGIN MRStealGaxxNotice
		 SAY ~(As she smiles and steps away, you wonder what suddenly brought up this topic. And, actually, you feel a little... weaker.)~
		IF ~~ THEN EXTERN PLAYER1 MRStealGaxxStolen
	END



	IF ~~ THEN BEGIN MRStealGaxxStolen1
		SAY ~Hehe! This ring RULES ALL, <CHARNAME>!~
		=
		~So very selfish of you, just keeping it for yourself.~
		++ ~Hey! How did you do that?~ GOTO MRStealGaxxHow
		++ ~(sigh) Imoen, why didn't you tell me you wanted it? Keep it, by all means.~ GOTO MRStealGaxxKeep
		++ ~Give it back!~ GOTO MRStealGaxxBack
		++ ~Gah, I hate it when you do that!~ GOTO MRStealGaxxHate
		++ ~Imoen! That ring is very powerful and must be treated with respect!~ GOTO MRStealGaxxPower
		++ ~Bah, keep it, it's not worth it.~ GOTO MRStealGaxxKeepApa
	END

	IF ~~ THEN BEGIN MRStealGaxxKeep
		SAY ~I think I'm gonna kee- huh?~
		= ~Did you just say I should keep it?~
		++ ~(Use reverse psychology) Sure, I don't mind at all. You deserve it more than me, anyways.~ GOTO MRStealGaxxKeep1
		++ ~(Be sincere) Sure, I don't mind at all. You deserve it more than me, anyways.~ GOTO MRStealGaxxKeep1
		++ ~It's not that important. Throw it away for all I care.~ GOTO MRStealGaxxKeepApa
	END

	IF ~~ THEN BEGIN MRStealGaxxKeep1
		SAY ~I- uh... (Imoen looks quite confused. She looks at you and then at the ring on her finger.)~
		= ~(Finally she purses her lips and frowns) I- I was just teasin' ya, I don't want the stupid ring! (She removes it from her finger and tosses it back at you.)~
		= ~(She turns around and, huffing, walks away from you muttering to herself) Stupid dumbhead with <PRO_HISHER> stupid morals and politeness... totally ruins the fun.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRStealGaxxKeepApa
		SAY ~(Imoen is surprised by your lack of interest.)~
		=
		~H- hey, ya don't want it? (She sings in a teasing way) I'm gonna keep it for sure!~
		++ ~Arrgh, give it back!~ GOTO MRStealGaxxBack
		++ ~Imoen! That ring is very powerful and must be treated with respect!~ GOTO MRStealGaxxPower
		++ ~Fine, keep it then. Just leave me alone.~ GOTO MRStealGaxxApa2
		++ ~It's all yours, Imoen.~ GOTO MRStealGaxxApa2
	END

	IF ~~ THEN BEGIN MRStealGaxxApa2
		SAY ~(She seems rather disappointed.)~
		=
		~Ohh, fine, there you go! (she tosses it at you.)~
		=
		~You are so BORING sometimes!~
		=
		~(You smile triumphantly and slip the ring back on your finger.)~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRStealGaxxKeepApa2a
		SAY ~Seriously? You don't want it back?~
		++ ~Of course I do! GIMME!~ GOTO MRStealGaxxBack
		++ ~No. Just leave me alone.~ GOTO MRStealGaxxApa2
		++ ~It's all yours, Imoen.~ GOTO MRStealGaxxApa2
	END


	IF ~~ THEN BEGIN MRStealGaxxPower
		SAY ~Hah! Dontcha think I know that? And who better to respect it than ME?~
		++ ~Argh, give it back!~ GOTO MRStealGaxxBack
		++ ~Bah. Keep it, then - it's all yours.~ GOTO MRStealGaxxKeepApa2a
	END

	IF ~~ THEN BEGIN MRStealGaxxBack
		SAY ~Huh? Give you what?~
		++ ~The ring!~ GOTO MRStealGaxxBack2
		++ ~This is pointless! Keep it, it's not worth your games!~ GOTO MRStealGaxxKeepApa2a
	END

	IF ~~ THEN BEGIN MRStealGaxxBack2
		SAY ~What ring?~
		++ ~The RING you have just STOLEN from me! The Ring of GAXX!~ GOTO MRStealGaxxGaxx2
		++ ~This is pointless! Keep it, it's not worth your games!~ GOTO MRStealGaxxKeepApa2a 
		++ ~The Ring of Gaxx you just swiped. I don't mind you having it.~ GOTO MRStealGaxxKeepApa2a
	END
		
	IF ~~ THEN BEGIN MRStealGaxxGaxx2
		SAY ~You're hallucinating again, <CHARNAME>. Why the heck would I take a ring with a stupid name like that?~
		++ ~(Sincere threat) Imoen, don't make me hurt you. Give me the ring, now.~ GOTO MRStealGaxxThreat
		++ ~(Empty threat) Imoen, don't make me hurt you. Give me the ring, now.~ GOTO MRStealGaxxThreat
		++ ~(Use reverse psychology) Actually, you deserve it more than me, anyways. Keep the ring.~ GOTO MRStealGaxxKeep2
		++ ~(Be sincere) Actually, you deserve it more than me, anyways. Keep the ring.~ GOTO MRStealGaxxKeep2
	END

	IF ~~ THEN BEGIN MRStealGaxxKeep2
		SAY ~I told you, I don't have- wait, what?~
		IF ~~ THEN GOTO MRStealGaxxKeepApa2a
	END

	IF ~~ THEN BEGIN MRStealGaxxThreat
		SAY ~Psht. Like you'd ever lay a hand on me. 'Sides, I told you - I don't have your stupid ring.~
			++ ~(sigh) Fine, keep it. This isn't worth the effort.~ GOTO MRStealGaxxApa2
			++ ~(Storm off in a huff.)~ GOTO MRStealGaxxHuff
	END

	IF ~~ THEN BEGIN MRStealGaxxHuff
		SAY ~Heh! Looks like the Marvelous Miss Im wins again!~
		= ~Oh, don't get all huffy on me, <CHARNAME>. It was just a joke! Learn to relax, sheesh.~
		=~(She takes your hand and presses the Ring of Gaxx into your palm) Here ya go. Now cheer up, 'kay?~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRStealGaxxHate
		SAY ~Huh? When I do what?~
		++ ~Stealing that ring from me like you just did!~ GOTO MRStealGaxxBack2
		++ ~Act like a stupid, spoiled child!~ GOTO MRStealGaxxChild
		++ ~WHATEVER! Keep it, it's not worth the effort!~ GOTO MRStealGaxxApa2
	END

	IF ~~ THEN BEGIN MRStealGaxxChild
		SAY ~(Imoen just laughs) Oooh, look at you all red and mad!~
		=
		~Okay, alright, here you go, yeesh... (She tosses the ring at you.)~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRStealGaxxHow
		SAY ~Huh? How did I do what?~
		++ ~Stealing my ring like that without me noticing it!~ GOTO MRStealGaxxBack2
		++ ~Haha, alright Imoen, I get the idea. Keep the ring, you've earned it.~ GOTO MRStealGaxxKeepApa
		++ ~Being such a stupid and spoiled little girl!~ GOTO MRStealGaxxChild
		++ ~WHATEVER! Keep it, it's not worth the effort!~ GOTO MRStealGaxxApa2
	END
END

APPEND PLAYER1

IF ~~ THEN BEGIN MRStealGaxxStolen
		SAY ~(A suspicion begins to grow in the back of your mind. You look down at the hand she had been holding.)~
                = ~(Your ring of Gaxx appears to be gone...)~
                = ~(... Straight to Imoen's ring finger.)~
		IF ~~ THEN EXTERN BIMOEN2 MRStealGaxxStolen1
	END
END