APPEND IMOEN2J
	IF ~~ THEN BEGIN MRPhaereBiTalk
		SAY ~Yeah? What about her?~
			++ ~Well, it's not really about her so much as about *you*. You seemed... attracted to her.~ GOTO MRPhaereBiTalk2
			++ ~Would you have slept with her?~ GOTO MRPhaereBiTalkBlunt
			++ ~It's nothing. Forget I asked.~ EXIT
	END

	IF ~~ THEN BEGIN MRPhaereBiTalkBlunt
		SAY ~What? Why in Oghma's name would you ask me that?~
		IF ~Gender(Player1,MALE)~ THEN REPLY ~I just noticed that I've never seen you with a boyfriend.~ GOTO MRPhaereBiTalkBoyfriend
		++ ~You were obviously attracted to her.~ + MRPhaereBiTalk2
		++ ~Just answer the question.~ + MRPhaereBiTalkRefuse
	END

	IF ~~ THEN BEGIN MRPhaereBiTalk2
		SAY ~She was hot, sure, but that doesn't mean I'm gonna jump in her bed.~
			++ ~So you were attracted to her?~ GOTO MRPhaereBiTalk3
			++ ~Why not? That would have been awesome!~ GOTO MRPhaereBiTalkEnd2
			IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~Eh, nevermind. It's none of my business.~ GOTO MRPhaereBiTalkEnd1
			IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~Eh, nevermind. It's none of my business.~ EXIT
	END

	IF ~~ THEN BEGIN MRPhaereBiTalk3
		SAY ~(Imoen purses her lips in annoyance) Why're you pushing me?~
		IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN GOTO MRPhaereBiTalkRudeLove
		IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN GOTO MRPhaereBiTalkRudeFriend
	END

	IF ~~ THEN BEGIN MRPhaereBiTalkBoyfriend
		SAY ~You've also never seen me with a girlfriend, you dork! Maybe *you've* got time to go around flirtin' with people and stuff while saving the world, but I sure don't!~
			IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~Defensive much? If you weren't bi, you wouldn't mind answering.~ GOTO MRPhaereBiTalkRudeLove
			IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~Defensive much? If you weren't bi, you wouldn't mind answering.~ GOTO MRPhaereBiTalkRudeFriend
			++ ~I'm sorry, I didn't mean to be rude. I'm just curious.~ GOTO MRPhaereBiTalkRudeFriend
			IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~You're right. It's none of my business.~ GOTO MRPhaereBiTalkEnd1
			IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~You're right. It's none of my business.~ EXIT
	END


	IF ~~ THEN BEGIN MRPhaereBiTalkRefuse
		SAY ~How about I *don't*? First off, why in the Nine Hells do you care who I sleep with? And secondly, you're being a rude little troll about it.~
			IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~I'm sorry, I didn't mean to be rude. I'm just curious.~ GOTO MRPhaereBiTalkRudeLove
			IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~I'm sorry, I didn't mean to be rude. I'm just curious.~ GOTO MRPhaereBiTalkRudeFriend
			++ ~That's MISTER Rude Little Troll to you!~ GOTO MRPhaereBiTalkEnd2
			IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~You're right. It's none of my business.~ GOTO MRPhaereBiTalkEnd1
			IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~You're right. It's none of my business.~ EXIT
	END

	IF ~~ THEN BEGIN MRPhaereBiTalkRudeLove
		SAY ~I love *you*, <CHARNAME>, and last I checked you're definitely <MALEFEMALE>. I don't see why anything else should matter.~
		++ ~You're right Im, our love is all that matters.~ + MRSweetTalker
		++ ~You're avoiding the question!~ GOTO MRPhaereBiTalkEnd2
		IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~You're right. It's none of my business.~ GOTO MRPhaereBiTalkEnd1
		++ ~C'mon, Im, you can trust me!~ GOTO MRPhaereBiTalkEnd2
	END

	IF ~~ THEN BEGIN MRPhaereBiTalkRudeFriend
		SAY ~I know we're friends and all, but it's none of your business who I sleep with -- or would sleep with -- if I even was sleeping with anyone, which I'm obviously not!~
		++ ~You're avoiding the question!~ GOTO MRPhaereBiTalkEnd2
		IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~You're right. It's none of my business.~ GOTO MRPhaereBiTalkEnd1
		++ ~C'mon, Im, you can trust me!~ GOTO MRPhaereBiTalkEnd2
	END
	
	IF ~~ THEN BEGIN MRPhaereBiTalkEnd2
		SAY ~(She rolls her eyes and ignores you) Whatever. Can we focus on something that's actually *important*? Thanks.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRPhaereBiTalkEnd1
		SAY ~(She smiles happily and kisses the corner of your mouth) Glad you see it my way.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRSweetTalker
		SAY ~Exactly! See?~ 
		IF ~~ THEN GOTO MRSweetTalker2
	END

	IF ~~ THEN BEGIN MRSweetTalker2
		SAY ~I've got high standards and I'm not planning on changing 'em. So stop worrying!~
		=
		~There's only one person I have eyes for... and that's you.~
		=
		~(She places one hand against your cheek and guides you into a soft, slow kiss that leaves no doubt as to her sincerity. When she pulls away, she smiles and touches her fingertip to your lips.)~
		=
		~Now hush up, 'kay? I don't even want to *think* of anyone other than you.~
		IF ~~ THEN EXIT
	END
END