// Third Solar Revelation
//When you have killed both sendai and abazigal

// Imoen asks about it once you return

// Triggers once you go back to whoever you killed (Sendai or Abazigal) and combat is over. Last line of dialogue is state 58 in SOLAR.DLG
// Triggers as long as !Global("ImoenRomanceActive","GLOBAL",3) and !Global("IRTShutUp","GLOBAL",1)

APPEND IMOEN25J
IF WEIGHT #-5 ~Global("IRTSolarFiveTalk","GLOBAL",1)~ THEN SF
	SAY ~Ungh. Hope whatever the Solar told you was worth the black out.~ [IRDawn]
	IF ~~ THEN DO ~SetGlobal("IRTSolarFiveTalk","GLOBAL",2) SetGlobal("IRTMarriageTalk","GLOBAL",1) SetGlobal("IRTPregnancyTalk","GLOBAL",1)~ GOTO SFN
END

IF ~~ THEN SFN
	SAY ~More life-altering revelations, I'm sure?~
	++ ~Nothing I didn't already know.~ + SF1
	++ ~I wasn't aware of what I learned, but it doesn't make a difference.~ + SF1
	++ ~Everything is much clearer now. Our next move needs to be considered carefully.~ + SF1
	++ ~It doesn't even matter. Nothing has changed, let's move on.~ + SF2
	++ ~I'm wondering what you're going on about. I lost consciousness, just like you, and now we're awake again. I don't know what's happening.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-4)~ + SF4
	++ ~I'm tired of your questions, Imoen. Be quiet.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-5)~ + SF3
END

IF ~~ THEN SF1
	SAY ~Oh yeah? What was it about, then?~
	++ ~The Five are idiots that don't even realize what the prophecy is all about.~ + SF1a
	++ ~Apparently every Bhaalspawn killed releases Bhaal essence that has been accumulating at the throne, fueling Bhaal's return.~ + SF1b
	++ ~I now understand why the Five were working together instead of fighting one another. They all were promised to become demigods.~ + SF1c
	++ ~Killing all these Bhaalspawn has only made Balthazar more of a threat. I need to deal with him immediately.~ + SF1d
	++ ~It's obvious that someone's been pulling the strings and engineering a wholesale Bhaalspawn slaughter.~ + SF1e
END

IF ~~ THEN SF1a
	SAY ~And there it is, the shocker of the decade. We knew they were idiots to begin with, because they keep thinking they can walk all over you. Wonder if the next one will boast just as much, after we just got through dragons and drow armies.~
	= ~Ya think maybe next time the Solar could just write you a note, like civilized people?~
	= ~Ah well, I guess now it's just Balthazar left.~
	IF ~~ THEN EXIT
END	

IF ~~ THEN SF1b
	SAY ~Huh. That doesn't sound like something we want. Is it something we want?~
	++ ~Yes, absolutely. I will claim it all, when the time comes.~ DO ~SetGlobal("IRTImoenWarnedAboutLeaving","GLOBAL",1) IncrementGlobal("IRTLoveMeter","GLOBAL",-2)~ + SF1b1
	++ ~Perhaps. It depends on whether I can turn it into a force for good.~ DO ~SetGlobal("IRTImoenWarnedAboutLeaving","GLOBAL",1) IncrementGlobal("IRTLoveMeter","GLOBAL",2)~ + SF1b2
	++ ~No, it's nothing we want. I don't know what will happen when we're the only ones left.~ + SF1b3
	++ ~That remains to be seen, because I'm not clear on what it means.~ + SF1b4
	++ ~The Five need to be dealt with regardless.~ + SF1b5
END

IF ~~ THEN SF1b1
	SAY ~Yeah... of course you would. If you could, that is. We still don't know how it's all gonna turn out. Maybe we'll end up fighting Bhaal himself.~
	IF ~~ THEN GOTO SF1bEnd
END

IF ~~ THEN SF1bEnd
	SAY ~It'd only make sense, if you think about it. There's nothing left for us to fight but the Gods themselves.~
	= ~Let's go find us our next victim, I guess.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SF1b2
	SAY ~(Imoen smiles.) Yeah, of course you'd say that. We've no idea how things are really gonna turn out, though. We could end up fighting Bhaal himself.~
	IF ~~ THEN GOTO SF1bEnd
END

IF ~~ THEN SF1b3
	SAY ~No flippin' idea. And explosion of rainbows and kittens? Pretty likely, that. Maybe we'll end up fighting Bhaal himself, who knows?~
	IF ~~ THEN GOTO SF1bEnd
END

IF ~~ THEN SF1b4
	SAY ~That makes two of us, and probably everybody else is in that boat as well. I'll betcha nobody really knows for sure. Maybe we'll end up fighting Bhaal himself, who knows?~
	IF ~~ THEN GOTO SF1bEnd
END

IF ~~ THEN SF1b5
	SAY ~Yep, just like we've been doing. I'll betcha none of them really know for sure what will happen when there's just you and me left. Maybe it's all building up to a fight against Bhaal himself, who knows?~
	IF ~~ THEN GOTO SF1bEnd
END

IF ~~ THEN SF1c
	SAY ~Huh. Promised by whom?~
	++ ~Their leader, whoever it is.~ + SF1c1
	++ ~I don't know, but I'm sure we will find out quite soon.~ + SF1c1
	++ ~I have a very clear candidate. You know who I'm talking about, right?~ + SF1c2
	++ ~I would not be surprised if it's the Solar, in the end.~ + SF1c3
	++ ~It doesn't matter, does it? They will go down, like everyone else has.~ + SF1c4
END

IF ~~ THEN SF1c1
	SAY ~I'll betcha it's a hundred-foot-tall titan with seven arms, heads like a hydra and acid for blood! It'll be the biggest and meanest thing we'll ever face!~
	= ~Or, y'know, Melissan. Because d'uh, who else could it be.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SF1c2
	SAY ~Is it Melissan? It's Melissan, isn't it. She's been pointing us at her next target and then conveniently vanishing. We're in for a sudden yet inevitable betrayal.~
	= ~It's alright, though... we'd have had to kill 'em all anyway.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SF1c3
	SAY ~Really? I think I'd be heartbroken if that were true. She's so damn magnificent.~
	= ~I suppose there's only one way to find out. Let's go find us our next victim.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SF1c4
	SAY ~Yeah, well said. Let's go find us our next victim.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SF1d
	SAY ~He's the only one left, isn't he? Sounds too easy, even. I'll bet there'll be something else to worry about the moment he goes down.~
	= ~Ah well, time to go find our next victim, I guess.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SF1e
	SAY ~Yeah, I totally agree. Something's been stinking this whole time, and it seems like every one of the Five that's fallen keeps calling us fools. I thought maybe they were just trying to get a bit of satisfaction before dropping dead, but there's quite the pattern by now. They wouldn't have been so smug without some kind of master plan we're not aware of.~
	= ~Who do you think it is?~
	++ ~Whoever their leader happens to be, though he or she has kept to the shadows so far.~ + SF1c1
	++ ~I don't know, but I'm sure we will find out quite soon.~ + SF1c1
	++ ~I have a very clear candidate. You know who I'm talking about, right?~ + SF1c2
	++ ~I would not be surprised if it's the Solar, in the end.~ + SF1c3
	++ ~It doesn't matter, does it? They will go down, like everyone else has.~ + SF1c4
END
	
IF ~~ THEN SF2
	SAY ~Oh, well... alright then. You should know.~
	IF ~~ THEN EXIT
END

IF ~~ THEN SF3
	SAY ~Hey, I just dropped unconscious for no reason! I think it's warranted to ask about it, but hey, whatever.~
	= ~Mush-for-brains...~
	IF ~~ THEN EXIT
END

IF ~~ THEN SF4
	SAY ~Right. Okay. Be that way.~
	IF ~~ THEN EXIT
END
END
