// Unlike the previous version of Spending Quality Time with Imoen, these are much more scripted,
// to adapt to the much more fast paced plot and sense of urgency. 
// Contents:
// In the Pocket Plane
// In the Pocket Plane, the 2nd


// PID Option:


// In the Pocket Plane


// 1st
//Triggerable after second solar talk

// PID Option found in PIDTrees.d:
// + ~Global("ImoenRomanceActive","GLOBAL",2) IsGabber(Player1) Global("IRTQTPocket1","GLOBAL",1) AreaCheck("AR4500")~ + ~(Spend some relaxing quality time with Imoen.)~ DO ~SetGlobal("IRTQTPocket1","GLOBAL",2) IncrementGlobal("IRTLoveMeter","GLOBAL",2)~ + 2QT

APPEND IMOEN25J
IF ~~ THEN 2QT
	SAY ~Oh, hey, <CHARNAME>. I've been wondering, how does that thing... *work*, exactly?~ [IRYayRom]
	= ~(Imoen is looking at the Fate Spirit statue.) Can you call pretty much anyone? Could you get Drizzt Do'Urden or Elminster if you asked nicely?~
	++ ~No, unfortunately. The list seems limited to only those who might have joined us at some point.~ + 2QT1
	++ ~I am certain we have far surpassed even them, Imoen.~ + 2QT2
	++ ~We don't need those people when we have each other.~ + 2QT3
	++ ~I don't care about that, I only wanted to hug for a while.~ + 2QT4
	++ ~I don't care about that, I just wanted to fondle you for a bit.~ + 2QT5
END

IF ~~ THEN 2QT1
	SAY ~Huh. I suppose it makes sense, in a weird way. As much sense as pulling people through the nether can make, I guess.~
	IF ~~ THEN GOTO 2QTEnd
END

IF ~~ THEN 2QTEnd
	SAY ~Technically you created it, right? This whole place, it's your doing somehow. Not to be nit-picky, but it leaves something to be desired. Care to make a few couches? A fireplace would be nice, too. And a kitchen. And real big, comfy beds.~
	= ~And walls. (Her smile creeps wider.) Soundproof walls, for some much needed privacy.~
	++ ~We would never leave if I did that, love. The scarce amenities are for our own good, you see.~ + 2QTEnd1
	++ ~Wouldn't that be nice. I have no control, though - not yet, at any rate.~ + 2QTEnd2
	++ ~(Sidle closer.) We don't need any of that to have a good time.~ + 2QTEnd3
END

IF ~~ THEN 2QTEnd1
	SAY ~Ha ha, the sad part is you're right. I can barely keep my hands off you as it is - can you imagine having our own secret pocket-lovenest? The Five would raze Faerun while we play footsie under the covers.~
	IF ~~ THEN GOTO 2QTEndCommon
END

IF ~~ THEN 2QTEndCommon
	SAY ~Gods, it's gettin' me all tingly just thinking about it.~
	++ ~You know, we do kind of have a secret pocket-lovenest, big bed or no...~ + 2QTEnd1a
	++ ~(Pull her closer.) We'd be doing more than that, I promise you.~ + 2QTEnd1b
	++ ~It's a good thing we've only tents and bedrolls then. Time to go back to the real world.~ + 2QTEnd1c
	++ ~Can't wait 'til the next stay at an inn.~ + 2QTEnd1d
END

IF ~~ THEN 2QTEnd1a
	SAY ~(Her smile grows as wide as can be.) We do, don't we. With a bunch of side-rooms now, away from everything else...~
	IF ~~ THEN GOTO 2QTFinal
END

IF ~~ THEN 2QTEnd1b
	SAY ~(Her smile grows as wide as can be.) Y'know, there's a bunch of side-rooms here away from everything else...~
	IF ~~ THEN GOTO 2QTFinal
END

IF ~~ THEN 2QTEnd1c
	SAY ~(She sighs.) Oh real world, how I hate you so...~
	IF ~~ THEN EXIT
END

IF ~~ THEN 2QTEnd1d
	SAY ~Mmm. You know... there's a bunch of side-rooms now. Away from everything else.~
	IF ~~ THEN GOTO 2QTFinal
END

IF ~~ THEN 2QTFinal
	SAY ~We can... spare a few minutes, can't we?~
	++ ~Absolutely. Come here.~ + 2QT5a
	++ ~Not right now, but hold on to that thought. We'll rest here soon enough...~ + 2QTEndLater
END

IF ~~ THEN 2QTEndLater
	SAY ~Heh. Can hardly wait.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 2QTEnd2
	SAY ~Well then, keep workin' at it. I expect no less than a luxury suite within the tenday. A girl's gotta have standards, ya know.~
	= ~Though maybe it's better if you don't. I can barely keep my hands off you as it is - can you imagine having our own secret pocket-lovenest? The Five would raze Faerun while we play footsie under the covers.~
	IF ~~ THEN GOTO 2QTEndCommon
END
	
IF ~~ THEN 2QTEnd3
	SAY ~Ha ha, we never did, right? We've always found ways to make it work even in the worst of places.~
	IF ~~ THEN GOTO 2QTEnd1d
END

IF ~~ THEN 2QT2
	SAY ~Hah, you think so? That's a weird thought. Nearly as weird as our little cocoon plane.~
	IF ~~ THEN GOTO 2QTEnd
END

IF ~~ THEN 2QT3
	SAY ~(Imoen chuckles softly and gives your lips a brief yet heartfelt kiss.) That's right. Next one of the Five we fight, we'll start hugging and kissing 'til they're sick to death. Murder by love. (Her gaze falls on the Fate Spirit once more.)~
	IF ~~ THEN GOTO 2QTEnd
END

IF ~~ THEN 2QT4
	SAY ~(Imoen easily sinks into your ready embrace.) Hah, alright. Not gonna complain about that. (She continues wistfully regarding the Fate Spirit.)~
	IF ~~ THEN GOTO 2QTEnd
END

IF ~~ THEN 2QT5
	SAY ~Pfah hah! At least yer honest about it. I've a mind to let you for a while, if I can fondle back. Does this seem an agreeable arrangement to ya?~
	++ ~Absolutely. Come here.~ + 2QT5a
	++ ~No, I forbid it. You must remain perfectly still while I touch you.~ + 2QT5b
END

IF ~~ THEN 2QT5a
	SAY ~(Imoen easily sinks in your ready embrace, laughing softly. Among increasingly passionate kisses you steal her away to a more private location...)~
	IF ~~ THEN DO ~SetGlobal("IRT2QTAfter","GLOBAL",1)  StartCutSceneMode() StartCutScene("2QTCut")~ EXIT
END

IF ~~ THEN 2QT5b
	SAY ~(Imoen blinks several times, not quite smiling.) Wow, that got super creepy in a hurry. Don't feel like humoring yer fetish at the moment, sorry.~
	= ~Try me again later, though. Might be fun to let you do all the touching...~
	IF ~~ THEN EXIT
END

// After the fade to black

IF WEIGHT #-10 ~Global("IRT2QTAfter","GLOBAL",1)~ THEN 2QTAfter
	SAY ~Whew... (Imoen pants heavily, trying to catch her breath. She is adjusting her hastily displaced clothes.) We got... a bit... carried away...~
	IF ~~ THEN DO ~SetGlobal("IRT2QTAfter","GLOBAL",2)~ GOTO 2QTAfterN
END

IF ~~ THEN 2QTAfterN
	SAY ~(She licks her lips and works on fixing up her hair.) We really shouldn't do this often. There's so much stuff to take care of, can't be pawing at each other all the time like we used to.~
	++ ~I think we both needed it, Imoen.~ + 2QTAf1
	++ ~Whenever we're out there, I'm constantly thinking about you. I won't be able to keep away if there is a chance to be together.~ + 2QTAf2
	++ ~Agreed. We have to focus until it's all resolved, or we could lose everything.~ + 2QTAf3
	++ ~Screw that. Let's go again, right now.~ + 2QTAf4
	++ ~You say this after the fact, but let's see how long that resolve lasts...~ + 2QTAf5
END

IF ~~ THEN 2QTAf1
	SAY ~Well... yeah, sure felt good to relieve all that tension. Yeah! It's all for the greater good, of course! It's our *duty* to break off from time to time and take care of all the pent-up stress. Otherwise, disaster might strike. It's life or death!~
	= ~Thank goodness we are such responsible individuals.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 2QTAf2
	SAY ~Gah. How can I possibly be responsible here if you keep saying these things? I already wanna jump you again. Bad <CHARNAME>! Bad!~
	= ~Let's get on the move before I give up on restraint altogether.~
	IF ~~ THEN EXIT
END

IF ~~ THEN 2QTAf3
	SAY ~That's right. I'm sure we won't ever jump each other, ever again. You and I, <CHARNAME>, we are bastions of restraint from now on. Yep.~
	= ~(Imoen looks you up and down and up again.) Not thinking about it already, nope, nope, nope...~
	IF ~~ THEN EXIT
END	

IF ~~ THEN 2QTAf4
	SAY ~Whoa, no no no no, keep yer mitts away from me, come on...~
	= ~(Despite her words, Imoen is biting her lip, looking you up and down and up again.)~
	= ~You really think it's okay?~
	++ ~(Answer by tangling your fingers in the back of her head and linking your lips to hers.)~ + 2QTAf4a
	++ ~Who cares? I want you, Imoen.~ + 2QTAf4b
	++ ~The world can wait another thirty minutes. Or an hour or two.~ + 2QTAf4b
	++ ~No, you're right, we better go.~ + 2QTAf4c
END	

IF ~~ THEN 2QTAf4a
	SAY ~(She doesn't resist your touch for even a moment. Her mouth reciprocates with hunger as she pushes against you, her hands already working to undo clasps and buttons...)~
	IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRT2QTAfter","GLOBAL",3)  StartCutSceneMode() StartCutScene("2QTACut")~ EXIT
END

IF ~~ THEN 2QTAf4b
	SAY ~(She doesn't need any more encouragement. Imoen closes the small distance between you and joins her mouth to yours, pushing herself against your body with avid hunger.)~
	= ~(Her hands quickly get to work undoing clasps and buttons...)~
	IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRT2QTAfter","GLOBAL",3)  StartCutSceneMode() StartCutScene("2QTACut")~ EXIT
END
	
IF ~~ THEN 2QTAf4c
	SAY ~Yeah... yeah. Of course we should. Yeah. Any more would be greedy...~
	IF ~~ THEN EXIT
END 

IF ~~ THEN 2QTAf5
	SAY ~Hey, I'll betcha I can last for a WHOLE hour, just you wait.~
	= ~(Imoen looks you up and down and up again.) Not thinking about it already, nope, nope, nope...~
	IF ~~ THEN EXIT
END	
END


// In the Pocket Plane, the 2nd
// Make sure this PID option is only available after either Sendai or Abazigal is dead, and the first pocket plane quality time has happened.
//	+ ~Global("ImoenRomanceActive","GLOBAL",2) IsGabber(Player1) GlobalGT("IRTQTPocket1","GLOBAL",1) Global("IRTQTPocket2","GLOBAL",0) AreaCheck("AR4500") OR(2) Dead("Abazigal") Dead("Sendai")~ + ~(Spend some relaxing quality time with Imoen.)~ DO ~SetGlobal("IRTQTPocket2","GLOBAL",1) IncrementGlobal("IRTLoveMeter","GLOBAL",2)~ + 4QT

APPEND IMOEN25J
IF ~~ THEN 4QT
	SAY ~It's so rough out there, <CHARNAME>. The fighting is constant, and the enemies so many. I didn't expect it to get this bad, if I'm honest.~ [IRYayRom]
	= ~Maybe we can have some time to just... sit? Anywhere here. Just sit and talk and hold each other. Maybe make fun of some of the weird statues and give them names.~
	++ ~How can you get tired of the action? The fighting is the best part of our lives!~ + 4QT1
	++ ~Whatever you like. I just want to spend time with you.~ + 4QT2
	++ ~That sounds like exactly the kind of thing I'm in the mood for.~ + 4QT3
	++ ~What we've been doing gets surreal at times, doesn't it? It's hard to believe the kind of enemies we've defeated.~ + 4QT4
	++ ~(Point in turn.) Lumpy, Stumpy, One-Eye Jones, Shortcake and Bob. Can we get to the kissing and heavy petting now?~ + 4QT5
END

IF ~~ THEN 4QT1
	SAY ~Hah. Don't you get sick of it sometimes? Don't get me wrong, I like adventure as much as any other gal, but it hasn't really been like that. It's gotten a bit ridiculous, honestly.~
	IF ~~ THEN GOTO 4QTSit
END
	
IF ~~ THEN 4QT2
	SAY ~Aww, that's a sweet thing to say. Downtime together sounds lovely right now. The way things have been, sometimes it feels like everything we do is slay ten-foot-tall monsters all day.~
	IF ~~ THEN GOTO 4QTSit
END

IF ~~ THEN 4QT3
	SAY ~Yeah, can't blame ya at all. The way things have been, sometimes it feels like everything we do is slay ten-foot-tall monsters all day.~
	IF ~~ THEN GOTO 4QTSit
END

IF ~~ THEN 4QT4
	SAY ~I know! Dragons, and giants, and golems, and ugly spiky things and monsters that defy description...~
	IF ~~ THEN GOTO 4QTSit
END

IF ~~ THEN 4QTSit
	SAY ~(Imoen sets up a blanket and a few snacks while speaking.) Remember leaving Candlekeep, nearly getting killed trying to fend off a stray dire wolf? What was that, two years ago? Not to sound full of myself or anything, but most adventurers don't get this far in their whole lives. Probably because they die first...~
	= ~(She sits on the blanket and pats the space next to her, smiling up at you.)~
	++ ~(Sit next to her.)~ + 4QTSitN 
	++ ~This spot is far too exposed for us to do what I want to do, if you catch my meaning.~ + 4QTSit2
END

IF ~~ THEN 4QTSitN
	SAY ~(Imoen draws you close, circling your waist with one arm and nestling herself against you. Her free hand darts into the kerchief of snacks and picks a cinnamon cookie from the pile.)~
	= ~How are we still alive, <CHARNAME>? Look at everything we've been through. No-one should've survived it, and yet here we are.~
	= ~(She looks up.) It's you, isn't it. You are incredible. That's the answer.~
	++ ~It's fate, Imoen. We are destined to be here, doing what we are doing.~ + 4QTS0
	++ ~Beats me! I'm one lucky <PRO_MANWOMAN>, that's for sure.~ + 4QTS1
	++ ~This is such a grim topic to talk about, I thought we were naming statues.~ + 4QTS2
	++ ~No - it's you and me, together. *We* are unstoppable, no matter what comes.~ + 4QTS3
	++ ~I'm glad you know my power. Everyone else keeps underestimating me.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1)~ + 4QTS4
	++ ~(Hold her chin and bring your lips to hers.)~ + 4QTS5
END

IF ~~ THEN 4QTS0
	SAY ~(She shakes her head.) Give yourself some credit. None of it would have happened without your strength and resolve, fate or no fate. You've earned it. (She kisses the underside of your jaw.)~
	IF ~~ THEN GOTO 4QTSNext
END

IF ~~ THEN 4QTS1
	SAY ~(She shakes her head.) Give yourself some credit. None of it would have happened without your strength and resolve, luck or no luck. You've earned it. (She kisses the underside of your jaw.)~
	IF ~~ THEN GOTO 4QTSNext
END

IF ~~ THEN 4QTS2
	SAY ~Oh Gods, you're right, I'm so sorry! I didn't mean to turn so bleak. Here, have a cookie. (She places hers in your mouth and digs for another.)~
	IF ~~ THEN GOTO 4QTSNextN
END
	
IF ~~ THEN 4QTS3
	SAY ~Hah hah, I wish. I mean, thanks an' all, but... you're something else. We wouldn't have survived without your strength and resolve, Imoen or no Imoen. Take the credit, you've earned it. (She kisses the underside of your jaw.)~
	IF ~~ THEN GOTO 4QTSNext
END

IF ~~ THEN 4QTS4
	SAY ~Fools that they are. It used to intimidate me, way back, but now it's just baffling - the boasting and the bravado, I'm talking about. You'd think they'd all learned to run away by now. (She kisses the underside of your jaw.)~
	IF ~~ THEN GOTO 4QTSNext
END
	
IF ~~ THEN 4QTS5
	SAY ~(She receives your kiss with calm joy, savoring the moment. Perhaps in an attempt not to take it further, once more she nestles herself against your chest.)~
	IF ~~ THEN GOTO 4QTSNext
END

IF ~~ THEN 4QTSNext
	SAY ~Anyway, I didn't mean to get so serious! This was supposed to be some nice, lightweight fun. (Imoen bites half the cookie into her mouth and chews happily.)~
	IF ~~ THEN GOTO 4QTSNextN
END

IF ~~ THEN 4QTSNextN
	SAY ~(She points a lazy finger straight ahead, at a statue with undulating limbs and a blocky, near featureless head.) That's Numbskull the Smothered. How about that one?~
	= ~(The figure in question has multiple elongated arms, a narrow waist and several pairs of eyes.)~
	++ ~Spiderfool.~ + 4QTStat1a
	++ ~Goro.~ + 4QTStat1b
	++ ~Shelob.~ + 4QTStat1b
	++ ~Kali.~ + 4QTStat1b
	++ ~Gertrude the All-seeing.~ + 4QTStat1a
	++ ~Dumb Bitch.~ + 4QTStat1c
	++ ~This game is silly, let's get to the fun part already. (Place a venturing hand on her thigh.)~ + 4QTSit2
END

IF ~~ THEN 4QTStat1a
	SAY ~Haha, good one.~
	IF ~~ THEN GOTO 4QTStat2
END

IF ~~ THEN 4QTStat1b
	SAY ~That's... oddly appropriate, somehow. I like it.~
	IF ~~ THEN GOTO 4QTStat2
END

IF ~~ THEN 4QTStat1c
	SAY ~Pff, you goon.~
	IF ~~ THEN GOTO 4QTStat2
END

IF ~~ THEN 4QTStat2
	SAY ~(She points at the next one, a hulking mass of stocky appendages yet soothing expression.) The Umber Funk! Your turn.~
	= ~(The adjacent statue is a half-formed torso with tentacle limbs, several protruding spikes and tormented features.)~
	++ ~Happy Camper.~ + 4QTStat2a
	++ ~Drunken Sculptor.~ + 4QTStat2b
	++ ~Jaheira.~ + 4QTStat2c
	++ ~The Nameless One.~ + 4QTStat2d
	++ ~Bad Day Jones.~ + 4QTStat2a
	++ ~Mother-in-Law.~ + 4QTStat2e
	++ ~This game is silly, let's get to the fun part already. (Place a venturing hand on her thigh.)~ + 4QTSit2
END

IF ~~ THEN 4QTStat2a
	SAY ~Hee hee, Spot on!~
	IF ~~ THEN GOTO 4QTTheEnd
END

IF ~~ THEN 4QTStat2b
	SAY ~(Imoen chuckles goodnaturedly.) No kiddin'. About-to-pass-out drunk, for sure.~
	IF ~~ THEN GOTO 4QTTheEnd
END

IF ~~ THEN 4QTStat2c
	SAY ~(Imoen swats your leg, though she laughs all the same.) That's sooo mean, and you know it. She doesn't have nearly as many spikes.~
	IF ~~ THEN GOTO 4QTTheEnd
END

IF ~~ THEN 4QTStat2d
	SAY ~Hah, that's cheating! They're *all* nameless ones, that's the whole point...~
	IF ~~ THEN GOTO 4QTTheEnd
END

IF ~~ THEN 4QTStat2e
	SAY ~Hahaha! Ohh, that's so mean-spirited. I like it.~
	IF ~~ THEN GOTO 4QTTheEnd
END

IF ~~ THEN 4QTTheEnd
	SAY ~(Together you carry on naming every grotesque statue in your pocket realm, the game soon turning into a conversation that goes nowhere in particular. Resting in each other's arms, you speak of simple things, things that have nothing to do with Bhaal, or death, or prophecy. Anything from growing up stories to the sky of the Pocket Plane, from counting calluses and scars to the way each of you enjoys breakfast and back to statue mockery. Imoen remains cheerful and upbeat throughout, in a striking resemblance to the Imoen you knew before all the harrowing hardship took its toll.)~
	= ~(Time slips you by, content in one another's company. Content in the fact that, regardless of dire circumstances or imminent danger, you can still talk freely to each other without consequence. You can still be Imoen and <CHARNAME>.)~
	IF ~~ THEN DO ~StartCutSceneMode() Wait(1) FadeToColor([40.0],0) Wait(1) RestParty() Wait(1) FadeFromColor([20.0],0) Wait(1) EndCutSceneMode()~ EXIT
END
	
IF ~~ THEN 4QTSit2
	SAY ~(You get a hearty laugh out of Imoen.) So impatient! I just wanted to talk for a bit, but there you are again, tempting me so... (She throws a meaningful glance at the pocket room with the sandy ponds.) I can set this up over there and see where that leads. Maybe somewhere we've been to before, who knows...~
	IF ~~ THEN GOTO 4QT5Sex
END

IF ~~ THEN 4QT5
	SAY ~(You get a hearty laugh out of Imoen.) So impatient! I just wanted to talk for a bit, but there you are again, tempting me so... (She throws a meaningful glance at the pocket room with the sandy ponds.) I can set up a blanket and some snacks over there and see where that leads. Maybe somewhere we've been to before, who knows...~
	IF ~~ THEN GOTO 4QT5Sex
END

IF ~~ THEN 4QT5Sex
	SAY ~What do you say?~
	++ ~That is far more desirable, yes.~ + 4QT5Sex1
	++ ~I thought you'd never get there.~ + 4QT5Sex1
	++ ~We can do better than that. (Pick her up and carry her exactly where you want to go.)~ + 4QT5Sex2
	++ ~Forget the blanket and the snacks, you're all I need, and I need it now. (Pull her up to you and take her in your arms.)~ + 4QT5Sex3
END

IF ~~ THEN 4QT5Sex1
	SAY ~(Without another word she hastily picks up the items and walks ahead of you into the idyllic chamber. The spring in her step gives away the sudden excitement that has come over her. The sway of her hips and the look she throws over her shoulder cast no doubt over her intent.)~
	= ~(You follow her in, spellbound in the promise of your mutual longing...)~
	IF ~~ THEN DO ~StartCutSceneMode() Wait(1) FadeToColor([30.0],0) Wait(1) RestParty() Wait(1) FadeFromColor([30.0],0) Wait(1) EndCutSceneMode()~ EXIT
END

IF ~~ THEN 4QT5Sex2
	SAY ~Whoa- hee hee hee! (Imoen breaks in giggles as you haul her into your arms and stride toward a secluded corner of your choosing. She holds on to you far tighter than is necessary, pressing herself against your chest.)~
	IF ~~ THEN GOTO 4QT5SexEnd
END

IF ~~ THEN 4QT5Sex3
	SAY ~Whoa- hee hee hee! (Imoen breaks in giggles as you haul her into your arms and stride toward the idyllic chamber. She holds on to you far tighter than is necessary, pressing herself against your chest.)~
	IF ~~ THEN GOTO 4QT5SexEnd
END

IF ~~ THEN 4QT5SexEnd
	SAY ~(Already she is placing ardent kisses on your jaw and neck...)~
	IF ~~ THEN DO ~StartCutSceneMode() Wait(1) FadeToColor([30.0],0) Wait(1) RestParty() Wait(1) FadeFromColor([30.0],0) Wait(1) EndCutSceneMode()~ EXIT
END
END











	
	
	
	


