// *** Imoen's Torture ***

// PID option:
//available after the second talk about Imoen's taint. Available to both romanced and friendly.

// + ~Global("IRTTortureTalk","GLOBAL",1)~ + ~It has been a while since we left Spellhold behind. Do the memories still haunt you, with everything that's happening now?~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRTTortureTalk","GLOBAL",2)~ + T1

CHAIN IMOEN25J T1
	~(Imoen reacts with subdued amusement, a tiny smile curving one side of her mouth.)~
	= ~They probably will 'til the day I die, <CHARNAME>.~
	= ~It's not so bad anymore, though. I think I'm over it. Kind of.~
	== IMOEN25J IF ~!Global("ImoenSummoned","GLOBAL",2)~ THEN ~ The time in Suldanessalar helped quite a bit. Got the chance for some quiet reflection an' all that therapy mumbo jumbo. It was nice while it lasted. And y'know what else helped a lot? Watching Irenicus explode into bloody bits. Say whatever you want - revenge *worked* for me.~
	== IMOEN25J IF ~Global("ImoenSummoned","GLOBAL",2)~ THEN ~The time I spent by myself helped quite a bit. I went back to the Friendly Arm Inn, rented a nice room and tried to sort through my issues. It was nice, while it lasted - not that I'm sad you called or anything. It was also getting a bit boring, hah.~
	== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~And of course, having you around helps a lot, love. I really appreciate your support with this stuff, y'know? Don't let that go unsaid. (She takes hold of your hand and kisses it.)~
	== IMOEN25J IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~And of course, having you around helps a lot. I really appreciate your support with this stuff, y'know? Don't let that go unsaid.~
	== IMOEN25J IF ~GlobalGT("IRTAerImFriend","GLOBAL",0)~ THEN ~Aerie's made things easier as well. Sometimes I feel she cares more than even I do. Guess that's why she's the cleric, huh? Such an infuriating bleedin' heart...~
	== AERIE25J IF ~IsValidForPartyDialog("Aerie") GlobalGT("IRTAerImFriend","GLOBAL",0)~ THEN ~I'm so sorry for caring, Imoen. Maybe I should stop, hmm?~
	== IMOEN25J IF ~IsValidForPartyDialog("Aerie") GlobalGT("IRTAerImFriend","GLOBAL",0)~ THEN ~Ha, right, as if you could!~
	== IMOEN25J ~Anyway, yeah, doing alright in that department. I'm a lot more worried about Bhaal's garbage clutterin' my head nowadays - not that they're mutually exclusive, mind. The torture nightmares often mix with the murder-dreams.~
	= ~Sleeping isn't all that fun, lately...~
END
   ++ ~They do? How so?~ + T5
   + ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~Then I don't feel bad anymore about keeping you up so often. (Wink at her.)~ + T4
   ++ ~You are tough, Imoen. I know you'll see your way through.~ + T3
   ++ ~Glad to know you're coping. I was only checking on you.~ + T2
   ++ ~We all have our demons. Let's move on.~ + T2

APPEND IMOEN25J
IF ~~ T2
   SAY ~Hey, thanks for asking. It really does mean a lot to me that you care.~
   IF ~~ THEN EXIT
END

IF ~~ T3
   SAY ~Hah, tough like a chewed-up strip of old leather, yup. The nightmares used to be harrowing, but now they're mostly... disturbing. The kinda dreams you wake up from and wonder what's wrong with yer head.~
   IF ~~ THEN GOTO TDr
END

IF ~~ T4
   SAY ~(She gives you a cheeky grin.) I can always count on ya to keep my mind off the nasty stuff.~
   ~The nightmares aren't as bad as they used to be, though. Nowadays they're mostly... disturbing. The kinda dreams you wake up from and wonder what's wrong with yer head.~
   IF ~~ THEN GOTO TDr
END

IF ~~ T5
   SAY ~Well, the nightmares used to be harrowing, but now they're mostly... disturbing. The kinda dreams you wake up from and wonder what's wrong with yer head.~
   IF ~~ THEN GOTO TDr
END

IF ~~ TDr
   SAY ~It's like the Taint's a sentient thing, showing me how things might have gone if I'd embraced it at the time. Do I even need to tellya what it's like? Here's a hint: a lot more violent killing would have happened.~
   ++ ~Really? That's interesting. Can you give me an example of these dreams?~ + TDrEx
   ++ ~And how does that make you feel?~ + TDr5
   ++ ~It's all a lie. Embracing the Taint inflicts its own brand of torture upon you. Shun its influence, always.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",-1) IncrementGlobal("IRTFightTaint","GLOBAL",1)~ + TDr4
   ++ ~That doesn't sound like a bad thing. Making use of the Taint would have saved you much grief.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1) IncrementGlobal("IRTControlTaint","GLOBAL",1)~ + TDr3
   ++ ~Your reluctance to accept our birthright baffles me. It's pointless to resist.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1) IncrementGlobal("IRTEmbraceTaint","GLOBAL",1)~ + TDr2
   ++ ~You'll be alright, Imoen. They're just dreams.~ + TDr1
END

IF ~~ TDr1
   SAY ~Yeah, I know. Wish I could tell myself that when I'm *in* the dream.~
   IF ~~ THEN GOTO T2
END

IF ~~ TDr2
   SAY ~Y'know, I really don't wanna get into all that. Thinking about Spellhold is depressing enough, thanks.~
   = ~But hey, thanks for asking, I guess. It means a lot to me that you care, even if it's in your own creepy twisted way.~
   IF ~~ THEN EXIT
END

IF ~~ TDr3
   SAY ~Yeah, I guess...~
   = ~But something tells me I'd be going through worse if I had. Or become a mindless Avatar of Destruction by now. Lost myself, or close to it.~
   = ~Not that I ever had a choice. You didn't choose to become the Slayer at first. It just... happened.~
   IF ~~ THEN GOTO TDrEnd
END

IF ~~ TDrEnd
   SAY ~Gah, I really didn't wanna get into all this. Thinking about Spellhold is depressing enough, thanks.~
   IF ~~ THEN GOTO T2
END

IF ~~ TDr4
   SAY ~Hah, you don't have to tell me twice about that. I might've escaped on my own, but I bet I'd be going through much worse by now, like... roaming about as a mindless Avatar of Destruction, or something. Lost myself completely, or close to it.~
   = ~Not that I ever had a choice, one way or another. You didn't choose to become the Slayer at first. It just... happened. I wonder if it might happen to me.~
   IF ~~ THEN GOTO TDrEnd
END

IF ~~ TDr5
   SAY ~Haha, how'd'ya think? Frikkin' frustrated, for one. It'd be *nice* to get a good night's sleep one of these days.~
   = ~But no, it's... it's scary, of course. This weird little devil whispering in my ear all the time, even as I sleep. It's scary, because in the dreams, when I get to escape, or when I get revenge... it feels *good*. That's the worst part. How good it feels.~
   ++ ~This is so interesting. Could you maybe give me an example of these dreams?~ + TDrEx
   ++ ~It's all a lie. Embracing the Taint inflicts its own brand of torture upon you. Shun its influence, always.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",-1) IncrementGlobal("IRTFightTaint","GLOBAL",1)~ + TDr4
   ++ ~That doesn't sound like a bad thing. Making use of the Taint would have saved you much grief.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1) IncrementGlobal("IRTControlTaint","GLOBAL",1)~ + TDr3
   ++ ~Your reluctance to accept our birthright baffles me. It's pointless to resist.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1) IncrementGlobal("IRTEmbraceTaint","GLOBAL",1)~ + TDr2
   ++ ~You'll be alright, Imoen. They're just dreams.~ + TDr1
END

IF ~~ TDrEx
   SAY ~But of course you'd ask. Yer morbid like that.~
   IF ~RandomNum(5,1)~ THEN GOTO TDrExKhalid
   IF ~RandomNum(5,2)~ THEN GOTO TDrExVat
   IF ~RandomNum(5,3)~ THEN GOTO TDrExCycles
   IF ~RandomNum(5,4)~ THEN GOTO TDrExBodhi
   IF ~RandomNum(5,5)~ THEN GOTO TDrExKnives
END

IF ~~ TDrExKhalid
   SAY ~It was pretty bad last night. (She goes quiet for a moment. Her gaze loses focus, as if she's deep in thought.) We were dissecting Khalid all over again...~
   = ~The smell of blood is stuck inside my nostrils, filling my head. I stand beside him, unable to speak, unable to move. I can just watch. Watch, smell and listen. The sounds are the worst.~
	= ~"See?" he says. "Look."~
	= ~That chopping sound, flesh split, muscles torn. Ribs that crack apart from the breastbone. The sounds have a different texture when it's done in a deliberate, methodical way; a different cadence that burrows into my memories and forever leaves its taint.~
	= ~His hands are stained in blood. His knives are red. Once more his fingers dip into the ribcage, and I scream inside my head. The body on the slab is nothing but a mockery of what Khalid once was. He has lost all meaning to me.~
	= ~My eyes burn as he exposes the heart, cuts into it, spreads the flesh apart. A crimson mist clouds my vision.~
	= ~"Do you see?" he asks. He's asked me a hundred times. I don't understand, I never have.~
	= ~Until now. Loathing surges within, and I give myself to the overpowering rage. My fist is a claw that slams upon the stone table, shattering it like a bundle of twigs, spraying blood everywhere. My arm is covered in spines like scythes. They plunge into his flesh, tearing and rending, splitting him open. It's a different sound altogether - a melodic sound. A righteous sound.~
	= ~My claw engulfs his face, and I squeeze, squeeze, squeeze in enraptured fury.~
   IF ~~ THEN GOTO TDrLast
END



IF ~~ TDrExVat
   SAY ~It was pretty bad last night. (She goes quiet for a moment. Her gaze loses focus, as if she's deep in thought.) I was in the vat again, pounding on the glass until my hands bled...~
   = ~Blurry shadows behind glass. His dwarves threw me in this tiny prison hours ago. It's cold here; my breath makes eddies around me, condensates on the curved wall despite my efforts not to take in much air. Every inhale is like needles pressing into my lungs. I don't remember anymore a time when it didn't hurt to breathe.~
	= ~The shadows move and shift again. I pound the glass, bloodstains and dirt smearing its surface. My fist barely makes faint thudding sounds. "Let me go!" I scream. "Just let me go..."~
	= ~A larger shadow grows behind the crystal. It resolves into his features. There is no emotion there, as usual: no hatred, no pity, no contempt, no mercy. Just steel-cold eyes, observing impassively. "We are close," he says. "It will be over soon."~

	= ~I want to throw myself at the glass and scream profanities at him, but instead I... whimper. I whimper, and shrink away, and incoherently beg for release. I'm trembling, crying, wretched, pathetic. The shadow blurs and shrinks, and soon I can feel the magical energy being unleashed all through the room. I've been here before. I know what's about to happen. I cry out and beg him to stop, but it's no use.~
	= ~The needles inside my chest stab all at once, and the pain makes me shrivel away from the wall, throwing me to the ground. Breathless screams are trapped in my throat, aching for release. A dull anger replaces despair. I hate this man. The hatred is like nothing I've ever felt before.~
	= ~I fuel the pain into it, fanning the flames. The hatred swells, adding weight to my breath, clenching my body. I give myself to the rage, and a crimson mist shrouds my vision. I watch my hands twist and shift. My flesh blackens. Pained grunts become growls.~
	= ~I leap at the glass and it effortlessly shatters forth. I land upon him, claws shredding at his chest, spines like scythes rending his flesh wherever I touch. I watch the pain unfold in enraged delight, thoughts clouded in primal pleasure as vengeance spreads to every part of me, like an intoxicating nectar soothing away all worry.~
	= ~Like sweet blood pouring down my throat.~
   IF ~~ THEN GOTO TDrLast
END

IF ~~ TDrExCycles
   SAY ~It was pretty bad last night. (She goes quiet for a moment. Her gaze loses focus, as if she's deep in thought.) I was chained to the slab again, torn to shreds...~
   = ~I just don't feel it anymore. The shackles in my hands and feet are so tight that my wrists and ankles are bleeding. Blood runs down my arms, staining my cheeks. My chest burns with every breath, my legs are charred, something is inside my skull. I look down and see my own organs, bleeding, pumping, eaten by acid, split open. I can't tell whether it's happening right now or it's all in my mind. I don't feel it anymore.~

	= ~Words float around me, and I barely understand them. "It is only a matter of time," he tells me, "but time is what I cannot spare."~
	= ~The more he does the less I care. I am beyond pain, beyond life. He can't hurt me anymore. I'm broken.~
	= ~Now there's a hand around my neck, holding up my head. He pours something into my mouth; I choke and sputter, but he forces me to swallow. I know the taste. I might have quaffed gallons of the stuff since Candlekeep. None of them ever tasted this strong, though.~
	= ~"You resist," he says. "But you will be shattered, eventually."~
	= ~My body is jolted awake by magic in a bottle. My mind reels from the shock of a thousand wounds agonizing to a close, and as it happens I understand that everything that got me to this point, everything that's been done to my body, my mind, my soul... it's all going to happen again. There is no escape.~

	= ~Anger swells in my chest, sudden and desperate. It gorges on the frustration, the hatred and self-pity. I hate this man. I hate him, I want him to die by my hand, and I want this more than I've ever desired anything in my life. I give myself to the anger, letting it grow, feed and fester without control. It hungers to take over me, and I let it, without hesitation.~
	= ~I feel myself change, morph into something glorious and terrible. I embrace it. I revel in it.~
	= ~The manacles shatter under the strain, followed by every shackle that binds me to the slab. I leap upon him, claws shredding at his chest, spines like scythes rending his flesh wherever I touch. I watch the pain unfold in enraged delight, thoughts clouded in primal pleasure as vengeance spreads to every part of me, like an intoxicating nectar soothing away the suffering that brought me here.~
	= ~Like sweet, warm blood pouring down my throat.~
   IF ~~ THEN GOTO TDrLast
END

IF ~~ TDrExBodhi
   SAY ~It was pretty bad last night. (She goes quiet for a moment. Her gaze loses focus, as if she's deep in thought.) I was in my cell again, and I'd almost checked out for good. It's so weird to dream of that time, I could feel my mind just... breaking, again...~

   = ~I huddle in the corner, as far from the door as I can get. The demon's eyes follow my every movement, malevolent beacons shrouded in darkness. I have never seen her before. I don't want to ever see her again.~
	= ~"My brother is too subtle," she says, "you are too stubborn, and I grow impatient."~
	= ~She steps in. It's as if the dark corners cling to her, a cowl of shadows obscuring her body, her features. Her approach is the sinuous slither of a viper.~
	= ~There are no more words, no warning. Her hand clamps on my neck and throws me against the wall. I try to fend her off, but it's like feebly clawing at a boulder. Vicious fangs flash in my vision as she chokes me, then tosses me to the floor, then starts kicking. She hisses and sputters, her anger and frustration washing over me in waves. "It belongs to me, girl!" she screams, and kicks me again. "It is already mine!" I can only curl up and cover my face.~

	= ~I try to plead, to offer anything I might have to give, but she just grabs me again and throws her arm behind a savage slap. Through the pain and the ringing in my ears I hear my blood spatter on the floor. The taste of it enkindles something inside me, something I've never felt before. At the same time, a different voice comes from the doorway.~

	= ~"Stop," he tells her. "If it were possible to beat it out of her, I would have already done it."~
	= ~His voice is enough to twist my insides in terror, but it also fuels this spark within, fanning it into an angry flame. The demon is holding me up against the wall, clawed hand pulled back and ready to strike again. She looks at the doorway and speaks, angry and spiteful.~
	= ~"Time is running out. The fool is making progress. <PRO_HESHE>'ll make it to the island soon."~
	= ~He responds to her, but I can hardly hear them anymore. There is a roaring inside my chest, within my skull. The growing flame gorges on the frustration, the hatred and endless torment. In wild desperation I give myself to the anger, letting it grow, feed and fester without control. It hungers to take over me, and I let it, without hesitation.~
	= ~Instantly raw strength flows into me, through me, like floodwaters coursing forth in a path of devastation. I claw at her arm again, and this time it breaks like a dry twig. She screams in pained surprise, giving me a sudden jolt of excitement, of raw pleasure. I shove and she collapses against the opposite wall, powerless to resist. As I advance on the demon I see my skin twist and morph, changing colors, sprouting wicked spines in places. I become something terrible. Glorious. In one leap I close the distance and shred her to pieces.~
	= ~His spell hits me as I let go of the remains. What should have been immediate death becomes an imperceptible vibration, an inconsequential tingle as I shrug off his magic like dust off my shoulders. I savor each instant as I run him down, dig my claws into his skull, tear and rend his flesh in delectable carnage.~
	= ~It is beautiful.~
  IF ~~ THEN GOTO TDrLast
END


IF ~~ TDrExKnives
   SAY ~It was pretty bad last night. (She goes quiet for a moment. Her gaze loses focus, as if she's deep in thought.) I was on the slab again, shortly after we were first captured. It's so weird that I still remember each and every one of his words...~

   = ~I can't stop looking down. I watch as the scalpel rips down my abdomen. It's a numb pain, intense yet dull. I don't bleed nearly as much as I should.~
	= ~He cuts in slow lines, describing everything step by step without a hint of emotion. "The incision starts under the sternum," he's telling me, "down the rectus abdominis muscle. Beneath lie the great and lesser omentum, keeping together stomach, liver and transverse colon."~
	= ~He goes on and on. His movements are mechanical; the process, routine. And yet it's different for him, now. He's searching for something within me. He's... exploring.~
	= ~His knife comes in and out of my insides. I can't avert my gaze, fascinated, sickened. Fear grips me tighter than his spells, yet beneath the fear bubbles something else. Something terrible. Terrifying. Tempting.~

	= ~He tells me not to worry. That he'll make sure I survive the process. The words shriek within my thoughts, triggering an avalanche of haunted experiences, of memories of what was, what is to come. Of hatred and unbridled rage. A crimson mist shrouds my vision, and I give myself to the overpowering influence surging from the depths of my soul.~
	= ~My limbs obey me once more, and like whips they clench upon his hands, push him off me. I'm getting off the slab, and as I do the wounds close, the flesh on my chest morphs and becomes... something else.~
	= ~My claws maintain an iron grip on his wrists as I spread my arms to the sides, slowly, as far as I can take them. In enraptured fury I watch the pain unfold as I tear him limb from limb.~
	= ~It is beautiful.~
   IF ~~ THEN GOTO TDrLast
END


IF WEIGHT #400 ~~ TDrLast
  SAY ~(Imoen seems slightly breathless. She closes her eyes, taking a moment to regain her composure.)~
	= ~S- sorry, I didn't mean to take it so far, I sounded like a psycho just now. So anyway... that's when I wake up, feeling like an evil goddess *and* complete crap at the same time.~
   IF ~~ THEN GOTO TDrLastN
END

IF ~~ THEN TDrLastN
   SAY ~It's a weird mix. I'd rather do without it.~
   ++ ~Did that really happen? Everything before the taint takes over, I mean.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1)~ + TDrReally
   ++ ~It's all a lie, Imoen. Though it might feel good at first, embracing the Taint inflicts its own brand of torture upon you.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",-1) IncrementGlobal("IRTFightTaint","GLOBAL",1)~ + TDr4
   ++ ~That didn't sound so unpleasant. Making use of the Taint would have saved you much grief.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1) IncrementGlobal("IRTControlTaint","GLOBAL",1)~ + TDr3
   ++ ~And yet you continue to reject our birthright? It's just baffling. You know it's pointless to resist, right?~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1) IncrementGlobal("IRTEmbraceTaint","GLOBAL",1)~ + TDr2
   ++ ~Thanks for sharing. At least they are just dreams. You'll be alright, Imoen.~ + TDr1
END

IF ~~ TDrReally
   SAY ~Y-yeah. Yeah, all that stuff happened, and worse. It's easy to gloss over the word "torture" and not think about the details.~
   = ~Not the happiest time in the world, our adventures in Amn...~
   ++ ~Imoen, I didn't know it was that horrible. You should have told me.~ + TDrR5
   + ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~(Bring Imoen into a hug.)~ + TDrR4Romanced
   + ~!Global("ImoenRomanceActive","GLOBAL",2)~ + ~(Bring Imoen into a hug.)~ + TDrR4Friend
   ++ ~That's rough. At least it's all over now.~ + TDrR3
   ++ ~I should have made them suffer more for what they did to you.~ + TDrR2
   ++ ~Are you sure you're alright, then? What you went through would scar anyone for years to come.~ + TDrR1
END

IF ~~ TDrR1
   SAY ~Well, obviously I'm never going to forget. And I get jittery in dark and closed places. And I might totally lose it if I ever get thrown in jail or a dungeon all by myself. But other than that... I manage.~
   ~I'm alright, <CHARNAME>. We've all got demons. (Her lips curve in a half-smile.) At least mine are dead.~
   IF ~~ THEN GOTO TDrTaint
END

IF ~~ TDrR2
   SAY ~(Imoen shrugs.) They're dead, and I'm still here. That's all that counts. (Her lips curve in a half-smile.) I appreciate the sentiment, though.~
   IF ~~ THEN GOTO TDrTaint
END

IF ~~ TDrR3
   SAY ~Yeah, true. (Imoen shrugs and gives you a half-smile.) Everyone's got demons, but at least mine are dead.~
   IF ~~ THEN GOTO TDrTaint
END

IF ~~ TDrR4Romanced
   SAY ~(Imoen gladly leans into you, squeezing you back. you feel her exhale a heavy sigh.)~
   = ~You're the best, <CHARNAME>. You always show me how much you care. I'm alright, really. (She pulls back, a half-smile curving her lips.) We've all got demons. At least mine are dead.~
   IF ~~ THEN GOTO TDrTaint
END

IF ~~ TDrR4Friend
   SAY ~(Though awkward and tense at first, Imoen soon relaxes in your arms, squeezing you back. You feel her exhale a heavy sigh.)~
   = ~You're such a good friend, <CHARNAME>. (She pulls back.) Thanks for that. I'm alright, really. We've all got demons. (Her lips curve in a half-smile.) At least mine are dead.~
   IF ~~ THEN GOTO TDrTaint
END

IF ~~ TDrR5
   SAY ~Aw, c'mon, I told you plenty. What's the point of reliving every detail? It's all done, it's over, and I'm still here. That's all that counts. (She gives you a half-smile.) We've all got demons, but at least mine are dead.~
   IF ~~ THEN GOTO TDrTaint
END

IF ~~ TDrTaint
   SAY ~B'sides, they're not that big a deal compared with the literal devil whispering crazy stuff in my ear, even as I sleep.~
   ++ ~I'm sure you'll deal with it one way or another.~ + TDr0
   ++ ~Those whispers are all lies. Embracing the Taint inflicts its own brand of torture upon you.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",-1) IncrementGlobal("IRTFightTaint","GLOBAL",1)~ + TDr4
   ++ ~Perhaps you should listen on your own terms. Making use of the Taint would have saved you much grief.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1) IncrementGlobal("IRTControlTaint","GLOBAL",1)~ + TDr3
   ++ ~Your reluctance to accept our birthright baffles me. It's pointless to resist.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1) IncrementGlobal("IRTEmbraceTaint","GLOBAL",1)~ + TDr2
   ++ ~You'll be alright, Imoen. They're just dreams.~ + TDr1
END

IF ~~ TDr0
   SAY ~Yup. I'll probably murder everyone in their sleep, eventually. Like I said, no big deal.~
   = ~But hey, thanks for asking. It really does mean a lot to me that you care.~
   IF ~~ THEN EXIT
END
END