
// This is a small conversation initiated by the player in which (s)he asks which gods Imoen worships, if any.
//Make available after the first abyss test.

 
/* PID Option leading here:

IF ~!Global("IRTHadFaithTalk","GLOBAL",1) Global("IRTGodBelief","GLOBAL",1)~ THEN REPLY ~Do you worship any god, Imoen?~ DO ~SetGlobal("IRTHadFaithTalk","GLOBAL",1)~ GOTO god1

*/

APPEND IMOEN25J
IF ~~ THEN god1
 SAY ~(Her eyes widen almost imperceptibly. For a moment it looks as if she's not going to answer at all.)~
 = ~I'm... not a very religious person, if you haven't noticed. I wouldn't say I *worship* a god, it's more like... mentions in passing, here and there. (She chuckles softly.) It's almost like swearing.~
 = ~Sometimes I mention Tymora. Other times, Mystra.~
 ++ ~Why Tymora?~ + god0
 ++ ~Why Mystra?~ + god9
 ++ ~Ah, I see. Good to know. I was just curious.~ + god2
 ++ ~I think only the dim-witted worship the gods.~ + god8
 ++ ~I'm glad you understand the importance of having a deity in your mind and heart.~ + god7
 ++ ~That makes no sense. You must believe in the one and only true faith: mine!~ + god5
 ++ ~I don't know. Isn't it silly to worship any god, considering our Bhaalspawn situation?~ + god5extra
END

IF ~~ THEN god2
 SAY ~(She nods in silence and shrugs, not really knowing what else to say.)~
 IF ~~ THEN EXIT
END

IF ~~ THEN god5
 SAY ~Oh boy, I knew that's what you were getting at. Not gonna be baited into a yelling match about religion, bud. Come back when you get the corn cob out yer arse, willya? (She pats your shoulder and walks away.)~
 IF ~~ THEN DO ~RunAwayFrom(Player1,25)~ EXIT
END

IF ~~ THEN god5extra
 SAY ~Hah. Yeah, I guess you're right... although, well, it doesn't hurt, y'know? It's not even worshipping, anyway; I just... dunno, sometimes when a spell goes right, I might say or think, "Whew, thanks Mystra", and that type of thing. I suppose a lot of mages do it.~
 = ~And Tymora, well... Who doesn't mention her now and then, especially people that do what we do? (She chuckles.) There's nothing deep about it, honestly, it's just... going with the gods of the trade. Sorry if it's kinda disappointing.~
 = ~B'sides, gotta pick one to pay lip service to. You don't wanna end up in the Wall, huh? Nasty way to spend eternity, I'd say.~
 = ~So, um... there. Question answered, Imoen wins! (She raises her fist, gloriously victorious, and steps forth to face new challenges.)~
 IF ~~ THEN EXIT
END

IF ~~ THEN god7
 SAY ~Um... thanks, I guess? There's nothing deep about it, honestly. It's just... going with the gods of the trade. Better than ending up in the Wall, I'd say.~
 = ~Sometimes when a spell goes right, I might say or think, "Whew, thanks Mystra", and that type of thing. I suppose a lot of mages do it. And Tymora, well... Who doesn't mention her now and then, especially people that do what we do? (She chuckles lightly.)~
 = ~So... there. That's pretty much it. Y'know, suddenly I'm feeling real hungry. Let's see what I got around here... (She rummages through her backpack while walking away.)~
 IF ~~ THEN DO ~RunAwayFrom(Player1,25)~ EXIT
END

IF ~~ THEN god8
 SAY ~Uh-huh. To each their own I guess. (She shrugs.) I'm not too fond of devout worshippers anyway. They're kinda creepy.~
 IF ~~ THEN GOTO godHungry
END

IF ~~ godHungry
   SAY ~Y'know, suddenly I'm feeling real hungry. Let's see what I got around here... (She rummages through her backpack while walking away.)~
 IF ~~ THEN DO ~RunAwayFrom(Player1,25)~ EXIT
END

IF ~~ THEN god9
 SAY ~D'uh, kinda obvious, isn't it? I can use magic thanks to Her, so... simply feels natural to respect that.~
 = ~I just... dunno, sometimes when a spell goes right, I might say or think, "Whew, thanks Mystra". That type of thing. I suppose a lot of mages do it.~
 ++ ~But Mystra has always been in clear opposition to Bhaal. How does that work for you?~ + god9d
 ++ ~Oh. And why Tymora?~ + god9c
 ++ ~I think worshipping any god is for the dim-witted.~ + god8
 ++ ~I'm glad you understand the importance of having a deity in your mind and heart.~ + god9b
 ++ ~That makes no sense. You must believe in the one and only true faith: mine!~ + god5
 ++ ~I don't know. Isn't it silly to worship any god, considering our Bhaalspawn situation?~ + god9a
 ++ ~Ah, I see. Well, thank you for answering, I was just curious.~ + god2
END

IF ~~ THEN god9a
 SAY ~Hah. Yeah, I guess you're right... although, well, it doesn't hurt, y'know? It's not even worshipping, anyway; it's just... going with the gods of the trade. Sorry if it's kinda disappointing.~
 = ~B'sides, gotta pick one to pay lip service to. You don't wanna end up in the Wall, huh? Nasty way to spend eternity, I'd say.~
 = ~So, um... there. Question answered, Imoen wins! (She raises her fist, gloriously victorious, and steps forth to face new challenges.)~
 IF ~~ THEN EXIT
END

IF ~~ THEN god9b
 SAY ~Um, thanks, I guess. Although, y'see, I never felt any kind of "religious call" to go and search for my one true faith or anything like that. It's just... going with the gods of the trade. B'sides, don't wanna end up in the Wall, huh? Nasty way to spend eternity, I'd say.~
 = ~So... there. That's pretty much it. Y'know, I'm really hungry! Let's see what's there to eat around here... (She rummages through her backpack while walking away, considering the talk officially over.)~
 IF ~~ THEN DO ~RunAwayFrom(Player1,25)~ EXIT
END

IF ~~ THEN god9c
 SAY ~Why? We're adventurers! Some amount of good luck always comes in handy, I'd think. And... well, it also has to do with Winthrop a little. He had this special fondness for Tymora. He'd say, "Always have the Lady Luck on your side." So I guess it stuck.~
 = ~Y'see, it's funny how no matter how skilled you are with a sword, or how many times you've cast an easy spell, there's always the chance of something terrible happening.~
 ++ ~I don't believe in luck. I fully trust my abilities; if I'm always in control, there is no room for luck.~ + god0b
 ++ ~I think worshipping any god is for the dim-witted.~ + god8
 ++ ~I'm glad you understand the importance of having a deity in your mind and heart.~ + god9b
 ++ ~That makes no sense. You must believe in the one and only true faith: mine!~ + god5
 ++ ~I don't know. Isn't it silly to worship any god, considering our Bhaalspawn situation?~ + god9a
 ++ ~Ah, I see. Well, thank you for answering, I was just curious.~ + god2
END

IF ~~ THEN god9d
 SAY ~Um... fine? Being a Bhaalspawn isn't my fault and I hate it, so praying to Mystra now an' then can only help, dontcha think?~
 ++ ~You only hate it because you don't understand it yet. Give it more time.~ + godCorrupt
 ++ ~Oh. And why Tymora?~ + god9c
 ++ ~I think worshipping any god is for the dim-witted.~ + god8
 ++ ~I'm glad you understand the importance of having a deity in your mind and heart.~ + god9b
 ++ ~That makes no sense. You must believe in the one and only true faith: mine!~ + god5
 ++ ~Ah, I see. Well, thank you for answering, I was just curious.~ + god2
 ++ ~Whatever. Let's go.~ + god2
END

IF ~~ THEN god0
 SAY ~Why? We're adventurers! Some amount of good luck always comes in handy, I'd think. And... well, it also has to do with Winthrop a little. He had this special fondness for Tymora. He'd say, "Always have the Lady Luck on your side." So I guess it stuck.~
 = ~Y'see, it's funny how no matter how skilled you are with a sword, or how many times you've cast an easy spell, there's always the chance of something terrible happening.~
 ++ ~I don't believe in luck. I fully trust my abilities; if I'm always in control, there is no room for luck.~ + god0b
 ++ ~Oh. And why Mystra?~ + god0a
 ++ ~I think worshipping any god is for the dim-witted.~ + god8
 ++ ~I'm glad you understand the importance of having a deity in your mind and heart.~ + god9b
 ++ ~That makes no sense. You must believe in the one and only true faith: mine!~ + god5
 ++ ~I don't know. Isn't it silly to worship any god, considering our Bhaalspawn situation?~ + god9a
 ++ ~Ah, I see. Well, thank you for answering, I was just curious.~ + god2
END

IF ~~ THEN god0a
 SAY ~D'uh, kinda obvious, isn't it? I can use magic thanks to Her, so... simply feels natural to respect that.~
 = ~I just... dunno, sometimes when a spell goes right, I might say or think, "Whew, thanks Mystra." That type of thing. I suppose a lot of mages do it.~
 ++ ~But Mystra has always been in clear opposition to Bhaal. How does that work for you?~ + god9d
 ++ ~I think worshipping any god is for the dim-witted.~ + god8
 ++ ~I'm glad you understand the importance of having a deity in your mind and heart.~ + god9b
 ++ ~That makes no sense. You must believe in the one and only true faith: mine!~ + god5
 ++ ~I don't know. Isn't it silly to worship any god, considering our Bhaalspawn situation?~ + god9a
 ++ ~Ah, I see. Well, thank you for answering, I was just curious.~ + god2
END

IF ~~ THEN god0b
 SAY ~Uh-huh. To each their own I guess. (She shrugs.) Dunno, it's hard to think that we're in control in this mess, but hey, whatever floats yer lily.~
 IF ~~ THEN GOTO godHungry
END

IF ~~ godCorrupt
   SAY ~Um, no, I don't think so. I'm pretty sure it has a lot more to do with the nightmares and bloodthirsty impulses.~
   = ~I think I understand plenty, thank you very much.~
   ++ ~Those are symptoms. When you look past that, The Taint is just another tool that you must learn to control.~ DO ~IncrementGlobal("IRTControlTaint","GLOBAL",1) IncrementGlobal("IRTCorruptImoen","GLOBAL",1)~ + godTaint1
   ++ ~But you don't, Imoen. You're like a wolf that wants to be a sheep. Bhaalspawn is what we are, and trying to deny it only causes needless pain.~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",1) IncrementGlobal("IRTEmbraceTaint","GLOBAL",1)~ + godTaint2
   ++ ~Ever the fool. There is only one choice: embrace your heritage or cower with the rest!~ + godFool
   ++ ~Perhaps you're right. Where were we?~ DO ~IncrementGlobal("IRTCorruptImoen","GLOBAL",-1)~ + godBack
END

IF ~~ godTaint1
   SAY ~Oh, yeah, sure. Pay no mind to the freakish life-draining abilities, and let's forget about becoming a gross spike monster! There's nothing evil about any of that, sure.~
   = ~Could do without all of it. And how did we end up talking about this, anyway?~
   = ~C'mon, I'm really hungry now, for some reason. Let's see what I got around here... (She rummages through her backpack while walking away.)~
 IF ~~ THEN DO ~RunAwayFrom(Player1,25)~ EXIT
END

IF ~~ godTaint2
   SAY ~Why do you have to say stuff like that? I *can* deny it, and I will. I'm not a damn predator, that's not who I am!~
   = ~Jeez. How did we end up talking about this, anyway? Let's just... move on, okay? For some reason I'm really hungry now.~
   = ~(Imoen rummages through her backpack as she walks away, no doubt looking for something to eat.)~
 IF ~~ THEN DO ~RunAwayFrom(Player1,25)~ EXIT
END

IF ~~ godBack
   SAY ~You were ever so curious about the gods I pay lip service to.~
   ++ ~Ah, yes. I was about to say that worshipping any god is for the dim-witted.~ + god8
   ++ ~That's right. I'm glad you understand the importance of having a deity in your mind and heart.~ + god9b
   ++ ~Indeed. What I was getting at is that you must believe in the one and only true faith: mine!~ + god5
   ++ ~But isn't it silly to worship any god, considering our Bhaalspawn situation?~ + god9a
   ++ ~Ah, I see. Well, that was it. Thank you for answering, I was just curious.~ + god2
END
END

CHAIN IMOEN25J godFool
~Yikes.~
== IMOEN25J IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~We're done here, if you're gonna start calling me names. How about you take some time to cool off before talking to me again?~ DO ~SetGlobal("IRTCooldownDue","GLOBAL",1) IncrementGlobal("IRTCooldownCounter","GLOBAL",1)~
== IMOEN25J IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN ~Whatever you say, <CHARNAME>. Rather be a fool than a slave.~
EXIT

