// Fourth Solar Revelation

// Imoen asks about it once you return to Balthazar's Chambers

//  Triggers once you go back to Balthazar's chamber. Last line of dialogue is state 67 in SOLAR.DLG
// Triggers as long as !Global("ImoenRomanceActive","GLOBAL",3) and !Global("IRTShutUp","GLOBAL",1)

APPEND IMOEN25J
IF WEIGHT #-5 ~Global("IRTSolarMelissanTalk","GLOBAL",1)~ THEN M
	SAY ~Well?~ [IRDawn]
	++ ~Well what?~ DO ~SetGlobal("IRTSolarMelissanTalk","GLOBAL",2)~ + M1
	++ ~Melissan is a pathological betrayer. She crossed Bhaal himself and now wants all the power.~ DO ~SetGlobal("IRTSolarMelissanTalk","GLOBAL",2)~ + M2
	++ ~We are going into the Abyss, to the Throne of Blood itself. Amelyssan, the High Deathstalker Matriarch gone-rogue, awaits us there.~ DO ~SetGlobal("IRTSolarMelissanTalk","GLOBAL",2)~ + M3
	++ ~I'm going to ram my fist so far down Melissan's throat that she'll be choking on my shoulder before she dies.~ DO ~SetGlobal("IRTSolarMelissanTalk","GLOBAL",2)~ + M4
	++ ~I just watched Bhaal throw a tantrum before getting disintegrated. Glad that he got his comeuppance, at least.~ DO ~SetGlobal("IRTSolarMelissanTalk","GLOBAL",2)~ + M5

END
	
IF ~~ THEN M1
	SAY ~The black out! You got whisked away again. Wish the Solar would drop a memo my way, too.~
	= ~Wouldja tell me what you saw, pleeeeease?~
	++ ~Melissan is a betrayer. She crossed Bhaal himself and now wants all the power.~ + M2
	++ ~Let's put it this way: I'm going to split Melissan's head open and spray her brains to the four corners of the Abyss.~ + M4
	++ ~I just watched Bhaal throw a tantrum before getting disintegrated. Glad that he got his comeuppance, at least.~ + M5
	++ ~(Explain with as many details as you can remember everything you witnessed, word for word.)~ + M6Plus

	++ ~I'm not in the mood, let's go.~ + M7
END

IF ~~ THEN M2
	SAY ~Oh-ho, Melissan, of course. Nobody saw that one coming. But betrayed Bhaal, huh? I guess she was his high priestess or something? What's that, triple-crossing? Quadruple-crossing? Such a trustworthy individual.~
	= ~So that means she played us for chumps. You can't be too happy about that.~
	++ ~You know what? I don't feel too strongly about it. She is only another obstacle, nothing more.~ + M2a
	++ ~We wouldn't have stood idly by while the Five did as they pleased, anyway.~ + M2b
	++ ~I would have outright killed her if the Solar hadn't intervened.~ + M4a
	++ ~Mark my words, we will settle our score and avenge every soul she has led to its demise.~ + M2c
	++ ~I will smear the floors with her entrails.~ + M4
	++ ~Nobody makes a fool out of me. I will take what is rightfully mine, even if I have to rip it out of her severed hand.~ DO ~SetGlobal("IRTImoenWarnedAboutLeaving","GLOBAL",1)~ + M4
END

IF ~~ THEN M2a
	SAY ~Hah. That's one way to look at it. Never crossed a word with the woman, so it's not like I feel *personally* betrayed or anything...~
	IF ~~ THEN GOTO M2End
END

IF ~~ THEN M2End
	SAY ~Alright then, thanks for keeping me in the loop! Can't wait to get all this madness over with, once and for all. I bet it won't be easy.~
	IF ~~ THEN EXIT
END

IF ~~ THEN M2b
	SAY ~No chance! We'd been dragged into it no matter what, especially with the whole destiny and prophecy hullabaloo going on around you. (She chuckles mirthlessly.) We're fated to solve the multiverse's problems, right?~
	= ~Alright then, thanks for keeping me in the loop, one way or another. Can't wait to get all this madness over with, once and for all. I bet it won't be easy.~
	IF ~~ THEN EXIT
END

IF ~~ THEN M2c
	SAY ~Hah, that's the spirit. She's tallied up a huge tab by now, right? She's basically responsible for every single bad thing that's happened in the Sword Coast lately. Somebody had to stop her, and - surprise surprise! - it's going to be us.~
	IF ~~ THEN GOTO M2End
END


IF ~~ THEN M3
	SAY ~Oh-ho, Melissan, of course. Nobody saw that one coming. But gone rogue, huh? What does that make her, a triple agent? A quadruple agent? Such a trustworthy individual.~
	= ~How in Moradin's beard do we get to the Throne of Blood, anyway?~
	++ ~The Solar will guide us, apparently.~ + M3a
	++ ~When the time comes, I must destroy the pocket plane, and so we will fall upon the Throne.~ + M3b
	++ ~Don't concern yourself with that, I'll make it happen.~ + M3a
	++ ~Eagles. Giant eagles.~ + M3c
	++ ~I have no idea. For now, there is one more challenge to get through.~ + M3d
END

IF ~~ THEN M3a
	SAY ~Alrighty then. Welp, lead the way! Thanks for keeping me in the loop. Gets frustrating sometimes not knowing what's going on.~
	IF ~~ THEN EXIT
END

IF ~~ THEN M3b
	SAY ~Aw, but it's sort of our home! It was gettin' real cozy there, with the friendly looking statues, and the constant thrumming, and the stormy green sky, and Cespenar... where will Cespenar go? Oh, the poor guy.~
	= ~The sacrifices we must make, I tell ya. Anyway, thanks for keeping me in the loop! Gets so frustrating not knowing what's going on...~ 
	IF ~~ THEN EXIT
END

IF ~~ THEN M3c
	SAY ~Uh-huh. Alright. I'm not even going to question it, we've had stranger things happen.~
	= ~Thanks for keeping me informed, one way or another. Sure gets frustrating sometimes, not knowing what's going on...~
	IF ~~ THEN EXIT
END

IF ~~ THEN M3d
	SAY ~Oh, joy. I'm ever so excited about that. Gee, wonder if it'll be yet another fight. You can bet your buttcheeks on that.~
	= ~Anyway, thanks for keeping me informed! Gets so frustrating not knowing what's going on...~
	IF ~~ THEN EXIT
END

IF ~~ THEN M4
	SAY ~Pfah hah! Wow, she must have really pissed you off. Did you actually talk to her? Or just got told what she's really been doing?~
	++ ~Oh, I talked to her, alright. I would have fought her right then and there if the Solar hadn't intervened.~ + M4a
	++ ~She is completely different from what we've seen. You should've seen the hatred and contempt on her face.~ + M4a
	++ ~Both. There will only be bits and pieces by the time I'm done with her.~ + M4a
	++ ~She was there in the flesh, I believe. She thinks herself a goddess now. We are going to prove her wrong.~ + M4a
END

IF ~~ THEN M4a
	SAY ~Wait, she was *in our pocket plane*? No way. That's not right. It's like... our home! She was in our home, yelling at you! The gall of that woman!~
	= ~She's gonna eat it now. Nobody comes to our house and takes a dump in our oatmeal. It's on, <CHARNAME>. You can count on me.~
	= ~Can't believe it. We'll put her in her place, just you wait.~
	IF ~~ THEN EXIT
END

IF ~~ THEN M5
	SAY ~Hah! Why would the Solar show you that? What happened?~
	++ ~Melissan is a pathological betrayer. She crossed Bhaal himself and now wants all the power.~ + M2
	++ ~Know that we are going to the Throne of Blood itself. Amelyssan, the High Deathstalker Matriarch gone-rogue, awaits us there.~ + M3
	++ ~Let's put it this way: I'm going to carve a jigsaw puzzle into Melissan's skin and then make her explode into so many pieces.~ + M4
	++ ~(Explain with as many details as you can remember everything you witnessed, word for word.)~ + M6Plus
	++ ~I'm not in the mood for this. Let's go.~ + M7
END

IF ~~ THEN M6
	SAY ~Uh-huh. I got that far. Who's the big bad, though, specifically? Not to be demanding or anything, I just wanna know what we'll be facing.~
	++ ~Melissan is a pathological betrayer. She crossed Bhaal himself and now wants all the power.~ + M2
	++ ~Know that we are going to the Throne of Blood itself. Amelyssan, the High Deathstalker Matriarch gone-rogue, awaits us there.~ + M3
	++ ~Let's put it this way: I'm going to carve a jigsaw puzzle into Melissan's skin and then make her explode into so many pieces.~ + M4
	++ ~(Explain with as many details as you can remember everything you witnessed, word for word.)~ + M6Plus
	++ ~I'm not in the mood for this. Let's go.~ + M7
END

IF ~~ THEN M6Plus
	SAY ~(Imoen pays close attention to everything you say. She seems equally amused and vexed by the time you finish.)~
	= ~It figures. You just can't trust evil High Matriarch Deathstalkers with anything! Poor Bhaal, did all that work sexin' up everybody for nothing.~
	= ~Melissan sounds completely deranged and delusional, though - I'm sorry, "Amelyssan". It must have galled her so to play nice for so long. Or maybe she was laughing on the inside all this time, feeling ever so diabolical with her schemes. It's kinda sad...~
	= ~Alright, thanks for lettin' me know. Feels good to be kept in the loop.~
	IF ~~ THEN EXIT
END

IF ~~ THEN M7
	SAY ~Jeez, I just wanna know what's goin' on...~
	IF ~~ THEN EXIT
END
END