/* Here go all of Imoen's states whenever you initiate dialogue with her */


APPEND IMOEN25J


// Romanced or Friendly

IF WEIGHT #999 ~IsGabber(Player1) !Global("ImoenRomanceActive","GLOBAL",3) !Global("IRTQuarrelDue","GLOBAL",1) !Global("IRTCooldownDue","GLOBAL",1) !Global("IRTBrokeUpTalk","GLOBAL",1) !AreaCheck("AR5203") !ActuallyInCombat() !AreaCheck("AR5000") !AreaCheck("AR5203")~ NormalPID
  SAY ~Yep?~ [IMOEN27]

// ~~ conversations ~~

  ++ ~Can I ask you something?~ + PIDQuestions

// ~~ Romantic interactions ~~

	// Quality times
	

		// After 2nd Test in Pocketplane
		+ ~Global("ImoenRomanceActive","GLOBAL",2) Global("BeginChallenge2","GLOBAL",3) IsGabber(Player1) Global("IRTQTPocket1","GLOBAL",0) AreaCheck("AR4500")~ + ~(Spend some quality time with Imoen.)~ DO ~SetGlobal("IRTQTPocket1","GLOBAL",1) IncrementGlobal("IRTLoveMeter","GLOBAL",2)~ + 2QT
		
		// After either Abazigal or Sendai is dead, in Pocketplane

		+ ~Global("ImoenRomanceActive","GLOBAL",2) IsGabber(Player1) Global("IRTQTPocket1","GLOBAL",1) Global("IRTQTPocket2","GLOBAL",0) AreaCheck("AR4500") Global("TalkedToSolar","GLOBAL",6)~ + ~(Spend some relaxing quality time with Imoen.)~ DO ~SetGlobal("IRTQTPocket2","GLOBAL",1) IncrementGlobal("IRTLoveMeter","GLOBAL",2)~ + 4QT
		
		
	// Brief Public Displays of Affection // IRTLoveMeter increases by 1 every 3 sets.

		// PDA0

	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) Global("IRTPDA","GLOBAL",0)~ + ~(Show Imoen some affection by caressing her cheek.)~ DO ~SetGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA0-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) Global("IRTPDA","GLOBAL",0)~ + ~(Show her some affection with a light kiss.)~ DO ~SetGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA0-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) Global("IRTPDA","GLOBAL",0)~ + ~(Tell Imoen something to remind her of your love for her.)~ DO ~SetGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA0-3

	// PDA1
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",1)~ + ~(Hold Imoen's hand.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA1-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",1)~ + ~(Pull Imoen close and give her a good squeeze.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA1-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",1)~ + ~(Plant a casual kiss on Imoen's lips.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA1-3
		
	// PDA2
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",2)~ + ~You look stunning, Imoen.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA2-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",2)~ + ~I just wanted to tell you that I appreciate how you always try to find humor in everything.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ GOTO PDA2-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",2)~ + ~I don't know if I've told you I've always been impressed with how smart you are.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ GOTO PDA2-3

	// PDA3
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",3)~ + ~(Pretend you're going in for a hug, but tickle her instead.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA3-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",3)~ + ~(Keep looking at her, admiring her beauty.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA3-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",3)~ + ~(Stand close to her just to see what she does.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA3-3

	// PDA4

	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",4)~ + ~(Wink at Imoen with a warm smile on your lips.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA4-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",4)~ + ~(Take Imoen's hand and kiss her fingertips one by one.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA4-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",4)~ + ~(Hold hands with Imoen.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA4-3

	// PDA5
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",5)~ + ~(Hug her and place a soft, wet kiss on her neck.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA5-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",5)~ + ~(Take her by surprise by suddenly grabbing her and planting a rough kiss on her mouth.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA5-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",5)~ + ~(Give Imoen a quick backrub.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA5-3
	
	// PDA6
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",6)~ + ~I like your hair, Imoen. It looks great.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA6-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",6)~ + ~The worst part of all this is that we don't get much time to be alone together.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA6-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",6)~ + ~Just checking in on you. How are you doing?~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA6-3

	// PDA7
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",7)~ + ~(Just lay one hand on her shoulder, giving her a soft supportive squeeze.)~ DO ~SetGlobal("bf251","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA7-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",7)~ + ~(Simply smile while looking at her.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA7-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",7)~ + ~I'm glad you are with me, Imoen.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA7-3
  
	// PDA8
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",8)~ + ~(You notice Imoen is tense. You step behind her and massage her neck and shoulders.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA8-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",8)~ + ~(Give Imoen a tight embrace.) I love you so much.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA8-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",8)~ + ~(You shamelessly give Imoen's left breast a gentle squeeze.) Boop!~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA8-3

	// PDA9
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",9)~ + ~(Whisper something filthy in her ear, just to see how she reacts.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA9-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",9)~ + ~(Give her a hug, then playfully bite her ear - well aware of how sensitive she is to it.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA9-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",9)~ + ~(Give an appreciative pat to her booty.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA9-3
		
	// PDA10
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",10)~ + ~(Give her ribs a playful poke.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA10-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",10)~ + ~(Get closer to Imoen for the pleasure of it.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA10-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",10)~ + ~(Pinch Imoen's butt.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA10-3
	
	// PDA11
	
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",11)~ + ~Imoen, I need you to stay out of sight. Your striking beauty keeps distracting me.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ GOTO PDA11-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",11)~ + ~You seemed lost in thought. What's going through your mind?~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ GOTO PDA11-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",11)~ + ~(Bring her into a hug.) I'm so fortunate to have you. Beautiful, intelligent, you always make me laugh, quick of wit and courageous too. You're everything anyone could ever want.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA11-3

	// PDA12

	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",12)~ + ~(Give Imoen's butt a sound smack.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA12-1
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",12)~ + ~(Pass your arm around her waist.) I love you, Imoen.~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA12-2
	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",12)~ + ~(Tenderly caress Imoen's cheek.)~ DO ~IncrementGlobal("IRTPDA","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA12-3


	// PDA13

	+ ~IsGabber(Player1) Global("ImoenRomanceActive","GLOBAL",2) RealGlobalTimerExpired("IRTPDATimer","GLOBAL") Global("IRTPDA","GLOBAL",13)~ + ~(Casually place your hand on the small of her back, standing beside her.)~ DO ~SetGlobal("IRTPDA","GLOBAL",0)  IncrementGlobal("IRTLoveMeter","GLOBAL",1) RealSetGlobalTimer("IRTPDATimer","GLOBAL",600)~ + PDA13-1

	
// ~~ exit dialogue ~~

  + ~IsGabber(Player1) RandomNum(8,1)~ + ~Nah, don't worry about it.~ + DiaExFT1
  + ~IsGabber(Player1) RandomNum(8,2)~ + ~No, never mind me.~ + DiaExFT2
  + ~IsGabber(Player1) RandomNum(8,3)~ + ~It was nothing. Let's go.~ + DiaExFT3
  + ~IsGabber(Player1) RandomNum(8,4)~ + ~Just ignore me, it was nothing.~ + DiaExFT4
  + ~IsGabber(Player1) RandomNum(8,5)~ + ~It doesn't matter, let's go on.~ + DiaExFT5
  + ~IsGabber(Player1) RandomNum(8,6)~ + ~Don't mind me.~ + DiaExFT6
  + ~IsGabber(Player1) RandomNum(8,7)~ + ~Don't worry, let's move out.~ + DiaExFT7
  + ~IsGabber(Player1) RandomNum(8,8)~ + ~I had nothing to say, really. We should get going.~ + DiaExFT8
  + ~!IsGabber(Player1) !IsGabber("Korgan") !IsGabber("Minsc")~ + ~It was nothing, Imoen.~ + DiaExFT9
  + ~IsGabber("Korgan")~ + ~Dun' mind me, lass.~ + DiaExFT9
  + ~IsGabber("Minsc")~ + ~Boo says he forgot what he was going to say!~ + DiaExFT9


END

// ~~ Questions state leading to several conversations ~~

	IF ~~ PIDQuestions
	  SAY ~Sure!~

	  /* Marriage */
      //after solar talk after killing senda or abazigal
	  + ~GlobalGT("IRTLoveMeter","GLOBAL",7) Global("IRTMarriageTalk","GLOBAL",1)  Gender(Player1,MALE)~ + ~Would you ever want to marry?~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRTMarriageTalk","GLOBAL",2)~ GOTO Mar1
	  + ~GlobalGT("IRTLoveMeter","GLOBAL",7) Global("IRTMarriageTalk","GLOBAL",1)  Gender(Player1,FEMALE)~ + ~Would you ever want to marry?~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRTMarriageTalk","GLOBAL",2)~ GOTO MarF
	  + ~!GlobalGT("IRTLoveMeter","GLOBAL",7) Global("IRTMarriageTalk","GLOBAL",1)~ + ~Would you ever want to marry?~ DO ~SetGlobal("IRTMarriageTalk","GLOBAL",2)~ GOTO MarTooLow

	  /* Children */
       //after solar talk after killing senda or abazigal
	  + ~Global("IRTPregnancyTalk","GLOBAL",1)~ + ~What do you think about ever having children?~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRTPregnancyTalk","GLOBAL",2)~ GOTO Preg1

	  /* Torture */
	  //after first bhaal talk
	  + ~Global("IRTTortureTalk","GLOBAL",1)~ + ~It has been a while since we left Spellhold behind. Do the memories still haunt you, with everything that's happening now?~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRTTortureTalk","GLOBAL",2)~ + T1

	  /* Worship */
      //after first challenge
	IF ~Global("IRTHadFaithTalk","GLOBAL",1) Global("BeginChallenge1","GLOBAL",12)~ THEN REPLY ~Do you worship any god, Imoen?~ DO ~SetGlobal("IRTHadFaithTalk","GLOBAL",2)~ GOTO god1
	  
	  /* Slayer-Ravager-Resisting the Taint */
	  
	  + ~Global("IRTResistTheSlayer","GLOBAL",3) Global("IRTResistTheSlayerQ","GLOBAL",0)~ + ~You've been dealing with the Taint for quite some time. How are you holding up?~ DO ~SetGlobal("IRTResistTheSlayerQ","GLOBAL",1) IncrementGlobal("IRTLoveMeter","GLOBAL",1)~ + HowResist
	  + ~Global("IRTImoenControlsSlayer","GLOBAL",2) Global("IRTImoenControlsSlayerQ","GLOBAL",0)~ + ~How is it for you to become the Slayer?~ DO ~SetGlobal("IRTImoenControlsSlayerQ","GLOBAL",1) IncrementGlobal("IRTLoveMeter","GLOBAL",1)~ + HowSlay 
	  + ~Global("IRTImoenIsRavager","GLOBAL",1) Global("IRTImoenIsRavagerQ","GLOBAL",0)~ + ~How is it to embrace Bhaal's power?~ DO ~SetGlobal("IRTImoenIsRavagerQ","GLOBAL",1) IncrementGlobal("IRTLoveMeter","GLOBAL",1)~ + HowAss 



	  ++ ~Actually, never mind.~ + DiaExFT2
	END



	// ~~ Random dialogue exits ~~


	IF ~~ DiaExFT1
	  SAY ~(Imoen shrugs) Whatever.~
	  IF ~~ THEN EXIT
	END

	IF ~~ DiaExFT2
	  SAY ~Um, alright.~
	  IF ~~ THEN EXIT
	END

	IF ~~ DiaExFT3
	  SAY ~Alright, whatever you say.~
	  IF ~~ THEN EXIT
	END

	IF ~~ DiaExFT4
	  SAY ~As if ignoring you would be difficult, ha!~
	  IF ~~ THEN EXIT
	END

	IF ~~ DiaExFT5
	  SAY ~Very well then.~
	  IF ~~ THEN EXIT
	END

	IF ~~ DiaExFT6
	  SAY ~That's eloquence.~
	  IF ~~ THEN EXIT
	END

	IF ~~ DiaExFT7
	  SAY ~(She shrugs.) You got it, chief.~
	  IF ~~ THEN EXIT
	END

	IF ~~ DiaExFT8
	  SAY ~(Imoen raises an eyebrow at you.) Sure, I guess.~
	  IF ~~ THEN EXIT
	END

	IF ~~ DiaExFT9
	  SAY ~Um, okay. Take your time, I guess.~
	  IF ~~ THEN EXIT
	END




// ~~ PID for ImoenRomanceActive = 3 ~~

IF WEIGHT #999 ~Global("ImoenRomanceActive","GLOBAL",3)~ PIDAngry
SAY ~(Imoen frowns.) What?~ [ IRQUIET ]
 ++ ~Imoen... I don't want to fight anymore. I miss you.~ + PIDAngry1
 ++ ~I am willing to forgive your offenses and consider you my friend once again if you apologize to me.~ + PIDAngry2
 ++ ~(Try to lighten the mood.) You know what? I feel magnanimous. If you apologize and admit that everything was your fault, I'll be your friend again.~ + PIDAngry3
 ++ ~I only wanted to remind you how much I hate your guts.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-100)~ + PIDAngry4
 ++ ~(Think of it better and walk away.)~ EXIT
END

IF ~~ PIDAngry1
  SAY ~(She raises an eyebrow, looking at you with no small amount of suspicion.)~
  IF ~!GlobalGT("IRTLoveMeter","GLOBAL",-10) !Global("IRTNeverForgive","GLOBAL",1)~ THEN GOTO PIDNotYetForgive
  IF ~GlobalGT("IRTLoveMeter","GLOBAL",-10) !Global("IRTNeverForgive","GLOBAL",1)~ THEN GOTO PIDForgive
  IF ~Global("IRTNeverForgive","GLOBAL",1)~ THEN GOTO PIDNeverForgive
END

IF ~~ PIDNeverForgive
  SAY ~I will *never* forgive what you did. Do you understand? Never.~
  = ~Now leave me alone.~
  IF ~~ THEN EXIT
END

IF ~~ PIDNotYetForgive
  SAY ~Are you joking? You've been nasty to me. You'll have to try harder.~
  = ~Now leave me alone.~
  IF ~~ THEN EXIT
END

IF ~~ PIDForgive
  SAY ~(Finally, she purses her lips.) I'd be lying if I said I didn't miss you too, fool that I am.~
  = ~Tellya what, here's the deal. You promise to be decent to me from now on, and I promise to do my best to get over this whole thing. I mean... I used to call you a friend. It was nice. I wanna go back to that.~
  ++ ~I promise. Let's leave all the anger behind us.~ + PIDForgiveYes
  ++ ~Promise? Take or refuse my apology, but I will make no such promise.~ + PIDForgiveNo
  ++ ~You are already making me angry again. Forget it.~ + PIDAngry4
END

IF ~~ PIDForgiveYes
  SAY ~(Though small and reserved, her smile is happier than you've seen in a long time.)~
  = ~Great. It's great to hear that. I promise to do my best not to get on your nerves too much, how's that?~
  = ~(She sighs.) Boy. I didn't realize how much this's been botherin' me. Feels good, like a big weight off my shoulders. I sure do hope it'll last this time...~
  = ~Anyway, let's keep at it, boss. Hopefully it'll stop being weird between us soon enough.~
  IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
END

IF ~~ PIDForgiveNo
  SAY ~Pff. Well, there's your answer, then. I'm not gonna get burned again. Forget about me.~
  IF ~~ THEN GOTO PIDAngry4
END

IF ~~ PIDAngry2
  SAY ~Hah. Okay. I'm sorry I ever called you a friend. How's that for an apology?~
  = ~Get bent, <CHARNAME>.~
  IF ~~ THEN EXIT
END

IF ~~ PIDAngry3
  SAY ~(She snorts out a chortle.) If you want to make amends, you're gonna have to try harder than that.~
  = ~You were awful to me, <CHARNAME>. I can't just laugh it off.~
  ++ ~I know. I'm sorry I drove us to this point. But I miss you, Imoen.~ + PIDAngry1
  ++ ~Hey, you drive me *nuts* sometimes. Like any sibling would, I guess.~ + PIDAngryNuts
  ++ ~Just get over it already!~ + PIDAngry4
  ++ ~(Shrug.) It's no use. Suit yourself, then.~ + PIDAngry4
END

IF ~~ PIDAngryNuts
  SAY ~Yeah, well, there is that kind of annoying sibling stuff, and then there's the crap you put me through.~
  ++ ~I know. I'm sorry I drove us to this point. I miss you, Imoen.~ + PIDAngry1
  ++ ~Just get over it already!~ + PIDAngry4
  ++ ~(Shrug.) It's no use. Suit yourself, then.~ + PIDAngry4
END

IF ~~ PIDAngry4
  SAY ~(She rolls her eyes.) Unbelievable...~
  IF ~~ THEN EXIT
END
END