
/* Contents:
// First Challenge
// Second Challenge
// Third Challenge
// Fourth Challenge
// Fifth Challenge
*/


// ~~ First challenge ~~

// Triggers as soon as the whole challenge is over, right when you are able to roam free again.

APPEND IMOEN25J
IF WEIGHT #10 ~Global("IRTTestTalk1","GLOBAL",1)~ THEN 1stT
	SAY ~That was awful.~ [IRSadRom]
	IF ~~ THEN DO ~SetGlobal("IRTTestTalk1","GLOBAL",2) SetGlobal("IRTHadFaithTalk","GLOBAL",1)~ GOTO 1stTAnswer
END

IF ~~ THEN 1stTAnswer
	SAY ~Are you alright, <CHARNAME>?~
	++ ~I am fine, though that was quite gruesome indeed. How about you?~ + 1stT1
	++ ~All that carnage... will it ever end? I'm sick of all this violence.~ + 1stT2
	++ ~You seem a bit pale. They weren't real, Imoen. We weren't killing innocent people.~ + 1stT3
	++ ~Why wouldn't I be? It was just another fight, like every other that came before it.~ + 1stT4
	++ ~Awful? I'm sad it's over. I could have used some more bloodshed.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-1)~ + 1stT5
END

IF ~~ THEN 1stT1
	SAY ~I was starting to feel sick. I mean, I know they're just spirits or summons or whatever and not real people, but they *looked* real enough as we hacked them to pieces. Bad enough to turn anyone's stomach.~
	IF ~~ THEN GOTO 1stT1Replies
END

IF ~~ THEN 1stT1Replies
	SAY ~I really hope that's not what we're in for from here on out. Takes quite a bit to make me queasy, but that just did it.~
	++ ~Same here. I could stand a little less murderous intent from everyone we meet.~ + 1stT1a
	++ ~Aww, poor little Imoen, she got scared from a littly itsy bit of blood. Would you like a blanket and a tummy rub?~ + 1stT1b 
	++ ~I'm certain it will only get worse. You'd do well to brace yourself.~ + 1stT1c
	++ ~The path I carve is violent and bloody. I wouldn't have it any other way.~ + 1stT1d
END

IF ~~ THEN 1stT1a
	SAY ~Hah. That'd be real nice. Maybe we should carry signs with us wherever we go: "It is okay to talk. You really don't need to attack us."~
	= ~Not that it would help much. Bet half the morons that go after us are illiterate.~
	IF ~~ THEN GOTO 1stTEnd1
END

IF ~~ THEN 1stT1b
	SAY ~Pffft. Don't get cute, you're talkin' to Dire Witch Imoen here! Mighty Bhaalspawn or no, I won't hesitate to roast yer eyebrows if you keep that up.~
	= ~Hm. Dire Witch Imoen. Doesn't sound half bad.~
	IF ~~ THEN GOTO 1stTEnd1
END

IF ~~ THEN 1stT1c
	SAY ~Oh, joy. At least you don't sugarcoat it.~
	= ~On the other hand, it wouldn't feel *right* to adventure with you without people tryin' to kill us all the time. It would feel like we're doing something wrong, y'know? It'd be downright weird.~
	IF ~~ THEN GOTO 1stTEnd1
END

IF ~~ THEN 1stT1d
	SAY ~No, of course you wouldn't, because yer a weirdo. Who could possibly want to have a fun adventure without people dying all around us all the time? Sure beats me.~
	IF ~~ THEN GOTO 1stTEnd1
END

IF ~~ THEN 1stTEnd1
	SAY ~(Imoen sighs.) Wonder what other wonderful surprises are coming up.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 1stT2
	SAY ~No kiddin'. I was starting to feel sick. I mean, I know they're just spirits or summons or whatever and not real people, but they *looked* real enough as we hacked them to pieces. Bad enough to turn anyone's stomach.~
	= ~I really hope that's not what we're in for from here on out. Takes quite a bit to make me queasy, but that just did it.~
	++ ~I will do everything in my power to avoid bloodshed whenever I can. It would help to get a little less murderous intent from everyone we meet.~ + 1stT1a
	++ ~I'm certain it will only get worse. You'd do well to brace yourself.~ + 1stT1c
	++ ~It's not so bad. In fact, I have a good feeling about what's to come. We won't have much more trouble, you'll see.~ + 1stT2b
	++ ~The path I carve is violent and bloody. It is my fate and I cannot escape it.~ + 1stT1c
	++ ~Let's tell the Solar we quit, and she can drop us off on a remote island, away from all the madness.~ + 1stT2a
END

IF ~~ THEN 1stT2a
	SAY ~Hah! Dunno if she'd go for that. Seems like she's quite the "gotta uphold duty" type. She'd probably scold you and give ya a good pull on the ears.~
	= ~But hey, nothing stops us from getting on a bunch of horses and high-tailing it to the Spine of the World. Becoming a mountain hermit doesn't sound half-bad after seeing this mess - but something tells me we'd end up right in the middle of it all, anyway...~
	IF ~~ THEN GOTO 1stTEnd1
END

IF ~~ THEN 1stT2b
	SAY ~Hah. I would absolutely *love* to still be able to believe that. Or was that a joke? That was a joke, wasn't it. 'Cuz it never gets better, you know. We're at the start of something big, it seems, and it's only gonna get worse.~
	= ~Jeez. At some point I became a huge downer and I didn't even realize it.~
	IF ~~ THEN GOTO 1stTEnd1
END
	
IF ~~ THEN 1stT3
	SAY ~Well, yeah, d'uh... but it was nasty all the same. They sure looked and felt and smelled real enough as we hacked them to pieces - I was starting to feel pretty sick.~
	IF ~~ THEN GOTO 1stT1Replies
END

IF ~~ THEN 1stT4
	SAY ~Yikes. Y'know, that's a pretty sad way of looking at things. Not judging or anything, 'cuz I'm sort of getting there myself. You fight enough monsters and idiots, it starts to lose its edge.~
	= ~You know our lives are messed up when getting into life or death situations is a routine thing, huh?~
	++ ~I wouldn't have it any other way.~ + 1stT1d
	++ ~Right. I could stand a little less murderous intent from everyone we meet.~ + 1stT1a
	++ ~Hey, are you having some kind of mental breakdown here? Because you're about due, it hasn't happened in at least a tenday.~ + 1stT1b
	++ ~I'm certain it will only get worse. You'd do well to brace yourself.~ + 1stT1c
	++ ~You are welcome to leave at any point.~ + 1stT4a
END

IF ~~ THEN 1stT4a
	SAY ~Aw, it's not like that, c'mon, I was agreeing with you! Well, sort of. I didn't mean to...~
	= ~Okay, sorry. I didn't mean it to sound like whining. Just making light of the terrible things we have to do sometimes.~
	IF ~~ THEN GOTO 1stT4End
END

IF ~~ THEN 1stT4End
	SAY ~I'm very much looking forward to the next one, right here by your side. Wouldn't miss it for the world.~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN 1stT5
	SAY ~(Imoen rolls her eyes.) There you go again, being a creep. Who says stuff like that?~
	= ~You, that's who. Shoulda known you'd be gleeful after slaughtering a village's worth of people. I mean, I know they weren't *real* people, but still.~
	++ ~This is who I am. If you are going to judge me like this, you might as well leave.~ + 1stT5a
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~How can you claim you love me and still say such things?~ + 1stT5love
	++ ~(Smirk.) Someone weaker and with redder hair and a love for whining might have been put off by it, but not me.~ + 1stT1b
	++ ~What can I say? Violence is in my nature. It will be in yours soon enough, as well.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1)~ + 1stT5b
	++ ~I'm only disappointed they came so fast. It would have been fun to make each death drawn out and far more painful.~ + 1stT5c
END

IF ~~ THEN 1stT5love
	SAY ~(She purses her lips.) I do love you... fool that I am. But I don't love everything that you do.~
	++ ~This is who I am. If you are going to judge me so, you might as well leave.~ + 1stT5a
	++ ~Well, it's good teamwork, in any case. I do all the killing, you do all the pouting and whining.~ + 1stT1b
	++ ~By now you should know that violence is in my nature. It will be in yours soon, as well.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1)~ + 1stT5b
	++ ~Fair enough. I could say the same about you.~ + 1stT5loveEnd
END
	
IF ~~ THEN 1stT5loveEnd
	SAY ~Well, then... seems like we agree on that. (She pauses for a little while.)~
	= ~You know... (she half-smiles,) sometimes I resent having such a complicated relationship, but then I realize how bored I'd get without it.~
	= ~I suppose I'm a bit of a creep as well.~
	IF ~~ THEN DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1)~ EXIT
END	
	
IF ~~ THEN 1stT5a
	SAY ~Aw, c'mon, it's not like that. I wouldn't say these things if I didn't care. I didn't mean...~
	= ~Okay, sorry. You've earned your... eccentricities, let's say. You've earned them with sweat and blood. It just gets daunting sometimes, you know? The terrible things that we have to do.~
	IF ~~ THEN GOTO 1stT4End
END

IF ~~ THEN 1stT5b
	SAY ~What? No, no way I'll go down that road. I'll fight it any way I can. It's not hopeless, you know? It can't be.~
	= ~Yer blaming your tendencies on the Taint like you never had a choice. You could at least own the terrible things you do, because it's all you, <CHARNAME>. Or at least, it used to be. I don't know how much Bhaal made it worse.~
	= ~Anyway, I didn't mean to get into any of that. I just wanted to know how you were doing, but gave you an earful instead. I think we can both agree that you've enough to worry about without me bitching at everything you do.~
	= ~Sorry about that.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 1stT5c
	SAY ~Alright, now yer just trying to rile me up. This conversation is over, glad you're doin' just peachy.~
	= ~... You creep.~
	IF ~~ THEN EXIT
END
END

// ~~ Second Challenge ~~
// Triggers when challenge is completed
// Make sure !Global("ImoenRomanceActive","GLOBAL",3) for this one

CHAIN IF WEIGHT #10 ~Global("IRTTestTalk2","GLOBAL",1)~ THEN IMOEN25J 2ndT
	~Whew. That was the weirdest thing, wasn't it?~ [IRShort] DO ~SetGlobal("IRTTestTalk2","GLOBAL",2)~
	== SAREV25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~I've often thought of seeing Tamoko again. This is not how I imagined it.~
	== IMOEN25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~Huh. I couldn't possibly picture you caring for someone, Sarevok.~
	== SAREV25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~It's easy to make men into monsters. I was a monster indeed. But also a man.~
	== IMOEN25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~That's... surprisingly deep. Tellya what, I won't even make fun of you this time.~
	== SAREV25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~Your empathy knows no bounds.~
	== IMOEN25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~I'm nice like that. But anyway... (Imoen turns to you.)~
	
END IMOEN25J 2ndTAnswer

APPEND IMOEN25J
IF ~~ THEN 2ndTAnswer
	SAY ~That's what happens when I'm not around to guide ya every step of the way, huh? I wonder who alternate-<CHARNAME> was bedding...~
	++ ~Really, Imoen? *That* is your first concern?~ + 2ndT1
	++ ~I'm far too disturbed by this to humor you right now. Please let me be for a while, I need to be alone.~ + 2ndT2
	++ ~I don't think that thing was capable of love.~ + 2ndT3
	++ ~Tamoko, no question.~ + 2ndT4
	++ ~The man with the bow, he was gruff but handsome.~ + 2ndT5
	++ ~I would bet on the wizard.~ + 2ndT5
	++ ~Anyone <PRO_HESHE> pleased, that's who.~ + 2ndT6
	++ ~It was all make-believe, Imoen. Illusions to make me think of my life and actions.~ + 2ndT7
END
END


CHAIN IMOEN25J 2ndT1
	~I'm just curious!~
	== IMOEN25J IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~My money's on Tamoko. Pretty AND toned AND deadly? Yeah, your type. Doubt she was the most fun to be around, though.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~My money's on Tamoko. Pretty AND toned AND deadly? Yeah, your type. I mean, you're with me, after all.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~Doubt she was the most fun to be around, though, so I have her beat in that department. That's very important, you know.~
	== SAREV25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~You would be surprised. She had a dry, venomous wit that she could use to great effect.~
	== IMOEN25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~Aw. Chrome-dome would know, I guess..~
END IMOEN25J 2ndTEnd


APPEND IMOEN25J
IF ~~ THEN 2ndTEnd
	SAY ~Anyway... that's two for two on creepy challenges. It's alright, the next one will be a pork chop eating contest, just you wait.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 2ndT2
	SAY ~Oh. Sorry. Of course.~
	= ~It wasn't you, by the way! I didn't mean to say it was you. I was just trying to make light of things. Anyway... yeah. Sorry.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 2ndT3
	SAY ~Aw, ya think so? Even the most hardened can still find someone to be intimate with. But you'd definitely know better, in this case.~
	IF ~~ THEN GOTO 2ndTEnd
END
END

CHAIN IMOEN25J 2ndT4
	~Hah, you seem pretty certain there!~
	== IMOEN25J IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~I can definitely see it, though. Pretty AND toned AND deadly? Yeah, your type. I doubt she was all that fun to be around, on the other hand.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~I can definitely see it, though. Pretty AND toned AND deadly? Yeah, your type. I mean, you're with me, after all.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~Doubt she was the most fun to be around, though, so I have her beat in that department. That's very important, you know.~
	== SAREV25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~You would be surprised.~
	== IMOEN25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~Aw. Chrome-dome would know, I guess..~
END IMOEN25J 2ndTEnd
	
CHAIN IMOEN25J 2ndT5
	~Hah! Really? Well, if you say so, I won't judge.~
	== IMOEN25J IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~My money's on Tamoko. Pretty AND toned AND deadly? Yeah, your type. Doubt she was the most fun to be around, though.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~My money's on Tamoko. Pretty AND toned AND deadly? Yeah, your type. I mean, you're with me, after all.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~Doubt she was the most fun to be around, though, so I have her beat in that department. That's very important, you know.~
	== SAREV25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~You would be surprised.~
	== IMOEN25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~Aw. Chrome-dome would know, I guess..~
END IMOEN25J 2ndTEnd
	
CHAIN IMOEN25J 2ndT6
	~Hah. <PRO_HESHE> did seem to be the "I take whatever I want" kind of <PRO_MANWOMAN>. With such charms, who could possibly resist <PRO_HIMHER>?~
	== IMOEN25J IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~My money's on Tamoko. Pretty AND toned AND deadly? Yeah, your type. Doubt she was the most fun to be around, though.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~My money's on Tamoko. Pretty AND toned AND deadly? Yeah, your type. I mean, you're with me, after all.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~Doubt she was the most fun to be around, though, so I have her beat in that department. That's very important, you know.~
	== SAREV25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~You would be surprised.~
	== IMOEN25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~Aw. Chrome-dome would know, I guess..~
END IMOEN25J 2ndTEnd

CHAIN IMOEN25J 2ndT7
	~Aw, c'mon, I know that. Just having some innocent fun! I'll take it wherever I can find it.~
	== IMOEN25J IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~My money's on Tamoko. Pretty AND toned AND deadly? Yeah, your type. Doubt she was the most fun to be around, though.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~My money's on Tamoko. Pretty AND toned AND deadly? Yeah, your type. I mean, you're with me, after all.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~Doubt she was the most fun to be around, though, so I have her beat in that department. That's very important, you know.~
	== SAREV25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~You would be surprised.~
	== IMOEN25J IF ~IsValidForPartyDialog("Sarevok")~ THEN ~Aw. Chrome-dome would know, I guess.~
END IMOEN25J 2ndTEnd

	
// 3rd Challenge	
// Triggers when challenge is completed

APPEND IMOEN25J
IF WEIGHT #0 ~Global("IRTTestTalk3","GLOBAL",1)~ THEN 3rdT
	SAY ~Who in their right mind would be tempted by this nonsense? "Sure, I've got insanely powerful foes trying to kill me and a prophecy nipping at my behind, but yeah, please turn me into a defenseless whelp again."~ [IRYayRom]
	IF ~~ THEN DO ~SetGlobal("IRTTestTalk3","GLOBAL",2)~ GOTO 3rdTN
END

IF ~~ THEN 3rdTN
	SAY ~I mean, I'd be all about going back in time and living our lives without Bhaal ever showing his ugly mug, but that's not what she was talking about here.~
	++ ~Agreed. There was no real choice here, as usual.~ + 3rdT1
	+ ~!Global("ImoenRomanceActive","GLOBAL",2)~ + ~Would you truly go back in time and relive your life without our heritage? Think of all that you would miss.~ + 3rdT2
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~Would you truly go back in time and relive your life without our heritage? Think of what you would lose.~ + 3rdT3
	++ ~I've fought far too hard to earn my place. There is no way I would ever go back to who I was.~ + 3rdT4
	++ ~I think you missed the point, Imoen. The real objective was to give me pause so that I don't become overconfident.~ + 3rdT5
	+ ~!Global("ImoenRomanceActive","GLOBAL",3)~ + ~Don't care. Let's move on.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-2)~ + 3rdT6
	+ ~Global("ImoenRomanceActive","GLOBAL",3)~ + ~For the last time, shut up. I will not tell you again.~ DO ~SetGlobal("IRTShutUp","GLOBAL",1)~ + 3rdT7
END	

IF ~~ THEN 3rdT1
	SAY ~What a shocker, huh? We ended up fighting yet again. At least this one was so single minded about ya that I was able to attack however I liked, ha ha.~
	IF ~~ THEN GOTO 3rdT1R
END

IF ~~ THEN 3rdT1R
	SAY ~Not that a giant spike monster throwing itself at your face is funny or anything... (She gives you a cheeky smile.) I appreciated the arrangement, is all.~
	++ ~If I had a choice, I'd rather every one of our enemies did that. I don't want you to ever be at risk.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1)~ + 3rdT1a
	++ ~I'm so very glad you didn't have a worry in the world, Imoen.~ + 3rdT1b
	++ ~I almost got torn apart! How can you be laughing about it?~ + 3rdT1b
	++ ~Fine, whatever you say. Let's move on.~ + 3rdT1c
END

IF ~~ THEN 3rdT1a
	SAY ~Aw, that's awful sweet of you, especially after what I just said. I was only teasin', y'know. I'm horrified every time you get hurt, I hate it.~
	IF ~~ THEN GOTO 3rdT1End
END

IF ~~ THEN 3rdT1b
	SAY ~Aw, c'mon, I was only teasing. I'm horrified every time you get hurt, I hate it. It's real hard to focus on what I'm doing sometimes, when you're in danger.~
	IF ~~ THEN GOTO 3rdT1End
END

IF ~~ THEN 3rdT1c
	SAY ~Aw, c'mon, don't be cross. I hate it when you get hurt, you know that.~
	IF ~~ THEN GOTO 3rdT1End
END

IF ~~ THEN 3rdT1End
	SAY ~You'd think I'd be used to it by now, huh? I mean, (Imoen chuckles) yer everyone's punching bag...~
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT2
	SAY ~Umm... yeah? No Sarevok, no Irenicus, no torture and endless killing. Bhaal didn't do us any damn favors, I don't think.~
	= ~Don't get me wrong, there's been real good times traveling with you, but we could've had those *without* the Bhaalspawn blood. We coulda left Candlekeep of our own terms, gone out into the world adventuring without a care... it might have been a wonderful life.~
	= ~Please, don't think I'm blaming ya, 'cause I really am not. I'm just sayin' we'd have had a lot more fun if we weren't Bhaalspawn.~
	++ ~And we would be much less powerful, too. Would you truly trade away all that you are capable of, just to have more fun?~ + 3rdT2a
	++ ~It's hard to disagree with that.~ + 3rdT2b
	++ ~All the wishes in the world can't change reality. Let's continue moving forward.~ + 3rdT2c
	++ ~It's all been because of me, regardless of who you blame. Maybe you should consider leaving my company.~ + 3rdT2d
END

IF ~~ THEN 3rdT2a
	SAY ~Hm. (Imoen seems to think about it for a moment.) I think I would. Can't lie, though - I'd miss it. I love my magic, I really do.~
	= ~We'd eventually get there, though! Not as fast, sure, but we'd get there all the same, or close enough. Who knows, maybe we'd be fighting the Five anyway, just trying to stop the slaughter and whatnot.~
	IF ~~ THEN GOTO 3rdT2End
END

IF ~~ THEN 3rdT2b
	SAY ~You know it! Can't lie, though - I'd miss my magic. Had to work so hard to get this far so fast, but I love it, I really do.~
	= ~Who knows, maybe we'd be fighting the Five anyway, just trying to stop the slaughter and whatnot. Wonder if I'd have gotten into magic at all. I hope so.~
	IF ~~ THEN GOTO 3rdT2End
END

IF ~~ THEN 3rdT2c
	SAY ~Yeah, yer right, of course. This is our lot, and we're gonna see it through no matter what. Everything else is idle talk.~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN 3rdT2d
	SAY ~What? No, are you nuts? Absolutely not. I'm with you, no matter what. I couldn't live with myself if I just left.~
	= ~B'sides, I'm a Bhaalspawn too. They'd hunt me down and run me through, eventually. (Imoen chuckles.) Better have yer protection!~
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT2End
	SAY ~But hey, what does it matter. This is our lot, and we're gonna see it through no matter what. Everything else is idle talk.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT3
	SAY ~Well... no, I guess I wouldn't. It's the hardship that brought us together, isn't it? I couldn't trade that away. Candlekeep Imoen would've never acted on... um.~
	= ~Never mind. No, I wouldn't go back. Not for anything.~
	++ ~Acted on what?~ + 3rdT3a
	++ ~Neither would I.~ + 3rdT3b
	++ ~I think I would, if we had ended up together anyway. I could do without all the bad things we've experienced.~ + 3rdT3c
	++ ~Nothing is worth the torture I've been through to get here. If I could choose, I would relive my life without the divine heritage.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-5)~ + 3rdT3d
END

IF ~~ THEN 3rdT3a
	SAY ~(Imoen seems a bit flustered.) No, dunno where I was going with that. We better get moving, huh? There's so much stuff to do still.~
	++ ~Come on, you were going to say something else.~ + 3rdT3Rel
	++ ~Indeed there is, let's go.~ EXIT
END

IF ~~ THEN 3rdT3Rel
	SAY ~(She rolls her eyes.) I *might* have entertained certain fantasies when I was a teenager and you were the only eligible person around, alright? Can't blame me for that. And there's no way I'd have ever acted on them.~
	= ~Um... unless you made the first move, that is.~
	++ ~Imoen, I made *so many moves* back then. I basically threw myself at you.~ + 3rdT3Rel1
	++ ~I wish I'd known. We could have been together much sooner.~ + 3rdT3Rel2
	++ ~Now the truth comes out! After you gave me such a hard time in Amn, too!~ + 3rdT3Rel3
	++ ~Hah! I don't blame you. I know what you mean.~ + 3rdT3Rel4
END

IF ~~ THEN 3rdT3Rel1
	SAY ~What? No you didn't. Not that I noticed, anyway, and besides! Under Gorion's constant watch? I don't think so, I'd have never gone for it. I meant if you made the first move later, once we were adventuring on our own.~
	IF ~~ THEN GOTO 3rdT3RelEnd
END

IF ~~ THEN 3rdT3Rel2
	SAY ~Under Gorion's constant watch? Nu-uh, I don't think so, I'd have never gone for it. I meant if you made the first move later, once we were adventuring on our own and we were just innocent people without Bhaalspawn blood an' all that.~
	IF ~~ THEN GOTO 3rdT3RelEnd
END

IF ~~ THEN 3rdT3Rel3
	SAY ~We were freshly minted Bhaalspawn then, everything was different! I knew you'd go there, this is why I didn't wanna tell. And I was a mess, too, and everything was awful! It's been hard to figure everything out, alright? Cut me some slack...~
	IF ~~ THEN GOTO 3rdT3RelEnd
END

IF ~~ THEN 3rdT3Rel4
	SAY ~Right! We were teenagers. Urges and fantasies and all that. Perfectly natural and innocent.~
	IF ~~ THEN GOTO 3rdT3RelEnd
END

IF ~~ THEN 3rdT3RelEnd
	SAY ~But whatever. How did we get so derailed? Doubt yourself, don't get too confident, yadda yadda yadda. Let's go hunt ourselves some more psychopaths.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT3b
	SAY ~(She smiles at you.) Pretty screwed up, huh. Some things are worth any price, I guess. I know you are.~
	= ~Anyway, it's not like it matters. She was offering something completely different and useless. I think the whole point was just to have a monster jump at your face again. At least this one was so single minded about ya that I was able to attack however I liked, ha ha.~
	IF ~~ THEN GOTO 3rdT1R
END

IF ~~ THEN 3rdT3c
	SAY ~Hah, you and me both. Thing is, she was offering something completely different and useless. I think the whole point was just to have a monster jump at your face again. At least this one was so single minded about ya that I was able to attack however I liked, ha ha.~
	IF ~~ THEN GOTO 3rdT1R
END

IF ~~ THEN 3rdT3d
	SAY ~Oh. Yeah, I guess you've a point. I can't blame you for feeling that way.~
	IF ~~ THEN GOTO 3rdT3RelEnd
END

IF ~~ THEN 3rdT4
	SAY ~Can you imagine goin' through all that stuff again? Or dealing with all this madness with a simple dagger and a quarterstaff? Listening to that... "spirit of doubt" or whatever it was made me a bit mad, honestly.~
	= ~I mean, what's the point? Just throwing another monster in your face? I'm starting to question the Solar's methods, here.~
	++ ~I am as well. More cryptic questions followed by yet another fight is the last thing I needed.~ + 3rdT4a
	++ ~I don't know, I'm sure there is a good reason for all of it.~ + 3rdT4a
	++ ~The point was to give me pause so that I don't become overconfident.~ + 3rdT5
	++ ~The point was to test my resolve and give reason to my determination.~ + 3rdT4b
	++ ~The point was to waste my time and give me a headache.~ + 3rdT4c
END	

IF ~~ THEN 3rdT4a
	SAY ~I'm tellin' ya, no reason other than having you chased by a crazy Slayer-thing. At least this one was so single minded about ya that I was able to attack however I liked, ha ha.~
	IF ~~ THEN GOTO 3rdT1R
END

IF ~~ THEN 3rdT4b
	SAY ~Huh. So do you feel more determined now?~
	++ ~Well, I have a more solid justification for it.~ + 3rdT4b1
	++ ~Not really, no. I feel the same.~ + 3rdT4b2
	++ ~Yes, actually. I literally beat doubt into the ground.~ + 3rdT4b3
END

IF ~~ THEN 3rdT4b1
	SAY ~Ah, I see. Well, as long as it's workin' for ya! I gotta say, it was pretty amusing to watch you talk to yourself.~
	= ~Alright, let's move on then.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT4b2
	SAY ~Haha, that's just what I was getting at. Oh well, at least I got a chuckle out of watching you talk to yourself.~
	= ~Alright, let's move on then.~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN 3rdT4b3
	SAY ~Haha, alright, fair enough. I gotta say, at least I got a chuckle out of watching you talk to yourself.~
	= ~So, we're done here, looks like. Time to move on.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT4c
	SAY ~Haha! Was the mission accomplished?~
	++ ~Absolutely. Let's get out of here.~ + 3rdT4c1
	++ ~Feeling fine, but definitely wasted everyone's time.~ + 3rdT4c2
	++ ~Oh, no. I learned such a valuable lesson: stop talking to the visions and start stabbing them on sight.~ + 3rdT4c3
END

IF ~~ THEN 3rdT4c1
	SAY ~Well said.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT4c2
	SAY ~It was somewhat entertaining to watch you talk to yourself, though.~
	= ~Alright, let's move on then.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT4c3
	SAY ~(She lets out a heartfelt laugh.) Aw, but it was so entertaining to watch you talk to yourself!~
	= ~(Imoen sighs and shakes her head.) Let's move on then.~	
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT5
	SAY ~Oh. Well... hmm. Did it work? Or... is that something that you even want? Dunno if this is precisely the time to shake our conviction...~
	++ ~I'm thankful. It's wise not to let overconfidence cloud your judgment. It might lead to brash, careless actions.~ + 3rdT5a
	++ ~No, and that's why I paid no mind to it - though I appreciate the insight into my own motivations.~ + 3rdT5a
	++ ~Exactly. It was a waste of everyone's time and a major annoyance.~ + 3rdT4b2
END

IF ~~ THEN 3rdT5a
	SAY ~Hm. I suppose that makes sense. I'll be honest, the best thing I got out of it was a bit of a chuckle when watching you talk to yourself.~
	= ~(Imoen sighs and shakes her head.) Let's move on then.~	
	IF ~~ THEN EXIT
END

IF ~~ THEN 3rdT6
	SAY ~Jeez, alrighty then. We're in such a damn big hurry...~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN 3rdT7
	SAY ~(Imoen blinks a few times, then nods with contrition.)~
	IF ~~ THEN EXIT
END
END
	
// 4th Challenge
// This next part triggers right after the challenge becomes available, before the challenge itself. Triggers when a party member goes inside the entrance hallway

APPEND IMOEN25J
IF WEIGHT #0 ~Global("IRTTestTalk4","GLOBAL",1)~ THEN 4thT
	SAY ~Wonder if it's gonna be another fight. Ya think it's gonna be another fight?~ [IRShort]
	++ ~It will most definitely be another fight.~ DO ~SetGlobal("IRTTestTalk4","GLOBAL",2)~ + 4thT1
	++ ~I hope so.~ DO ~SetGlobal("IRTTestTalk4","GLOBAL",2)~ + 4thT2
	++ ~Only one way to find out, right?~ DO ~SetGlobal("IRTTestTalk4","GLOBAL",2)~ + 4thT3
	++ ~I could use a challenge of wits, for once.~ DO ~SetGlobal("IRTTestTalk4","GLOBAL",2)~ + 4thT4
	++ ~I don't care. Let's get it over with.~ DO ~SetGlobal("IRTTestTalk4","GLOBAL",2)~ + 4thT5
END

IF ~~ THEN 4thT1
	SAY ~I really don't want it to be another fight...~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thT2
	SAY ~Yeah, because yer weird like that.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thT3
	SAY ~(Imoen sighs.) Right you are.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thT4
	SAY ~Yeah, no kiddin'. Whatever happened to clever riddles?~
	= ~Anyway, let's just go and find out, I guess.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thT5
	SAY ~Good stuff.~
	IF ~~ THEN EXIT
END
END

// This next part triggers after the challenge is over
// make sure !Global("IRTShutUp","GLOBAL",1)

APPEND IMOEN25J 
IF WEIGHT #0 ~Global("IRTTestTalk4","GLOBAL",3)~ THEN 4thTAfter
	SAY ~What a surprise, it was another fight after all.~
	IF ~~ THEN DO ~SetGlobal("IRTTestTalk4","GLOBAL",4)~ GOTO 4thTA
END

IF ~~ THEN 4thTA
	SAY ~You know, it makes me think that there's gotta be a good reason behind it. If the tests always end in fighting, it means we're being prepared for some horrible final battle, dontcha think?~
	++ ~We are definitely being prepared for some horrible final battle.~ + 4thTA1
	++ ~So be it. I never expected this entire issue to be resolved amicably.~ + 4thTA2
	++ ~These challenges aren't only about fighting, though. They all try to screw with my head somehow.~ + 4thTA3
	++ ~I hope not. I grow weary of all the violence.~ + 4thTA4
	++ ~I can't wait for it to happen already.~ + 4thTA5
END

IF ~~ THEN 4thTA1
	SAY ~... Are you just repeating what I say back to me?~
	++ ~I am definitely not repeating what you say back to you.~ + 4thTA1a
	++ ~Only agreeing with you, Imoen.~ + 4thTA1b
	++ ~Yes. It makes these conversations end faster.~ + 4thTA1a
END

IF ~~ THEN 4thTA1a
	SAY ~Ha-ha, very funny. Here I am, trying my best to give you all my support, and that's how you repay me. Maybe I should teach you a lesson myself and give ya a fight of my own.~
	= ~(A smile creeps onto her lips.) You big smart-ass, you...~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thTA1b
	SAY ~Right. (A smile creeps onto her lips.) As well you should, then.~
	= ~Let's just get going, you big smart-ass.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thTA2
	SAY ~(Imoen sighs.) Sad to say, neither did I...~
	= ~Gonna keep hope alive, though. Maybe I'm missing the point entirely, and the tests are all about much deeper philosophical issues. Do you maybe feel wiser now?~
	++ ~I don't see how fighting for my life at every turn could make me wiser.~ + 4thTA2a
	++ ~I have much keener insight of who I am and why I do things, so I would say yes.~ + 4thTA2b
	++ ~I can't tell. Maybe?~ + 4thTA2a
	++ ~This is pointless. Let's go.~ + 4thTA2c
END

IF ~~ THEN 4thTA2a
	SAY ~Yeah, my point exactly.~
	= ~Oh well, let's keep going I guess.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thTA2b
	SAY ~Oh. That's nice. As long as it's working for ya, then.~
	= ~Let's keep going, I guess.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thTA2c
	SAY ~Alright, alright, just tryin' to make sense of things...~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thTA3
	SAY ~Yeah, that's true. There isn't anything truly *valuable*, though. Visions of what was, what could've been, what might be... it all feels pretty needless. Do you think it's all helping somehow?~
	++ ~No. I don't see how fighting for my life at every turn could help me along.~ + 4thTA2a
	++ ~I have much keener insight of who I am and why I do things, so I would say yes.~ + 4thTA2b
	++ ~I can't tell. Maybe?~ + 4thTA2a
	++ ~I trust it will all come clear in the end. The Solar doesn't seem like the type to waste anyone's time.~ + 4thTA3a
END

IF ~~ THEN 4thTA3a
	SAY ~Yeah, you've a point there. Of all the things you could say about her, "playful" isn't one.~
	= ~Oh well, let's keep going, I guess. It might eventually make sense, who knows.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 4thTA4
	SAY ~Glad I'm not the only one. I've been close to sick sometimes, I'm sure you know. Fighting the army at the Oasis was really bad.~
	IF ~~ THEN GOTO 4thTA4End
END

IF ~~ THEN 4thTA4End
	SAY ~And yet there's this gross thing inside of me that *craves* all that. I find myself looking forward to it sometimes, and it gives me shudders when I realize it. Stupid Bhaal and all of his stupid designs...~
	= ~I guess if the next challenge is another fight, we can probably be sure that's what it's all building up to. But hey, one way or another, we'll be ready. If there's something I've learned traveling with ya is that everything works out in the end, no matter how rough it gets.~
	= ~Onwards, then, to victory and beyond! (Imoen charges forward wielding an imaginary sword.)~
	IF ~~ THEN DO ~RunAwayFrom(Player1,30)~ EXIT
END

IF ~~ THEN 4thTA5
	SAY ~Can't say I disagree, if only to just get it all over with. I'm getting pretty burned out with all the fighting.~
	IF ~~ THEN GOTO 4thTA4End
END
END


// Fifth Challenge
// Can be different depending on whether Imoen has already become the Ravager
//  Triggers when challenge is completed

APPEND IMOEN25J
IF WEIGHT #-5 ~Global("IRTTestTalk5","GLOBAL",1) Global("IRTImoenIsRavager","GLOBAL",1)~ THEN 5thR
	SAY ~Is that... is that really what the Ravager looks like?~ [IRQUIET]
	IF ~~ THEN DO ~SetGlobal("IRTTestTalk5","GLOBAL",2)~ GOTO 5thRR
END

IF ~~ THEN 5thRR
	SAY ~Is that how I look like when I let go?~
	++ ~Yes. Glorious.~ + 5thR1
	++ ~Indeed, but you are not nearly as tough to fight.~ + 5thR2
	++ ~I'm afraid so.~ + 5thR3
	++ ~It's not you, Imoen. It's the ugly monster we have to live with. Two separate things.~ + 5thR4
END

IF ~~ THEN 5thR1
	SAY ~Glorious? Yeah, maybe... in a horrifying way. I don't think my version is nearly as resilient, though.~
	IF ~~ THEN GOTO 5thREnd
END

IF ~~ THEN 5thREnd
	SAY ~I don't know what to feel. I should be disgusted, but instead I'm... proud? But disgusted all the same? Is it the Taint, making me feel this way?~
	= ~It'll be over soon, one way or another. I don't even know what I want anymore...~
	IF ~~ THEN EXIT
END

IF ~~ THEN 5thR2
	SAY ~That's what I thought, yeah. Probably has to do with how much Bhaal essence is actually in me.~
	IF ~~ THEN GOTO 5thREnd
END

IF ~~ THEN 5thR3
	SAY ~Huh. How... awful.~
	IF ~~ THEN GOTO 5thREnd
END

IF ~~ THEN 5thR4
	SAY ~Is it? Is it really? The more time I spend with it, the more it seems we are one in the same.~
	IF ~~ THEN GOTO 5thREnd
END

IF WEIGHT #-5 ~Global("IRTTestTalk5","GLOBAL",1) !Global("IRTImoenIsRavager","GLOBAL",1)~ THEN 5th
	SAY ~Gods, that was insane. *That's* what really inside us, isn't it.~ [IRDawn]
	IF ~~ THEN DO ~SetGlobal("IRTTestTalk5","GLOBAL",2)~ GOTO 5thT
END

IF ~~ THEN 5thT
	SAY ~Do you think we could turn into that, if we were to completely give in?~
	++ ~If there is a way, I haven't found it yet.~ + 5thT1
	++ ~Impossible. That monster was beyond the power of any Bhaalspawn.~ + 5thT2
	++ ~I'm not willing to find out - are you?~ + 5thT3
	++ ~Absolutely, but the price is far too costly.~ + 5thT4
	++ ~I wish, we'd be unstoppable!~ + 5thT5
END

IF ~~ THEN 5thT1
	SAY ~You mean you'd *look* for it? I don't think that was a monster that could be controlled. It seems the kind of monster that takes you over.~
	IF ~~ THEN GOTO 5thTPreEnd
END

IF ~~ THEN 5thTPreEnd
	SAY ~Makes me want to get rid of this curse even more. What a horrible monster to fight against - no wonder it's been difficult.~
	IF ~~ THEN GOTO 5thTEnd
END

IF ~~ THEN 5thT2
	SAY ~I dunno if it's about power, though. That monster seemed like the kind that takes over. The kind that preys on weaker Bhaalspawn.~
	IF ~~ THEN GOTO 5thTPreEnd
END

IF ~~ THEN 5thT3
	SAY ~No, no way! It makes me want to get rid of it even more. What a horrible monster to fight against. No wonder it's been difficult.~
	IF ~~ THEN GOTO 5thTEnd
END

IF ~~ THEN 5thTEnd
	SAY ~Just one more step, now. After facing that thing... I can't even feel scared anymore of what might be waiting for us.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 5thT4
	SAY ~Yeah, our lives, to be precise. I don't think that was a monster that could be controlled. It seems the kind of monster that takes you over.~ 
	IF ~~ THEN GOTO 5thTPreEnd
END

IF ~~ THEN 5thT5
	SAY ~Yeah, and also Bhaal's puppets! I don't think a monster like that could be controlled. It's the kind of monster that takes you over.~
	IF ~~ THEN GOTO 5thTPreEnd
END
END
