// Imoen will tease other vanilla NPCs if they are sleeping with the PC
// Won't do it for the EE version characters because we don't care about them
// note: all dialogue was appended to B(NAME)25 files


/* Trigger globals: 
IRTTeaseAerieRom = 1
IRTTeaseJaheiraRom = 1
IRTTeaseViconiaRom = 1
IRTTeaseAnomenRom = 1
*/

// Aerie

CHAIN IF WEIGHT #500 ~Global("AerieRomanceActive","GLOBAL",2) Global("IRTTeaseAerieRom","GLOBAL",0) See("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		InParty(Myself)
		InParty("Aerie")
		!ActuallyInCombat()~ THEN BIMOEN25 TeaseAer
	~So Aerie, you've been beddin' my <PRO_BROTHERSISTER> for a while. How's that workin' for ya?~ [ IRQUIET ] DO ~SetGlobal("IRTTeaseAerieRom","GLOBAL",1)~
	== BAERIE25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Oh my. A- are you always this blunt?~
	== BIMOEN25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Oh, um, sorry. Alright, let's do this properly, gotta keep up all those good ol' social norms. (Imoen pointedly clears her throat and carefully enunciates her every word:)~
	== BIMOEN25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Aerie, may I have a moment of your time? There is an issue I'd like to bring to your attention.~
	== BAERIE25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~(Aerie rolls her eyes, though a smile plays on her lips.) Yes? What can I help you with?~
	== BIMOEN25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Yer shaggin' my <PRO_BROTHERSISTER> and I'm checkin' in on ya.~
	== BAERIE25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~(Aerie pauses. She's blushing and trying not to laugh at the same time.) Whyever would you ask that all of a sudden?~

	== BAERIE25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Oh my. Whyever would you ask that all of a sudden?~

	== BIMOEN25 ~Well, as <CHARNAME>'s big sister, I think I've an obligation to make sure <PRO_HESHE>'s on <PRO_HISHER> best behavior. Just lemme know if <PRO_HESHE>'s not treatin' ya right, and I'll make sure to scold <PRO_HIMHER> good.~
	== BAERIE25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Oh, well... I- I'm doing quite nicely. <PRO_HESHE>'s a darling. No complaints, um... thank you for asking?~
	== BIMOEN25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Really? No complaints at all?~
	== BAERIE25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~N- no, can't say I have any.~
	== BIMOEN25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Oh, c'mon, that can't be right. Does <PRO_HESHE> give ya too much to carry? Does <PRO_HESHE> getcha enough sweets? Is <PRO_HISHER> kiss quota fulfilled every day? Takes care of your needs in the bedroll?~
	== BAERIE25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~A- alright, I think this conversation should be over now.~
	== BIMOEN25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~What? No, no, I'm tryin' to help, I can help! C'mon, gimme something.~
	== BAERIE25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Well, actually...~

	== BAERIE25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~(Aerie giggles.) Big sister? You? You're the most irresponsible, happy-go-lucky person I've ever met. *<PRO_HESHE>'s* the big <PRO_BROTHERSISTER>, Imoen. You are the unhinged brat giving <PRO_HIMHER> constant headaches.~
	== BIMOEN25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~What? That's crazy talk! I'm the best big sister there ever was! C'mon, yer always whining about sumthin' or other, let me have it.~
	== BAERIE25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~<CHARNAME> is a darling. I've no complaints.~
	== BIMOEN25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Oh, *really*? So I've never heard, "ogh, these are too many things to carry!" or "I hope we rest at an inn soon," or "I so wish I could launder these clothes with real soap"? Those words've never come out of yer mouth, huh?~
	== BAERIE25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Those are not relationship complaints, though!~
	== BIMOEN25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Well, then, I'm sure you have some of those too. Come ooooon...~
	== BAERIE25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~(Aerie bites her lower lip.) Actually...~

	== BIMOEN25 ~Oooo! Yes?~
	== BAERIE25 ~I could use more footrubs.~
	== BIMOEN25 ~Footrubs! Got it!~
	= ~<CHARNAME>! Hey, <CHARNAME>! Oh, don't pretend yer not listening. You're droppin' the ball on footrubs. I expect to see ya every night getting those pretty little piggies of hers all taken care of, ya hear? Special attention to the calluses on the heel and sides - or you'll get a drubbin' from your big sister! And you don't wanna make me mad, now, do ya?~
	= ~Yeah, I thought not.~

	== BAERIE25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~(Aerie's face is somewhere between aghast and amused. Her cheeks are beet-red when she looks in your direction.)~
	== BIMOEN25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~There ya go.~
	== BAERIE25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Th... thank you?~
	== BIMOEN25 IF ~!GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Yer welcome, toots.~

	== BAERIE25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~(Aerie regards Imoen with a hapless, long-suffering stare.)~
	== BAERIE25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Thank you, Imoen. Thank you so much for that.~
	== BIMOEN25 IF ~GlobalGT("IRTImAerTalks","GLOBAL",1)~ THEN ~Anytime, girlfriend.~
EXIT



// Jaheira

CHAIN IF WEIGHT #500 ~Global("JaheiraRomanceActive","GLOBAL",2) Global("IRTTeaseJaheiraRom","GLOBAL",0) See("Jaheira") !StateCheck("Jaheira",CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		InParty(Myself)
		InParty("Jaheira")
		!ActuallyInCombat()~ THEN BIMOEN25 TeaseJah
	~So Jaheira, you've been beddin' my <PRO_BROTHERSISTER> for a while. How's that workin' for ya?~ [ IRQUIET ] DO ~SetGlobal("IRTTeaseJaheiraRom","GLOBAL",1)~
	== BJAHEI25 ~(Jaheira blinks in silence for a while, regarding Imoen with arched eyebrows.) You don't beat around the bush with your questions, do you, child.~
	== BIMOEN25 ~Huh, wouldn't it be more like sister-in-law, now? I mean, yer kinda like my step-mom an' all, and it's not like yer married to <CHARNAME>, but... I dunno, bit weird for ya to call me "child" when yer shaggin' my <PRO_BROTHERSISTER>.~
	== BJAHEI25 ~That you're not *my* child doesn't make you any less of a child, Imoen. A rather impertinent one, at that.~
	== BIMOEN25 ~Speakin' of marriage, when are you two gettin' hitched? You should press <PRO_HIMHER> on that, y'know. You gotta be assertive with <CHARNAME>. Take it from me, I'm <PRO_HISHER> big sister. If you don't push <PRO_HIMHER> to it <PRO_HESHE>'ll forever stall and never getcha that dream wedding you keep fantasizing about.~
	== BJAHEI25 ~I already had a dream wedding, Imoen. It was in a quiet, secluded grove with very close friends, many years ago.~
		== BIMOEN25 ~(Imoen's expression falls.) Oh. Oh, I'm so sorry, I was just teasing you, I didn't mean to-~
	== BJAHEI25 ~It is quite alright, Imoen. Don't worry about it.~
	== BIMOEN25 ~No, no, I feel awful now. Way to shove yer feet in your mouth, Imoen, yeesh. Shoulda thought it through.~
	== BJAHEI25 ~... Perhaps I'll take your advice, after all. <CHARNAME> could use more assertiveness from me, don't you think?~
	== BIMOEN25 ~(Imoen's smile returns.) Oh, yes. Absolutely.~
EXIT


// Viconia

CHAIN IF WEIGHT #500 ~ Global("IRTTeaseViconiaRom","GLOBAL",0) Global("ViconiaRomanceActive","GLOBAL",2) See("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		InParty(Myself)
		InParty("Viconia")
		!ActuallyInCombat()~ THEN BIMOEN25 TeaseVic
	~So Viconia, you've been beddin' my <PRO_BROTHERSISTER> for a while. How's that workin' for ya?~ [ IRQUIET ] DO ~SetGlobal("IRTTeaseViconiaRom","GLOBAL",1)~
	== BVICON25 ~It is slow progress, but my teachings are finally bearing fruit.~
	== BIMOEN25 ~Wow. That answer was way faster, sincere and disturbing than I expected.~
	== BVICON25 ~And what did you expect, dalhar? A shocked stare? A disdainful retort? A blush and a whimper, perhaps?~
	== BIMOEN25 ~Y- yeah, actually. Though yer skin's so dark, it's hard to know when yer blushing.~
	= ~Um. That's not racist, is it?~
	== BVICON25 ~I wouldn't care one way or another. Is there a point to this worthless banter?~
	== BIMOEN25 ~N- no, not really. I was gonna make sure <PRO_HESHE>'s doing right by ya, but I think you got that under control.~
	== BVICON25 ~<CHARNAME> is strong like no other. That is enough to keep me satisfied. Or did you come hoping for details, little broken girl? I wouldn't mind discussing the finer points of drawing pleasure from a <PRO_MANWOMAN>'s touch. It's been too long, and my options for conversation partners on the subject are... limited.~
	== BIMOEN25 ~Nope, nope, nope, this conversation is over, thanks, good luck with all that!~
EXIT

// Anomen

CHAIN IF WEIGHT #500 ~Global("AnomenRomanceActive","GLOBAL",2) Global("IRTTeaseAnomenRom","GLOBAL",0) See("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		InParty(Myself)
		InParty("Anomen")
		!ActuallyInCombat()~ THEN BIMOEN25 TeaseAno
	~So Anomen, you've been beddin' my <PRO_BROTHERSISTER> for a while. How's that workin' for ya?~ [ IRQUIET ] DO ~SetGlobal("IRTTeaseAnomenRom","GLOBAL",1)~
	== BANOME25 ~What a crude way to phrase a question! That, I believe, is none of your business, girl.~
	== BIMOEN25 ~It's not? I'll have you know I'm <CHARNAME>'s big sister. If yer doin' anything weird with her, you'll have to answer to me, understand?~
	== BANOME25 ~I refuse to be a part of this conversation.~
	== BIMOEN25 ~That sounds mighty suspicious. I'm watching you, Annie. Dontcha ever forget it.~
	== BANOME25 ~(Anomen pointedly ignores Imoen.)~
	== BIMOEN25 ~I'm watching you...~
EXIT




























