//*** Reunited in Spellhold, after the Ritual ***//
/* Imoen2.dlg is ONLY of imoen rejoin dialogue in spellhold */

REPLACE IMOEN2
	IF ~~ THEN BEGIN 0
	 SAY ~I'm sorry, <CHARNAME>, I was just so worried...~ [ MRImRom1 ]
	 ++ ~Imoen! I thought I had lost you forever. I missed you so much! Are you alright?~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRReunitedLove
	 ++ ~Are you hurt? What did he do to you?~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRReunitedHurt
	 ++ ~Are you *my* Imoen again? You know who I am now, right?~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRReunitedOkay
	 ++ ~Yes, it was most unpleasant. But we are reunited and all is well again.~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRReunitedWell
	 ++ ~We survived, but not unscathed. I must know what he did to me... and you.~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRReunitedHurt
	 ++ ~Yes, yes, I was there. Let's just get back to that room and finish him.~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRReunitedFinish
	 ++ ~Oh, here we go again. Will I have to listen to your horrible whining everywhere I go? Why didn't you just die?~DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRReunitedNo
	END
END


APPEND IMOEN2

	IF ~~ THEN BEGIN MRReunitedLove
		SAY ~I... don't worry about me. Are *you* okay?~
	 ++ ~We survived, but not unscathed. I must know what he did to me... and you.~ GOTO MRReunitedHurt
	 ++ ~I'm fine now, though it was most unpleasant. But we are reunited and all is well again.~ GOTO MRReunitedWell
	 ++ ~I will be once we get back to that room and finish him.~ GOTO MRReunitedFinish
	END

	IF ~~ THEN BEGIN MRReunitedHurt 
	 SAY ~I... (Imoen visibly shudders) I don't know, really. Same thing he did to you, I guess, since we're... the same?~ 
	 IF ~~ THEN GOTO MRReunited2
	END

	IF ~~ THEN BEGIN MRReunitedWell
	 SAY ~I... (Imoen visibly shudders) I wish it were so... but it really isn't, is it? Everything's changed now. Now that we're the... same?~
	 IF ~~ THEN GOTO MRReunited2
	END

	IF ~~ THEN BEGIN MRReunitedFinish 
	 SAY ~B-back to... Irenicus? (Imoen visibly shudders) I, ah, I guess... if we can stand up to him after what he did... to us both.~
	 IF ~~ THEN GOTO MRReunited2
	END

	IF ~~ THEN BEGIN MRReunited2 
	 SAY ~<CHARNAME>, he made me see what you are and- and what *I* am... and then he tore it away from me.~
	 = ~I don't know who I am now. I feel hollow inside. Empty. And I can't get rid of the pain. Always, every moment, this horrible pain.~
	 IF ~~ THEN GOTO MRReunited3
	END

	IF ~~ THEN MRReunited3
	 SAY ~He took something vital from us. Our divine souls... I just find out I'm a child of a god, and then its essence is ripped from my body. Now I am empty and dying. And you are, too.~
	 ++ ~We'll survive by helping each other, like you helped me in the dream during the ritual.~ GOTO MRReunited3Dream
	 ++ ~I am strong, and I will not waste away. I survived the fight in the dream, didn't I?~ GOTO MRReunited3Dream
	 ++ ~Imoen, we'll survive just fine. You'll learn to cope just as I have. It's not so bad.~ GOTO MRReunited3Cope
	 ++ ~Then give up and die. He has stolen from me as well, but I will fight on. I must.~ GOTO MRReunited3Cope
	END

	IF ~~ THEN BEGIN MRReunited3Cope
	 SAY ~The things he showed me... they were so black and horrid. It made me feel things that... (She shakes her head, eyes staring into nothingness) It was too much. Now life is just death in waiting.~
	 IF ~~ THEN GOTO MRReunited4
	END

	IF ~~ THEN BEGIN MRReunited3Dream
	 SAY ~Dream? I had no dream during my ritual. It was nothing but a waking nightmare. Darkness, and agony, and my will draining away as... as- (her voice breaks, and for a moment she is unable to continue.)~
		IF ~~ THEN GOTO MRReunited5
	END

	IF ~~ THEN BEGIN MRReunited4
	 SAY ~I'm bleak, I know, but I've been alone here for so long... juist sitting alone in a cell, strange things whispering in my head.~
	= ~I haven't dealt with this for as long as you. It's not pleasant.~
	  ++ ~Neither were you. I've had a damnable time with you in my first dreams, especially in that last ritual.~ GOTO MRReunited3Dream
	  ++ ~And yet you seemed so sure of yourself when you helped in my dream.~ GOTO MRReunited3Dream
	END

	IF ~~ THEN BEGIN MRReunitedOkay
		SAY ~(Imoen looks at you questioningly) Why- why'd you say that? I'm Imoen, you're <CHARNAME>, like always.~
			++ ~When I found you, you were but a shadow of your normal self. You didn't recognize me.~ GOTO MRReunitedOkay2
			++ ~Nevermind that - I thought I'd lost you forever, I missed you so much! Are you alright now?~ GOTO MRReunitedLove
			++ ~Good to know. At least we are reunited and all is well again.~ GOTO MRReunitedWell
			++ ~I'm only glad we're still alive, though not unscathed. I must know what he did to me... and you.~ GOTO MRReunitedHurt
			++ ~If you say so. Let's get back to that room and finish him.~ GOTO MRReunitedFinish
			++ ~Already you are infuriating. Will I have to listen to your horrible whining everywhere I go? Why didn't you just die?~ GOTO MRReunitedNo
		END

	IF ~~ THEN BEGIN MRReunitedOkay2
		SAY ~I- I don't remember that at all. It's been like... waking up from a nightmare, and now I'm standing here, and you're right there in front of me.~
		= ~At least we're together this time around.~
			++ ~I thought I had lost you forever, I missed you so much! Are you alright?~ GOTO MRReunitedLove
			++ ~Are you hurt? What did he do to you?~ GOTO MRReunitedHurt 
			++ ~Yes, it's been most unpleasant. But you're right, now we are reunited and all is well again.~ GOTO MRReunitedWell
			++ ~Yes, yes, whatever you say. Let's just get back to that room and finish him.~ GOTO MRReunitedFinish
			++ ~Much to my regret, clearly. Will I have to listen to your horrible whining everywhere I go? Why didn't you just die?~ GOTO MRReunitedNo
		END

	IF ~~ THEN BEGIN MRReunited5
	 SAY ~Has this affected you differently than me? You've been dealing with the Bhaal essence longer. Perhaps you are more focused...~
	= ~Or perhaps it is more focused upon you.~
			++ ~I don't know. Regardless, we have to get back what Irenicus took from us.~ GOTO MRReunited5End
			++ ~What do you mean?~ GOTO MRReunited6
			++ ~We have no time for a philosophical debate. It can wait until after Irenicus has paid for what he did.~ GOTO MRReunited5End
			++ ~There was a malevolent taint in my first dreams. Is there a will behind it, I wonder?~ GOTO MRReunited5Dreams
	END

	IF ~~ THEN BEGIN MRReunited5Dreams
		SAY ~'First dreams'? Whatcha mean by that?~
			++ ~(This isn't the moment to broach the subject. You will talk about it later) Nevermind that; I just meant to say that my dreams have always had some sort of 'evil' presence in them.~ GOTO MRReunited5DreamsAvoid
			++ ~Well, I had many dreams. The first three were about my Taint; the others, however... (Tell her all about your dreams.)~ GOTO MRReunited5DreamsOverload
	END

	IF ~~ THEN BEGIN MRReunited5DreamsAvoid
		SAY ~Yeah, I remember your dreams back on the Sword Coast. Seems like dead gods never rest easy... and you've been dealing with this stuff a lot longer than I have.~
		IF ~~ THEN GOTO MRReunited6
	END

	IF ~~ THEN BEGIN MRReunited5DreamsOverload
		SAY ~<CHARNAME>, <CHARNAME>! You're goin' way too fast - my head's still spinning from what's going on right now. Just- just tell me later. 'Sides, I think the dreams about your Taint are probably more important.~
		= ~Seems like dead gods never rest easy... and you've been dealing with this stuff a lot longer than I have.~
		IF ~~ THEN GOTO MRReunited6
	END

	IF ~~ THEN BEGIN MRReunited6
	 SAY ~I've been getting weaker. I don't know how long it's been since... what he did, but there's something different inside me. Something missing, sapping my strength, my willpower.~
	 IF ~~ THEN GOTO MRReunited5End
	END

	/* most important conversation split */
	/* note a safe option has been added to not add Imoen to party, this is the old vanilla game choice so you can meet her at copper coronet */
	IF ~~ THEN BEGIN MRReunited5End
		SAY ~Irenicus... (Her mouth curls in disgust as the name leaves her lips. Imoen's eyes betray her hatred, her fear.)~
		= ~I... I guess we have to face him, don't we? Sooner or later.~
		= ~Let's go. It's real nice to be with you again, <CHARNAME>.~
		IF ~NumInPartyGT(1)
			OR(11)
			IsValidForPartyDialog("Korgan")
			IsValidForPartyDialog("Nalia")
			IsValidForPartyDialog("Aerie")
			IsValidForPartyDialog("Jan")
			IsValidForPartyDialog("Keldorn")
			IsValidForPartyDialog("HaerDalis")
			IsValidForPartyDialog("Anomen")
			IsValidForPartyDialog("Cernd")
			IsValidForPartyDialog("Valygar")
			IsValidForPartyDialog("Mazzy")
			IsValidForPartyDialog("Hexxat")~ THEN REPLY ~Likewise. Let's go.~ DO ~ ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRIntroductions
		IF ~NumInPartyGT(1)
			!IsValidForPartyDialog("Korgan")
			!IsValidForPartyDialog("Nalia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Jan")
			!IsValidForPartyDialog("Keldorn")
			!IsValidForPartyDialog("HaerDalis")
			!IsValidForPartyDialog("Anomen")
			!IsValidForPartyDialog("Cernd")
			!IsValidForPartyDialog("Valygar")
			!IsValidForPartyDialog("Mazzy")
			!IsValidForPartyDialog("Hexxat")
			OR(7)
			IsValidForPartyDialog("Jaheira")
			IsValidForPartyDialog("Viconia")
			IsValidForPartyDialog("Edwin")
			IsValidForPartyDialog("Minsc")
			IsValidForPartyDialog("Neera")
			IsValidForPartyDialog("Dorn")
			IsValidForPartyDialog("Rasaad")~ THEN REPLY ~Likewise. Let's go.~ GOTO MRIntroductionsOld
		IF ~NumInPartyGT(1)
			OR(11)
			IsValidForPartyDialog("Korgan")
			IsValidForPartyDialog("Nalia")
			IsValidForPartyDialog("Aerie")
			IsValidForPartyDialog("Jan")
			IsValidForPartyDialog("Keldorn")
			IsValidForPartyDialog("HaerDalis")
			IsValidForPartyDialog("Anomen")
			IsValidForPartyDialog("Cernd")
			IsValidForPartyDialog("Valygar")
			IsValidForPartyDialog("Mazzy")
			IsValidForPartyDialog("Hexxat")~ THEN REPLY ~We'll never be apart again, that much I promise. Let's go get our souls back.~ DO ~ ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRIntroductions
		IF ~NumInPartyGT(1)
			!IsValidForPartyDialog("Korgan")
			!IsValidForPartyDialog("Nalia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Jan")
			!IsValidForPartyDialog("Keldorn")
			!IsValidForPartyDialog("HaerDalis")
			!IsValidForPartyDialog("Anomen")
			!IsValidForPartyDialog("Cernd")
			!IsValidForPartyDialog("Valygar")
			!IsValidForPartyDialog("Mazzy")
			!IsValidForPartyDialog("Hexxat")
			OR(7)
			IsValidForPartyDialog("Jaheira")
			IsValidForPartyDialog("Viconia")
			IsValidForPartyDialog("Edwin")
			IsValidForPartyDialog("Minsc")
			IsValidForPartyDialog("Neera")
			IsValidForPartyDialog("Dorn")
			IsValidForPartyDialog("Rasaad")~ THEN REPLY ~We'll never be apart again, that much I promise. Let's go get our souls back.~ GOTO MRIntroductionsOld
		IF ~!NumInPartyGT(1)~ THEN REPLY ~It'll be good to have some company again.~ GOTO MRSolod
		  IF ~NumInPartyGT(1) /* Safe option to join if party is all other mod npc's */
			!IsValidForPartyDialog("Korgan")
			!IsValidForPartyDialog("Nalia")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Jan")
			!IsValidForPartyDialog("Keldorn")
			!IsValidForPartyDialog("HaerDalis")
			!IsValidForPartyDialog("Anomen")
			!IsValidForPartyDialog("Cernd")
			!IsValidForPartyDialog("Valygar")
			!IsValidForPartyDialog("Mazzy")
			!IsValidForPartyDialog("Hexxat")
			!IsValidForPartyDialog("Jaheira")
			!IsValidForPartyDialog("Viconia")
			!IsValidForPartyDialog("Edwin")
			!IsValidForPartyDialog("Minsc")
			!IsValidForPartyDialog("Neera")
			!IsValidForPartyDialog("Dorn")
			!IsValidForPartyDialog("Rasaad")~ THEN REPLY #49529 /* ~Then let's get going. Join with me, and we will escape this place immediately.~ */ DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30)~ GOTO 21
		++ ~Whoa! We? Who invited *you* along?~ GOTO MRReunited5Kicked
		IF ~~ THEN REPLY #49537 /* ~Because of group balance, I have no room. Can you find your way out alone?~ */ GOTO 22
	END

	IF ~~ THEN BEGIN MRReunited5Kicked
		SAY ~Wh- what? Are you... are you serious?~
		= ~You're going to just leave me here?~
			++ ~You're unstable, weak, and useless. I don't need you.~ GOTO MRReunitedNo
			++ ~No, no. I just meant you needed to wait for an invitation - it's only polite, after all.~ GOTO MRReunitedInvite
			++ ~It's for the best, trust me.~ GOTO MRReunitedNo
	END

	IF ~~ THEN BEGIN MRReunitedInvite
		SAY ~Ah, okay? Then, umm... can I have an invitation?~
			++ ~NO! Ha ha! You're useless, Imoen - why in Bhaal's name would you think I'd want YOU around? Get lost!~ GOTO MRReunitedNo
			++ ~But of course! Imoen, I hereby invite you to join me in my fantastical and amazing adventures throughout, uh... Spellhold!~ GOTO MRReunitedInvite2
	END

	IF ~~ THEN BEGIN MRReunitedInvite2
		SAY ~(She smiles despite herself) Yer nuts. But I accept the invitation.~
		= ~Now just... please... let's get out of here.~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30) JoinParty()~ EXIT
	END

	IF ~~ THEN BEGIN MRReunitedNo
		SAY ~(Imoen's expression drops to shocked horror. For a moment she only stares at you, eyes filling with tears.)~
		=
		~I... I was just... (Your rejection appears to be too much for her to bear.)~
		IF ~~ THEN GOTO MRReunitedNo2
	END
END

CHAIN IMOEN2 MRReunitedNo2
~I thought... I... (Imoen starts to sob. She stumbles away from you, her strides taking her into the foreboding darkness of Spellhold. Alone and hopeless, surely a horrible death awaits her.)~
== KELDORJ IF ~IsValidForPartyDialog("Keldorn")~ THEN ~You have just killed her, <CHARNAME>. But it seems you don't care at all about that.~
==JAHEIRAJ IF ~IsValidForPartyDialog("Jaheira")~ THEN ~I cannot believe what I've just witnessed. I pity your merciless heart.~
==AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~And th- that's all? After all this time, you treat her like this? I do not understand you, <CHARNAME>...~
==VICONIJ IF ~IsValidForPartyDialog("Viconia")~ THEN ~Good riddance. Clearly she demonstrates her weakness by not spitting on your face and then proving herself useful to your cause.~
==NALIAJ IF ~IsValidForPartyDialog("Nalia")~ THEN ~That was cruel and disgusting. I hope you don't treat all your 'old friends' like that.~
==MAZZYJ IF ~IsValidForPartyDialog("Mazzy")~ THEN ~That was absolutely unnecessary, <CHARNAME>. Why treat her like that?~
==MINSCJ IF ~IsValidForPartyDialog("Minsc")~ THEN ~She is not coming? Boo will miss her...~
END IMOEN2 MRReunitedNo3

APPEND IMOEN2
	IF ~~ THEN BEGIN MRReunitedNo3
		SAY ~(You merely stare as she disappears into the eternal night of Spellhold.)~
		IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3) EscapeArea()
		ReputationInc(-2) ActionOverride(Player1,ApplySpellRES("SPMRACNE",Player1))~ EXIT
	END

	IF ~~ THEN BEGIN MRIntroductions
		SAY ~Umm, <CHARNAME>... aren't you gonna introduce me to your friends?~
			++ ~Oh, of course!~ EXTERN PLAYER1 MRIntroductionsYes
			++ ~You can get to know them all by yourself, Imoen.~ GOTO MRIntroductionsNo
	END
END


APPEND IMOEN2
	IF ~~ THEN BEGIN MRIntroductionsOldNext
		SAY ~Wow! well, it's nice to have some friends along. Let's see what happens!~
		IF ~OR(2) InParty("Jaheira") InParty("Minsc")~ THEN DO ~ RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30) JoinParty()~ EXIT
		IF ~!InParty("Jaheira") !InParty("Minsc")~ THEN GOTO MRIntroductionsJM2
	END

	IF ~~ THEN BEGIN MRIntroductionsJM2
		SAY ~Hey, wait. What happened to Jaheira and Minsc? I thought they got out.~
			++ ~We left them there to find their way out by themselves, remember? We had more chances if we split up. I never saw them again.~ GOTO MRSolodJMLeave
			++ ~We left them there to rot. We didn't need them.~ GOTO MRSolodJMLeave
			++ ~It's not the first of our worries right now. We should be moving already.~ GOTO MRSolodEnd
			++ ~We went separate ways soon after we escaped.~ GOTO MRSolodJMSeparate
			++ ~I'm sorry, but... they died.~ GOTO MRSolodJMDied
	END

	IF ~~ THEN BEGIN MRIntroductionsNo
		SAY ~Alright, that's mighty polite of you. (She sighs.)~
		=
		~Oh well... (Imoen turns to the first new face she sees) So who are you?~
		=
		~(You tune out the babbling chatter of introductions, and soon enough the group is back on its way.)~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30) JoinParty()~ EXIT
	END

	IF ~!NumInPartyGT(2)~ THEN BEGIN MRSolod
		SAY ~You... you came here all by yourself?~
		=
		~Gosh. I mean, okay, I always knew you were hard to kill, but... wow. That must've been tough.~
			++ ~I've always been a loner. You know that.~ GOTO MRSolodLoner
			++ ~No one wants to help a Bhaalspawn, Imoen. I've learned that lesson all too well.~ GOTO MRSolodBhaal
			++ ~It was too dangerous to bring anyone else. I'd never forgive myself if the blood of a friend were on my hands.~ GOTO MRSolodJMWhere
			++ ~There is power in my path, and I have no plans to share it.~ GOTO MRSolodPower
			++ ~(You shrug) I didn't really feel like having a group of people following me, that's all.~ GOTO MRSolodLoner
			++ ~Yes, and I expect you to keep quiet. Otherwise, you'll force me to leave you here.~ GOTO MRSolodLeave
	END

	IF ~~ THEN BEGIN MRSolodLoner
		SAY ~Okay, but there's 'loner' and then there's *loner*! Aren't you takin' that a bit to the extreme?~
		= ~And what happened to Jaheira and Minsc? I thought they made it out.~
			++ ~We left them there to find their way out by themselves, remember? We had more chances if we split up. I never saw them again.~ GOTO MRSolodJMLeave
			++ ~We left them there to rot. We didn't need them.~ GOTO MRSolodJMLeave
			++ ~It's not the first of our worries right now. We should be moving already.~ GOTO MRSolodEnd
			++ ~We went separate ways soon after we escaped.~ GOTO MRSolodJMSeparate
			++ ~I'm sorry but... they died.~ GOTO MRSolodJMDied
	END

	IF ~~ THEN BEGIN MRSolodJMWhere
		SAY ~Huh. Good point. But... what happened to Jaheira and Minsc? I thought they made it out?~
			++ ~We left them there to find their way out by themselves, remember? We had more chances if we split up. I never saw them again.~ GOTO MRSolodJMLeave
			++ ~We left them there to rot. We didn't need them.~ GOTO MRSolodJMLeave
			++ ~It's not the first of our worries right now. We should be moving already.~ GOTO MRSolodEnd
			++ ~We went separate ways soon after we escaped.~ GOTO MRSolodJMSeparate
			++ ~I'm sorry but... they died.~ GOTO MRSolodJMDied
	END

	IF ~~ THEN BEGIN MRSolodJMDied
		SAY ~Oh, no! Really? I'm... I'm so sorry. I guess... at least now Jaheira and Khalid are together. And... Minsc and Dynaheir.~
		= ~(She presses her fingers into her temples) I- my head hurts. Everything after Baldur's Gate is fuzzy and vague.~
		IF ~~ THEN GOTO MRSolodEnd
	END

	IF ~~ THEN BEGIN MRSolodEnd
		SAY ~Well... I'm glad you came for me either way. Let's get out of here.~ 
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30) JoinParty()~ EXIT
	END

	IF ~~ THEN BEGIN MRSolodJMLeave
		SAY ~Did... did we? I don't think- I can't remember. (She presses her fingers into her temples) My head hurts really bad. Everything after Baldur's Gate is fuzzy and vague.~
		IF ~~ THEN GOTO MRSolodEnd
	END

	IF ~~ THEN BEGIN MRSolodJMSeparate
		SAY ~We- you- (She presses her fingers into her temples) They did? Sorry, my head hurts. Everything after Baldur's Gate is fuzzy and vague.~ 
		IF ~~ THEN GOTO MRSolodEnd
	END

	IF ~~ THEN BEGIN MRSolodBhaal
		SAY ~Yeah, I can imagine. Guess it's just you and me, huh? The two of us against the world! (She tries to smile, but suddenly she draws in a sharp breath and presses her fingers to her temples.)~
		= ~Sorry. My head hurts. Everything after Baldur's Gate is kinda fuzzy and vague.~ 
		IF ~~ THEN GOTO MRSolodEnd
	END

	IF ~~ THEN BEGIN MRSolodPower
		SAY ~Hah, you greedy bastard. You'll spare a bit of it for your dearest childhood friend, right?~
		= ~(Her expression sobers up) You- you'll keep me with you, right? At least 'til we go outta here... please?~
		++ ~I said the power is MINE! Go away!~ GOTO MRSolodPowerEnd
		++ ~So long as you stay in my shadow, you can follow me wherever you want.~ GOTO MRSolodPowerShadow
		++ ~But of course! You're practically part of me. I'd never consider leaving you, Imoen.~ GOTO MRSolodPowerNice
		++ ~I don't know. I haven't decided yet. Let's go on together... for now.~ GOTO MRSolodPowerShadow
		++ ~Be quiet, girl! So long as you keep silent, I will tolerate you.~ GOTO MRSolodPowerShadow
	END

	IF ~~ THEN BEGIN MRSolodPowerNice
		SAY ~(Imoen smiles) I'm glad you feel that way. Well, not so much about the whole power-hungry thing, but... nothin' new about that.~
		= ~<CHARNAME> and Imoen, together against the world. (She sighs) Let's get outta here. I don't feel so good.~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30) JoinParty()~ EXIT
	END

	IF ~~ THEN BEGIN MRSolodPowerEnd
		SAY ~(Imoen jumps back) Whoa, easy there! C'mon, I'll help ya, no need to get crabby... I'll stay out of your way, alright? I'll be like a shadow, no talking at all.~
		= ~Give me a chance, please. I- I don't want to be alone here.~
		IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4) RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30) JoinParty()~ EXIT
	END

	IF ~~ THEN BEGIN MRSolodPowerShadow
		SAY ~(The slight smile on her lips fades away as she realizes that you're serious.)~
		= ~Al- alright... I'll stay out of your way, <CHARNAME>. Just don't leave me alone here. ~
		= ~(She presses her fingers to her temples) My head's killin' me. Can we just go? I wanna get out of here.~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30) SetGlobal("ImoenRomanceActive","GLOBAL",4) JoinParty()~ EXIT
	END

	IF ~~ THEN BEGIN MRSolodLeave
		SAY ~You'd- you'd *leave* me here? Are you serious? After everything we've been through together?~
			++ ~If it means surviving, then yes. Now shut up.~ GOTO MRSolodLeave2
			++ ~The past is the past. I focus on the present - and in the present, you're a liability.~ GOTO MRSolodLeave2
			++ ~I'm just kidding! Can't you take a joke?~ GOTO MRSolodLeaveJoke
	END

	IF ~~ THEN BEGIN MRSolodLeave2
		SAY ~(Imoen purses her lips with disgust) Sorry, <CHARNAME>. No words from me, I promise.~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30) SetGlobal("ImoenRomanceActive","GLOBAL",3) JoinParty()~ EXIT
	END

	IF ~~ THEN BEGIN MRSolodLeaveJoke
		SAY ~No, I can't! Not now, not here! If you- if you had ANY idea of what I've been through...~
			++ ~Well, I don't, and I don't care to know. Now shut up and let's go.~ GOTO MRSolodLeave2
			++ ~I'm sorry, Im, really, I am. That was cruel and insensitive of me.~ GOTO MRSolodLeaveApologize
	END

	IF ~~ THEN BEGIN MRSolodLeaveApologize
		SAY ~Yes, it was.~
		= ~Let's just concentrate on getting out of here, I guess. Maybe we can talk later.~
		IF ~~ THEN DO ~RealSetGlobalTimer("MRImoenLovetalkTimer","GLOBAL",30) JoinParty()~EXIT
	END
END
