
//No. 1: 30,000 gold
APPEND BIMOEN2
	IF ~Global("MRMoneyTalk","LOCALS",0)
	InPartySlot(LastTalkedToBy,0)
	    GlobalGT("Chapter","GLOBAL",%bg2_chapter_3%)
		!StateCheck(Player1,CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		InParty("Imoen2")
		See(Player1)
		!ActuallyInCombat()~ THEN BEGIN MR1MoneyTalk
		SAY ~Wow, <CHARNAME>. I've been counting a little here...~
		IF ~~ THEN DO ~SetGlobal("MRMoneyTalk","LOCALS",1) ~ GOTO MR1MoneyTalkMain
	END

	IF ~~ THEN BEGIN MR1MoneyTalkMain
		SAY ~We're rich! We have over thirty thousand gold pieces! No wonder you were so carefree with your spending while trying to get to Spellhold.~
		=
		~Gosh, this is a fortune. We might turn into snobs if we aren't careful enough. (She chuckles.)~
		++ ~Imoen, there was no need to count. I know perfectly well how much we have. Just ask me next time.~ GOTO MR1MoneyTalkLaw
		++ ~Actually, at the time, it really was a huge amount of money.~ GOTO MR1MoneyTalkN1
		++ ~That's my money! MINE! Don't ever touch my money again!~ GOTO MR1MoneyTalkChaos
		++ ~Adventuring can be very lucrative. I guess that's why people keep getting waylaid on the road for a few dirty coins.~ GOTO MR1MoneyTalkGood
		IF ~PartyHasItem("WA2ROBE")
		!HasItemEquiped("WA2ROBE","Imoen2")~ THEN REPLY ~That's more or less the price of the Robe of Vecna we have, Imoen.~ GOTO MR1MoneyTalkVecna1
		IF ~HasItemEquiped("WA2ROBE","Imoen2")~ THEN REPLY ~That's more or less the price of the Robe of Vecna you're wearing, Imoen.~ GOTO MR1MoneyTalkVecna2
		++ ~A fortune? I'm just getting started. Soon I'll own this country. I'll own the whole world!~ GOTO MR1MoneyGroup
	END


	IF ~~ THEN BEGIN MR1MoneyTalkLaw
		SAY ~And miss the opportunity to count all that money by myself? Hah, not a chance!~
		++ ~That ambition of yours... I guess that's why people keep getting mugged for a few dirty coins.~ GOTO MR1MoneyTalkGood
		IF ~PartyHasItem("WA2ROBE")
			!HasItemEquiped("WA2ROBE","Imoen2")~ THEN REPLY ~That's more or less the price of the Robe of Vecna we have, Imoen.~ GOTO MR1MoneyTalkVecna1
		IF ~HasItemEquiped("WA2ROBE","Imoen2")~ THEN REPLY ~That's more or less the price of the Robe of Vecna you're wearing, Imoen.~ GOTO MR1MoneyTalkVecna2
		++ ~Well, it's my money, so don't touch it again! Ever!~ GOTO MR1MoneyTalkChaos
	END

	IF ~~ THEN BEGIN MR1MoneyTalkN1
		SAY ~Yeah, tell me about it! Heh, remember when we left Candlekeep? A hundred gold pieces was a *fortune*!~ 
		IF ~~ THEN GOTO MR1MoneyGroup
	END


	IF ~~ THEN BEGIN MR1MoneyTalkChaos
		SAY ~Hah! You nutty tart, you. Sure, don't worry, I won't be touching it again.~
		= ~You're a bit loopy, you know that? Not that I mind it, really.~
		IF ~~ THEN GOTO MR1MoneyGroup
	END

	IF ~~ THEN BEGIN MR1MoneyTalkGood
		SAY ~Hah, 'dirty coins'... I'm sure if it wasn't for coins like this we'd be using wooden clubs and butter knives!~ 
		IF ~~ THEN GOTO MR1MoneyGroup
	END

	IF ~~ THEN BEGIN MR1MoneyTalkVecna2
		SAY ~No way! Really? Wow, we have equipment that's worth a castle all of our own!~
		= ~Guess I'll have to be more careful with it, huh? Look, it has a little stain already. I'll have it clean in no time.~
		IF ~~ THEN GOTO MR1MoneyGroup
	END

	IF ~~ BEGIN MR1MoneyTalkVecna1
		SAY ~No way! Really? Wow, we have equipment that's worth a castle all of our own!~
		= ~But how come I'm not wearing it?! I'm the one that deserves it the most! I'm gonna be an archmage soon, so I need proper equipment.~
		IF ~HasItemEquiped("WA2ROBE",Player1)~ THEN GOTO MR1MoneyTalkVecna1P1
		IF ~!HasItemEquiped("WA2ROBE",Player1)~ THEN GOTO MR1MoneyTalkVecna1O1
	END

	IF ~~ THEN BEGIN MR1MoneyTalkVecna1P1
		SAY ~No fair! You always keep the best stuff for yourself!~
		++ ~I think it's best, for the good of the group.~ + MR1MoneyGroup
		++ ~Well, I *am* the leader, Imoen.~+ MR1MoneyGroup
		IF ~Gender(Player1,MALE)~ THEN REPLY ~I just like how it fits me. I look fabulous!~ GOTO MR1MoneyTalkSwishyM
		IF ~Gender(Player1,FEMALE)~ THEN REPLY ~I just like how it fits me. I look fabulous!~ GOTO MR1MoneyTalkSwishyF
		++ ~To the strongest go the spoils. I'm the most powerful, and I plan on keeping it that way.~ GOTO MR1MoneyGroup
	END

	IF ~~ THEN BEGIN MR1MoneyGroup
		SAY ~Hmph...~
		IF ~~ THEN GOTO MR1MoneyTalk2Serious
		
	END
	IF ~~ THEN BEGIN MR1MoneyTalkSwishyF
		SAY ~ It'd still look better on me. You look dumb in a dress.~
		IF ~~ THEN GOTO MR1MoneyGroup
	END

	IF ~~ THEN BEGIN MR1MoneyTalkSwishyM
		SAY ~Riiiight. Sure you do, Mister Swishy.~
		= ~But you know who'd look even more fabulous in it? Me!~ 
		IF ~~ THEN GOTO MR1MoneyGroup
	END

	IF ~~ THEN BEGIN MR1MoneyTalkVecna1O1
		SAY ~(She looks at the person who is wearing it) No offense intended an' all.~
		IF ~!HasItemEquiped("WA2ROBE","Nalia") !HasItemEquiped("WA2ROBE","Aerie") !HasItemEquiped("WA2ROBE","Jan") !HasItemEquiped("WA2ROBE","Edwin")~ GOTO MR1MoneyTalkVecna1Noone
		IF ~HasItemEquiped("WA2ROBE","Nalia") IsValidForPartyDialog("Nalia")~THEN EXTERN BNALIA MR1MoneyTalkVecna1Nalia
		IF ~HasItemEquiped("WA2ROBE","Aerie") IsValidForPartyDialog("Aerie")~THEN EXTERN BAERIE MR1MoneyTalkVecna1Aerie
		IF ~HasItemEquiped("WA2ROBE","Jan") IsValidForPartyDialog("Jan")~THEN EXTERN BJAN MR1MoneyTalkVecna1Jan
		IF ~HasItemEquiped("WA2ROBE","Edwin") IsValidForPartyDialog("Edwin")~THEN EXTERN BEDWIN MR1MoneyTalkVecna1Edwin
	END

END

CHAIN BNALIA MR1MoneyTalkVecna1Nalia
~None taken, Imoen.~
END BIMOEN2 MR1MoneyTalk2Serious

CHAIN BAERIE MR1MoneyTalkVecna1Aerie
~I was... I was just told to wear it. I didn't ask for it.~
END BIMOEN2 MR1MoneyTalk2Serious

CHAIN BJAN MR1MoneyTalkVecna1Jan
~I could never be offended by you, Immy!~
END BIMOEN2 MR1MoneyTalk2Serious

CHAIN BEDWIN MR1MoneyTalkVecna1Edwin
~You are beneath my notice, simpleton. (As if I could be offended by an upstart hedge-mage like her!)~
END BIMOEN2 MR1MoneyTalk2Serious

APPEND BIMOEN2
	IF ~~ THEN BEGIN MR1MoneyTalkVecna1Noone
		SAY ~Oh well...~
		IF ~~ THEN GOTO MR1MoneyTalk2Serious
	END

	IF ~~ THEN BEGIN MR1MoneyTalk2Serious
		SAY ~But seriously, isn't this too much money just for us?~
		= ~I don't have a problem with being rich, mind you, but, well... I can't help feeling a little guilty.~
		++ ~ We need this money, Imoen, not only for equipment but also for emergencies. What if we need to bribe someone powerful or something like that?~ GOTO MR1MoneyTalkSeriousBribe
		++ ~Well, I always try to give a few coins to the beggars whenever I can.~ GOTO MR1MoneyTalkSeriousBeg
		++ ~Me too, but I tell that feeling to shut up with a brand new magic ring now and then.~ GOTO MR1MoneyTalkSeriousEvil
		++ ~Hmm, maybe you're right.~ GOTO MR1MoneyTalkSeriousN1
		++ ~*You*, maybe. Not me, that's for sure.~ GOTO MR1MoneyTalkSeriousEvil
	END

	IF~~THEN BEGIN MR1MoneyTalkSeriousEvil
		SAY ~(She rolls her eyes) Alright, I get the idea. But just think of all the lives that would be improved with only a tenth of what we have!~
		IF ~InParty("Nalia")~ THEN GOTO MR1MoneyTalkSeriousNalia
		IF ~!InParty("Nalia")~ THEN GOTO MR1MoneyTalkSeriousEvil2
	END

	IF ~~ THEN BEGIN MR1MoneyTalkSeriousNalia
		SAY ~Oohh, I'm starting to sound like Nalia.~
		IF ~~ THEN GOTO MR1MoneyTalkSeriousEvil2
	END

	IF ~~ THEN BEGIN MR1MoneyTalkSeriousEvil2
		SAY ~But I guess we *do* need it, after all.~
	END

	IF ~~ THEN BEGIN MR1MoneyTalkSeriousN1
		SAY ~Yeah, think of all the lives that would be improved forever with only a tenth of what we have!~
		IF ~InParty("Nalia")~ GOTO MR1MoneyTalkSeriousNalia
		IF ~!InParty("Nalia")~ GOTO MR1MoneyTalkSeriousEvil2
	END


	IF ~~ THEN BEGIN MR1MoneyTalkSeriousBeg
		SAY ~Yeah, but I find that's not really enough. Think of all the lives that would be improved forever with only a tenth of what we have!~
		IF ~InParty("Nalia")~ GOTO MR1MoneyTalkSeriousNalia
		IF ~!InParty("Nalia")~ GOTO MR1MoneyTalkSeriousBribe
	END
		
	IF ~~ THEN BEGIN MR1MoneyTalkSeriousBribe
		SAY ~You've got a point there, but I just can't help but think of all the lives that would be better off forever with only a tenth of what we have!~
		IF ~InParty("Nalia")~ GOTO MR1MoneyTalkSeriousNalia
		IF ~!InParty("Nalia")~ GOTO MR1MoneyTalkSeriousEvil2
	END
	
//No. 2: 60,000 gold

	IF WEIGHT #518
		~Global("MRMoneyTalk","LOCALS",0)
		GlobalGT("Chapter","GLOBAL",%bg2_chapter_3%)
		InPartySlot(LastTalkedToBy,0) 
		!StateCheck(Player1,CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		InParty("Imoen2")
		See(Player1)
		!ActuallyInCombat()~ THEN BEGIN MR2MoneyTalk
		SAY ~Hey,what's this in my pocket?~
		IF ~~ THEN DO ~SetGlobal("MRMoneyTalk","LOCALS",1)~ GOTO MR2MoneyTalkMain
	END
		
	IF ~~ THEN BEGIN MR2MoneyTalkMain
		SAY ~A gold piece! <CHARNAME>, another one for the collection!~
		=
		~And hey, what's this little thing in this bag? Another gold piece!~
		=
		~And this in my backpack? Wait, wait, lemme guess... a GOLD PIECE! And it's with many, many others!~
		++ ~And all *carefully* organized, so please put them back before you drop something!~ GOTO MR2MoneyTalkLaw
		++ ~Alright, what's gotten into you now?~ GOTO MR2MoneyTalkN1
		++ ~They get lonely by themselves, you know. The more the merrier!~ GOTO MR2MoneyTalkChaos
		++ ~Heh, yeah, there *are* a lot of them around here...~ GOTO MR2MoneyTalkGood
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~And you're telling me this because...? Do you not like the riches of nations in your hands?~ GOTO MR2MoneyTalkEvil1
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~And you're telling me this because...? Do you not like the riches of nations in your hands?~ GOTO MR2MoneyTalkEvil2
	END
		

	IF ~~ THEN BEGIN MR2MoneyTalkLaw
		SAY ~Oh, c'mon, I know how to handle gold. Don't forget I used to be the best thief in all Faerun!~
		=
		~'Sides, what kind of stuffy old bore organizes their gold pieces, of all things?~
		++ ~Alright, so I'm boring. What's your point?~ GOTO MR2MoneyTalkN1
		++ ~They get lonely by themselves, you know. The more the merrier!~ GOTO MR2MoneyTalkChaos
		++ ~Well, there *are* a lot of them around here...~ GOTO MR2MoneyTalkGood
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~And? Do you not like the riches of nations in your hands?~ GOTO MR2MoneyTalkEvil1
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~And? Do you not like the riches of nations in your hands?~ GOTO MR2MoneyTalkEvil2

	END

	IF ~~ THEN BEGIN MR2MoneyTalkN1
		SAY ~We have *so* much money. We could forget about everything and retire to a life of luxuries!~
		=
		~Hmm, guess our souls would have something to say to that, but anyway...~
		IF ~~ THEN GOTO MR2MoneyTalkCont
	END

	IF ~~ THEN BEGIN MR2MoneyTalkGood
		SAY ~Right you are! Around sixty thousand gold pieces. That's a whole load of cash!~
		IF ~~ THEN GOTO MR2MoneyTalkN1
	END

	IF ~~ THEN BEGIN MR2MoneyTalkChaos
		SAY ~Hah! You goon. I betcha sing them lullabies at night, too, to help them get to sleep.~
		IF ~~ REPLY ~Of course! And wash them, and polish them, and give them crumbs for breakfast...~ GOTO MR2MoneyTalkChaos2
		IF ~Class(Player1,BARD)~ REPLY ~Well, I *would*, if my singing weren't so bad.~ GOTO MR2MoneyTalkBard
		IF ~!Class(Player1,BARD)~ REPLY ~Well, I *would*, if my singing weren't so bad.~ GOTO MR2MoneyTalkNotBard
		IF ~~ REPLY ~What can I say? I love gold!~ GOTO MR2MoneyTalkChaos2
	END

	IF ~~ THEN BEGIN MR2MoneyTalkBard
		SAY ~Bad? <CHARNAME>, you are one of the most famous bards in Faerun! Don't pull that false modesty stuff on me... you're a great singer, and you know it.~
		IF ~~ GOTO MR2MoneyTalkCont
	END

	IF ~~ THEN BEGIN MR2MoneyTalkNotBard
		SAY ~Eh, don't remind me. I've heard gibberlings that carry a tune better than you.~
		= ~*Way* better.~
		IF ~~ GOTO MR2MoneyTalkCont
	END

	IF ~~ THEN BEGIN MR2MoneyTalkChaos2
		SAY ~Yeah, yeah, I can see it now: Billionaire Bhaalspawn. Literally swimming in money!~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MR2MoneyTalkEvil1
		SAY ~Uh... no? I mean, c'mon, no one *needs* this much money!~
		IF ~CheckStatGT(Player1,16,CHR)~ THEN REPLY ~It's not about *needing*, Imoen. It's about wanting, about having. We've earned this, every piece of it, with blood, sweat, and tears. And we deserve to enjoy the fruits of our struggles however we desire.~ GOTO MR2MoneyTalkEvil3
		IF ~CheckStatGT(Player1,12,CHR) CheckStatLT(Player1,16,CHR)~ THEN REPLY ~What a king needs is different from what a peasant needs. What we - heroes and demi-gods - need, is different than the common man. Can you really say we don't need it?~ GOTO MR2MoneyTalkEvil3
		IF ~CheckStatLT(Player1,12,CHR)~ THEN REPLY ~Who said anything about needing it? It's our money, we can use it for whatever we want.~ GOTO MR2MoneyTalkCont
		++ ~Look, if you don't want it, just give it to me. Then everyone's happy.~ GOTO MR2MoneyTalkEvil4
		++ ~Stop complaining and start walking. We've got work to do.~ GOTO MR2MoneyTalkEvil4
	END

	IF ~~ THEN BEGIN MR2MoneyTalkEvil2
		SAY ~Well... it's tempting, I'll admit. But no one *needs* this much money!~
		IF ~CheckStatGT(Player1,16,CHR)~ THEN REPLY ~It's not about *needing*, Imoen. It's about wanting, about having. We've earned this, every piece of it, with blood, sweat, and tears. And we deserve to enjoy the fruits of our struggles however we desire.~ GOTO MR2MoneyTalkEvil3
		IF ~CheckStatGT(Player1,12,CHR) CheckStatLT(Player1,16,CHR)~ THEN REPLY ~What a king needs is different from what a peasant needs. What we - heroes and demi-gods - need, is different than the common man. Can you really say we don't need it?~ GOTO MR2MoneyTalkEvil3
		IF ~CheckStatLT(Player1,12,CHR)~ THEN REPLY ~Who said anything about needing it? It's our money, we can use it for whatever we want.~ GOTO MR2MoneyTalkCont
		++ ~Look, if you don't want it, just give it to me. Then everyone's happy.~ GOTO MR2MoneyTalkEvil4
		++ ~Stop complaining and start walking. We've got work to do.~ GOTO MR2MoneyTalkEvil4
	END

	IF ~~ THEN BEGIN MR2MoneyTalkEvil3
		SAY ~Huh. Well, I guess I can see that.~
		=
		~We *have* been through a lot... and we aren't exactly ordinary people with ordinary lives.~ 
		IF ~~ THEN GOTO MR2MoneyTalkCont
	END

	IF ~~ THEN BEGIN MR2MoneyTalkEvil4
		SAY ~Geez. Sorry I got in the way of your ego, Your Greediness.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MR2MoneyTalkCont
		SAY ~Y'know what'd be fun, though? Burning through some of this money and throwing a huge party!~
		++ ~Uhh... I don't think that'd be very appropriate, y'know?~ GOTO MR2MoneyTalkParty1
		++ ~Don't you remember what we're up against? We don't have time for parties!~ GOTO MR2MoneyTalkParty1
		++ ~Now you're talking! You grab the ale, I'll get the wenches! ~ GOTO MR2MoneyTalkParty2
		++ ~Hmm, well, I don't know...~ GOTO MR2MoneyTalkParty2
	END

	IF ~~ THEN BEGIN MR2MoneyTalkParty1
		SAY ~I *know* that, you moron! I was just kiddin', sheesh!~
		IF ~~ THEN GOTO MRMoneyTalkCont2
	END

	IF ~~ THEN BEGIN MR2MoneyTalkParty2
		SAY ~Hahah, don't trouble yourself, I was only kiddin'!~
		IF ~~ THEN GOTO MRMoneyTalkCont2
	END

	IF ~~ THEN BEGIN MRMoneyTalkCont2
		SAY ~I hope you buy me something *nice* with all that money though. It's useless if you don't spend it. You know that, right?~
		++ ~(Slap your forehead and roll your eyes) Really? I though it was just supposed to be shiny.~ GOTO MR2MoneyTalkNeg
		IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~(Thoughts of Imoen clad in a tight-fitting, extremely low-cut leopard fur bodice spring to mind) Heh, what if I buy you...~ GOTO MR2MoneyTalkSexy
		++ ~Buy you something? Buy *me* something, you mean!~ GOTO MR2MoneyTalkGreedy
		++ ~Actually, I enjoy having a lot of money.~ GOTO MR2MoneyTalkGreedy
		++ ~Look, Imoen, now's not really a good time.~GOTO MR2MoneyTalkNeg
	END

	IF ~~ THEN BEGIN MR2MoneyTalkSexy
		SAY ~(You tell her about the 'outfit' you have in mind and what you plan to do to her while she is wearing it. Her eyes open wider and wider, but she can't help a mischievous giggle.)~
		=
		~(She slaps you on your arm, pretending to be upset) Now that's *nasty*, <CHARNAME>! You're such a pervert!~
		=
		~(However the smile and wink she throws at you afterwards makes you think that she actually liked the idea...)~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MR2MoneyTalkNeg
		SAY ~(Imoen simply sticks her tongue out to you.)~
		=
		~Fine, be that way.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MR2MoneyTalkGreedy
		SAY ~Aww, c'mon! Nothing for me? Not even something small? Like, I dunno, a little villa on the Sword Coast? My own private butler? Pleeeeease?~
		++ ~Hmm... Well, you *might* be able to convince me.~ GOTO MR2MoneyTalkEnd
		IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~(Thoughts of Imoen clad in a tight-fitting, extremely low-cut leopard fur bodice spring to mind) Heh, what if I buy you...~ GOTO MR2MoneyTalkSexy
		++ ~Look, Imoen, now's not really a good time.~GOTO MR2MoneyTalkNeg
		++ ~I said no! No villas, no butlers! NO!~ GOTO MR2MoneyTalkNeg
	END

	IF ~~ THEN BEGIN MR2MoneyTalkEnd
		SAY ~(She claps her hands happilly, literally bouncing in excitement) Whoohoo! Now, where was that list I made...?~
		IF ~~ THEN EXIT
	END

	//No. 3: 100,000 gold

	IF WEIGHT #519
	~Global("MRMoneyTalk","LOCALS",0)
	InPartySlot(LastTalkedToBy,0)
	GlobalGT("Chapter","GLOBAL",%bg2_chapter_3%)
	!StateCheck(Player1,CD_STATE_NOTVALID)
 !StateCheck(Myself,CD_STATE_NOTVALID)
	InParty("Imoen2")
	See(Player1)
	!ActuallyInCombat()~ THEN BEGIN MR3MoneyTalk
		SAY ~Wow!~
		IF ~~ THEN DO ~SetGlobal("MRMoneyTalk","LOCALS",1) ActionOverride(Player1,SetDialog("Player1"))~ GOTO MR3MoneyTalk2
	END
	
	IF ~~ THEN BEGIN MR3MoneyTalk2
	SAY ~Now that's too much!~
	IF ~~ THEN EXTERN PLAYER1 MR3MoneyTalkSide 
	END
END

APPEND PLAYER1
	IF ~~ THEN BEGIN MR3MoneyTalkSide
		SAY ~(You hear the sound of some coins falling to the ground.)~
		=
		~(Looking back, you see coins scattered all around Imoen. She holds a torn bag in her right hand.)~
		IF ~~ THEN EXTERN BIMOEN2 MR3MoneyTalkMain
	END
END

APPEND BIMOEN2
	IF ~~ THEN BEGIN MR3MoneyTalkMain
		SAY ~My gold bag actually *burst*! The dream of every nobleman, come true!~
		=
		~And that's not all; there are *so* many coins in my backpack that I can barely put in the other things I really need!~
		=
		~Y'know, I'm tired of this. We've come to a point where gold only weighs us down!~
		IF ~IsValidForPartyDialog("Nalia")~THEN EXTERN BNALIA MR3MoneyTalkNalia
		IF ~!IsValidForPartyDialog("Nalia")
			IsValidForPartyDialog("Aerie")~THEN EXTERN BAERIE MR3MoneyTalkAerie
		IF ~!IsValidForPartyDialog("Nalia")
			!IsValidForPartyDialog("Aerie")
			IsValidForPartyDialog("Keldorn")~THEN EXTERN BKELDOR MR3MoneyTalkKeldorn
		IF ~!IsValidForPartyDialog("Nalia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Keldorn") 
			IsValidForPartyDialog("Korgan")~THEN EXTERN BKORGAN MR3MoneyTalkKorgan
		IF ~!IsValidForPartyDialog("Nalia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Keldorn") 
			!IsValidForPartyDialog("Korgan") 
			IsValidForPartyDialog("Edwin")~THEN EXTERN BEDWIN MR3MoneyTalkEdwin
		IF ~!IsValidForPartyDialog("Nalia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Keldorn") 
			!IsValidForPartyDialog("Korgan") 
			!IsValidForPartyDialog("Edwin")
			IsValidForPartyDialog("Viconia")~THEN EXTERN BVICONI MR3MoneyTalkViconia
		IF ~!IsValidForPartyDialog("Nalia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Keldorn")
			!IsValidForPartyDialog("Korgan")
			!IsValidForPartyDialog("Edwin")
			!IsValidForPartyDialog("Viconia")~ THEN GOTO MR3MoneyTalkNoone
	END
END


APPEND BNALIA
	IF ~~ THEN BEGIN MR3MoneyTalkNalia
		SAY ~I fully agree. Let's donate it to the less fortunate; give it to the homeless and the poor that have nothing to begin with.~
	IF ~!IsValidForPartyDialog("Aerie")
		!IsValidForPartyDialog("Keldorn")
		!IsValidForPartyDialog("Korgan")
		!IsValidForPartyDialog("Edwin")
		!IsValidForPartyDialog("Viconia")~THEN EXTERN BIMOEN2 MR3MoneyTalkNoone
	IF ~IsValidForPartyDialog("Aerie")~THEN EXTERN BAERIE MR3MoneyTalkAerie
	IF ~!IsValidForPartyDialog("Aerie")
		IsValidForPartyDialog("Keldorn")~THEN EXTERN BKELDOR MR3MoneyTalkKeldorn
	IF ~!IsValidForPartyDialog("Aerie")
		!IsValidForPartyDialog("Keldorn") 
		IsValidForPartyDialog("Korgan")~THEN EXTERN BKORGAN MR3MoneyTalkKorgan
	IF ~!IsValidForPartyDialog("Aerie")
		!IsValidForPartyDialog("Keldorn") 
		!IsValidForPartyDialog("Korgan") 
		IsValidForPartyDialog("Edwin")~THEN EXTERN BEDWIN MR3MoneyTalkEdwin
	IF ~!IsValidForPartyDialog("Aerie")
		!IsValidForPartyDialog("Keldorn") 
		!IsValidForPartyDialog("Korgan") 
		!IsValidForPartyDialog("Edwin") 
		IsValidForPartyDialog("Viconia")~THEN EXTERN BVICONI MR3MoneyTalkViconia 
	END
END

APPEND BAERIE
	IF ~~ THEN BEGIN MR3MoneyTalkAerie
		SAY ~That's right, we don't need all this money! Let's put it to good use and help some noble cause!~
	IF ~!IsValidForPartyDialog("Keldorn")
		!IsValidForPartyDialog("Korgan")
		!IsValidForPartyDialog("Edwin")
		!IsValidForPartyDialog("Viconia")~THEN EXTERN BIMOEN2 MR3MoneyTalkNoone
	IF ~IsValidForPartyDialog("Keldorn")~THEN EXTERN BKELDOR MR3MoneyTalkKeldorn
	IF ~!IsValidForPartyDialog("Keldorn") 
		IsValidForPartyDialog("Korgan")~THEN EXTERN BKORGAN MR3MoneyTalkKorgan
	IF ~!IsValidForPartyDialog("Keldorn") 
		!IsValidForPartyDialog("Korgan") 
		IsValidForPartyDialog("Edwin")~THEN EXTERN BEDWIN MR3MoneyTalkEdwin
	IF ~!IsValidForPartyDialog("Keldorn") 
		!IsValidForPartyDialog("Korgan") 
		!IsValidForPartyDialog("Edwin") 
		IsValidForPartyDialog("Viconia")~THEN EXTERN BVICONI MR3MoneyTalkViconia 
	END
END

APPEND BKELDOR
	IF ~~ THEN BEGIN MR3MoneyTalkKeldorn
		SAY ~Accumulating money for no purpose is one of the worst mistakes we can make in this life, my friend. Let others use what you do not need.~
	IF ~!IsValidForPartyDialog("Korgan")
		!IsValidForPartyDialog("Edwin")
		!IsValidForPartyDialog("Viconia")~THEN EXTERN BIMOEN2 MR3MoneyTalkNoone
	IF ~IsValidForPartyDialog("Korgan")~THEN EXTERN BKORGAN MR3MoneyTalkKorgan
	IF ~!IsValidForPartyDialog("Korgan") 
		IsValidForPartyDialog("Edwin")~THEN EXTERN BEDWIN MR3MoneyTalkEdwin
	IF ~!IsValidForPartyDialog("Korgan") 
		!IsValidForPartyDialog("Edwin") 
		IsValidForPartyDialog("Viconia")~THEN EXTERN BVICONI MR3MoneyTalkViconia
	END
END

APPEND BKORGAN
	IF ~~ THEN BEGIN MR3MoneyTalkKorgan
		SAY ~No one's gonna touch me bloody money! Try it an' I'll cut yer throat open!~
	IF ~!IsValidForPartyDialog("Edwin")
		!IsValidForPartyDialog("Viconia")~THEN EXTERN BIMOEN2 MR3MoneyTalkNoone
	IF ~IsValidForPartyDialog("Edwin")~THEN EXTERN BEDWIN MR3MoneyTalkEdwin
	IF ~!IsValidForPartyDialog("Edwin") 
		IsValidForPartyDialog("Viconia")~THEN EXTERN BVICONI MR3MoneyTalkViconia
	END
END


APPEND BEDWIN

	IF ~~ THEN BEGIN MR3MoneyTalkEdwin
		SAY ~Ignore the twit, <CHARNAME>. Obviously she cannot understand the power of wealth.~
	IF ~!IsValidForPartyDialog("Viconia")~THEN EXTERN BIMOEN2 MR3MoneyTalkNoone
	IF ~IsValidForPartyDialog("Viconia")~THEN EXTERN BVICONI MR3MoneyTalkViconia
	END
END

APPEND BVICONI
	IF ~~ THEN BEGIN MR3MoneyTalkViconia
		SAY ~Nau, never! Why give those wretches something that they cannot get by themselves? Use it for you and the group!~
	IF ~~ THEN EXTERN BIMOEN2 MR3MoneyTalkNoone
	END
END

APPEND BIMOEN2
	IF ~~ THEN BEGIN MR3MoneyTalkNoone
		SAY ~Donate it to an orphanage, gamble it all away, buy the ultimate weapon of all time... just get rid of some of it!~
		++ ~You know, you're right. I'll leave a good part of it in the next temple we visit.~ GOTO MR3MoneyTalkCont
		++ ~You're right! Let's go to the nearest tavern and gamble it away!~ GOTO MR3MoneyTalkCont
		++ ~Great idea! Let's get the best equipment money can buy!~ GOTO MR3MoneyTalkCont
		++ ~I don't know. What if we find something really expensive that we need no matter what the cost?~ GOTO MR3MoneyTalkCarry
		++ ~Why the rush? Money doesn't go bad. You never know when it might come in handy.~ GOTO MR3MoneyTalkCarry
		++ ~NO! My money, all MINE! Mine, mine, mine, mine!~ GOTO MR3MoneyTalkChaos
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(You sigh) Again about gold? Imoen, wealth isn't evil. Wealth is power... and power isn't evil, either. ~ GOTO MR3MoneyTalkEvil1
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(You sigh) Again about gold? Imoen, wealth isn't evil. Wealth is power... and power isn't evil, either. ~ GOTO MR3MoneyTalkEvil2
	END

	IF ~~ THEN BEGIN MR3MoneyTalkCont
		SAY ~Finally! Now that's what I wanted to hear.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MR3MoneyTalkCarry
		SAY ~Fine, but *you* carry it... (with a low grunt, she takes her backpack and throws it at you) ... by yourself!~
		=
		~(You catch the pack in mid air, but it's so heavy that your arm is nearly wrenched out of its socket and you stagger back, thrown off balance.)~
		=
		~(Maybe there's some merit to her argument...)~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MR3MoneyTalkChaos
		SAY ~W-whoa! You're one of those money-obsessed *jerks*, arentcha?~
		=
		~Tell you what, forget about it. Reasoning with you is like trying to reason with a gibberling, only worse.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MR3MoneyTalkEvil1
		SAY ~Hmph. If people weren't so obsessed with money and power, you gotta admit the world would be a better place.~
		=
		~Think of all the nutjobs we've run into who are all "oooh I'm the all powerful" or "gimme all your money!"~
		IF ~CheckStatGT(Player1,16,CHR)~ THEN REPLY ~Don't let the delusions of a few scare you away. You're a demi-god, Imoen, not a two-bit thug. Power and glory is your birthright.~ GOTO MR3MoneyTalkEvil3
		IF ~CheckStatGT(Player1,12,CHR) CheckStatLT(Player1,16,CHR)~ THEN REPLY ~Being poor or humble isn't a guarantee of being sane. You'll meet as many crazy peasants as you will crazy kings.~ GOTO MR2MoneyTalkEvil3
		IF ~CheckStatLT(Player1,12,CHR)~ THEN REPLY ~True, but we aren't nutjobs, are we? Don't let a few crazies ruin it for everyone.~ GOTO MR2MoneyTalkEvil3
		++ ~Look, if you don't want it, just give it to me. Then everyone's happy.~ GOTO MR2MoneyTalkEvil4
		++ ~Stop complaining and start walking. We've got work to do.~ GOTO MR2MoneyTalkEvil4
	END


	IF ~~ THEN BEGIN MR3MoneyTalkEvil2
		SAY ~I know you think that, but... I dunno. I mean, think of all the nutjobs we've run into who are all "ooh I'm the all powerful" or "gimme all your money!"~
		IF ~CheckStatGT(Player1,16,CHR)~ THEN REPLY ~Don't let the delusions of a few scare you away. You're a demi-god, Imoen, not a two-bit thug. Power and glory is your birthright.~ GOTO MR3MoneyTalkEvil5
		IF ~CheckStatGT(Player1,12,CHR) CheckStatLT(Player1,16,CHR)~ THEN REPLY ~Being poor or humble isn't a guarantee of being sane. You'll meet as many crazy peasants as you will crazy kings.~ GOTO MR3MoneyTalkEvil5
		IF ~CheckStatLT(Player1,12,CHR)~ THEN REPLY ~True, but we aren't nutjobs, are we? Don't let a few crazies ruin it for everyone.~ GOTO MR3MoneyTalkEvil5
		++ ~Look, if you don't want it, just give it to me. Then everyone's happy.~ GOTO MR2MoneyTalkEvil4
		++ ~Stop complaining and start walking. We've got work to do.~ GOTO MR2MoneyTalkEvil4
	END

	IF ~~ THEN BEGIN MR3MoneyTalkEvil3
		SAY ~Maybe... y'know, sometimes you *almost* make sense. Almost.~
		=
		~ And if you really, really want to keep all the money...~
		IF ~~ THEN GOTO MR3MoneyTalkCarry
	END

	IF ~~ THEN BEGIN MR3MoneyTalkEvil4
		SAY ~(Imoen simply sticks her tongue out to you.)~
		=
		~Fine, be that way.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MR3MoneyTalkEvil5
		SAY ~Y'know what? Sometimes you *almost* make sense. Maybe I oughta get my head checked.~
		=
		~But if you really, really want to keep all the money...~
		IF ~~ THEN GOTO MR3MoneyTalkCarry
	END
END
