//** Talk about the Slayer Dreams **//
//* the character has already Slayer-changed once **//
APPEND IMOEN2J 
	IF ~Global("MRSlayDreamResolved","GLOBAL",1)~ THEN BEGIN MRSlayTalk
		SAY ~You okay, <CHARNAME>? I heard you talking in your sleep.~
		++ ~Yes, nothing to worry about.~ DO ~SetGlobal("MRSlayDreamResolved","GLOBAL",2) RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ + MRSlayTalkStop
		++ ~You couldn't sleep, either?~ DO ~SetGlobal("MRSlayDreamResolved","GLOBAL",2) RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ + MRSlayContinue3
		++ ~I hope talking is all I did.~ DO ~SetGlobal("MRSlayDreamResolved","GLOBAL",2) RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ + MRSlayContinue2
		++ ~Sorry to disturb you.~ DO ~SetGlobal("MRSlayDreamResolved","GLOBAL",2) RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ + MRSlayContinue1
	END

	IF ~~ THEN BEGIN MRSlayTalkStop
		SAY ~(Her sleepless eyes look at you doubtfully.)~
                = ~Well, okay.~
		IF ~~ THEN EXIT
	END
	
	IF ~~ THEN BEGIN MRSlayContinue1
		SAY ~Oh, please. As if I could sleep, anyway.~
		IF ~~ THEN GOTO MRSlayContinueNext
	END

	IF ~~ THEN BEGIN MRSlayContinue2
		SAY ~Hah. For the most part. There were a few rude gestures, too.~
		IF ~~ THEN GOTO MRSlayContinueNext
	END

	IF ~~ THEN BEGIN MRSlayContinue3
		SAY ~(Imoen looks away) No. Not really.~
		IF ~~ THEN GOTO MRSlayContinueNext
	END

        IF ~~ THEN BEGIN MRSlayContinueNext
		SAY ~(Imoen is briefly lost in thought. She composes herself and forces a smile) So wutcha dream about?~
		++ ~I can't remember now.~ + MRSlayTalkStop
		++ ~Imoen... did you ever dream about the Slayer?~ + MRSlayDream
	END


	IF ~~ THEN BEGIN MRSlayDream
		SAY ~Huh? About the Slayer? Of course not. Why ya ask? Is that what you dreamed about?~
			++ ~Hrm, nevermind. Just me thinking crazy again.~ GOTO MRSlayDreamEnd
			++ ~Yeah, I did. About you and the Slayer.~ GOTO MRSlayDream2
	END

	IF ~~ THEN BEGIN MRSlayDream2
		SAY ~(Her eyebrow arches up) Oh? Like what?~ [ MRImRom5 ]
			++ ~It took place in Candlekeep, as usual. I appeared before you inside the library, and you began talking to me... (Tell her what happened in the dream.)~ GOTO MRSlayDream3
			IF ~!Global("MRSlayDreamLoop","GLOBAL",1)~ THEN REPLY ~Well, it really wasn't *you*. It seems my... um, 'instinct', has chosen your body as its avatar.~ DO ~SetGlobal("MRSlayDreamLoop","GLOBAL",1)~ GOTO MRSlayDreamAvatar
			++ ~You appeared, told me the Slayer is a nice guy, killed all my companions - including yourself - and then it ended. Oh, you also taught me to count up to five!~ GOTO MRSlayDreamShort
			++ ~I awoke in a bed in Calimshan. You were there, lying beside me, wearing nothing under the sheets but one of these thin, translucent silks... just when I was about to throw back the covers, the Slayer appeared dressed in a swimsuit and invited us to... (Tell her all about your dream.)~ GOTO MRSlayDreamCrazy
			++ ~Hrm, nevermind. Just me thinking crazy again.~ GOTO MRSlayDreamNo
	END


	IF ~~ THEN BEGIN MRSlayDreamNo
		SAY ~You sure? Some things are better if you get them off your chest.~
		++ ~Don't worry about me, I'll be just fine. Come, let's go on.~ GOTO MRSlayDreamEnd
		++ ~Hmm, maybe you're right. Very well, I'll tell you.~ GOTO MRSlayDream1a
	END

	IF ~~ THEN BEGIN MRSlayDreamEnd
		SAY ~(She shrugs, sighing) Your choice...~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDream1a
		SAY ~Great! So?~
			++ ~It took place in Candlekeep, as usual. I appeared before you inside the library, and you began talking to me... (Tell her what happened in the dream.)~ GOTO MRSlayDream3
			IF ~!Global("MRSlayDreamLoop","GLOBAL",1)~ THEN REPLY ~Well, it really wasn't *you*. It seems my... um, 'instinct', has chosen your body as its avatar.~ DO ~SetGlobal("MRSlayDreamLoop","GLOBAL",1)~ GOTO MRSlayDreamAvatar
			++ ~You appeared, told me the Slayer is a nice guy, killed all my companions - including yourself - and then it ended. Oh, you also taught me to count up to five!~ GOTO MRSlayDreamShort
			++ ~I awoke in a bed in Calimshan. You were there, lying beside me, wearing nothing under the sheets but one of these thin, translucent silks... just when I was about to throw back the covers, the Slayer appeared dressed in a swimsuit and invited us to... (Tell her all about your dream.)~ GOTO MRSlayDreamCrazy
	END

	IF ~~ THEN BEGIN MRSlayDreamCrazy
		SAY ~Uh-huh, right. So when I got naked and went into the pool, it was filled with sand instead of water.~
		=
		~And then the Slayer flew over me, peeing some kind of green liquid that melted the sand to ankheg milk.~
		=
		~Yeah, that sounds... perfectly normal to me. Now, in a completely unrelated topic... have you hit your head lately?~
		++ ~Haha, oh Imoen, I'm just kidding! I thought you'd be laughing by now.~ GOTO MRSlayDreamCrazyJoke
		++ ~Normal? Well, I found it quite disturbing. I hope I don't have such weird dreams anymore.~ GOTO MRSlayDreamCrazy2
		++ ~I can't remember. So... yes? I want candy now.~ GOTO MRSlayDreamCrazyCandy
		++ ~I'm fine. Let's go on.~ DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDreamCrazyJoke
		SAY ~(Imoen frowns, but after a moment she begins to smile) Yer such a stinker! You were so serious about it!~
		IF ~InParty("Aerie")~ THEN GOTO MRSlayDreamCrazyAerie
		IF ~!InParty("Aerie")~ THEN GOTO MRSlayDreamCrazyNext
	END
END

CHAIN IMOEN2J MRSlayDreamCrazyAerie
	~Spending all this time with Aerie is dulling my senses, I think. Otherwise I'd have seen through all that nonsense right away!~
	== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~Hey!~
	== IMOEN2J IF ~IsValidForPartyDialog("Aerie")~ THEN ~See? I was *joking*, Aerie!~
	== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~I know, Imoen... I just thought I'd speak on cue. (She giggles.)~
	== IMOEN2J IF ~IsValidForPartyDialog("Aerie")~ THEN ~(Imoen smiles at her and turns back to you.)~
END IMOEN2J MRSlayDreamCrazyNext

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRSlayDreamCrazyNext
		SAY ~Well, at least it's good to see you don't take things *so* seriously all the time, <CHARNAME>. It really doesn't make sense to dwell endlessly upon it, believe me...~
		=
		~(She sighs) So, alright. What was the *real* dream about?~
			++ ~It took place in Candlekeep, as usual. I appeared before you inside the library, and you began talking to me... (Tell her what happened in the dream.)~ GOTO MRSlayDream3
			++ ~Well, it really wasn't *you*. It seems my... um, 'instinct', has chosen your body as its avatar.~ GOTO MRSlayDreamAvatar
			++ ~You appeared, told me the Slayer is a nice guy, killed all my companions - including yourself - and it ended. Oh, you also taught me to count up to five!~ GOTO MRSlayDreamShort
	END	

	IF ~~ THEN BEGIN MRSlayDreamCrazy2
		SAY ~I sure hope so...~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDreamCrazyCandy
		SAY ~(Imoen stares at you, lips pursed) I sure hope yer leading us to Irenicus. It wouldn't surprise me if we end up in a candy shop at the end of the world.~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000) SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDreamShort
		SAY ~Whoa. That didn't make sense at all!~
		=
		~Let's try something else - how about you repeat it, slowly and with some *details*? It'll surely help.~
		++ ~Oh, alright. It took place in Candlekeep, as usual... (Tell her calmly what happened in the dream.)~ GOTO MRSlayDream3
		++ ~That's not what is important. IOt really wasn't *you*. It seems my... um, 'instinct', has chosen your body as an avatar.~ GOTO MRSlayDreamAvatar
		++ ~No, no, I have a better proposal: what if you mind your own business and stop being so nosy, Imoen?~ GOTO MRSlayDreamNosey
	END

	IF ~~ THEN BEGIN MRSlayDreamNosey
		SAY ~Huh? But it was *you* who wanted to tell me in the first place, you troll brain!~
		=
		~Hmph...~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000) SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDreamAvatar
		SAY ~Hah, and you can't figure out why? Apart from my *great* looks, I'm the only human on the realms that you'd obey blindly and unquestionably. So y'see, yer instinct is a smart! (She winks at you.)~
		=
		~But *anyway*, better if you tell me about the whole dream, hmm?~
		++ ~It took place in Candlekeep, as usual. I appeared before you inside the library, and you began talking to me... (Tell her what happened in the dream.)~ GOTO MRSlayDream3
		++ ~Don't mind it. Thanks for talking about it with me.~ + MRSlayDreamMidEND
		++ ~No, no, I have a better proposal: what if you mind your own business and stop being so nosy, Imoen?~ GOTO MRSlayDreamNosey
	END
	
	IF ~~ THEN BEGIN MRSlayDreamMidEND
           SAY ~Oh, well... we barely talked about it at all, but alright. Glad to be of service!~
               IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ EXIT
        END

	IF ~~ THEN BEGIN MRSlayDream3
		SAY ~(Imoen listens to you as you tell her about the dream. When you are done, she looks at you with a thoughtful expression.)~
		=
		~Wait, wait. So yer sayin'... I explained how you could become the Slayer?~
		++ ~Yes, that's it, more or less.~ GOTO MRSlayDream4
		++ ~Yeah. What do you think about it?~ GOTO MRSlayDream4
		++ ~Well, you seemed more interested in killing people than anything else.~ GOTO MRSlayDream4
		++ ~Not at all. Weren't you listening?~ GOTO MRSlayDreamListen
		++ ~Yes, but I didn't listen to you at all. I just stared at the pretty colors.~ GOTO MRSlayDreamListen2
	END

	IF ~~ THEN BEGIN MRSlayDream4
		SAY ~Hmmm...~
		IF ~~ THEN GOTO MRSlayDream5
	END

	IF ~~ THEN BEGIN MRSlayDreamAvatar2
		SAY ~Hah, and you can't figure out why? Apart from my *great* looks, I'm the only human on the realms that you'd obey blindly and unquestionably. So y'see, yer instinct is a smart! (She winks at you.)~
		IF ~~ THEN GOTO MRSlayDream5
	END

	IF ~~ THEN BEGIN MRSlayDreamListen
		SAY ~Oh, alright, enlighten me then, <PRO_LADYLORD> <CHARNAME>!~
		++ ~Uh, actually, I guess you were right.~ GOTO MRSlayDreamListen2
		++ ~In the first place, it wasn't *you*, but some creation of my subconscious. And secondly, you tried to *convince* me to become the Slayer, not just explain to me how to become it.~ GOTO MRSlayDreamCorrect
		++ ~The dream was about *onions*, don't you see? ONIONS!~ GOTO MRSlayDreamOnion
	END

	IF ~~ THEN BEGIN MRSlayDreamListen2
		SAY ~Hmph...~
		IF ~~ THEN GOTO MRSlayDream5
	END

	IF ~~ THEN BEGIN MRSlayDreamStrange
		SAY ~(Imoen looks at you strangely, but decides to reply.)~
		IF ~~ THEN GOTO MRSlayDream5
	END

	IF ~~ THEN BEGIN MRSlayDreamCorrect
		SAY ~Oh, excuse me, do you want me to write a detailed summary of your dream so we can check it point by point?~
		=
		~How 'bout you try to not be that much of a goblin cock, alright?~
		IF ~~ THEN GOTO MRSlayDreamListen2
	END

	IF ~~ THEN BEGIN MRSlayDreamOnion
		SAY ~(Imoen raises an eyebrow) Um, what?~
		++ ~YES! The Slayer is big, right? Big and dark. But I don't want to become the Slayer, right? I want to be the opposite of it; and what's the opposite of something big and dark? Something *little* and *white*, right? So... what's little and white? A PEELED ONION! Haha!~ GOTO MRSlayDreamOnion2
		++ ~Of course: the Slayer is inside me, in my inner self. To reach it, I only have to explore myself, *layer by layer*... what else has layers? ONIONS! Slayer, onion layer! You see?~ GOTO MRSlayDreamOnion2
		++ ~Uh, nothing, nothing. What do you think of these dreams?~ GOTO MRSlayDreamStrange
		++ ~Well, I like onions.~ GOTO MRSlayDreamOnion3
	END

	IF ~~ THEN BEGIN MRSlayDreamOnion2
		SAY ~(She stares at you as the profound conclusion you have reached begins to sink in.)~
		=
		~Yep. You are right. You have opened my eyes, really.~
		=
		~Let's... let's keep going, eh?~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDreamOnion3
		SAY ~Yeah, well... that's lovely for you. Keep up the good work, <CHARNAME>.~
		=
		~Let's... let's keep going, eh?~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDream5
		SAY ~You've got some pretty weird dreams, that's for sure. And they always manage to involve *me* in some way.~
		=
		~Guess it's the way your 'Bhaal side' manifests in you. You keep it suppressed while conscious, but in the dream world it has more freedom.~
		=
		~But it seems you're having a harder time keeping it away. I mean, you turned into the Slayer earlier, when fighting Bodhi. And now you tell me you can turn into it at will. You're becoming more and more a part of that 'Bhaal side' within you.~
		=
		~Not very appealing, huh? You don't have to tell me, it isn't funny, I know.~
		++ ~Not very, not. I do wonder why my 'inner instinct' takes your image. It's kind of... creepy.~ GOTO MRSlayDream5Avatar
		++ ~I don't really know, Imoen. The way you put it in the dream, it doesn't look that bad.~ GOTO MRSlayDream5NotBad
		++ ~Imoen... have you been experiencing things like this too?~ GOTO MRSlayDream5Imoen
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~Why isn't it appealing? Isn't the power the Slayer brings me appealing? Isn't the essence of a God... attractive?~ GOTO MRSlayDream5Appeal
		++ ~Speak for yourself. I intend to have all that power, and much more. And I will be able to control it.~ GOTO MRSlayDream5Control
		++ ~(Sigh) You are right, Imoen. Come, we've talked quite a lot already, and we have things to do.~ GOTO MRSlayDream5End
	END

	IF ~~ THEN BEGIN MRSlayDream5End
		SAY ~Yeah, I guess so...~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDream5Control
		SAY ~(Imoen looks at you with grave concern) I didn't think you were that naive, <CHARNAME>. I *know* that you aren't...~
		=
		~You won't be able to control it. It will swallow you. Can't you see what the last part of the dream means? Become the Slayer too many times... and you won't *be* <CHARNAME> any more.~
		=
		~As the Slayer you will be immensely powerful, but it won't be *you*. What good will all that power do you then?~
		=
		~I can't stop you from following that path. All I can do is ask you... please... don't seek that end.~
		=
		~Forget about the power, <CHARNAME>. If not for me, do it for yourself.~
		=
		~(Imoen touches your arm affectionately, a sincere plea in her eyes. With a squeeze, she walks away from you.)~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000) RunAwayFrom(Player1,30)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDream5Appeal
		SAY ~No. No, it isn't. Don't give in to that temptation. Didn't you understand what the last part of the dream means? Tread lightly with the Slayer, else you'll pay for it with your life.~
		=
		~It's even warning you! (She raises her hand, fingers extended, in front of your eyes) Five times, can't you see? Each time you fall to the lure of the Slayer... (She folds her fingers in, one by one) your basic nature will fade... and fade... and fade... (Her hand is closed) until you are consumed.~
		=
		~You are no god, no matter what you think. You've only a small portion of Bhaal's essence. Let the power overwhelm you completely... and you'll be no more than a beast.~
		=
		~I can't stop you from following that path. All I can ask you is... please, don't seek that end.~
		=
		~Forget about the power, <CHARNAME>. If not for me, do it for yourself.~
		=
		~(Imoen touches your arm affectionately, a sincere plea in her eyes. With a squeeze, she walks away from you.)~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000) RunAwayFrom(Player1,30)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDream5Imoen
		SAY ~Well... (She looks away warily.)~
		= ~Not like that, but... there are times when I... hear things. Things in my head.~
		= ~But it's nothing like what you have, I'm sure.~
		++ ~Oh no, Imoen. I am so sorry to hear that...~ GOTO MRSlayDream5Imoen2
		++ ~I do wonder why my 'inner instinct' takes your image. It's kind of... creepy.~ GOTO MRSlayDream5Avatar
		++ ~I don't know, Imoen. From the way you put it in the dream, it doesn't look *that* bad.~ GOTO MRSlayDream5NotBad
		++ ~(Sigh) These are the things we must cope with. Come, we've talked quite a lot already, and we have things to do.~ GOTO MRSlayDream5End
	END

	IF ~~ THEN BEGIN MRSlayDream5NotBad
		SAY ~Hey, look, first of all, it's not *me* who told you all that, alright? I've told you a lotta things, but I know for sure I'd never tell you to let the Slayer in and have a feast with your insides.~
		=
		~I don't care what your dreams says; becoming the slayer is *clearly* the dumbest choice you could make. Didn't you understand the last part of the dream? It's even warning you! Give in five times, and you'll be consumed by its power.~
		=
		~This offer the taint's making isn't an offer at all. It's just trying to dupe you. Yer smarter than that, I know you are.~
		=
		~(Imoen places her hand on your arm with affection) Forget about the power, <CHARNAME>. It's not real. Listen to me, okay?~
		=
		~(Imoen looks at you with a friendly smile and a plea in her eyes. She gives your arm a squeeze and walks away.)~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000) RunAwayFrom(Player1,30)~ EXIT
	END


	IF ~~ THEN BEGIN MRSlayDream5Avatar
		SAY ~I dunno. Since I'm a Child of Bhaal too and we have this 'common bond', I guess your instinct uses it to its advantage, trying to trick you or something.~
		= ~But you ignore me most of the time anyway, so all you gotta do is ignore the dream version too. (She winks at you.)~
		++ ~I won't fall to the Slayer, of that I am completely sure. You don't have to worry about that, Imoen.~ GOTO MRSlayDream6
		++ ~I don't know, Imoen. You made it seem in the dream as if it wasn't something that bad.~ GOTO MRSlayDream5NotBad
		++ ~Well, I might start now. I intend to have all that power, and much more. And I will be able to control it.~ GOTO MRSlayDream5Control
		++ ~Hah, it won't, Imoen. come, we've talked quite a lot already and we have things to do.~ GOTO MRSlayDream5End
	END

	IF ~~ THEN BEGIN MRSlayDream5Imoen2
		SAY ~Oh, don't worry about me, I'll be fine!~
		=
		~Start to worry when you find me running around, screaming 'KILL, KILL!', frothing and waving a sword about...~
		=
		~Hmm. Maybe that last sentence should have stayed in my head.~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000)~ EXIT
	END

	IF ~~ THEN BEGIN MRSlayDream6
		SAY ~I wish it were that simple.~
		=
		~(She places her hand on your arm, affection in her eyes) Resist it. It may be difficult but... I know you can, <CHARNAME>.~
		=
		~(With a smile, she walks away from you.)~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",3000) RunAwayFrom(Player1,30)~ EXIT
	END
END