BEGIN ~MRYWin~
BEGIN ~MRJaenya~
BEGIN ~MRTarren~
BEGIN ~MRNevea~
BEGIN ~MRYIm~
BEGIN ~MRKiller~

// This is a talk with Solar about Imoen's past. It starts as an additional option right before Solar is about to show you yours.
// Fully implemented as far as I can tell

// There is a post-event talk at the end of this file that needs to be triggered
//After Yaga Shura

ADD_TRANS_TRIGGER SOLAR 20 ~OR(3) Global("ImoenRomanceActive","GLOBAL",0) !InParty("Imoen2") Dead("Imoen2")~ DO 0 1

EXTEND_BOTTOM SOLAR 20
IF ~!Global("ImoenRomanceActive","GLOBAL",0) InParty("Imoen2") !Dead("Imoen2")~  THEN REPLY ~Wait. If at all possible, I wish Imoen to be by my side for this.~ EXTERN Solar SolIm
END


APPEND SOLAR
IF ~~ THEN SolIm
  SAY ~This knowledge concerns only you, Spawn of Bhaal. No other shall benefit from it. What reason leads you to make this request?~
  ++ ~True. Forget I asked anything.~ + SI5
  + ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~Imoen is a vital part of myself. Only she understands what I'm going through. I want her to be present so I can share thoughts with her on the matter.~ + SI4
  ++ ~I want her to see all this so later I don't have to tell her about it.~ + SI3
  ++ ~Imoen is a Bhaalspawn. For all you know *she* could end up at the center of this prophecy. I want you to show her where she comes from, too.~ + SI2
  ++ ~I'm prone to forgetting things, but she'll remember every detail.~ +SI3
  ++ ~My reasons are my own, Solar. Do as I say.~ + SI1
END

IF ~~ THEN SI1
  SAY ~Your demands hold no power over one such as I, <CHARNAME> - at least for now. I am but a messenger, a link between you and the knowledge that you require to face what is to come. I answer to the greater purpose of your guidance.~
  IF ~~ THEN GOTO SolIm2
END

IF ~~ THEN SI2
  SAY ~Perhaps this may be so, god-child. It lies beyond my power to foretell the conclusion of your tale. It could be your half-sister who, in the end, shall rise to fulfil the prophecy. Only fate itself knows.~
  IF ~~ THEN GOTO SolIm2
END

IF ~~ THEN SI3
  SAY ~A pragmatic standpoint, to be sure.~
  IF ~~ THEN GOTO SolIm2
END

IF ~~ THEN SI4
  SAY ~(The Solar simply nods in acknowledgement.)~
  IF ~~ THEN GOTO SolIm2
END

IF ~~ THEN SI5
  SAY ~(The Solar simply nods in acknowledgement.)~
  IF ~~ THEN GOTO 22
END

IF ~~ THEN SolIm2
  SAY ~Know that your motives are of no concern to me. I ask so that you may become aware of the true reasons behind your desires and actions. It is central to your education that you truly understand what your innermost ambitions are.~
  = ~Your will be done. (As the Solar finishes her sentence, you hear a muffled moan behind you.)~
  IF ~~ THEN DO ~SetGlobal("IRTSolarPast","GLOBAL",1) StartCutSceneMode() StartCutScene("IRSola01")~ EXIT

// Cutscene: Camera pans to Imoen, Imoen moans and approaches the PC, then starts dialogue

END
END



CHAIN IF WEIGHT #1 ~Global("IRTSolarPast","GLOBAL",1)~ THEN IMOEN25J SolIm3
	~<CHARNAME>? What the heck- oh. (Imoen eyes the Solar warily.) I... see.~ [IRQUIET] DO ~SetGlobal("IRTSolarPast","GLOBAL",2)~
	= ~Time for more divine intervention, huh? Kinda rude to knock us out like that...~
	== SOLAR ~You have been summoned, Child of Bhaal, at the request of <CHARNAME>. It is only by the grace of your divine blood that you are permitted to witness the truth to be revealed to <PRO_HIMHER>. Listen closely, and learn.~
END SOLAR 22

//we dont want this option appearing if mod is installed.
ADD_TRANS_TRIGGER SOLAR 29 ~!Global("IRTSolarPast","GLOBAL",2)~ DO 0

EXTEND_BOTTOM SOLAR 29
	IF ~Global("IRTSolarPast","GLOBAL",2)~ THEN REPLY ~Now, what about Imoen? Surely her past is of some relevance.~ EXTERN IMOEN25J SolIm5
	IF ~Global("IRTSolarPast","GLOBAL",2)~ THEN REPLY ~I ask you please now, do for Imoen what you have done for me. She deserves to know the truth.~ EXTERN IMOEN25J SolIm5
	IF ~Global("IRTSolarPast","GLOBAL",2)~ THEN REPLY ~(Remain silent, letting the Solar depart.)~ GOTO 30
END

CHAIN IMOEN25J SolIm5
	~Aw, n- no, there's really no need, I'm sure the Solar is way too busy with her own things to be diggin' up stuff like that. B'sides, it's the old "Bhaal-impregnates-mom-who-dies-after-birth" story, not much of a mystery there.~
	== SOLAR ~On the contrary, Spawn of Bhaal. The truth has been hidden from you in many ways, not unlike it has been for many others of your kind. Your circumstances, nonetheless, are peculiar even among those that share your divine heritage.~
	== IMOEN25J ~Huh?~
	== SOLAR ~Perhaps it is time for the truth to be revealed. And who better than your own genitor to tell such a story? Now is your turn to listen closely, Daughter of Bhaal, for many have died so that you may live.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",1) StartCutSceneMode() StartCutScene("IRSola02")~ EXIT

// Cutscene: Imoen's mother appears.


CHAIN IF WEIGHT #1 ~Global("IRTImoenPast","GLOBAL",1)~ THEN MRJaenya Past1
	~I greet you, Imoen, my daughter. I am Jaenya of Waterdeep, and I am a tailor by trade. Or I was, at least, until seven days before your birth.~
	= ~You do not remember me. Nor do you remember the manner in which we parted ways. It is my understanding that it would best remain this way.~
	== SOLAR ~You have been called upon to tell your story, spirit. You are not to care about the consequences. It is time for this one to know her origins.~
	== MRJaenya ~Unbeknownst to my husband, I bore the child of the Lord of Murder within me. I was but a simple tailor, how could I oppose the will of a god? The memories of that night would forever haunt my every dream thereafter.~
	= ~My beloved thought it was his offspring, at first. As time passed, however, the guilt and shame in my breast made him doubtful, suspicious. My soul was shattered by the lies I told, as my life had been shattered by Bhaal on the fateful night of your conception. He confronted me, questioning my faithfulness. I could not bear the look in his eyes any longer.~
	= ~I revealed the truth, among pleas and tears. He took me in his arms. He said that everything would be all right, and I believed him.~
	= ~Seven days before your birth, my daughter, they came. Bearing torches, shrouded in hatred and fear, they set my humble home aflame while I slept. My husband was with them, full of sorrow, tortured by the choice he had made.~
	= ~Before you judge, consider that this was the Time of Troubles. My husband was a pious man, doing what was right. What worth is the life of a mortal, when she carries Evil itself in her womb?~
	= ~Others thought differently, however.~ DO ~SetGlobal("IRTImoenPast","GLOBAL",2) StartCutSceneMode() StartCutScene("IRSola03")~ 
EXIT

// Cutscene: Young Winthrop appears, along with his two adventuring partners. One woman, two men in total. Nevea is a mage, Tarren is sword and shield warrior, Winthrop is dual wielding rogue.



CHAIN IF WEIGHT #1 ~Global("IRTImoenPast","GLOBAL",2)~ THEN MRNevea Past2
	~We knew what was about to take place, and we would not let it happen.~
	== MRYWin ~I was reluctant at first. But we were young, and adventurous, and some of us even righteous.~
	== MRTarren ~No matter how vile the Spawn would be, this innocent woman was not to blame. We would not stand by and let her be burned alive.~
	== MRNevea ~We made it inside the house before it was too late. With my magic we could escape through the cellar undetected.~
	== MRJaenya ~I followed the directions of the strangers in a sort of trance, as I heard the furious voices outside cheering at the blazing fire that was to consume me and my offspring.~
	== MRNevea ~We would travel North, to the outskirts of Kryptgarden Forest - a place to which surely no townsperson would follow. There we'd hide until the abomination was born. If the mother survived, we'd escort her to Neverwinter, where hopefully she could start anew with her trade.~
	== MRYWin ~We agreed on slaying the Bhaalspawn at birth. Surely it would be a hideous monster... we could only hope that the mother would not be harmed irreparably during labor. Even in her state, she showed the innate resilience and will to live that runs in your own blood.~
	== MRJaenya ~There you were born, my child, among high trees and before three young adventurers that did what they could to assist you into the world. A beautiful baby human girl, rosy, healthy - everything I'd ever hoped my child would be like. You had such powerful lungs, we were worried the entire forest would come to devour us.~
	== MRTarren ~We realized that this was no monster. We could not possibly end this new life.~
	== MRYWin ~What to do, then? You were now our responsibility, woman and child. Had we saved your lives only to leave you stranded?~
	== MRJaenya ~I had lost everything, and yet, looking at your tiny face... I could feel nothing but joy. You had become my life. Nothing would harm you as long as I lived... and this resolve was to be tested for the first time shortly after your birth.~
	== MRTarren ~Someone *had* followed us. It was no townsperson.~
	== MRNevea ~I stood watch the night that the Deathstalkers first made an attempt to take the Bhaalspawn girl. A shrouded figure fell upon me, and I would have been slain had I not been fast enough with my protective spells. The assassin was like a whirlwind, deadly and unpredictable.~
	== MRYWin ~We fought the stranger with all we had, but his skill broadly surpassed ours. We were just a group of barely experienced adventurers, while this man seemed fueled by death itself. We fended him off for a short while... he kicked me and knocked the air out of my lungs.~
	== MRTarren ~He struck me down in a swift blow to my unguarded flank.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",3) StartCutSceneMode() StartCutScene("IRSola04")~ EXIT

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",3)~ THEN MRNevea PATATA
	~Having exhausted my spells, his dagger pierced my robes, skin and flesh. It was a blow I would not survive.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",4) StartCutSceneMode() StartCutScene("IRSola05")~ EXIT

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",4)~ THEN MRYWin PATATA2
	~In a rage I managed to bury both my blades deep in his back. He still had the strength to stab my leg before falling.~
	== MRJaenya ~I hurried to attend to their wounds... but it was too late for Tarren and Nevea.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",5) StartCutSceneMode() StartCutScene("IRSola06")~ EXIT

// Cutscene: Camera pans to Tarren, Ghosts emerge from their bodies

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",5)~ THEN MRNevea PATATA3
	~I gave my life doing what I thought was right, and for that I am thankful.~
	== MRTarren ~So much left undone, so many things I could have done better. Still, I regret nothing.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",6) StartCutSceneMode() StartCutScene("IRSola07")~ EXIT

// Cutscene: Both disappear

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",6)~ THEN MRYWin PATATA4
	~They were good friends. I had known them for most of my life. My naive days of adventuring died with them.~
= ~That night my fate was permanently linked to yours. The followers of Bhaal would hunt his offspring to bring the Lord of Murder back, while Cyric's cultists would strive to stop this from happening. If this Deathstalker knew about you, surely more would come... and I'd be damned if you or your mother would come to any harm as long as I lived. My friends' deaths would not be in vain.~
	= ~We took to the road. We traveled, long and far... always looking behind our shoulders, never staying anywhere for long.~
	== MRJaenya ~It was a harsh life. I learned to use weapons to defend myself, even developed a deep love for magic. We avoided many encounters and fought through many others. As we traveled we met various friends that sympathized with our cause, Gorion among them.~
	= ~We also became... close. Very close.~
	== MRYWin ~Over time, I came to love you and your mother more than I could have ever imagined possible.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",7) StartCutSceneMode() StartCutScene("IRSola08")~ EXIT

// Cutscene: Jaenya and Winthrop teleport to be next to each other. Young Imoen appears.

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",7)~ THEN MRYWin PATATA5
	~Regardless of all the hardship and dangers we faced, they were the happiest seven years of my life.~
	== MRYIm ~Mom and dad were the best, though a bit smothering sometimes. They'd always be so worried about me.~
	== MRJaenya ~It was hard to raise a child in our constant travels. But you were strong, and smart, and restless and stubborn. You quickly realized that our lifestyle differed much from most.~
	== MRYIm ~That's right. So when I asked, mom and dad told me the truth.~
	== MRJaenya ~Of course we did, my sweet princess. Your dad and I were king and queen of a far off kingdom. We were forced into exile by your evil uncle and his supporters, who wanted the throne for themselves. They would forever hunt us so that we could never reclaim our kingdom. This is why it was very important that wherever we go, we keep our identity secret.~
	== MRYIm ~Mum would never lie to me. I was a princess!~
	== MRYWin ~We desperately hoped your heritage would never manifest, and you'd live a happy, long life. Perhaps, some day, we would be able to forget its existence.~
	== MRJaenya ~A shame, my child, that these dreams were to be truncated.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",8) StartCutSceneMode() StartCutScene("IRSola09")~ EXIT

// Cutscene: The deathstalker appears.

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",8)~ THEN MRKiller PATATA6
	~They eluded us constantly. They bested some of our most skilled members, a feat beyond the capabilities of many. No more.~
	== MRYWin ~We stopped in a small settlement in the northern reaches of Cormyr after months of quiet travels with no sign of ever being followed. So... we stayed. We made a simple life there, made friends. Though we remained cautious, we allowed ourselves a glimmer of hope.~
	== MRKiller ~I patiently watched, and waited. Waited for them to grow comfortable, to start forgetting.~
	== MRJaenya ~Two years later, we called the place home. We would sometimes not bother to take turns to sleep. I'd overlook some of my magic wards, or forget to keep a weapon at hand. I even let myself dream of more children with the man I loved.~
	== MRYIm ~I had friends, and an actual home! It was a bummer sometimes to always have mom or dad around, but I didn't really mind.~
	== MRYWin ~I let myself relax, forgo some of my training, drink a bit too much some nights. I'd forget to ready my armor every night, especially when work was too exhausting. In a way, I let go of the fear.~
	== MRKiller ~The moment to strike had come.~
	== MRJaenya ~It was a day of local festivities. We drank a little more harvest wine than we should have at the local faire, and didn't watch for signs of intrusion when getting back home. Winthrop opened the door, and the trap sprung.~
	== MRYWin ~There was a quiet click, and the needle pierced my skin. A shadow was cast from above as the poison took over. I tried to warn them, but I was already growing numb.~
	== MRJaenya ~From the rooftop the deathstalker plunged his blade into my shoulder, straight through to my heart.~
	== MRYWin ~She fell in front of me, eyes wide as she gasped for breath. Helplessly I watched her blood pool on the floor and touch my listless fingers.~
	== MRYIm ~Something lifted me into the air. I smelled something that made me wanna throw up, and then I felt like falling into a deep, dark pit, and continued falling and falling and falling...~
	== MRYWin ~He was gone in an instant. The pain faded to black.~
	== MRJaenya ~After all those years... we had failed.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",9) StartCutSceneMode() StartCutScene("IRSola10")~ EXIT

// Cutscene: Jaenya dies and Winthrop collapses, Gorion appears.

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",9)~ THEN d1gori PATATA7
	~The villagers found him at the brink of death. Their druid did all she could, but Jaenya was too far gone. With a heavy heart, I arrived soon after Winthrop regained consciousness.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",10) StartCutSceneMode() SmallWait(8) ActionOverride("MRYWin2",PlayDeadInterruptable(1)) Wait(2) ActionOverride("MRYWin2",StartDialogNoSet("MRYWin2"))~ EXIT

// Cutscene: Winthrop gets back up

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",10)~ THEN MRYWin PATATA7a
	~Gorion had warned us that this would eventually happen. He gave us the means to contact him should disaster strike. And that's exactly what I did.~
	== d1gori ~We knew this day would come. A few of my colleagues and I rode the winds of magic to his aid. We would hunt the girl down on one condition: no more traveling, no more fleeing. We would erase all traces of your existence and hide you in a secluded place, safe from harm.~
	== MRYWin ~We had been selfish to refuse this in the past. Maybe if we ran far enough, if we resisted long enough...~
	= ~How wrong we'd been.~
	== d1gori ~Deep within the Marsh of Tun, the servants of the dead Lord of Murder prepared for the ritual sacrifice. There is no telling what horrors you witnessed before our arrival. The enemy met our assault with sorceries and dark prayers - many of them fell, as did some very close friends of mine. The scene was all too familiar.~
	== MRYWin ~We made it to the altar, and saw you there, prostrate under a twisted blade ready to strike. The terror in your eyes... I will never forget. Gorion struck down the priest as I pried you away from Death's grip.~
	== d1gori ~We then made our escape, keeping the enemy at bay just long enough for me to transport us to safety.~
	== MRYWin ~You were in a state of shock. There were cuts and markings all over your skin, your face was stained with soot and blood. Nothing I did would shake you form it.~
	== d1gori ~You had seen too much... you knew too much. We erased our tracks, all of them, as we had done before. We made sure no-one would know of your whereabouts, of your very existence.~
	== MRYWin ~I said goodbye, knowing that you would be my daughter no more.~
	== d1gori ~In the safety of a secluded grove they cleansed your mind, healed it from all harm. The process was lengthy. You were barely conscious through it all.~
	== MRYWin ~For two years I waited. I worked at the Candlekeep inn while trying to become someone else entirely, fighting to let go of the past, to remove it from my memories as if it had never existed. I lost myself for some time, drowning my pain and shame in alcohol, neglecting the skills I had honed for so long...~
DO ~SetGlobal("IRTImoenPast","GLOBAL",11) StartCutSceneMode()  StartCutScene("IRSola12")~ EXIT

// Cutscene: Winthrop turns into a fat man

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",11)~ THEN MRYWin PATATA8
	~But at least you were finally safe. Perhaps I'd finally saved you from your heritage.~
	== d1gori ~You healed, eventually. In the process, every memory of the past was banished from your mind, to be replaced by the truth you've kept with you until now. The secret had to be absolute.~
	= ~And so I brought you with me to Candlekeep. The way events unfolded since then, you already know.~
DO ~SetGlobal("IRTImoenPast","GLOBAL",12) StartCutSceneMode() StartCutScene("IRSola11")~ EXIT

// Cutscene: Everyone disintegrates, camera pans to Solar.

CHAIN IF WEIGHT #-1 ~Global("IRTImoenPast","GLOBAL",12)~ THEN SOLAR PATATA9
	~Thus the past has been revealed to you, Spawn of Bhaal. Had you known the truth before now, would events have unfolded differently? Would you be the same person? Are you the same person at this moment, now that you are aware?~
	= ~Ponder these questions, Imoen. Perhaps in the answers you will find a part of yourself long forgotten. (The Solar turns to address both of you.)~
	DO ~SetGlobal("IRTImoenPast","GLOBAL",13) ActionOverride("Imoen2",SetDialog("IMOEN25J"))~
END SOLAR 30




// Post event talk
// Triggers just as the party returns to normal, some five to ten seconds after Melissan goes away


APPEND IMOEN25J
IF WEIGHT #0 ~Global("IRTPostPastTalk","GLOBAL",1)~ THEN PP
	SAY ~So... wow.~ [IRDusk]
	IF ~Global("IRTImoenPast","GLOBAL",13)~ THEN DO ~SetGlobal("IRTPostPastTalk","GLOBAL",2)~ GOTO PPImoen
	IF ~!Global("IRTImoenPast","GLOBAL",13)~ THEN DO ~SetGlobal("IRTPostPastTalk","GLOBAL",2)~ GOTO PPNoImoen
END

IF ~~ THEN PPImoen
	SAY ~Those stories about our past were nuts. What did you think about them?~
	++ ~I don't even know who I am anymore.~ + PPI0
	++ ~It was interesting, but it doesn't change anything, does it?~ + PPI1
	++ ~I don't believe one word.~ + PPI3
	++ ~Whoa, Winthrop used to have a waist? Who could've known...~ + PPI4
	++ ~Everyone sacrificed so much for our benefit. We have a big responsibility, Imoen.~ + PPI5
	++ ~What a waste of time! I couldn't wait for it to be over.~ + PPI6
END

IF ~~ THEN PPI0
	SAY ~Aw, jeez. Don't take it so hard. You were a baby, there's nothing you could've done, just like I had no choice in anything. There's no point wondering what coulda been.~
	= ~In fact, that's what was running through my mind toward the end. We are who we are and knowing how that came to be or what could've been different doesn't change a darn thing. Yer still <CHARNAME>, and I'm still Imoen, and Gorion raiding temples all willy-nilly or Sarevok showing up out of nowhere doesn't affect anything we do now. Right?~
	= ~You know I'm right.~
	++ ~How can you be so glib? We've ruined so many lives simply by existing!~ + PPI0a
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~I'm glad you were there with me. You always know what to say to make me feel better, love.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",2)~ + PPI0b
	+ ~!Global("ImoenRomanceActive","GLOBAL",2)~ + ~I'm glad you were there with me. You always know what to say to make me feel better.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",2)~ + PPI0c
	++ ~Yes, you're right. It doesn't matter, one way or another.~ + PPI0d
	++ ~I don't know. I'll keep thinking about it.~ + PPI0e
	++ ~We must carry on, regardless. Let's go.~ + PPI0f
END

IF ~~ THEN PPI0a
	SAY ~But we're not to blame, though! All we can do is work with what we've got. If you're so bent out of shape about it, let's go out there and try extra hard to help the people we find. That's all we can do, other than lie down and die.~
	= ~C'mon, let's get going. Dwellin' on it will only make it worse.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPI0b
	SAY ~Haha, ever so glad to be of service, <PRO_SIRMAAM>. (Imoen gives you a quick hug and a swift kiss.) C'mon, let's get going. Dwellin' on this stuff is utterly pointless.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPI0c
	SAY ~Haha, ever so glad to be of service, <PRO_SIRMAAM>. (Imoen winks at you.) C'mon, let's get going. Dwellin' on this stuff is utterly pointless.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPI0d
	SAY ~Thank you! I knew I was on to something. Now, that being said... the whole thing sure was weird, wasn't it? Our moms talking to us, Stuffy Mr. G going in and saving the day, pint-size Sarevok, ol' Puffguts wielding swords and whatnot...~
	= ~Gosh, it feels bad to call him Puffguts now - he gave up his whole life for me. He's... he's my dad, really. Makes me regret all of those pranks and shirked chores.~
	= ~If we survive, I'd love to go back and call him dad, just to see his reaction. It'll be great.~
	= ~Anyway, let's get going. Dwellin' on this stuff right now is utterly pointless.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPI0e
	SAY ~Alright, you do that. It was pretty heavy stuff, with our moms talking to us, Stuffy Mr. G going in and saving the day, pint-size Sarevok and ol' Puffguts wielding swords and whatnot...~
	= ~Gosh, it feels bad to call him Puffguts now. But anyway, we better get going. Dwellin' on this stuff doesn't get us anywhere.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPI0f
	SAY ~That's the spirit.~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN PPI1
	SAY ~Hm. No, I guess it doesn't. It was just weird, honestly, with our moms talking to us, stuffy Mr. G going around raiding temples and being a hero, and a pint-size Sarevok to top it off.~
	= ~It sure makes me feel bad for all the crap I put good ol' Puffguts through. He didn't deserve even half the pranks or shirked chores. Boy, it even feels wrong to call him Puffguts now - he gave up his whole life for me. He's... he's my dad, really. If only I'd known...~
	IF ~~ THEN GOTO PPIN
END
	
IF ~~ THEN PPI2
	SAY ~I know how you feel. It's surreal, isn't it? Our moms talking to us, and stuffy ol' Mr. G going around raiding temples and being a hero. Casts in a different light how he was so severe and overprotective with us all the time.~
	= ~I don't even wanna talk about pint-size Sarevok, and don't get me started on Puffguts. It even feels wrong to call him Puffguts now, he gave up his life for me. He's... he's my dad, really. If only I'd known...~
	IF ~~ THEN GOTO PPIN
END
	
IF ~~ THEN PPI3
	SAY ~Oh, really? I didn't even think about that. You truly believe the Solar is lying to us? Doesn't seem like the type...~
	++ ~It's all a conspiracy to get me to do what they want. Mark my words.~ + PPI3a
	++ ~The best deceivers are those that never tip their hand.~ + PPI3a
	++ ~No, you're right. I simply find it hard to trust anyone, with everything that's happened.~ + PPI3b
	++ ~Truth or not, it doesn't matter in the end. We are still the same, regardless of the distant past.~ + PPI3c
END

IF ~~ THEN PPI3a
	SAY ~Huh. Oh, you know what? We can't really confirm your story, but we sure could talk to Winthrop when all of this is over. If, uh... if we survive, that is. We'll get the truth then.~
	= ~Alright then, I won't even think much of it. I'll sure be looking at the Solar a bit more closely now.~
	= ~Back to the fight, I suppose.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPI3b
	SAY ~Boy, do I know that feeling. I find myself second-guessing every peasant we meet just in case they're looking to screw us over. Can't be a healthy attitude.~
	= ~Anyway, can't blame ya for not believing the whole story. It was surreal, with our moms talking to us, and stuffy Mr. G going around raiding temples and being a hero, and a pint-size Sarevok to top it off.~
	= ~It sure makes me feel bad for all the crap I put good ol' Puffguts through. He didn't deserve even half the pranks or shirked chores. It even feels wrong to call him Puffguts now - he gave up his whole life for me. He's... he's my dad, really. If only I'd known...~
	IF ~~ THEN GOTO PPIN
END

IF ~~ THEN PPI3c
	SAY ~Huh. Yeah, can't argue with that. It just makes me feel bad. Apparently ol' Puffguts didn't deserve even half the pranks or shirked chores I put him through.~
	= ~But like you said, it doesn't change who we are now. We couldn't have done a damn thing then. We would've been fine without the distraction, honestly.~
	= ~Back to the fight, I say. Let's worry about the past later, if we survive.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPI4
	SAY ~Hah, I know! It was just *weird*! And not just that, but also our moms talking to us, and stuffy Mr. G raiding temples and being a grand hero, and a pint-size Sarevok being all grumpy and adorable.~
	= ~They went through a lot to save us, though. Casts in a different light how severe and overprotective Gorion was. And ol' Puffguts... he'd look at me sometimes in this way I can't explain, when he thought I wasn't looking. Now I get it. I shouldn't have put him through so many pranks or shirked so many chores.~
	= ~Boy, it feels wrong to call him Puffguts now - he gave up his whole life for me. He's... he's my dad, really. If only I'd known...~
	IF ~~ THEN GOTO PPIN
END

IF ~~ THEN PPI5
	SAY ~Aw, gee, as if the burden wasn't heavy enough. You have a whole prophecy riding on yer shoulders, on top of dealing with the Five Clowns and their armies. You don't need to add the lives of people we never even knew. They made their choices, and there's nothing we could've done to change them.~
	= ~Don't get me wrong, I'm grateful an' all, but I don't feel guilty or responsible about what we just saw. Mostly I feel... weird. I mean, our moms talking to us, Stuffy Mr. G raiding temples and being a grand hero, pint-size Sarevok being all grumpy and adorable, ol' Puffguts wielding swords and wearing tight-fitting armor... the whole thing was surreal. If it had been just me, I'd have thought I was dreaming.~
	= ~Boy, it feels wrong to call him Puffguts now - he gave up his whole life for me. He's... he's my dad, really. If only I'd known...~
	IF ~~ THEN GOTO PPIN
END
	
IF ~~ THEN PPI6
	SAY ~Aw, c'mon, it wasn't that bad. We got to see our moms! That's gotta be worth something.~
	= ~I do wonder about the timing though. Did we really need a distraction on top of everything that's happening around us? I'm a bit confused about the Solar's teaching methods...~
	= ~Anyway, let's not waste any more time and get back to what matters.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPIN
	SAY ~Anyway, considering everything we're going through right now... probably we should concentrate on staying alive. We can go soul-searching later.~
	= ~Heh-heh, soul-searching. Get it? I crack myself up.~
	++ ~Comedy gold, Imoen. You're right, let's get on with our business.~ + PPIN1	
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~I'm glad things worked out the way they did. I can't imagine life without you.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",3)~ + PPIN2
	+ ~!Global("ImoenRomanceActive","GLOBAL",2)~ + ~I'm glad things worked out the way they did. I couldn't get through all this without you.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",3)~ + PPIN3
	++ ~I expected you to be more rattled. They tampered with your mind, doesn't it bother you?~ + PPIN4
	++ ~Honestly I'm just waiting for you to shut up so we can start looting all these corpses.~ + PPIN5
END

IF ~~ THEN PPIN1
	SAY ~I have so much material, you've no idea...~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPIN2
	SAY ~(Imoen smiles broadly.) You smooth talker. That's the nicest thing you coulda said. (She comes closer, takes your face in her hands and pours her heart into a gentle kiss.)~
	= ~(She lingers next to you in a loose embrace.) I wonder about that sometimes, y'know - pretty sure I've told you before. If you weren't there for me... I don't know. It's an alien thought. Literally can't imagine growing up without you.~
	= ~I'd probably have died right over there. (Imoen tilts her chin toward Saradush.) Or got chased down by Sarevok, or any other power-hungry Bhaalspawn. Who knows.~
	= ~Anyway, we better get on with doing terrible Bhaalspawn things before I get too sentimental.~
	= ~I love you, <CHARNAME>.~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN PPIN3
	SAY ~(Imoen smiles broadly.) That's the nicest thing you coulda said to me. (Her cheeks are flush with color.) It means the world to hear that.~
	= ~I know for a fact it's not true, though. You're the toughest <PRO_RACE> in Faerun, bar none. There's not even a contest. You'd have found a way, no matter what.~
	= ~Still, thanks a lot for saying it. (Imoen gives you a quick hug and a peck to the cheek, squeezing your forearm with appreciation.)~
	= ~We better get on with doing terrible Bhaalspawn things before I get too sentimental...~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPIN4
	SAY ~Eh. (She shrugs one shoulder.) It... *kinda* does? Sounds like I was beyond messed up at the time. They didn't seem to have much of a choice.~	
	= ~I guess after getting the Jon Irenicus treatment and going crazy for a while, a little bit of for-her-own-good amnesia isn't that big a deal.~
	= ~You could say it's a... forgettable offense. Eh-heh-heh.~
	++ ~You are such a dork. Let's get on with our business.~ + PPIN1	
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~I'm glad things worked out the way they did. I can't imagine life without you.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",3)~ + PPIN2
	+ ~!Global("ImoenRomanceActive","GLOBAL",2)~ + ~I'm glad things worked out the way they did. I couldn't get through all this without you.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",3)~ + PPIN3
	++ ~Enough about that then. I've been itching to loot all the items Yaga-Shura and his army no longer need.~ + PPIN5
END
	
IF ~~ THEN PPIN5
	SAY ~Pff. Knock yourself out, all yours. Seems like half my life is spent rifling through dead people's belongings.~
	= ~ hope you have fun cramming platemail into bags of holding...~
	IF ~~ THEN EXIT
END


IF ~~ THEN PPNoImoen
	SAY ~That story about your past was nuts. How do ya feel about it?~
	++ ~I don't even know who I am anymore.~ + PPNI1
	++ ~It was interesting, but it doesn't change anything, does it?~ + PPNI2
	++ ~It was illuminating. So much of my life is cast under a different light now.~ + PPNI3
	++ ~Sarevok sure was an ugly kid!~ + PPNI4
	++ ~It was a waste of my time.~ + PPNI5
END

IF ~~ THEN PPNI1
	SAY ~Aw, jeez. Don't take it so hard. You were a baby, there's nothing you could've done. If you ask me, there's no point wondering what coulda been. In fact, that's what was running through my mind toward the end.~
	IF ~~ THEN GOTO PPNIEnd
END

IF ~~ THEN PPNIEnd
	SAY ~We are who we are and knowing how that came to be or what could've been different doesn't change a darn thing. Yer still <CHARNAME>, and I'm still Imoen, and Gorion raiding temples all willy-nilly or pint-size Sarevok showing up out of nowhere doesn't affect anything we do now. Things could've been different if this or that had gone differently... big whoop, right?~
	= ~You know I'm right.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPNI2
	SAY ~No, it sure doesn't! I'm glad you feel that way. In fact, that's exactly what was running through my mind toward the end.~
	IF ~~ THEN GOTO PPNIEnd
END

IF ~~ THEN PPNI3
	SAY ~Really? Huh. I'm not in your shoes or anything, so of course I can't tell you how to feel, but... I dunno, it didn't make a darn difference to me.~
	= ~Alright, so you were a baby and there was this evil temple and Sarevok coulda been saved instead of you. Does it really matter? Our upbringing was little more than happenstance, well - big whoop! You can make the same argument with nearly anything. Sarevok could've been killed outright and then our lives would be hugely different. Gorion could've taken an arrow to the face and then we wouldn't have lived. Irenicus could have gone after different Bhaalspawn and then we'd never even have heard of him. You see where I'm going with this?~
	= ~What happened is what happened, and what could've been is irrelevant. Interesting to think about, for sure, but... it doesn't matter in the end. Right?~
	= ~You know I'm right. You've got too many things to worry about already, don't let this slow you down one bit, is what I'm saying.~
	IF ~~ THEN EXIT
END

IF ~~ THEN PPNI4
	SAY ~Pfha-hah-hah! That was my first thought too! Oh Gods, we're terrible.~
	= ~Glad yer taking it lightly, though. I dunno about you, but I was left pretty cold by the whole thing.~
	IF ~~ THEN GOTO PPNIEnd
END

IF ~~ THEN PPNI5
	SAY ~Y'know, I pretty much feel the same way. In fact, that's what was running through my mind toward the end.~
	IF ~~ THEN GOTO PPNIEnd
END
END

