//*** Jaheira ***//

/* Jaheira reaction Dialog #1 */

CHAIN 
IF ~InParty("Jaheira")
See("Jaheira")
!Global("MRSleptImoen","GLOBAL",1)
Global("ImoenRomanceActive","GLOBAL",1)
Global("MRJaheiraIncest","LOCALS",0)
!StateCheck("Jaheira",CD_STATE_NOTVALID)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !ActuallyInCombat()
 ~ THEN BIMOEN2 MRJaheiraReact1
~Jaheira, you've been looking at me the whole day! Is there something wrong with my face?~
DO ~SetGlobal("MRJaheiraIncest","LOCALS",1)~
==BJAHEIR ~You are imagining things, Imoen.~
==BIMOEN2 ~Hmph. I know you well enough, Jaheira. If my hair looks stupid, just tell me.~
==BJAHEIR ~It looks fine.~
==BIMOEN2 ~What is it then? Are my fingernails not painted? Well, they ain't, you got me there.~
==BJAHEIR ~Imoen, would you please stop? I am not in the mood for this.~
==BIMOEN2 ~Lighten up, Jaheira! I know this isn't the perfect moment, but still... we can't be all dead serious all the time. It's so... freaky.~
==BJAHEIR ~Could you not talk about freaks to me? Thank you.~
==BIMOEN2 ~Jaheira? Hey, wait...~
EXIT

/* Jaheira reaction Dialog #2 */
/* Triggers sometime after, if the sex scene hasn't happened yet */

CHAIN 
IF ~InParty("Jaheira")
	See("Jaheira")
	!Global("MRSleptImoen","GLOBAL",1)
	Global("MRJaheiraIncest","LOCALS",1)
	Global("ImoenRomanceActive","GLOBAL",1)
	!StateCheck("Jaheira",CD_STATE_NOTVALID)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !ActuallyInCombat()~ THEN BIMOEN2 MRJaheiraReact2
~Okay, Jaheira, the 'patronizing gaze' thing is getting really old. What'd I do this time?~
DO ~SetGlobal("MRJaheiraIncest","LOCALS",2)~
==BJAHEIR ~If you do not like it, don't look at me.~
==BIMOEN2 ~Funny, I was gonna say the same thing.~
==BJAHEIR ~(She sighs.) I saw you... looking at <PRO_HIMHER>. The same way that Khalid looked at me, when we were... together.~
==BJAHEIR ~It is disturbing. I worry that perhaps not everything is... alright with you, after your... experiences.~
==BIMOEN2 ~What? What in Mystra's name are you talking about?~
==BJAHEIR ~Do not act as if you do not know. You and <PRO_HIMHER>.~ 
==BIMOEN2 IF ~Gender(Player1,MALE)~ THEN ~Him who?~
==BIMOEN2 IF ~Gender(Player1,FEMALE)~ THEN ~Her who?~
==BJAHEIR IF ~Gender(Player1,MALE)~ THEN ~Your BROTHER, Imoen. Of all the men you could be ogling, why him?~
==BJAHEIR IF ~Gender(Player1,FEMALE)~ THEN ~Your SISTER, Imoen. Not only must you cast your gaze at a woman, but at your own flesh and blood?~ 
==BIMOEN2 ~You... you think I've been making goo-goo eyes at <CHARNAME>?~
==BJAHEIR ~I have not "thought" it - I have seen it. There was a gleam in your eye's that I have never seen before.~
==BIMOEN2 ~That's- that's crazy! You're freaking me out, Jaheira.~
==BJAHEIR ~I could say the same.~
EXIT


/* Jaheira reaction Dialog #3 */
/* if the sex scene hasn't happened yet */

CHAIN IF ~
	InParty("Jaheira")
	See("Jaheira")
	!Global("MRSleptImoen","GLOBAL",1)
	Global("MRJaheiraIncest","LOCALS",2)
	Global("ImoenRomanceActive","GLOBAL",1)
	!StateCheck("Jaheira",CD_STATE_NOTVALID)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !ActuallyInCombat()~ THEN BIMOEN2 MRJaheiraReact3
~(Sigh) What is it Jaheira?~
DO ~SetGlobal("MRJaheiraIncest","LOCALS",3)~
==BJAHEIR ~I see you refuse to quit this weird game after all.~
==BIMOEN2 ~Why does it bother you so much when <CHARNAME> and I chat? Are you afraid we'll suddenly jump at each other and tear our clothes off?~
==BJAHEIR ~Something like that, yes.~
==BIMOEN2 ~Look, I love <PRO_HIMHER> as a friend, as a <PRO_BROTHERSISTER>... nothing more. You're really seeing things. Are you sure that *I'm* the one not right in the head?~
==BJAHEIR ~Imoen, we've traveled together a long time, and I know you well. You have never acted this way before.~
==BIMOEN2 ~And how am I acting? Am I drooling at the sight of <PRO_HIMHER>? Mumbling <PRO_HISHER> name in my sleep? Trying to make a tattoo of <PRO_HIMHER> on my shoulder using a blunt dagger?~
==BJAHEIR ~You care for <PRO_HIMHER>. Differently then ever. In an unnatural way.~
==BIMOEN2 ~Maybe I'm just happy that <PRO_HESHE> risked everything to save me from the madman that caged me and tortured me for the sake of some insane experiment? Yes, I am grateful to <CHARNAME> - but it's not like I want to jump in <PRO_HISHER> bedroll or something. Could you stop suggesting that, please?~
==BJAHEIR ~I don't understand why you deny it so vehemently.~
==BIMOEN2 ~Deny *what*? This is stupid. I've had enough of this discussion.~
==BJAHEIR ~(Sigh.)~
EXIT


/* Jaheira reaction Dialog #4 */
/* Triggers only if all of the previous dialogs occurred, and after the sex scene: Global("MRSleptImoen","GLOBAL",1) and after her initial reaction to it */

CHAIN IF ~InParty("Jaheira")
	See("Jaheira")
	Global("MRSleptImoen","GLOBAL",1)
	Global("MRJaheiraReaction","GLOBAL",2)
	!Global("MRJaheiraIncest","LOCALS",4)
	Global("ImoenRomanceActive","GLOBAL",1)
	!StateCheck("Jaheira",CD_STATE_NOTVALID)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !ActuallyInCombat()~ THEN BIMOEN2 MRJaheiraReact4
~Do you want to say something Jaheira?~
DO ~SetGlobal("MRJaheiraIncest","LOCALS",4)~
==BJAHEIR IF ~Gender(Player1,MALE)~ THEN ~I hope at least that you won't get pregnant.~
==BJAHEIR IF ~Gender(Player1,FEMALE)~ THEN ~At least you cannot get pregnant.~
==BIMOEN2 ~Oh, please, not this again.~
==BJAHEIR ~At least have the courtesy not to deny it every time we speak about it. Especially after what happened.~
==BIMOEN2 ~Couldn't we just... concentrate on our task? I don't wanna talk about it.~
==BJAHEIR ~Imoen, you had a terrible experiment conducted on your brain. What you are doing now seems to be some sort of relief method. But it is wrong, Imoen. It is against nature.~
==BIMOEN2 ~I said I don't-~
==BJAHEIR ~And nature is everything, Imoen. If we violate her laws, we degrade ourselves below animal level. Is that what you want?~
==BIMOEN2 ~This conversation is over.~
EXIT


/* Comment on the Death of Khalid -- Must be the first banter Imoen has with Jaheira, preferably in Spellhold */
/* Only if both are ValidForPartyDialog, of course */

CHAIN
IF ~InParty("Jaheira")
See("Jaheira")
Global("MRJaheiraIncest","LOCALS",0)
Global("MRJaheiraMiss","LOCALS",0)
GlobalGT("Chapter","GLOBAL",%bg2_chapter_3%)
!StateCheck("Jaheira",CD_STATE_NOTVALID)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !ActuallyInCombat()~ THEN BIMOEN2 MRDeathKhalid
~Jaheira... it's been a while since I last saw you. How're you feeling?~
DO ~SetGlobal("MRJaheiraMiss","LOCALS",1)~
==BJAHEIR ~My back hurts a bit. Perhaps I'm getting old. (She chuckles quietly.)~
==BIMOEN2 ~It's good to hear you laugh again. So good to hear laughter.~
==BJAHEIR ~(She looks at Imoen sadly) I suppose it would be rude to ask how you are feeling.~
==BIMOEN2 ~Not at all... but there isn't much to say. Really.~
==BJAHEIR ~If you do not wish to talk about it, I understand. But talking makes things easier. It helped me to talk of things after the death of Khalid. It eases the pain.~
==BIMOEN2 ~All I can say is that I really wish I'd died along with Khalid, Jaheira. I really do.~
==BJAHEIR ~Do not speak so, Imoen. Khalid would be so proud of you, were he still with us.~
==BIMOEN2 ~The worst thing is: that's what he wants. He wants you to think of death, to give up. He-~
==BIMOEN2 ~I - I'm sorry. I shouldn't burden you with all this. I'm sorry.~
== BJAHEIR ~Do not apologize. You will heal, with time. We both will.~
EXIT


/* Viconia banter #1 */

CHAIN
IF ~InParty("Imoen2")
See("Imoen2")
!StateCheck("Imoen2",CD_STATE_NOTVALID)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !ActuallyInCombat()
 GlobalGT("Chapter","GLOBAL",%bg2_chapter_3%)
Global("MRViconiaKnives","LOCALS",0)~ THEN BVICONI MRViconiaTalk
~Do you still dream about your capture, dalhar?~
DO ~SetGlobal("MRViconiaKnives","LOCALS",1)~
==BIMOEN2 ~Every night, Viconia.~
==BVICONI ~Does your breath quicken at the thought of his knives stroking your flesh? Does his voice whisper dark promises that send shivers up your back? Do you feel the sweat on your skin as his touch mends your wounds?~
==BIMOEN2 ~Y'know, you really are sick, Viconia.~
==BVICONI ~Perhaps, kul'gobuss. But we drow know that pain and pleasure are like lovers intertwined, and one is never far from the other.~

EXIT

/* Viconia banter #2 */

CHAIN
IF ~InParty("Imoen2")
See("Imoen2")
!Global("BodhiDead","GLOBAL",1)
Global("MRViconiaSoul","LOCALS",0)
GlobalGT("Chapter","GLOBAL",%bg2_chapter_3%)
!StateCheck("Imoen2",CD_STATE_NOTVALID)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !ActuallyInCombat()~ THEN BVICONI MRViconiaTalk2
~Where is your soul, Imoen? Have you perhaps misplaced it?~
DO ~SetGlobal("MRViconiaSoul","LOCALS",1)~
==BIMOEN2 ~Where is yours, Viconia?~
==BVICONI ~That I have no patience with mewling husks like you does not mean that I lack a soul. I shall thrive and live to a ripe old age, while you are dying as we speak.~
==BIMOEN2 ~A ripe old age, huh? You're pathetic, Viconia. <CHARNAME> has saved your sorry carcass twice now - first from the Flaming Fist and then from fanatics after your head!~
==BIMOEN2 ~Even if I don't make it, I'll die with friends and people who care for me. All you'll have is an unloved and unmarked grave. If you died today, Viconia... will anyone shed a tear?~
==BVICONI ~You assume I care. As if I would wish to be mourned by simpletons and slaves.~
EXIT

/* Viconia banter #3 */

CHAIN
IF ~InParty("Imoen2")
See("Imoen2")
Global("MRViconiaTorture","LOCALS",0)
Global("MRViconiaKnives","LOCALS",1)
!StateCheck("Imoen2",CD_STATE_NOTVALID)
 !StateCheck(Myself,CD_STATE_NOTVALID)
 !ActuallyInCombat()~ THEN BVICONI MRViconiaTalk3
~It must grieve you so, dalhar.~
DO ~SetGlobal("MRViconiaTorture","LOCALS",1)~
==BIMOEN2 ~(sighs.) What must, Viconia?~
==BVICONI ~How the mage used you. The jaluk took what he wanted and left you with nothing - not even a few coppers for your trouble.~
==BVICONI ~He didn't even have the decency to use your soul for himself; he gave it away as a worthless trinket to his sister. Oh, how that must have galled you.~
==BIMOEN2 ~Just... just leave me alone, Viconia.~
EXIT
