/* Phaere Innuendo */

EXTEND_TOP UDPHAE01 106 #2
	IF ~OR(2)
	Global("ImoenRomanceActive","GLOBAL",1)
	Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~My companion, Imoen.~ GOTO 110
END

APPEND IMOEN2J
	IF ~Global("PhaereInnuendo","GLOBAL",2)
		Global("MRSleptPhaere","GLOBAL",1)~ THEN BEGIN MRSleptPhaere
		SAY ~Sheesh, what a racket. Did you get any sleep at *all*? Y'know, I always thought stone walls would muffle sound a little better.~
		++ ~What I did last night is none of your business, Imoen.~ DO ~SetGlobal("MRSleptPhaere","GLOBAL",2)~GOTO MRSleptPhaere1
		++ ~Not a single wink, but man, it was worth it!~ DO ~SetGlobal("MRSleptPhaere","GLOBAL",2)~ GOTO MRSleptPhaere2
		++ ~Eh, for a drow, Phaere was pretty yawn-inspiring.~ DO ~SetGlobal("MRSleptPhaere","GLOBAL",2)~ GOTO MRSleptPhaere3
	END

	IF ~~ THEN BEGIN MRSleptPhaere1
		SAY ~Oh c'mon, like it's hard to figure out! (she mimics Phaere's voice) "Oh, Veldrin! Harder! Yes!"~
		=
		~Y'all were about as subtle as two trolls in heat, so don't get all high-and-mighty at me, mister.~
		++ ~I'm not proud of it. I did what I had to do.~ GOTO MRSleptPhaere1Need
		++ ~Hmm... yes, she *did* sound very pleased, didn't she?~ GOTO MRSleptPhaere1Proud
		++ ~Shut. Up.~ GOTO MRSleptPhaere1Proud
	END

	IF ~~ THEN BEGIN MRSleptPhaere1Need
		SAY ~(Imoen smirks) Yeah, I'm sure that was *such* a sacrifice for you.~ 
		IF ~~ THEN GOTO MRSleptPhaere1Proud
	END

	IF ~~ THEN BEGIN MRSleptPhaere2
		SAY ~Hah! Yeah, I figured as much.~ 
		IF ~~ THEN GOTO MRSleptPhaere1Proud
	END

	IF ~~ THEN BEGIN MRSleptPhaere3
		SAY ~What? It sure didn't sound like it from *this* side of the door!~ 
		IF ~~ THEN GOTO MRSleptPhaere1Proud
	END

	IF ~~ THEN BEGIN MRSleptPhaere1Proud
		SAY ~Gosh, with all that moaning, even *I* got a little - uh - I mean...~
		=
		~Y'know, actually, it's really none of my business. Let's keep moving, 'kay?~
		++ ~You're right, it's not. Let's go.~ EXIT
		++ ~*You* got turned on by-~ GOTO MRSleptPhaere1ProudEnd
		++ ~Hah! I knew you liked-~ GOTO MRSleptPhaere1ProudEnd
		++ ~That's disgust-~ GOTO MRSleptPhaere1ProudEnd
	END

	IF ~~ THEN BEGIN MRSleptPhaere1ProudEnd
		SAY ~(Imoen glares at you, blushing furiously) LET'S KEEP MOVING.~
		IF ~~ THEN EXIT
	END

	IF ~Global("PhaereInnuendo","GLOBAL",3)
		Global("MRSleptPhaere","GLOBAL",1) ~ THEN BEGIN MRNoSleptPhaere
		SAY ~You're back already? (Imoen giggles) Performance problems, 'Veldrin'? I got a spell for that!~
		++ ~I *could* have, I just didn't want to.~ DO ~SetGlobal("MRSleptPhaere","GLOBAL",2)~ GOTO MRNoSleptPhaere1
		IF ~OR(5)
			IsValidForPartyDialog("Viconia")
			IsValidForPartyDialog("Aerie")
			IsValidForPartyDialog("Anomen")
			IsValidForPartyDialog("Keldorn")
			IsValidForPartyDialog("Jaheira")~ THEN REPLY ~You do? Oh, thank the gods! Quick, cast it!~ DO ~SetGlobal("MRSleptPhaere","GLOBAL",2)~ GOTO MRNoSleptPhaere2All
		++ ~Ha ha. Very funny.~ DO ~SetGlobal("MRSleptPhaere","GLOBAL",2)~GOTO MRNoSleptPhaere3
	END
	
	IF ~~ THEN BEGIN MRNoSleptPhaere2All
		SAY~I was joking, you goon! Even if I did have that spell, it sure wouldn't do you any good now.~
		
		IF ~OR(5)
			IsValidForPartyDialog("Viconia")
			IsValidForPartyDialog("Aerie")
			IsValidForPartyDialog("Anomen")
			IsValidForPartyDialog("Keldorn")
			IsValidForPartyDialog("Jaheira")~ THEN GOTO MRNoSleptPhaere2Cler
		
		IF ~IsValidForPartyDialog("Viconia") 
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Anomen")
			!IsValidForPartyDialog("Keldorn")
			!IsValidForPartyDialog("Jaheira")~ THEN GOTO MRNoSleptPhaere2Vic
		IF ~IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Viconia")
			!IsValidForPartyDialog("Anomen")
			!IsValidForPartyDialog("Keldorn")
			!IsValidForPartyDialog("Jaheira")~ THEN GOTO MRNoSleptPhaere2Aer
		IF ~IsValidForPartyDialog("Anomen")
			!IsValidForPartyDialog("Viconia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Keldorn")
			!IsValidForPartyDialog("Jaheira")~ THEN GOTO MRNoSleptPhaere2Ano
		IF ~IsValidForPartyDialog("Keldorn")
			!IsValidForPartyDialog("Viconia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Anomen")
			!IsValidForPartyDialog("Jaheira")~ THEN GOTO MRNoSleptPhaere2Kel
		IF ~IsValidForPartyDialog("Jaheira")
			!IsValidForPartyDialog("Viconia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Anomen")
			!IsValidForPartyDialog("Keldorn")~ THEN GOTO MRNoSleptPhaere2Jah
	END
	
	IF ~~ THEN BEGIN MRNoSleptPhaere3
		SAY ~C'mon, you gotta admit, not many people would walk out willingly from a chance like that!~
		++ ~Some people, perhaps. I wasn't tempted in the slightest.~ GOTO MRNoSleptPhaere1
		++ ~We have a mission to accomplish, and sex would just be a distraction.~ GOTO MRNoSleptPhaereDistract
		++ ~Drow just aren't my type. Too... evil-y.~ GOTO MRNoSleptPhaereEvil
		++ ~You think so? Why don't YOU sleep with her?~ GOTO MRNoSleptPhaereBi
		IF ~OR(4)
		Global("ImoenRomanceActive","GLOBAL",1)
		Global("AerieRomanceActive","GLOBAL",2)
		Global("JaheiraRomanceActive","GLOBAL",2)
		Global("ViconiaRomanceActive","GLOBAL",2)~ THEN REPLY ~My heart is already taken. I could never betray that.~ GOTO MRNoSleptPhaereWho
	END
		
	IF ~~ THEN BEGIN MRNoSleptPhaere2Vic
		SAY ~'Sides, 'cure impotence' would be a clerical spell, dontcha think? Maybe you should ask Viconia.~
			++ ~Uh, actually, maybe it's best that we just focus on our quest.~ EXIT
			IF ~IsValidForPartyDialog("Viconia") Global("ViconiaRomanceActive","GLOBAL",2)~ THEN REPLY ~So, Viconia - you wouldn't want to deny Phaere a chance with me, right?~ EXTERN VICONIJ MRNoSleptPhaere1
			IF ~IsValidForPartyDialog("Viconia") !Global("ViconiaRomanceActive","GLOBAL",2)~ THEN REPLY ~So, Viconia - you wouldn't want to deny Phaere a chance with me, right?~ EXTERN VICONIJ MRNoSleptPhaere2
			IF ~CheckStatGT(Player1,9,WIS)
			OR(4)
		Global("AerieRomanceActive","GLOBAL",2)
		Global("JaheiraRomanceActive","GLOBAL",2)
		Global("ViconiaRomanceActive","GLOBAL",2)
		Global("AnomenRomance","GLOBAL",2)~
			THEN REPLY ~(Perhaps asking this in front of your beloved isn't the best of ideas) I was joking! I wouldn't touch that woman with a 10-foot pole.~ GOTO MRNoSleptPhaere1
	END

	IF ~~ THEN BEGIN MRNoSleptPhaere2Aer
		SAY ~'Sides, 'cure impotence' would be a clerical spell, dontcha think? Maybe you should ask Aerie.~
			++ ~Uh, actually, maybe it's best that we just focus on our quest.~ EXIT
			IF ~IsValidForPartyDialog("Aerie") Global("AerieRomanceActive","GLOBAL",2)~ THEN REPLY ~Aerie, between your arcane and divine knowledge, you *must* know a solution!~ EXTERN AERIEJ NoSleptPhaere1
			IF ~IsValidForPartyDialog("Aerie") !Global("AerieRomanceActive","GLOBAL",2)~ THEN REPLY ~Aerie, between your arcane and divine knowledge, you *must* know a solution!~ EXTERN AERIEJ NoSleptPhaere2
			IF ~CheckStatGT(Player1,9,WIS)
			OR(4)
		Global("AerieRomanceActive","GLOBAL",2)
		Global("JaheiraRomanceActive","GLOBAL",2)
		Global("ViconiaRomanceActive","GLOBAL",2)
		Global("AnomenRomance","GLOBAL",2)~
			THEN REPLY ~(Perhaps asking this in front of your beloved isn't the best of ideas) I was joking! I wouldn't touch that woman with a 10-foot pole.~ GOTO MRNoSleptPhaere1
	END

	IF ~~ THEN BEGIN MRNoSleptPhaere2Ano
		SAY ~'Sides, 'cure impotence' would be a clerical spell, dontcha think? Maybe you should ask Anomen.~
			++ ~Uh, actually, maybe it's best that we just focus on our quest.~ EXIT
			IF ~IsValidForPartyDialog("Anomen")~ THEN REPLY ~Anomen, we are the young and frustrated! Surely you could cast something?~ EXTERN ANOMENJ MRNoSleptPhaere
			IF ~CheckStatGT(Player1,9,WIS)
			OR(4)
		Global("AerieRomanceActive","GLOBAL",2)
		Global("JaheiraRomanceActive","GLOBAL",2)
		Global("ViconiaRomanceActive","GLOBAL",2)
		Global("AnomenRomance","GLOBAL",2)~
			THEN REPLY ~(Perhaps asking this in front of your beloved isn't the best of ideas) I was joking! I wouldn't touch that woman with a 10-foot pole.~ GOTO MRNoSleptPhaere1
	END

	IF ~~ THEN BEGIN MRNoSleptPhaere2Kel
		SAY ~'Sides, 'cure impotence' would be a clerical spell, dontcha think? Maybe you should ask Keldorn.~
			++ ~Uh, actually, maybe it's best that we just focus on our quest.~ EXIT
			IF ~IsValidForPartyDialog("Keldorn")~ THEN REPLY ~Come on, Keldorn, you're experienced. Help a guy out?~ EXTERN KELDORJ MRNoSleptPhaere
			IF ~CheckStatGT(Player1,9,WIS)
			OR(4)
		Global("AerieRomanceActive","GLOBAL",2)
		Global("JaheiraRomanceActive","GLOBAL",2)
		Global("ViconiaRomanceActive","GLOBAL",2)
		Global("AnomenRomance","GLOBAL",2)~
			THEN REPLY ~(Perhaps asking this in front of your beloved isn't the best of ideas) I was joking! I wouldn't touch that woman with a 10-foot pole.~ GOTO MRNoSleptPhaere1
	END

	IF ~~ THEN BEGIN MRNoSleptPhaere2Jah
		SAY ~'Sides, 'cure impotence' would be a druidic spell, dontcha think? Maybe you should ask Jaheira.~
			++ ~Uh, actually, maybe it's best that we just focus on our quest.~ EXIT
			IF ~IsValidForPartyDialog("Jaheira") Global("JaheiraRomanceActive","GLOBAL",2)~ THEN REPLY ~Do you have any 'natural remedies', Jaheira?~ EXTERN JAHEIRAJ MRNoSleptPhaere1
			IF ~IsValidForPartyDialog("Jaheira") !Global("JaheiraRomanceActive","GLOBAL",2)~ THEN REPLY ~Do you have any 'natural remedies', Jaheira?~ EXTERN JAHEIRAJ MRNoSleptPhaere2
			IF ~CheckStatGT(Player1,9,WIS)
			OR(4)
		Global("AerieRomanceActive","GLOBAL",2)
		Global("JaheiraRomanceActive","GLOBAL",2)
		Global("ViconiaRomanceActive","GLOBAL",2)
		Global("AnomenRomance","GLOBAL",2)~
			THEN REPLY ~(Perhaps asking this in front of your beloved isn't the best of ideas) I was joking! I wouldn't touch that woman with a 10-foot pole.~ GOTO MRNoSleptPhaere1
	END
	
	IF ~~ THEN BEGIN MRNoSleptPhaere2Cler
		SAY ~'Sides, 'cure impotence' wouldn't be an arcane spell. Maybe you should ask one of the other healers.~
			++ ~Uh, actually, maybe it's best that we just focus on our quest.~ EXIT
			IF ~IsValidForPartyDialog("Viconia") Global("ViconiaRomanceActive","GLOBAL",2)~ THEN REPLY ~So, Viconia - you wouldn't want to deny Phaere a chance with me, right?~ EXTERN VICONIJ MRNoSleptPhaere1
			IF ~IsValidForPartyDialog("Viconia") !Global("ViconiaRomanceActive","GLOBAL",2)~ THEN REPLY ~So, Viconia - you wouldn't want to deny Phaere a chance with me, right?~ EXTERN VICONIJ MRNoSleptPhaere2
			IF ~IsValidForPartyDialog("Aerie") Global("AerieRomanceActive","GLOBAL",2)~ THEN REPLY ~Aerie, between your arcane and divine knowledge, you *must* know a solution!~ EXTERN AERIEJ NoSleptPhaere1
			IF ~IsValidForPartyDialog("Aerie") !Global("AerieRomanceActive","GLOBAL",2)~ THEN REPLY ~Aerie, between your arcane and divine knowledge, you *must* know a solution!~ EXTERN AERIEJ NoSleptPhaere2
			IF ~IsValidForPartyDialog("Jaheira") Global("JaheiraRomanceActive","GLOBAL",2)~ THEN REPLY ~Do you have any 'natural remedies', Jaheira?~ EXTERN JAHEIRAJ MRNoSleptPhaere1
			IF ~IsValidForPartyDialog("Jaheira") !Global("JaheiraRomanceActive","GLOBAL",2)~ THEN REPLY ~Do you have any 'natural remedies', Jaheira?~ EXTERN JAHEIRAJ MRNoSleptPhaere2
			IF ~IsValidForPartyDialog("Anomen")~ THEN REPLY ~Anomen, we are the young and frustrated! Surely you could cast something?~ EXTERN ANOMENJ MRNoSleptPhaere
			IF ~IsValidForPartyDialog("Keldorn")~ THEN REPLY ~Come on, Keldorn, you're experienced. Help a guy out?~ EXTERN KELDORJ MRNoSleptPhaere
			IF ~CheckStatGT(Player1,9,WIS)
			OR(4)
			Global("AerieRomanceActive","GLOBAL",2)
			Global("JaheiraRomanceActive","GLOBAL",2)
			Global("ViconiaRomanceActive","GLOBAL",2)
			Global("AnomenRomance","GLOBAL",2)~
			THEN REPLY ~(Perhaps asking this in front of your beloved isn't the best of ideas) I was joking! I wouldn't touch that woman with a 10-foot pole.~ GOTO MRNoSleptPhaere1
		END
			
END

APPEND VICONIJ
	IF ~~ THEN BEGIN MRNoSleptPhaere1
		 SAY ~(her eyes narrow) Iblith caluss! I will share you when and with whom I choose - if I so choose.~
		= ~You are still a lowly, pathetic <PRO_RACE>. Do not let your swollen manhood enlarge your ego as well.~
		IF ~~ THEN EXTERN IMOEN2J MRNoSleptPhaere4
	END
	IF ~~ THEN BEGIN MRNoSleptPhaere2
		SAY ~Her passion would kill you, iblith. Drow lusts are not for the weak of heart.~ 
		IF ~~ THEN EXTERN IMOEN2J MRNoSleptPhaere4
	END
END

APPEND AERIEJ
	IF ~~ THEN BEGIN NoSleptPhaere1
	SAY ~N-no! Why in Baervar's name would you even want to go back in there? I th-thought... I thought you loved *me*...~
	= ~J-just... just leave me alone, <CHARNAME>. Please.~
	IF ~~ THEN DO ~RunAwayFrom(Player1,45) SetGlobal("AerieRomanceActive","GLOBAL",3)~ EXTERN IMOEN2J MRNoSleptPhaere4
	END
	
	IF ~~ THEN BEGIN NoSleptPhaere2
	SAY ~N-no! Why in Baervar's name would you even want t-t-to go back in there?~
	IF ~~ THEN EXTERN IMOEN2J MRNoSleptPhaere4
	END
END

APPEND JAHEIRAJ
	IF ~~ THEN BEGIN MRNoSleptPhaere1
		SAY ~Are you truly so stupid as to ask me this, <CHARNAME>? Do I- does our *friendship* mean nothing to you?~
		= ~You sicken me. Stand away.~
		IF ~~ THEN DO ~SetGlobal("JaheiraRomanceActive","GLOBAL",3)~ EXTERN IMOEN2J MRNoSleptPhaere4
 END
	
	IF ~~ THEN BEGIN MRNoSleptPhaere2
		SAY ~(Jaheira rolls her eyes and pointedly ignores you.)~
		IF ~~ THEN EXTERN IMOEN2J MRNoSleptPhaere4
 END
END

APPEND ANOMENJ
	IF ~~ THEN BEGIN MRNoSleptPhaere
	SAY ~'We'? *I* have both self-control and dignity - neither of which I see in you now. Leave me be if you wish to wallow in your degenerate lust.~
	IF ~~ THEN EXTERN IMOEN2J MRNoSleptPhaere4
 END
END

APPEND KELDORJ
 IF ~~ THEN BEGIN MRNoSleptPhaere
		SAY ~Help you? <CHARNAME>, you should consider yourself blessed to have escaped that witch's evil claws.~
		IF ~~ THEN EXTERN IMOEN2J MRNoSleptPhaere4
 END
END
		


CHAIN IMOEN2J MRNoSleptPhaere1
	~Hah! Yeah, right! Did you miss the fact that Phaere is practically sex on two legs?~
	== IMOEN2J IF ~InParty("Viconia")~ THEN ~Heck, she's hotter than Viconia, and that's saying something.~
	== IMOEN2J IF ~IsValidForPartyDialog("Viconia")~ THEN ~Er... no offense, Viccy.~
	== VICONIJ IF ~IsValidForPartyDialog("Viconia")~ THEN ~Spare me your limp platitudes, rivvil.~
	== IMOEN2J IF ~IsValidForPartyDialog("Viconia")~ THEN ~Platitudes ain't the only limp thing 'round here, looks like...~
END
	++ ~We have a mission to accomplish, and sex would just be a distraction.~ GOTO MRNoSleptPhaereDistract
	++ ~Drow just aren't my type. Too... evil. ~ GOTO MRNoSleptPhaereEvil
	++ ~You think so? Why don't YOU sleep with her?~ GOTO MRNoSleptPhaereBi
	IF ~OR(4)
	Global("ImoenRomanceActive","GLOBAL",1)
	Global("AerieRomanceActive","GLOBAL",2)
	Global("JaheiraRomanceActive","GLOBAL",2)
	Global("ViconiaRomanceActive","GLOBAL",2)~ THEN REPLY ~My heart is already taken. I could never betray that.~ GOTO MRNoSleptPhaereWho

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRNoSleptPhaere4
		SAY ~Oooh - and <CHARNAME> got shot *down*!~
		=
		~Haha. That just totally made this whole Underdark thing a lot more worth it.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRNoSleptPhaereDistract
		SAY ~Really? Wow. Well, I gotta admire you for that. I dunno if I'd've been able to resist if... uh... I mean...~
		=
		~Y'know, actually, it's really none of my business. Let's keep moving, 'kay?~
		++ ~*You* think that Phaere-?~ GOTO MRSleptPhaere1ProudEnd
		++ ~Hah! I knew you liked-~ GOTO MRSleptPhaere1ProudEnd
		++ ~That's disgust-~ GOTO MRSleptPhaere1ProudEnd
	END

	IF ~~ THEN BEGIN MRNoSleptPhaereBi
		SAY ~I dunno. I mean, sure, it'd be tempting, but, uh... I mean...~
		=
		~Y'know, actually, it's really none of my business. Let's keep moving, 'kay?~
		++ ~Seriously? You'd sleep with-~ GOTO MRSleptPhaere1ProudEnd
		++ ~Hah! I knew you liked-~ GOTO MRSleptPhaere1ProudEnd
		++ ~That's disgust-~ GOTO MRSleptPhaere1ProudEnd
	END

	IF ~~ THEN BEGIN MRNoSleptPhaereEvil
		SAY ~Good point. Nothin' kills the mood like waking up with a knife in your back, huh?~
		=
		~(She pats you on the shoulder) Good job, bro, good job.~ 
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRNoSleptPhaereWho
		SAY ~Sure, sure, like I... wait. (Her eyes widen) You're serious?~
		=
		~Who? When? Why haven't you mentioned anything before now?~
		IF ~Global("JaheiraRomanceActive","GLOBAL",2) InParty("Jaheira")~ THEN REPLY ~You've met her before, actually. It's Jaheira.~ GOTO MRNoSleptPhaereReallyJa
		IF ~Global("AerieRomanceActive","GLOBAL",2) InParty("Aerie")~ THEN REPLY ~Well, I only met her when I was in Athkatla. It's Aerie.~ GOTO MRNoSleptPhaereReallyAe
		IF ~Global("ViconiaRomanceActive","GLOBAL",2) InParty("Viconia")~ THEN REPLY ~You've met her before, actually. It's Viconia.~ GOTO MRNoSleptPhaereReallyVi
		IF ~Global("ImoenRomanceActive","GLOBAL",1)~ THEN REPLY ~It's you, Imoen. My heart belongs to you.~ GOTO MRNoSleptPhaereReallyIm
		++ ~No, no, I misspoke, ha ha. I'm not in love with anyone.~ GOTO MRNoSleptPhaereReallyHaha
		++ ~Because it wasn't any of your business, and it still isn't!~ GOTO MRNoSleptPhaereReally
	END
END

CHAIN IMOEN2J MRNoSleptPhaereReallyJa
~(Imoen looks towards Jahiera, her eyes wide with surprise)... *really*?~
= ~Oh geez, you guys haven't done it, have you? 'Cause Jaheira's like practically our step-mom and—~
== JAHEIRAJ ~*ahem!* (Jaheira glares at you) I do not think that is any of Imoen's business, *Veldrin*.~
EXIT

CHAIN IMOEN2J MRNoSleptPhaereReallyAe
~(Imoen looks towards Aerie, her eyes wide with surprise)... *really*?~
= ~Oh geez, you guys haven't done it, have you? I mean, Aerie's so sweet and innocent and-~
	==AERIEJ IF ~Global("SleptAerie","GLOBAL",1)~ THEN ~(Aerie looks away, not able to stand your gaze as she utters her reply) I—I—I'm not that innocent, Imoen...~
	==AERIEJ IF ~!Global("SleptAerie","GLOBAL",1)~ THEN ~Oh n-no, no, Imoen...! I love <CHARNAME>, b-but we haven't... haven't...~
	==IMOEN2J ~Aww, Aerie, it's alright! There's nothing wrong with it. When two people are in love and the time is right an' all that... well, y'know.~
	==IMOEN2J ~Wow. Well, I'll hush then. That's just... wow!~
EXIT

CHAIN IMOEN2J MRNoSleptPhaereReallyVi
~(Imoen looks towards Viconia, her eyes wide with surprise)... *really*?~
= ~Oh geez, you guys haven't done it, have you? 'cause if y'all start getting out the ropes and whips and stuff-~
	==VICONIJ IF ~Global("SleptViconia","GLOBAL",1)~ THEN ~(Viconia arches one pale eyebrow and glances over to you) Perhaps I chose the wrong sibling as my lover, <CHARNAME>. Had you but half of Imoen's imagination...~
	 == IMOEN2J IF ~Global("SleptViconia","GLOBAL",1)~ THEN ~What? No, no! I have no imagination, none whatsoever. That's me: Miss Boring herself!~
	 == IMOEN2J IF ~Global("SleptViconia","GLOBAL",1)~ THEN ~So... uh... yeah. You stay with <CHARNAME>, and I'll just... not mention that ever, ever again.~
	==VICONIJ IF ~!Global("SleptViconia","GLOBAL",1)~ THEN ~(Viconia snorts her disdain) As if I would sully myself with this phlithus jaluk.~
	==IMOEN2J IF ~!Global("SleptViconia","GLOBAL",1)~ THEN ~Oh, thank Sune! I dunno if I'd've ever been able to get that image out of my head.~
EXIT

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRNoSleptPhaereReally
			 SAY ~Hmph. Jerk. You're an open book, anyways, y'know.~
			 =
			~I'll figure it out sooner or later. Just you wait!~
			IF ~~ THEN EXIT
	END
	
	IF ~~ THEN BEGIN MRNoSleptPhaereReallyHaha
	   SAY ~Yeeeah, yeah, sure, mm-hmm. Bit of a slip of the tongue there, think.~
	   = ~It's okay, I'll figure it out sooner or later. Just you wait!~
	   IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRNoSleptPhaereReallyIm
		 SAY ~Me? Haha, yer a nut sometimes, y'know. (She reaches out and pinches your cheek, smiling happily and giving you a wink) But I love you too.~
			 ++ ~(Insist) No, Imoen... I'm *in love* with you. You're everything I want.~ GOTO MRNoSleptPhaereReallyIm1
			 ++ ~(Smile back and say nothing.)~ EXIT
	END
END

CHAIN IMOEN2J MRNoSleptPhaereReallyIm1
 ~(Her eyes widen as she realizes that you are completely serious.)~
 =
 ~You...love me? Like... you- you'd want to...?~
 == JAHEIRAJ IF ~IsValidForPartyDialog("Jaheira") Global("MRDreamRomanceComment","LOCALS",1) !Global("JaheiraRomanceActive","GLOBAL",2)~ THEN ~Do you still insist on this foolishness? <CHARNAME>, I thought you a wiser <PRO_MANWOMAN> than this.~
 == JAHEIRAJ IF ~IsValidForPartyDialog("Jaheira") Global("MRDreamRomanceComment","LOCALS",1) Global("JaheiraRomanceActive","GLOBAL",2)~ THEN ~You- You have the NERVE to say that while I stand here, <CHARNAME>? After telling me- after making me think-~ DO ~ SetGlobal("JaheiraRomanceActive","GLOBAL",3)~
 ==AERIEJ IF ~IsValidForPartyDialog("Aerie") Global("MRDreamRomanceComment","LOCALS",1) Global("AerieRomanceActive","GLOBAL",2)~ THEN ~W-w-what? You... you said you loved *me*, <CHARNAME>. How c-c-could you lie about that?~ DO ~SetGlobal("AerieRomanceActive","GLOBAL",3)~
 ==VICONIJ IF ~IsValidForPartyDialog("Viconia") Global("MRDreamRomanceComment","LOCALS",1) Global("ViconiaRomanceActive","GLOBAL",2)~ THEN ~Iblith caluss! Be silent before you make an even greater fool of yourself.~ DO ~SetGlobal("ViconiaRomanceActive","GLOBAL",3)~
 ==ANOMENJ IF ~IsValidForPartyDialog("Anomen") Global("MRDreamRomanceComment","LOCALS",1) Global("AnomenRomanceActive","GLOBAL",2) ~ THEN ~(You notice Anomen's eyes narrow and his mouth tighten in a thin line before he quickly turns away.)~ DO ~ SetGlobal("AnomenRomanceActive","GLOBAL",3)~
 == KELDORJ IF ~IsValidForPartyDialog("Keldorn")~ THEN ~<CHARNAME>? Are you quite aware of what you are saying?~
 ==MAZZYJ IF ~IsValidForPartyDialog("Mazzy")~ THEN ~I... I am... stunned, to say the least.~
 ==EDWINJ IF ~IsValidForPartyDialog("Edwin")~ THEN ~(Yet another saccharine admission of undying love. Do these apes have nothing more imaginative to say?)~
 ==KORGANJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Hah! The look o' terror in 'er eyes - that alone be worth the whole trip!~
 == IMOEN2J ~We just found out that I'm your sister, and you want to bed me? That's nasty! Yer joking still, right? Hah, y'got me! Let's all pretend it was a GRAND JOKE and move on! Like, *right now*.~
 = ~(Imoen walks away.)~
END
	IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT


