

// Second Solar Revelation
//first death of either sendai or abazigal
// Appending a request for Imoen's presence at the beginning of the conversation with Solar

EXTEND_BOTTOM SOLAR 31
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~Why haven't you brought Imoen as well? She needs to see this as much as I.~ DO ~SetGlobal("TalkedToSolar","GLOBAL",4)~ + SolP1
END

APPEND SOLAR
IF ~~ THEN SolP
	SAY ~She is not at the center of the prophecy, god-child. You are. It was unclear before, but there is no question now.~
	++ ~I need her here all the same. I would be nothing without her.~ + SolP1
	++ ~That is only your opinion. She is just as important.~ + SolP1
	++ ~Perhaps that is true. Continue, then.~ + 32
	++ ~I will not listen without her by my side.~ + SolP2
END

IF ~~ THEN SolP1
	SAY ~Believe as you may. This revelation is for your eyes alone, regardless.~
	IF ~~ THEN GOTO 32
END

IF ~~ THEN SolP2
	SAY ~Treasure the truth or cast it aside, you may do with it as you please.~
	IF ~~ THEN GOTO 32
END
END

// Imoen asks about it once you return

// Triggers once you go back to whoever you killed (Sendai or Abazigal) and combat is over. Last line of dialogue is state 48 in SOLAR.DLG
// Triggers as long as !Global("ImoenRomanceActive","GLOBAL",3) and !Global("IRTShutUp","GLOBAL",1)

APPEND IMOEN25J
IF WEIGHT #-5 ~Global("IRTSolarPresentTalk","GLOBAL",1)~ THEN SP
	SAY ~It happened again! The fight was over and I blacked out, just like before.~ [IRDawn]
	IF ~~ THEN DO ~SetGlobal("IRTSolarPresentTalk","GLOBAL",2)~ GOTO SPN
END

IF ~~ THEN SPN
	SAY ~It was the Solar, wasn't it. Teaching you more stuff.~
	++ ~I don't know what you're talking about. I blacked out and woke up, just like you.~ + SP1
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~I asked for your presence, but I was denied.~ + SP2
	++ ~It's true. I have much to think about, now.~ + SP3
	++ ~Yes, but it was all irrelevant.~ + SP4
	++ ~I'd rather not talk about it.~ + SP5
END

IF ~~ THEN SP1
	SAY ~Aw. Really? Coulda sworn...~
	IF ~~ THEN GOTO SPDismissal
END

IF ~~ THEN SPDismissal
	SAY ~Well, alrighty then. At least another one of the Five is dealt with. What a bitch of a fight that was, good riddance.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SP2
	SAY ~Psheh, figures. Always with the second-rate Bhaalspawn treatment. Seems like I get all the downsides with none of the perks...~
	IF ~~ THEN GOTO SPQuestion
END

IF ~~ THEN SP3
	SAY ~Ogh, I knew it. Sneaky sneaky Solar, wonder how she even does it.~
	= ~He. It. One of these days I'll ask her what pronoun I should use.~
	IF ~~ THEN GOTO SPQuestion
END

IF ~~ THEN SP4
	SAY ~Hah, of course you'd say that. She could be giving you the keys to the Throne of Blood in a silver platter and you'd still insist in doing things your way.~
	= ~That's why I like you so much.~
	IF ~~ THEN GOTO SPQuestion
END

IF ~~ THEN SP5
	SAY ~Ouch. That bad, huh.~
	IF ~~ THEN GOTO SPDismissal
END	
	
IF ~~ THEN SPQuestion
	SAY ~So c'mon, spill the beans already. What was it about?~
	++ ~Apparently the prophecy is about stopping the Five, and it's on me to get it done.~ + SPQ1
	++ ~The prophecy is a sham, and it's all a contest where the fittest will survive.~ + SPQ2
	++ ~There is nothing I can do, fate will drive me toward conflict no matter what.~ + SPQ3
	++ ~I was honored with the prophesied duty to stop death and destruction. I am a fated force of good, Imoen.~ + SPQ4
	++ ~I learned what I already knew: my whole life is but a pawn in divine chess.~ + SPQ5
	++ ~None of it mattered. I will do as I see fit, just as it has always been.~ + SPQ6
	++ ~I am the one that will vanquish them all and claim the Throne of Bhaal.~ DO ~SetGlobal("IRTImoenWarnedAboutLeaving","GLOBAL",1)~ + SPQ7
END

IF ~~ THEN SPQ1
	SAY ~Huh. So, basically... doing exactly what we've been doing all this time? Gee whiz, Solar. Such astounding revelations you shower upon us.~
	= ~I wonder what kind of prophecy it would've been if Irenicus had decided to run a sword through our chests the many times we were completely at his mercy. D'ya think the prophecy accounts for power-hungry madmen kidnapping the messiah?~
	IF ~~ THEN GOTO SPQEnd
END

IF ~~ THEN SPQ2
	SAY ~Huh. So, basically... exactly what it's been so far? Gee whiz, Solar. Such astounding revelations you shower upon us.~
	IF ~~ THEN GOTO SPQEnd
END

IF ~~ THEN SPQ3
	SAY ~Aw, c'mon, that's grim. We've always had a choice. We could hang ourselves right now! Isn't that great? It's the choice we get all the time, kill or die.~
	= ~It's true, though. We'd have been hunted down if we hadn't pushed through all the crazy stuff we've done. One way or another, conflict would've found you. Maybe we should be glad that at least this way we're sort of on top.~
	= ~Blah, fate's a load of troll guts, anyway. Look, another one of the Five is down, one less nutter to worry about. That's something to be glad about, right? What a bitch of fight that was, good riddance.~
	= ~We'll see it to the end, <CHARNAME>. Maybe then we'll start getting choices again.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SPQ4
	SAY ~Hah hah, boy, and yer gonna let it go to your head, arentcha. Well, don't let me stop you. I'll take "fated force of good" over "bloodthirsty Bhaalspawn" any time of the day.~
	= ~I'm inclined to believe you, though. You're the driving force behind all these terrible people getting defeated, and now you can add this nutter over here to the list. What a bitch of a fight that was, good riddance.~
	= ~We'll see it to the end, <CHARNAME>. Maybe then fate will lay off and we'll be able to make choices again.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SPQ5
	SAY ~Hah hah! Aw, c'mon, don't be like that, I'm sure it wasn't so clear cut. I bet there was a lot of tough questions and stuff that's up for interpretation and whatnot...~
	= ~B'sides, we've always had a choice. We could hang ourselves right now! Isn't that great? It's the choice we get all the time, kill or die. Yay.~
	IF ~~ THEN GOTO SPQEnd
END

IF ~~ THEN SPQ6
	SAY ~Hah, y'know what, I like hearing you say that. Get too hung up in prophesies and fate and whatnot and you end up with your head stuffed up your own butt.~
	IF ~~ THEN GOTO SPQEnd
END
	
IF ~~ THEN SPQ7
	SAY ~Huh. Really, now. And the Solar told you this straight out? She doesn't seem the type...~
	= ~I mean, yeah, probably, but just because you're *you*. I wouldn't rely on some prophecy to make it a certainty, though.~
	= ~But we'll see what happens when it happens. For now, another of the Five just went down. What a bitch of a fight that was, good riddance.~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN SPQEnd
	SAY ~Fate's a load of troll guts, if you ask me. But hey, at least we dealt with another one of the Five, one less nutter to worry about. What a bitch of a fight that was, good riddance.~
	IF ~~ THEN EXIT
END
END


