// *** Fortunetell ***

EXTEND_BOTTOM TRGYP02 2
	IF ~Name("Imoen2",LastTalkedToBy)~THEN EXTERN IMOEN2J MRFortuneTold
END



CHAIN TRGYP02 MRFortuneChain
	~Be still, child. This will take but a moment. Ah, yes. Hmm.~
 = ~(The fortuneteller closes her eyes. A frown slowly draws down her fine eyebrows.)~
 = ~(When her eyes open once more, her businesslike aloofness has shifted to pity, to surprise, to sadness.)~
 = ~Child. Oh, child.~

	== TRGYP02 IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~You are a very strong woman, Empty One. Many men would have succumbed to half what you've been through. Your blood has helped you in this but... your inner strength is all the greater.~
	== TRGYP02 IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~You are a very strong woman, Godchild. Many men would have succumbed to half what you've been through. Your blood has helped you in this but... your inner strength is all the greater.~

	== TRGYP02 IF ~Global("ImoenRomanceActive","GLOBAL",1)~ THEN ~You have suffered so much, and yet continue to torture yourself further. You act strong, if only to hide the fear of what is to come.~
	== TRGYP02 IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~You have suffered so much, and for so long. You act strong, if only to hide the fear within. The fear of loss. The fear of failure. The voice of doubt.~
	== TRGYP02 IF ~GlobalGT("ImoenRomanceActive","GLOBAL",2)~ THEN ~You have suffered so much, and yet continue to torture yourself further. You act strong, if only to hide the fear within you. Not only of what is to come, but the fear brought by the burden of regret, of mistaken choices.~

	== TRGYP02 IF ~!Global("BodhiDead","GLOBAL",1)~ THEN ~I so wish I could help you, but yours is a future that escapes my sight, my poor, empty child. Keep your coin, please. Your path is shrouded in dark shadows.~
 	== TRGYP02 IF ~Global("BodhiDead","GLOBAL",1)~ THEN ~I so wish I could help you, but yours is a future that escapes my sight, my poor child. Keep your coin, please. Your path is shrouded in dark shadows.~

 == TRGYP02 ~Hold what you love close to your heart, Imoen. Don't cast it away, no matter what.~ DO ~GiveGoldForce(10)~
 == IMOEN2J ~Um, I... alright, I guess.~

 == IMOEN2J IF ~Global("ImoenRomanceActive","GLOBAL",1)~ THEN ~(Imoen turns to look at you, confusion clear in her face. Blushing, she averts her eyes and walks away.)~ DO ~RunAwayFrom(Player1,40)~
 == IMOEN2J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~Gee, whaddya know, another vague prophecy of doom and gloom thrown our way. It's like we collect them.~
 == IMOEN2J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~At least it didn't cost a single copper, huh? C'mon, there's really nothing to see here.~
 == IMOEN2J IF ~GlobalGT("ImoenRomanceActive","GLOBAL",2)~ THEN ~(Imoen turns to look at you, confusion clear in her face. Frowning, she shakes her head and walks away.)~ DO ~RunAwayFrom(Player1,40)~
EXIT

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRFortuneTold
		SAY ~Uh-oh. Dunno if this is such a great idea. (Imoen hesitantly offers her right hand to the gypsy.)~
		IF ~~ THEN EXTERN TRGYP02 MRFortuneChain
	END
END
