//** Must happen directly upon entering Suldanessellar **//
APPEND IMOEN2J   //// It seems this whole dialogue was overlooked and wasn't updated

	IF ~Global("MRSuldComment","GLOBAL",1)~ THEN BEGIN MRLoveTalk6
	 SAY ~I... I need to talk to you, <CHARNAME>.~
	 = ~Alone.~
	 ++ ~You and everyone else. Wait your turn.~ DO ~SetGlobal("MRSuldComment","GLOBAL",2)~ + MRLoveTalk6-Insist
	 ++ ~What? Have you not noticed we're kinda busy?~ DO ~SetGlobal("MRSuldComment","GLOBAL",2)~ + MRLoveTalk6-Insist
	 + ~NumInPartyGT(2)~ + ~Of course. (Motion her to step away from the group.)~ DO ~SetGlobal("MRSuldComment","GLOBAL",2)~ + MRLoveTalk6-1
	 + ~!NumInPartyGT(2)~ + ~Of course. What's wrong?~ DO ~SetGlobal("MRSuldComment","GLOBAL",2)~ + MRLoveTalk6-1
	 ++ ~Sure. Make it quick.~ DO ~SetGlobal("MRSuldComment","GLOBAL",2)~ + MRLoveTalk6-1
	END

	IF ~~ MRLoveTalk6-Insist
	 SAY ~*Now*, <CHARNAME>.~
		++ ~No. Now is not the time!~ DO ~SetGlobal("MRSuldComment","GLOBAL",2)~ + MRLoveTalk6-End
		++ ~Don't order me around. Don't think I won't treat you just like any other upstart mage I've met.~ DO ~SetGlobal("MRSuldComment","GLOBAL",2)~ + MRLoveTalk6-Threat
		+ ~NumInPartyGT(2)~ + ~So demanding. What's wrong? (Motion her to step away from the group.)~ + MRLoveTalk6-1
		+ ~!NumInPartyGT(2)~ + ~So demanding. What's wrong?~ + MRLoveTalk6-1
		++ ~Sure. Make it quick.~ + MRLoveTalk6-1
		+ ~Gender(Player1,MALE) Global("ImoenRomanceActive","GLOBAL",2) ~ + ~Oh gods. You aren't pregnant, are you?~ + MRLoveTalk6-Preg
	END

	IF ~~ MRLoveTalk6-Preg
	 SAY ~What? No! It has nothing to do with that! At all!~
		++ ~Oh. Well, in that case - now is not the time!~ DO ~SetGlobal("MRSuldComment","GLOBAL",2)~ + MRLoveTalk6-End
		+ ~NumInPartyGT(2)~ + ~Well, what is it then? (Motion her to step away from the group)~ + MRLoveTalk6-1
		+ ~!NumInPartyGT(2)~ + ~Well, what is it then?~ + MRLoveTalk6-1
	END

	IF ~~ MRLoveTalk6-Threat
	 SAY ~Are you- did you just *threaten* me?~
	 IF ~~ THEN GOTO MRLoveTalk6-ThreatLeave
	END

	IF ~~ MRLoveTalk6-ThreatLeave
	 SAY ~You seriously have the nerve to threaten me? Well, lemme tell ya what, '<PRO_BROTHERSISTER>' - I've got my limits, too. And you just crossed them.~
	 = ~Find some other 'upstart mage' to save your ass.~
	 IF ~~ THEN DO ~ SetGlobal("ImoenRomanceActive","GLOBAL",3) LeaveParty() EscapeArea()~ EXIT
	END


	IF ~~ MRLoveTalk6-End
	 SAY ~But- (Her lips press together tightly. Her fists clench - for a moment it looks like she's about to throw a punch at you.)~
         = ~You didn't even know what I was going to say! Y'know what, fine. You don't need to hear it. You'll never get to hear it.~
	 = ~Let's get this over with.~

	 IF ~~ THEN EXIT
	END

	IF ~~ MRLoveTalk6-1
	 SAY ~I...~
	 IF ~NumInPartyGT(2)~ + MRLoveTalk6-1_1
	 IF ~!NumInPartyGT(2)~ + MRLoveTalk6-1_2
	END

	IF ~~ MRLoveTalk6-1_1
	 SAY ~(You step a safe distance away from the group. As soon as Imoen is out of earshot, her resolute expression cracks and crumbles.)~

	 IF ~~ + MRLoveTalk6-1a
	END

	IF ~~ MRLoveTalk6-1_2
	 SAY ~(Imoen lowers her voice. Her resolute expression cracks and crumbles.)~

	 IF ~~ + MRLoveTalk6-1a
	END

	IF ~~ MRLoveTalk6-1a
	 SAY ~I- I can't do this, <CHARNAME>. I can't.~
	 ++ ~Do what? What are you talking about?~ + MRLoveTalk6-2
	 ++ ~You can and you will! That's an order!~ + MRLoveTalk6-2a
	 ++ ~Um. Okay? I don't understand.~ + MRLoveTalk6-2b

	END

	IF ~~ MRLoveTalk6-2a
	 SAY ~No, I- I can't! Because of...~
	 IF ~~ + MRLoveTalk6-2
	END

      	IF ~~ MRLoveTalk6-2b
	 SAY ~No, of course you don't. You can't. You waltz into this place like it's some other quest to complete, but all I can think about is... it's...~
	 IF ~~ THEN GOTO MRLoveTalk6-2
	END

	IF ~~ MRLoveTalk6-2
	 SAY ~*Him*! Irenicus! You've no idea what he did to me, <CHARNAME>. I thought I was strong enough to just- just *ignore* it, but I'm not.~
	 = ~I'm scared. I can't face him again. I just can't.~
	 ++ ~You faced Bodhi down without a problem.~ + MRLoveTalk6-3
	 ++ ~Oh, c'mon, I was tortured too. Or have you forgotten?~ + MRLoveTalk6-3
	 + ~NumInPartyGT(2)~ + ~Yes, you can. You're not alone now. We're here to protect you this time.~ + MRLoveTalk6-3
	 + ~!NumInPartyGT(2)~ + ~Yes, you can. You're not alone now. I'm here to protect you this time.~ + MRLoveTalk6-3
	END

	IF ~~ MRLoveTalk6-3
	 SAY ~You don't *understand*! (She yanks up one of her sleeves and shoves her arm in your face) D'you think a few scars is all he did to me? You really think he's that unimaginative?~
	 = ~He had *decades* to design his experiments. And magic doesn't always leave marks. You of all people should know that.~

	 ++ ~But, Imoen, you are stronger than-~ + MRLoveTalk6-4
	 ++ ~Stop being such a snivelling little-~ + MRLoveTalk6-4
	 ++ ~Never fear! I, <CHARNAME>, shall-~ + MRLoveTalk6-4
	 ++ ~I know, but-~ + MRLoveTalk6-4
	END

	IF ~~ MRLoveTalk6-4
	 SAY ~(She abruptly shoves you backwards) No! YOU should've been there! It's YOUR fault!~
	 =

	 ~You just- you just STOOD there and let him take me! You pranced around Athkatla playing adventure-<PRO_GIRLBOY> while I rotted in that cell!~
	 =

	 ~While he cut me open, while he chained me down, while he turned me inside out piece by piece and showed me what was inside! He took *everything* from me!~
	 =

	 ~And then he'd heal me. Rip the skin off my body and heal me. Crack open my mind and then heal me. Dissect me, enchant me, possess me, grind me down until I didn't know where I was - until I didn't know *who* I was.~
	 =

	 ~(Tears glitter in her eyes, spill down her cheeks. Her body trembles, but her fists remain clenched tightly at her sides) You don't know. He never touched you. Not like that.~
         = ~Not like me.~
	 ++ ~Do NOT blame me! I busted my arse to come save you as fast as I could! You know as well as I do that I couldn't do anything to stop him at the Promenade.~ + MRLoveTalkN1
	 ++ ~No? Irenicus tortured me too. Do you think I'm not scarred in more ways than one? Don't pretend you're the only one that's suffered!~ + MRLoveTalk6-4MeToo


	 ++ ~Are we done with this sob story? 'Cause I still have a bad guy to kill, and you will help me do it.~ + MRLoveTalkN2
	 ++ ~You need to overcome this, Imoen. And it'll all be over once you shove a knife into his gullet.~ + MRLoveTalkN3
	 ++ ~Imoen, I had no idea. I'm sorry.~ + MRLoveTalk6-5
	 ++ ~Hey, that kinda sounds like fun!~ + MRLoveTalk6-4Joke
	END

	IF ~~ MRLoveTalk6-4MeToo
	 SAY ~I'm not pretending anything! I know what he did to you. Don't you think I was there? Don't you think he made me watch every time he sliced you open?~
	 = ~Did he grind you down to *nothing*, though? Did he make you want to die - actually *crave* death? He didn't. He didn't have the time with you. But he had all the time in the world for me.~
	 ++ ~So it's my fault, then? I busted my arse to come save you as fast as I could. It tore me up inside to lose you.~ + MRLoveTalkN1

	 ++ ~Are we done with this sob story? 'Cause I still have a bad guy to kill, and you will help me do it.~ + MRLoveTalkN2
	 ++ ~You need to overcome this, Imoen. And it'll all be over once you shove a knife into his gullet.~ + MRLoveTalkN3
	 ++ ~Imoen, I had no idea. I'm sorry.~ + MRLoveTalk6-5
	END

	IF ~~ MRLoveTalk6-4Joke
	 SAY ~Like... fun? (Her eyes narrow dangerously) You think this is a JOKE? You think what he *did* to me, is a joke?~
	 = ~I- I can't believe that I ever even *dreamt* that you would understand!~
	 IF ~~ + MRLoveTalk6-4End2
	END

        IF ~~ MRLoveTalkN1
           SAY ~I don't care! Maybe for once everything doesn't revolve around you. Maybe you could stop talking and just *listen* to what I'm saying!~
           IF ~~ THEN GOTO MRLoveTalk6-5
        END

        IF ~~ MRLoveTalkN2
           SAY ~A sob story? Is that what you think it is? A blasted sob story? I should leave you right where you stand!~
           ++ ~No, I don't think that. I'm just frustrated. I need you right now, Imoen. After all we've been through, you can't fail me now.~ + MRLoveTalk6-7
           ++ ~It IS a sob story. Stop listening to your doubt and your fear. Stop giving him control over you. Only the weak hide and cower, and I know, I *know* you are not weak. So quit pretending you can't face your demons.~ + MRLoveTalkN2a
           ++ ~Then leave! Leave, flee from the man that ruined our lives, if you like. I'll be forging forward, avenging the fallen, getting our revenge.~ + MRLoveTalkN2b
        END
        
        IF ~~ THEN MRLoveTalkN2a
           SAY ~(Though anger burns on her cheeks, soon it gives way to hesitation. She averts her gaze, breathes out in defeat.)~
           = ~What if the demons take over, <CHARNAME>? That's what I'm afraid of. But... you're right.~
           = ~You're right.~
           IF ~~ THEN GOTO MRLovetalk6-7Leave
        END

        IF ~~ THEN MRLoveTalkN2b
           SAY ~(Though anger burns on her cheeks, soon it gives way to hesitation. She averts her gaze, breathes out in defeat.)~
           = ~I could never live with that. And... you know that, don't you.~
           IF ~~ THEN GOTO MRLoveTalk6-7
        END

        IF ~~ MRLoveTalkN3
           SAY ~It's not that simple! I wish it were. You need to stop talking and just *listen* to what I'm saying!~

           IF ~~ THEN GOTO MRLoveTalk6-5
        END


	IF ~~ MRLoveTalk6-4End2
	 SAY ~I've got half a mind to leave you here and let you face him on your own. Maybe then you'd understand!~
	 = ~Just... just don't talk to me! Don't touch me, don't look at me!~
	 IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3)~ EXIT
	END

	IF ~~ MRLoveTalk6-5
	 SAY ~What I'm telling you is that I can't face him, <CHARNAME>. If I do, I know I'll just break down and panic and- and-~
	 ++ ~It's okay, I understand. You don't have to. You really don't.~ + MRLoveTalk6-6
	 ++ ~You'd just abandon me like that? I need you, Imoen. You know that. After all we've been through, after all we've suffered... you can't fail me now.~ + MRLoveTalk6-7

	 ++ ~And become a liability? Best if you don't continue, then.~ + MRLoveTalk6-6
	 ++ ~I don't buy that. You're just listening to doubt and fear right now. Stop giving him control over you. Only the weak hide and cower, and I know, I *know* you are not weak. So quit pretending you can't face your demons.~ + MRLoveTalkN2a
         ++ ~I get it - you're a coward, so you make up a sob story to get out of this situation. Well, I don't need you! Get lost!~ + MRLoveTalkN2
	END

	IF ~~ MRLoveTalk6-6
	 SAY ~Are... are you sure?~
	 ++ ~No, I'm not sure! You have to come, you just have to!~ + MRLoveTalk6-7
	 ++ ~You know I need you, but I won't force you into anything. If you don't think you can do it, then that's that.~ + MRLoveTalk6-7

	 ++ ~Of course. I realize now, it's for the best if you stay behind.~ + MRLoveTalk6-7
	END

	IF ~~ MRLoveTalk6-7
	 SAY ~(Her mouth purses into a frown. Her eyes travel from you, to the sprawling elven city, to the canopy above. Imoen bites her lower lip, brow knit in a worried mien.)~

	 IF ~~ THEN GOTO MRLovetalk6-7Leave
	END


	IF ~~ MRLovetalk6-7Leave
	 SAY ~I can't let you do this on your own. If I don't face him... we'll never be free.~
	 = ~I- I'm sorry... you risked everything to get me, and then to get my soul back. We got here and I saw everything that's going on, and I started breathing really hard, and I thought my head would explode if I didn't let it out. And once more you take the hit for me.~


         = ~(Imoen shakes her head and looks at you with determination) Let's go make him pay for everything he's done, <CHARNAME>. Don't worry about me. I'm all in.~
	 IF ~~ THEN EXIT
	END
END