// Here go all very brief conversations that Imoen initiates

// Contents:
// Small talk in the fire giants' lair
// Imoen's Warning if you go kill Yaga-Shura without destroying his heart
// Imoen comments on Sendai's priestess
// Imoen comments on Abazigal's lair
// Imoen comments on running out of money




// Small talk in the fire giants' lair

APPEND IMOEN25J 
IF WEIGHT #10 ~Global("IRTFireGiantLairTalk","GLOBAL",1)~ THEN fg
 SAY ~Oh gosh, I'm meltin' here. Couldn't be Beach Giants or Lake Giants, it *had* to be Fire, We-Live-in-a-Huge-Oven Giants.~ [IRQUIET]
 IF ~~ THEN DO ~SetGlobal("IRTFireGiantLairTalk","GLOBAL",2)~ GOTO fgNext
END

IF ~~ THEN fgNext
 SAY ~Smelly bastards, too!~
 + ~NumInPartyGT(2)~ + ~We all are hot, Imoen. The sooner we're done here, the sooner we can get out.~ + fg1
 + ~!NumInPartyGT(2)~ + ~I'm hot too, Imoen. The sooner we're done here, the sooner we can get out.~ + fg1
 ++ ~I'm letting you plan our next trip. I seem to pick all the wrong places to visit.~ + fg2
 ++ ~Let's kill them all, take what we need, and then make this cave collapse over their corpses.~ + fg3
 ++ ~(Whisper harshly.) We are surrounded by monsters! Stay quiet!~ + fg4
 ++ ~(Chuckle under your breath and motion to keep going forward.)~ + fg5
 ++ ~A new place, a new complaint from the usual whiner.~ + fg6
END

IF ~~ THEN fg1
	SAY ~True thing. (She wipes her brow for the tenth time.) Protection from Fire, here we come.~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN fg2
	SAY ~(Imoen giggles a bit louder than she intended and quickly covers her mouth, giving you an apologetic look.)~
	= ~(She drops her voice to a whisper.) Better get this thing done before we melt into a pool of sweaty goo.~
	IF ~~ THEN EXIT
END

IF ~~ THEN fg3
	SAY ~Yeah, let's do that. We've yet to encounter a problem that doesn't get solved by indiscriminate violence. Don't think this one will be any different.~
	IF ~~ THEN DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1)~ EXIT
END

IF ~~ THEN fg4
	SAY ~(Imoen recoils a bit. A complaint seems to form on her lips but, whatever it is, she decides to keep it to herself.)~
	IF ~~ THEN EXIT
END

IF ~~ THEN fg5
	SAY ~(Smiling, she wipes her brow yet again and follows your lead.)~
	IF ~~ THEN EXIT
END

IF ~~ THEN fg6
	SAY ~Hey, it's warranted this time! You can barely breathe here. But alright, fine, I get the point...~
	IF ~~ THEN EXIT
END
END


// Imoen's Warning if you go kill Yaga-Shura without destroying his heart

APPEND IMOEN25J
IF WEIGHT #10 ~Global("IRTInSiegeCampEarly","GLOBAL",1)~ THEN YagaEarly
SAY ~We really shouldn't be here. Yaga-Shura's still protected by his mojo, there's nothing we can do to him 'til we take that down. Better get outta here before we get spotted...~[IRQUIET]
  ++ ~I know what I'm doing, Imoen. Trust me.~ + YE5
  ++ ~You're right, I forgot about that. We better get moving.~ + YE4
  ++ ~Nothing can take me down. Yaga-Shura is no different than the rest.~ + YE3
  ++ ~I figured we could skip that part and slaughter that giant with raw power, as we always do.~ + YE2
  ++ ~Calm down, I just came here to see their numbers and assess the threat. We'll be on our way soon enough.~ + YE1
  ++ ~(Ignore her.)~ DO ~SetGlobal("IRTInSiegeCampEarly","GLOBAL",2) ~ EXIT
END

IF ~~ THEN YE1
  SAY ~Alrighty then, but we better be quick about it or we'll have a pissed off invulnerable giant on our arse.~
  IF ~~ THEN DO ~SetGlobal("IRTInSiegeCampEarly","GLOBAL",2)~ EXIT
END

IF ~~ THEN YE2
  SAY ~I dunno, it seems this guy's downright invulnerable because of the weird thing he did with his heart. But hey, yer the boss. Worst thing that can happen is we all die horribly.~
  = ~Gotta say though, I love the sheer amount of thought you put into this plan.~
  IF ~~ THEN DO ~SetGlobal("IRTInSiegeCampEarly","GLOBAL",2)~ EXIT
END

IF ~~ THEN YE3
  SAY ~Yeesh. Maybe nothing's been able to take you down *yet*? A downright invulnerable super giant just might do it.~
  = ~But hey, yer the boss. Worst thing that can happen is we all die horribly.~
  IF ~~ THEN DO ~SetGlobal("IRTInSiegeCampEarly","GLOBAL",2)~ EXIT
END

IF ~~ THEN YE4
  SAY ~Always at your beck and call, o' wise leader.~
  IF ~~ THEN DO ~SetGlobal("IRTInSiegeCampEarly","GLOBAL",2)~ EXIT
END

IF ~~ THEN YE5
  SAY ~Alrighty then, but if we end up runnin' like chickens in front of a huge army, I'm gonna make sure to yell "I told you so" before we die horribly.~
  IF ~~ THEN DO ~SetGlobal("IRTInSiegeCampEarly","GLOBAL",2)~ EXIT
END
END



// Imoen comments on Sendai's priestess
//  Trigger right after she vanishes - she says the following in SENPRI.DLG:
// Fool! I am drow. You are naught but iblith-filth! Sendai need not be bothered, for I shall destroy you! Enter Ogremoch's chamber if you dare. Defeat him, and I shall face you myself.
// Requires !Global("ImoenRomanceActive","GLOBAL",3)

APPEND IMOEN25J
IF WEIGHT #-5 ~Global("IRTSendai","GLOBAL",1)~ THEN Sen
	SAY ~Wow. She was... gorgeous. Do we really need to kill her?~[IRQUIET]
	++ ~I know! She doesn't sound like the reasonable type, though.~ + Sen1
	++ ~Yes, Imoen. We have to kill her, like everything else in here.~ + Sen2
	+ ~IsValidForPartyDialog("Viconia")~ + ~Drow beauty is deceiving. Most are monsters inside, and there is no question about this one.~ EXTERN VICON25J Sen3
	+ ~!IsValidForPartyDialog("Viconia")~ + ~Drow beauty is deceiving. Most are monsters inside, and there is no question about this one.~ + Sen4
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~What do you suggest, that we invite her into our bed?~ + Sen5
	+ ~OR(2) Gender(Player1,MALE) !Global("ImoenRomanceActive","GLOBAL",2)~ + ~I didn't know you liked women that way, Imoen.~ + Sen5
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~I don't appreciate you having a wandering eye.~ + Sen5
	++ ~I found her quite ugly, to be honest.~ + Sen6
END

IF ~~ THEN Sen1
	SAY ~I dunno, maybe she's got a secret heart of gold, just waiting to come out for the right people. We could be her saviors, huh?~
	= ~Yeah, fat chance. It's gonna feel like striking down a unicorn, though...~
	IF ~~ THEN GOTO SenEnd
END

IF ~~ THEN Sen2
	SAY ~Aw. Hunting her down feels like striking down a unicorn, is all.~
	IF ~~ THEN GOTO SenEnd
END
END

APPEND VICON25J
IF ~~ THEN Sen3
	SAY ~I wholeheartedly agree.~
	IF ~~ THEN EXTERN IMOEN25J Sen4
END
END 

APPEND IMOEN25J
IF ~~ THEN Sen4
	SAY ~Yeah... yeah, I don't doubt it. It's just, striking her down is gonna feel like stabbing a unicorn, y'know.~
	IF ~~ THEN GOTO SenEnd
END

IF ~~ THEN Sen5
	SAY ~No, no no no, I didn't mean it like that, I meant it like... feels like striking down a unicorn.~
	IF ~~ THEN GOTO SenEnd
END

IF ~~ THEN Sen6
	SAY ~Really? She's stunning! Must've been the light or something. I'm tellin' ya, I feel like we're striking down a unicorn here.~
	IF ~~ THEN GOTO SenEnd
END

IF ~~ THEN SenEnd
	SAY ~An evil, bloodthirsty unicorn that's bent on murdering everyone for her almighty mistress.~
	= ~Yeah, I guess we have to kill her.~
	IF ~~ THEN DO ~SetGlobal("IRTSendai","GLOBAL",2)~ EXIT
END
END

// Imoen comments on Abazigal's lair
// This one triggers as soon as you enter the chamber with all the spikes on the ground, lair of Fll'Yissetat. AR6004
// Trigger only if !Global("ImoenRomanceActive","GLOBAL",3)

APPEND IMOEN25J
IF WEIGHT #-5 ~Global("IRTAbazigal","GLOBAL",1)~ THEN Aba
	SAY ~Alright, I gotta say, of all the things I expected to find in the lair of a mighty dragon Bhaalspawn, *this* layout is nowhere near. I mean... don't even get me started on the random house with the skeleton monsters.~ [IRQUIET]
	= ~Maybe Abazigal is ahead of his time where architecture is concerned. Or maybe it's a sign that he's a bit crazy?~
	++ ~I see nothing wrong with it. It makes sense that all these aquatic creatures would move about through caves and underwater tunnels.~ DO ~SetGlobal("IRTAbazigal","GLOBAL",2)~ + Aba1
	++ ~I think crazy is exactly right. We better watch ourselves.~ DO ~SetGlobal("IRTAbazigal","GLOBAL",2)~ + Aba2
	++ ~We are in very serious danger, you should save the small talk for later.~ DO ~SetGlobal("IRTAbazigal","GLOBAL",2)~ + Aba3
	++ ~You have just spoken my thoughts out loud.~ DO ~SetGlobal("IRTAbazigal","GLOBAL",2)~ + Aba4
	++ ~You could argue that we're just as crazy, swimming through these waterlogged passageways like merfolk.~ DO ~SetGlobal("IRTAbazigal","GLOBAL",2)~ + Aba5
END

IF ~~ THEN Aba1
	SAY ~(Imoen keeps quiet for a while, blinking profusely.)~
	= ~Maybe that's a sign that *you're* a bit crazy. Good thing I already knew that.~
	IF ~~ THEN EXIT
END

IF ~~ THEN Aba2
	SAY ~Yay, we're drenched in smelly water and about to fight a crazy dragon. Such joy we find in our lives.~
	IF ~~ THEN EXIT
END

IF ~~ THEN Aba3
	SAY ~Alright, alright, sorry, just makin' an observation...~
	IF ~~ THEN EXIT
END

IF ~~ THEN Aba4
	SAY ~Hah. I'm glad I'm not the only one. This place is *weird*.~
	IF ~~ THEN EXIT
END

IF ~~ THEN Aba5
	SAY ~(Imoen keeps quiet for a while, blinking profusely.)~
	= ~You make an excellent point.~
	IF ~~ THEN EXIT
END
END	


// Imoen comments on running out of money
// Triggers if party gold goes lower than 700 after having killed Yaga-Shura
// Needs !Global("ImoenRomanceActive","GLOBAL",3)

APPEND IMOEN25J
IF WEIGHT #-5 ~Global("IRTLowGold","GLOBAL",1)~ THEN broke
	SAY ~Wow. I can't believe we just spent all of our money. I thought we'd never run out.~ [IRShort]
	++ ~I'm not worried. We'll amass just as much and more in no time.~ DO ~SetGlobal("IRTLowGold","GLOBAL",2)~ + broke1 
	++ ~My perception of how much a gold piece is worth has radically changed since Candlekeep.~ DO ~SetGlobal("IRTLowGold","GLOBAL",2)~ + broke2
	++ ~There is no point in hoarding it. Now we're much better equipped.~ DO ~SetGlobal("IRTLowGold","GLOBAL",2)~ + broke3
	++ ~I must have all the things, ALL OF THEM!~ DO ~SetGlobal("IRTLowGold","GLOBAL",2)~ + broke4
	++ ~I'm getting buyer's remorse already.~ DO ~SetGlobal("IRTLowGold","GLOBAL",2)~ + broke5
END

IF ~~ THEN broke1
	SAY ~Hah, yeah, I don't doubt it. These guys'll buy anything! I guess they place a lot of stock on the resale value, with all the powerful adventurers and mercenaries traveling around.~
	IF ~~ THEN GOTO brokeEnd
END

IF ~~ THEN broke2
	SAY ~Oh Gods, yes! Remember, scraping together enough coins to buy a potion? Pooling every bit we had to get a decent cape? Those were the days.~
	IF ~~ THEN GOTO brokeEnd
END

IF ~~ THEN broke3
	SAY ~oh, hey, not arguing with ya. It's just a bit crazy, the kinda money we burn through.~
	IF ~~ THEN GOTO brokeEnd
END
	
IF ~~ THEN broke4
	SAY ~Hahah! Yer well on the way, then. With the amount of stuff we're hauling around to sell, soon you'll be able to have every single piece of equipment that ever existed.~
	IF ~~ THEN GOTO brokeEnd
END
	
IF ~~ THEN broke5
	SAY ~Hahah! That's too bad. At least we'll get the money back pretty damn quickly. It's not like the old days, scraping together enough coins to buy a potion and then feeling so bad when you needed to drink it...~
	IF ~~ THEN GOTO brokeEnd
END

IF ~~ THEN brokeEnd
	SAY ~It feels so far away when a thousand gold pieces seemed like all the money in the world. Nowadays we're spending that much on a single arrow, almost...~
	= ~Ah well, there's no question our bags will be bursting with gold coins again soon enough.~
	IF ~~ THEN EXIT
END
END



