
BEGIN ~MRWOMER~

APPEND MRWOMER

	IF ~~ THEN BEGIN MRWoman
		SAY ~... And see my wares! From exotic fabrics to rare jewelry and every imaginable accessory the quality of which would impress even the greatest of the kings!~
		=~Come, come and see today what this humble merchant brings you from distant lands! You will not find anything like this again, and tomorrow will be too late!~ 
		 IF ~~ THEN REPLY ~(Curious, you approach the merchant's stand.)~ EXTERN PLAYER1 MRBraceletApproach
		 IF ~Global("ImoenRomanceActive","GLOBAL",2)
		~ THEN REPLY ~(Jewelry, huh? You could surprise Imoen with a gift.)~ EXTERN PLAYER1 MRBraceletApproach1
		 IF ~Global("AerieRomanceActive","GLOBAL",2)
		~ THEN REPLY ~(Jewelry, huh? You could surprise Aerie with a gift.)~ EXTERN PLAYER1 MRBraceletApproach1
		 IF ~Global("JaheiraRomanceActive","GLOBAL",2)
		~ THEN REPLY ~(Jewelry, huh? You could surprise Jaheira with a gift.)~ EXTERN PLAYER1 MRBraceletApproach1
		 IF ~Global("ViconiaRomanceActive","GLOBAL",2)
		~ THEN REPLY ~(Jewelry, huh? You could surprise Viconia with a gift.)~ EXTERN PLAYER1 MRBraceletApproach1
		 IF ~Global("AnomenRomanceActive","GLOBAL",2)
		~ THEN REPLY ~(Jewelry, huh? You could surprise Anomen with a gift.)~ EXTERN PLAYER1 MRBraceletApproach1
		 IF ~Global("NaliaRomanceActive","GLOBAL",2)
		~ THEN REPLY ~(Jewelry, huh? You could surprise Nalia with a gift.)~ EXTERN PLAYER1 MRBraceletApproach1
		 IF ~Global("TashiaRomanceActive","GLOBAL",2)
		~ THEN REPLY ~(Jewelry, huh? You could surprise Tashia with a gift.)~ EXTERN PLAYER1 MRBraceletApproach1
		 IF ~~ THEN REPLY ~(Pay the woman no mind.)~ EXTERN PLAYER1 MRBraceletGoAway
	END

	IF ~Global("MRRingSellImoen","GLOBAL",3)~ THEN BEGIN MRWoman2 // from:
	 SAY ~Aah, new customers! My name is Mara, and I'm ever so pleased to have your attention. Welcome to this humble traveling stand!~
	 = ~Tomorrow I'll be on my way to Trademeet, so have a look at my extensive and varied merchandise now, my dear friends. You won't know what to buy first!~
	 = ~(She turns to Imoen) Ah, young girl, interested in some of my fine jewels? Perhaps these sapphire earrings? They would set off your eyes to grand advantage.~
	 IF ~~ THEN EXTERN IMOEN2J MRBraceletIm
	END

	IF ~~ THEN BEGIN MRWomanAnnoyed // from:
	 SAY ~Oh, you need only take your time, young lady! I'm certain you will find something suitable for your refined tastes.~
	 = ~(Mara the merchant turns to address you) And you, my good <PRO_LADYLORD>. What can this humble trader do for you?~
	 IF ~OR(5)
		Global("AerieRomanceActive","GLOBAL",2)
		Global("JaheiraRomanceActive","GLOBAL",2)
		Global("ViconiaRomanceActive","GLOBAL",2)
		Global("NaliaRomanceActive","GLOBAL",2)
		Global("AnomenRomanceActive","GLOBAL",2)
		!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~I'm looking for a gift for my--~ EXTERN IMOEN2J MRBraceletElbow
	 IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~(Lower your voice) I'm getting a gift for her. She's--~ EXTERN IMOEN2J MRBraceletElbow
	 IF ~~ THEN REPLY ~Nothing, it seems, since everything here is utter garb--~ EXTERN IMOEN2J MRBraceletElbow
	 IF ~~ THEN REPLY ~I'll just browse for a while, give me some--~ EXTERN IMOEN2J MRBraceletElbow
	END

	IF ~~ THEN BEGIN MRWomanNotice // from:
	 SAY ~(Mara draws a half-smile that quickly broadens to enthusiasm) Aah, I see you have set your eyes upon my finest piece.~
	 IF ~~ THEN EXTERN IMOEN2J MRPurse
	END

	IF ~~ THEN BEGIN MRAfterPurse
	SAY ~Ah, but like most true beauty, the wonder of this piece springs from within. (Mara takes it in her rotund hands with care, almost devotion.)~
	 = ~Can you not sense it, young lady? Yes, I'd presume one such as you would. Its otherworldly allure hums deep, as deep as its powerful aura. You need only bring it close to your heart.~
         = ~(She holds it out to you. Deep in your chest you feel a strange tingle, like nervous jitters spread through your entire ribcage. It transitions into a peaceful sense of contentment.)~
	 = ~Its magical properties are undeniable. Might you be interested, my good <PRO_LADYLORD>?~
	 IF ~~ THEN EXTERN IMOEN2J MRWomanPrice
	END
	
	IF ~~ THEN BEGIN MRWomanPriceJade
	SAY ~Oh, but... yes, of course. My apologies, I did not mean to presume. This is quite the expensive piece, in any event. (Mara carefully places the bracelet back in its case.)~
        = ~I have a full selection of jade rings, right over here. Emerald-set, perhaps? Rubies make a lovely combination.~
	IF ~~ THEN EXTERN IMOEN2J MRWomanBuyRing
	END

	IF ~~ THEN BEGIN MRHold
	SAY ~Hey, wait a moment... the bracelet. Where is the bracelet?~
	= ~You! You took it! Thieves! GUARDS! THIEVES!~
	IF ~~ THEN EXTERN IMOEN2J MRHoldNot
	END
END


