APPEND IMOEN2J
	// just before sleep at underdark exit comment

	 IF ~Global("MRCampSleepTalk","GLOBAL",1) AreaCheck("AR2500")~ THEN BEGIN MRCampfireAct2
		SAY ~Aah... (Imoen stretches) This place is great. Look, that spot over there will do.~ [ IRQUIET ]
		IF ~~ THEN DO ~SetGlobal("MRCampSleepTalk","GLOBAL",2)
		ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe1")~
		EXIT	
	END
END
//campfire cutscene start
//act 2

//loveme1a.bcs start
APPEND IMOEN2J
	IF ~Global("MRCampfireMusic","GLOBAL",1)~ THEN BEGIN MRCampfireMusic
		SAY ~Yeah, a beautiful place, dontcha think? Let's rest here!~ [ IRQUIET ]
		IF ~~ THEN REPLY ~(You unpack your bedroll and prepare to lie down for the night.)~ DO ~SetGlobal("MRCampfireMusic","GLOBAL",2)~ GOTO MRCampfireMusic2
	END

	IF ~~ THEN BEGIN MRCampfireMusic2
		SAY ~Huh? What're you doing?~
		++ ~I'm preparing the place where I am going to sleep, like every time we rest.~ GOTO MRCampfireMusic2Rest
		++ ~Uh, going to sleep? I thought you wanted to sleep here.~ GOTO MRCampfireMusic2Rest
		++ ~You said you wanted to rest here. What's the matter?~ GOTO MRCampfireMusic2Rest
		++ ~Have you seen my teddy bear? I need it to fall asleep. You haven't stolen it again, have you?~ GOTO MRCampfireMusic2Rest
	END

	IF ~~ THEN BEGIN MRCampfireMusic2Rest
		SAY ~No no, I wanted to *rest* here, but not just go to sleep and that's all! Y'know what I mean?~
		IF ~NumInPartyGT(2)~ THEN REPLY ~Sleep is what I do when I need rest.~ GOTO MRCampfireMusic2Group
		IF ~!NumInPartyGT(2)~ THEN REPLY ~Sleep is what I do when I need rest.~ GOTO MRCampfireMusic2Solo
		IF ~NumInPartyGT(2)~ THEN REPLY ~So what do you have in mind?~ GOTO MRCampfireMusic2Group
		IF ~!NumInPartyGT(2)~ THEN REPLY ~So what do you have in mind?~ GOTO MRCampfireMusic2Solo
		++ ~Aah, yes, about time you brought this up. I thought we'd never get to this part. (Eye her up and down, get closer to her.)~ GOTO MRCampfireMusic2Naughty
	END

	IF ~~ THEN BEGIN MRCampfireMusic2Naughty
		SAY ~(Imoen looks at you warily.)~
		= ~What in Torm's name are you talkin' about?~
		IF ~~ THEN REPLY ~Isn't it obvious? Our mutual attraction, it's undeniable. I care about you, you care about me. Let's stop pretending.~ GOTO MRCampfireMusic2NaughtyNice
		IF ~Gender(Player1,MALE)~ THEN REPLY ~Knockin' boots, a bit of the ol' in and out, a roll in the hay - have SEX, SEX dammit! I think I've earned it!~ GOTO MRCampfireMusic2Naughty2Male
		IF ~Gender(Player1,FEMALE)~ THEN REPLY ~Knockin' boots, bumping uglies, a roll in the hay - have SEX, SEX dammit! I think I've earned it!~ GOTO MRCampfireMusic2Naughty2Female
		++ ~Haha, I got you going for a moment there. You aren't the only one that can joke around, you know?~ GOTO MRCampfireMusic2NaughtyJoke
	END

	IF ~~ THEN BEGIN MRCampfireMusic2NaughtyJoke
		SAY ~Hah. Guess you're right.~
		IF ~NumInPartyGT(2)~ THEN GOTO MRCampfireMusic2Group
		IF ~!NumInPartyGT(2)~ THEN GOTO MRCampfireMusic2Solo
	END

	IF ~~ THEN BEGIN MRCampfireMusic2Naughty2Male
		SAY ~(Imoen's face goes pale) What? Is this what's been going on in your head? All this time, opening up to you, getting closer, sharing my deepest secrets... you were *undressing me* in your head?~
		= ~You- you BASTARD! What's wrong with you? I'm your sister, you creep! Even if I weren't, you're the last person I'd ever touch like that!~
		= ~I'm done. How could I ever trust you, knowing that all you want is - is to bed me like I'm some two-bit harlot?~
		= ~I thought you were a better <PRO_MANWOMAN> than that. And obviously I was wrong. Goodbye!~
		IF ~~ THEN DO ~LeaveParty()
		SetGlobal("KickedOut","LOCALS",1)
		SetDialog("Imoen2p")
		ReputationInc(-1)
		SetGlobal("ImoenRomanceActive","GLOBAL",3)
		EscapeAreaMove("ar0406",504,1493,0)~ // IMOEN SHOULD GO TO THE COPPER CORONET~
		EXIT
	END

	IF ~~ THEN BEGIN MRCampfireMusic2Naughty2Female
		SAY ~(Imoen's face goes pale) What? Is this what's been going on in your head? All this time, opening up to you, getting closer, sharing my deepest secrets... you were *undressing me* in your head?~
		= ~You- you disgusting creep! What's wrong with you? I'm your sister! Did you forget about that? And even if I weren't, you're the last person I'd ever touch that way!~


		= ~I'm done. How could I ever trust you, knowing that all you want is - is to bed me like I'm some two-bit harlot?~
		= ~I thought you were a better <PRO_MANWOMAN> than that. And obviously I was wrong. Goodbye!~
		IF ~~ THEN DO ~LeaveParty()
		ReputationInc(-1) 
		SetGlobal("KickedOut","LOCALS",1)
		SetDialog("Imoen2p")
		SetGlobal("ImoenRomanceActive","GLOBAL",3)
		EscapeAreaMove("ar0406",504,1493,0)~ // IMOEN SHOULD GO TO THE COPPER CORONET~
		EXIT
	END

	IF ~~ THEN BEGIN MRCampfireMusic2NaughtyNice
		SAY ~(Imoen's face goes pale) What? Oh, no, no, <CHARNAME>, you got it completely wrong. I do love you, but... not in that way.~

                = ~I mean, you matter a lot to me, you're the most important person in my life right now. I just... there's nothing else. You understand?~

		++ ~Oh.~ GOTO MRCampfireMusic2NaughtyNiceSad
		IF ~Gender(Player1,MALE)~ THEN REPLY ~What? You don't like guys? Is that it?~ GOTO MRCampfireMusic2NaughtyNiceSadF
		IF ~Gender(Player1,FEMALE)~ THEN REPLY ~Is it because I'm a woman? Because I love you more than any man ever could.~ GOTO MRCampfireMusic2NaughtyNiceSadF
		++ ~Yeah, I understand. You're just another leech that wants my help but won't give anything in exchange.~ GOTO MRCampfireMusic2NaughtyNiceBitch
	END

	IF ~~ THEN BEGIN MRCampfireMusic2NaughtyNiceSad
		SAY ~Oh, I'm so sorry <CHARNAME>! It might be partly my fault. I must've sent all the wrong signals. It's heartbreaking to disappoint you like this.~

		=
		~(Her voice drops to a barely audible whisper) Y'see, I... I decided some time ago. No matter what happens, I can't let myself fall for you. It just can't be.~
		=
		~I'm sorry, <CHARNAME>... it cannot be.~
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7)
                SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfireMusic2NaughtyNiceSadF
		SAY ~No, that's not it at all! I'm so sorry <CHARNAME>. It might be partly my fault, I must've sent all the wrong signals. It's heartbreaking to disappoint you like this.~

		=
		~(Her voice drops to a barely audible whisper) Y'see, I... I decided some time ago. No matter what happens, I can't let myself fall for you. It just can't be.~
		=
		~I'm sorry, <CHARNAME>... it cannot be.~
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7)
                SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfireMusic2NaughtyNiceBitch
		SAY ~Fine, get mad at me. I won't hold it against you.~
		=
		~I'm so sorry, <CHARNAME>. It cannot be.~
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7)
                SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfireMusic2Group
		SAY ~Well, just light a fire, sit all of yer butts down and I'll show ya the kind of relaxation I have in mind for tonight.~

		++ ~(Do as she says.)~	DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe2")~ EXIT
        	++ ~Whoa! It was about time. Party orgy! (Begin to undress.)~ GOTO MRCampfireMusic2Orgy

	END

	IF ~~ THEN BEGIN MRCampfireMusic2Solo
		SAY ~Well, just light a fire, sit down yer butt and I'll show you the kind of relaxation I have in mind for tonight.~
		++ ~Whoa! It was about time. Alone in the forest, let's have some action! (Begin to undress.)~ GOTO MRCampfireMusic2Orgy
		++ ~(Do as she says.)~	DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe2")~ EXIT
	END


	IF ~~ THEN BEGIN MRCampfireMusic2Orgy
		SAY ~Uh, what didya say, <CHARNAME>? I got distracted by the bird that just took off from that bush...~
		++ ~(Discreetly put your clothes back on and just do as she says.)~ DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe2")~ EXIT
		IF ~NumInPartyGT(2)~ THEN REPLY ~(Ignore her and get naked.)~ GOTO MRCampfireMusic2OrgyGroup
		IF ~!NumInPartyGT(2)~ THEN REPLY ~(Ignore her and get naked.)~ GOTO MRCampfireMusic2OrgySolo
	END
END


CHAIN IMOEN2J MRCampfireMusic2OrgyGroup
	~(She - and everyone else - is astounded when they see your state of undress. You realize too late that this is no orgy.)~
	= ~(She stares at you in shock. Her lips begin to tremble. Then she can't hold it anymore and bursts into laughter.)~
	==VICONIJ IF ~CheckStatGT(Player1,13,CHR) IsValidForPartyDialog("Viconia")~ THEN ~(Viconia arches an eyebrow as she regards your naked form - and her gaze is most certainly appreciative.)~
	==AERIEJ IF ~Gender(Player1,MALE) IsValidForPartyDialog("Aerie")~ THEN ~<CHARNAME>! W-w-what are you- Put back on your c-clothes!~
	==NALIAJ IF ~Gender(Player1,MALE) IsValidForPartyDialog("Nalia")~ THEN ~*ahem* <CHARNAME>? Could you... ah.. cover yourself?~
	==NALIAJ IF ~Gender(Player1,MALE) CheckStatGT(Player1,13,CHR) IsValidForPartyDialog("Nalia")~ THEN ~Not that I'm complaining about the view, mind you.~
	==NALIAJ IF ~Gender(Player1,MALE) !CheckStatGT(Player1,10,CHR) IsValidForPartyDialog("Nalia")~ THEN ~Some of us could live without seeing your 'charms'.~
	==MAZZYJ IF ~Gender(Player1,MALE) IsValidForPartyDialog("Mazzy")~ THEN ~That is hardly appropriate, <CHARNAME>. Is there a purpose to this tawdry display?~
	==VICONIJ IF ~!CheckStatGT(Player1,13,CHR) IsValidForPartyDialog("Viconia")~ THEN ~(Viconia rolls her eyes) Were I you, <CHARNAME>, I would not be so quick to parade your... shortcomings.~
	==JAHEIRAJ IF ~Gender(Player1,MALE) IsValidForPartyDialog("Jaheira")~ THEN ~(Jaheira merely snorts and turns away, obviously unimpressed by your antics.)~

	==KORGANJ IF ~Gender(Player1,FEMALE) CheckStatGT(Player1,9,CHR) IsValidForPartyDialog("Korgan")~ THEN ~Oi! Oi! Now that be worth campin' in a bloody field o' flowers!~
	==KORGANJ IF ~Gender(Player1,FEMALE) !CheckStatGT(Player1,10,CHR) IsValidForPartyDialog("Korgan")~ THEN ~Kin o' a god or not, yer still an ugly bugger. Put yer clothes back on 'fore ye ruin me eyes for good!~
	==EDWINJ IF ~Gender(Player1,FEMALE) CheckStatGT(Player1,13,CHR) IsValidForPartyDialog("Edwin")~ THEN ~Idiocy! Everywhere I turn, idiocy! (Although if idiocy always had such succulent breasts, perhaps I would be more forgiving.)~
	==EDWINJ IF ~Gender(Player1,FEMALE) !CheckStatGT(Player1,13,CHR) !CheckStatLT(Player1,10,CHR) IsValidForPartyDialog("Edwin")~ THEN ~Idiocy! Everywhere I turn, idiocy!~
	==EDWINJ IF ~Gender(Player1,FEMALE) CheckStatLT(Player1,10,CHR) IsValidForPartyDialog("Edwin")~ THEN ~Idiocy! Everywhere I turn, idiocy! (Ugh! Hideous! It shall take a week to get that image out of my mind!)~
	==JANJ IF ~Gender(Player1,FEMALE) IsValidForPartyDialog("Jan")~ THEN ~Did I ever tell you about the time my second-cousin-twice-removed Bertle went skinny dipping in the jungle? No? There were flesh-eating fish in the water. It didn't end well.~
	==HAERDAJ IF ~Gender(Player1,FEMALE) CheckStatGT(Player1,12,CHR) IsValidForPartyDialog("HaerDalis")~ THEN ~Ah, my ravishing raven - how long I have yearned to see you in all your glory.~
	==HAERDAJ IF ~Gender(Player1,FEMALE) !CheckStatGT(Player1,12,CHR) IsValidForPartyDialog("HaerDalis")~ THEN ~Ah, my raven - while you have a unique beauty, often concealment is the greater part of glamour.~
	==ANOMENJ IF ~Gender(Player1,FEMALE) IsValidForPartyDialog("Anomen")~ THEN ~Milady, I must protest! Have some dignity for yourself!~
	==VALYGARJ IF ~Gender(Player1,FEMALE) IsValidForPartyDialog("Valygar")~ THEN ~Well, that was... unexpected.~
	==KELDORJ IF ~Gender(Player1,FEMALE) !CheckStatGT(Player1,13,CHR) IsValidForPartyDialog("Keldorn")~ THEN ~That is hardly appropriate, <CHARNAME>. Is there a purpose to this tawdry display?~
	==MINSCJ IF ~IsValidForPartyDialog("Minsc")~ THEN ~Yes! Wait - Boo says that I should not also take off my clothes and dance around. Mayhaps I should listen.~
	==CERNDJ IF ~IsValidForPartyDialog("Cernd")~ THEN ~Is it not normal that <PRO_HESHE> wears what nature has provided? Do not be bothered by their comments, <CHARNAME>.~
	
	==IMOEN2J ~(She barely manages to speak) What... what are you doing!~
END ++ ~Euhh... we were supposed to get it on!~ EXTERN IMOEN2J MRCampfireMusic2Sex
	++ ~Uh... I'm gonna go swimming. Yeah, that's it.~ EXTERN IMOEN2J MRCampfireMusic2OrgyBath

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRCampfireMusic2OrgySolo
		SAY ~(Her eyes widen when she sees your state of undress. You realize too late that, shockingly enough, Imoen wasn't suggesting you have wild sex by the campfire.)~
		~(She stares at you in shock. Her lips begin to tremble. Then she can't hold it anymore and bursts into laughter.)~
		= ~(She barely manages to speak) What... what are you doing!~
		++ ~Euhh... we were supposed to get it on!~ GOTO MRCampfireMusic2Sex
		++ ~Uh... I'm gonna go swimming. Yeah, that's it.~ GOTO MRCampfireMusic2OrgyBath
	END


	IF ~~ THEN BEGIN MRCampfireMusic2OrgyBath
		SAY ~G-get your clothes on! We'll have time for that later!~
		=
		~(She's laughed so hard that she's wiping tears from her cheeks) Gods, you're a nutter!~
		=
		~Just sit down and stay there!~
		IF ~~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe2")~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfireMusic2Sex
		SAY ~Get it... on? (She's laughed so hard that she's wiping tears from her cheeks.)~
		= ~Gods, you're such a pervert! Get your clothes on and sit down there, dammit!~
		IF ~~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe2")~ EXIT
	END

	//LoveMe2.baf

	// *** Act 3 ***

	IF ~NumInPartyGT(2) Global("MRCampfireMusic","GLOBAL",2)~ THEN BEGIN MRCampfireMusic3Group
		SAY ~(Imoen stares at the flames. Everyone is sitting around the small fire, but few words have been said. Finally, Imoen speaks.)~ [ MRImRom5 ]
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",3)~ GOTO MRCampfireMusic4
	END

	IF ~!NumInPartyGT(2) Global("MRCampfireMusic","GLOBAL",2)~ THEN BEGIN MRCampfireMusic3Solo
		SAY ~(Imoen stares at the flames. You both are sitting around the small fire, but few words have been said. Finally, Imoen speaks.)~ [ MRImRom5 ]
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",3)~ GOTO MRCampfireMusic4
	END
END

CHAIN IMOEN2J MRCampfireMusic4
~This place is so perfect. So peaceful... well, now that the drow have given up for a while.~
= ~It's been a long time since I've felt like this. A really long time.~
= ~(She looks wistful for a moment, then lightly shakes her head. Her eyes glint with anticipation for some reason, yet her smile betrays wariness.)~
= ~Y'know what? I've been thinkin' forever about showing you, and this is just the perfect time. I'm a bit nervous about it, no-one's ever seen it 'cept for Gorion and ol' Puffguts. Gimme a sec...~



= ~(Imoen looks for something inside her pack. After searching through her belongings, she finally takes out a small object.)~
== IMOEN2J IF ~!Class(Player1,BARD)~ THEN ~(She shows it to you: a little ivory figurine in the form of a musical instrument. It looks like a lute, or something quite similar.)~
== IMOEN2J IF ~Class(Player1,BARD)~ THEN ~(She shows it to you: a little ivory figurine in the form of a string instrument. You recognize it as a guitar - a rather rare instrument you've only seen in books.)~



== IMOEN2J ~(She places it on her lap, then begins to cast a spell. The arcane words echo in your head as the small figurine begins to move by itself. It slowly grows until a full-sized instrument rests in Imoen's arms; it looks wooden now, but still the colour of ivory.)~
= ~(She gently cradles the instrument against her bust) Ah, yes, I missed ya, girl. (She looks up) Quite the thing, huh? Well, here's the real surprise.~

= ~(Imoen's fingers begin to gracefully fly over the strings, playing a beautiful melody. Triumphantly she looks at you; she's practically glowing.)~ [ MRImInt3 ]
= ~Surprised? Can't blame ya. Best kept secret in all of Faerun.~
= ~You can blame Gorion for this. He was always tryin' to get me into magic, remember? So I wouldn't end up as a common thief, like he feared. But magic stuff was booooooring back then.~
= ~So he gave me this, instead. Bard was better than rogue, I bet he figured. Try to steer me to the finer arts in life an' all that. (She stumbles slightly, talking and playing at the same time, but quickly recovers.)~
= ~I had no idea things like this existed. He said it came from far, far South, "past Lapaliiya and Halruaa". No clue where those might be on a map.~
== IMOEN2J IF ~Class(Player1,BARD)~ THEN ~He joked - he actually joked! - about not wantin' to spoil you too much with it, so he gave it to me instead. Maybe it'd inspire me, huh? It kinda did. Kinda.~
== IMOEN2J IF ~!Class(Player1,BARD)~ THEN ~He joked - he actually joked! - about not wantin' to spoil you too much with it. So he gave it to me instead. Maybe it'd inspire me, huh? It kinda did. Kinda.~
== IMOEN2J ~Wanna know the real shocking part, though? It was actually Puffguts that taught me to play. Can you believe it? He'd been far and wide, done so many things when he was younger. He must've been thin at some point, huh. Unheard-of.~
= ~He was good. Like, really good. Who coulda known those huge fingers could move so fast? Super secretive about it, too. It's as if the whole "lazy barkeep in a quiet keep" thing was just pretend. Like there was a life he'd left behind and couldn't go back to... but it showed through his music.~
= ~(She giggles) Boy, did I drive him mad with this thing. I'll be honest, he wasn't a very patient teacher. I kind of... blackmailed him to play.~
= ~Anyway, clearly I never became a bard, and a good thing that is. I don't like audiences. I really... *really* don't. I get all clammy and sweaty and gross and everything just goes terribly wrong.~
= ~But I kept practicing when alone. Puffgut's basement was real good for that. Eventually I hid even from him and Mister G - they thought I'd given it up, just like everything else...~

= ~And that's it! How's that for a story? (She beams at you and plays something else.)~ [ MRImInt2 ]
== JAHEIRAJ IF ~IsValidForPartyDialog("Jaheira")~ THEN ~Most impressive, child. That you've been able to learn this all by yourself demonstrates a great determination.~
== AERIEJ IF ~IsValidForPartyDialog("Aerie") !Class(Player1,BARD)~ THEN ~Imoen, this is great! Our camp will never be sad and quiet anymore.~
== AERIEJ IF ~IsValidForPartyDialog("Aerie") Class(Player1,BARD)~ THEN ~Imoen, this is great! You can join up with <CHARNAME>, perform for us every night...~
== NALIAJ IF ~IsValidForPartyDialog("Nalia")~ THEN ~We held a great string concert once, back at home. You bring fond memories to bear, Imoen. It's a joy to listen to you.~
== JANJ IF ~IsValidForPartyDialog("Jan")~ THEN ~Aah, it reminds me of the time when Uncle Squishberry challenged a traveling minstrel who had a passion for turnips to a bagpipe contest. They were both such windbags that they played non-stop from dawn to dusk never tiring. The contest, which likely could have gone on for days, was ended abruptly when Aunt Squishberry stabbed their instruments with her cooking knife. It was a terrible, terrible loss...~
== VICONIJ IF ~IsValidForPartyDialog("Viconia")~ THEN ~I don't understand all that mystery, liggr. Playing an instrument is perhaps the most useless activity I can think of.~
== EDWINJ IF ~IsValidForPartyDialog("Edwin")~ THEN ~Look, the monkey knows how to use her opposable fingers! (The only ability she has managed to develop in all these years of worthless living, I can be sure.)~
== KORGANJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Arr this is stupid! We should be killin' some bloody elves instead of sittin' here huggin' trees!~
== MINSCJ IF ~IsValidForPartyDialog("Minsc")~ THEN ~Ooh, it's such a nice thing. Boo likes it a lot, right Boo?~
== HAERDAJ IF ~IsValidForPartyDialog("HaerDalis")~ THEN ~Ahh, I wish I had known this before. You and I, my precious wildflower, we could go far together!~
== KELDORJ IF ~IsValidForPartyDialog("Keldorn")~ THEN ~You handle that instrument well, Imoen. It appears you've many talents. I wonder what else you can do that you have not shown us yet.~
== MAZZYJ IF ~IsValidForPartyDialog("Mazzy")~ THEN ~Very impressive indeed, Imoen. I'm surprised you could keep this marvelous thing to yourself all this time. (Mazzy smiles) You have been too selfish!~
== ANOMENJ IF ~IsValidForPartyDialog("Anomen")~ THEN ~That was quite the story. Promise you will play more frequently from now on, Imoen.~
END IMOEN2J MRCampfireMusic5

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRCampfireMusic5
		SAY ~Surprised?~
		++ ~This is crazy. When do you even get the chance to practice?~ GOTO MRCampfireMusic5How
		+ ~!Class(Player1,BARD)~ + ~I knew nothing of this. How could you hide this from me all this time? Why didn't you tell me?~ GOTO MRCampfireMusic5WhyNot
		IF ~Class(Player1,BARD)~ THEN REPLY ~Imoen, we could have been a great duo. Why did you hide this from me?~ GOTO MRCampfireMusic5WhyNot
                ++ ~It somehow makes sense. Don't mind me, now. I'll just sit back and enjoy.~ GOTO MRCampfireMusic5Continue
		IF ~!Class(Player1,BARD)~ THEN REPLY ~Imoen, please take no offense, but I don't like music at all. I beg that you stop playing.~ GOTO MRCampfireMusic5Hate
		++ ~I hate music, please stop it at once!~ GOTO MRCampfireMusic5Hate
	END

	IF ~~ THEN BEGIN MRCampfireMusic5Hate
		SAY ~(She stops, puzzled) Whatever you mean by that? Everyone likes at least *some* sort of music!~ [ MRImEndG ]
		++ ~Gotcha! It was just a joke, dummy.~ GOTO MRCampfireMusic5HateJoke
		IF ~!Class(Player1,BARD)~ THEN REPLY ~Well, I don't, so quit it.~ GOTO MRCampfireMusic5HateYes
		++ ~No, I don't hate all music. Only *your* music.~ GOTO MRCampfireMusic5HateYou
	END

	IF ~~ THEN BEGIN MRCampfireMusic5HateYou
		SAY ~Wow. This is why I *hate* audiences. You're a big fat jerk, you know?~
		= ~I don't even know why I ever wanted to play in front of *you* anyway.~
		=~Whatever. I'm going to bed.~
		IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4)
		SetGlobal("MRCampfireMusic","GLOBAL",7)
        	StartCutSceneMode() StartCutScene("Cut34a")~
		EXIT
	END

	IF ~~ THEN BEGIN MRCampfireMusic5HateYes
		SAY ~You never mentioned anything like that. It's quite unusual, you know? I'd bet even *Irenicus* likes some kind of music.~
		IF ~~ THEN GOTO MRCampfireMusic5HateStopGroup
		IF ~!NumInPartyGT(2)~ THEN GOTO MRCampfireMusic5HateStopSolo
	END

	IF ~~ THEN BEGIN MRCampfireMusic5HateStopGroup
		SAY ~Oh well, if ya don't like it there's no point to keep doing this, really. Sorry people, show's over!~
		IF ~~ THEN GOTO MRCampfireMusic5HateStopEnd
	END

	IF ~~ THEN BEGIN MRCampfireMusic5HateStopSolo
		SAY ~Oh well, if ya don't like it there's no point to keep doin' this, really. Show's over, then!~
		IF ~~ THEN GOTO MRCampfireMusic5HateStopEnd
	END

	IF ~~ THEN BEGIN MRCampfireMusic5HateStopEnd
		SAY ~(She shrinks her instrument again and puts it away. Imoen seems uncomfortable at first, but soon she shrugs it off and behaves normally for the rest of the night. After some more idle chat around the campfire, you go to bed for some much needed rest.)~
		IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player2)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3a")~ EXIT
		
		IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player3)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3b")~ EXIT
		
		IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player4)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3c")~ EXIT
		
		IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player5)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3d")~ EXIT
		
		IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player6)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3e")~ EXIT
		
		IF ~!Global("ImoenRomanceActive","GLOBAL",1)~ THEN DO ~StartCutSceneMode() StartCutScene("Cut34a")~ EXIT
	END


	IF ~~ THEN BEGIN MRCampfireMusic5HateJoke
		SAY ~Pff, you goon. Had me worried for a moment there... (she starts playing again.)~ [ MRImInt2 ]
		++ ~This is so crazy, though. When do you even get the time to practice?~ GOTO MRCampfireMusic5How
		++ ~Why wouldn't you tell me about something like this?~ GOTO MRCampfireMusic5WhyNot
        ++ ~Don't mind me, now. I'll just sit back and enjoy.~ GOTO MRCampfireMusic5Continue
	END

	IF ~~ THEN BEGIN MRCampfireMusic5How
		SAY ~I haven't been able to for a while, is why I'm so rusty. But hey, gimme some credit! I learned magic fast enough, didn't I? Maybe I only needed a few minutes with this thing before I could run laps around chords.~
		= ~Okay, not... really, but it's not that hard. I feel like gettin' better from this point forward, *that* would be hard.~
		++ ~So why would you hide this from me in the first place?~ GOTO MRCampfireMusic5WhyNot
		++ ~(Nod and let her continue playing.)~ GOTO MRCampfireMusic6
		++ ~Good enough for me. I'm going to just lean back and enjoy it.~ GOTO MRCampfireMusic5Continue
	END

	IF ~~ THEN BEGIN MRCampfireMusic5WhyNot
		SAY ~Weren't you listenin' just now? I'm a big fat chicken. Squawk, squawk squawk, that's me. Gosh, it was tough enough workin' up the courage for tonight. Just thinking of a bigger audience... (She shudders.)~
		=
		~Y'know, I was toyin' with the idea when we solved the whole Baldur's Gate mess, trying to find a good time to do it... but then Irenicus' goons showed up and ruined everything.~
		=
		~I hadn't played again 'til now. I was a bit worried. Did it show? I hope not.~
		++ ~A little, but you pulled through. Go on playing, I'll enjoy listening.~ GOTO MRCampfireMusic5Continue
		++ ~No, not at all. I'm thoroughly impressed, Imoen.~ GOTO MRCampfireMusic5Continue2
        ++ ~(Nod and let her continue playing.)~ GOTO MRCampfireMusic6
	END



	IF ~~ THEN BEGIN MRCampfireMusic5Continue
		SAY ~But of course you will! (She chuckles happily, and stops the melody she was playing.)~ [ MRImEndG ]
		IF ~~ THEN GOTO MRCampfireMusic6
	END

	IF ~~ THEN BEGIN MRCampfireMusic5Continue2
		SAY ~But of course you are! (She chuckles happily, and stops the melody she was playing.)~ [ MRImEndG ]
		IF ~~ THEN GOTO MRCampfireMusic6
	END

	IF ~~ THEN BEGIN MRCampfireMusic6
		SAY ~Alright, here goes. I hope you like this.~
                = ~(Imoen prepares a chord and clears her throat with a slight cough. Soon she's plucking strings, gently easing the ambiance into a simple tune.)~ [ MRImInt1 ]
		= ~(She starts to sing softly, her heart pouring onto the melody. Though the pitch wavers at times, it remains honest and earnest and altogether true.)~

		= ~Tears on dust, free they fall-
		Drops of rage of a broken thrall

		His soulmate dead, his daughter slain
		Wrath unbound - fans the flame.~

		= ~Vengeance sworn, he takes the quest
		To a distant foe, step by step
		
		What matters the price? In blood he'll pay
		And wrath will take the pain away.~

		= ~Weary and worn, weathered, then withered
		Rust biting bone, a sword that once glimmered
		
		Shattered and broken, the memory grows dimmer
		Lives, made corpses; crumbs for a sinner.~

		= ~Thorns for his tomb, he falls,
		To one hundred deaths, a thrall,
		
		Hollow of heart, soul-slain,
		He dies alone, in dread and shame.~
		= ~(Her voice fades, as the last chord echoes in the night air. Imoen opens her eyes, a faint smile on her lips.)~

		IF ~~ THEN GOTO MRCampfireMusic7
	END
END

CHAIN IMOEN2J MRCampfireMusic7
~(You'd never heard Imoen sing before. Sometimes she'd whistle, sometimes she'd hum - but you can't remember her ever singing.)~ [ MRImRom6 ]
== JAHEIRAJ IF ~IsValidForPartyDialog("Jaheira")~ THEN ~That was delightful, Imoen. Thank you.~
== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~Such a sad story... (Aerie sniffs and wipes her face dry.)~
== NALIAJ IF ~IsValidForPartyDialog("Nalia")~ THEN ~That was beautiful.~
== JANJ IF ~IsValidForPartyDialog("Jan")~ THEN ~You should come over to my home and play in front of the whole family. I'm sure they'd enjoy it! Well, except Granny Jansen, she's completely deaf.~
== VICONIJ IF ~IsValidForPartyDialog("Viconia")~ THEN ~Foolish girl. My ears feel sullied by this amateur display.~
== EDWINJ IF ~IsValidForPartyDialog("Edwin")~ THEN ~Ooo, look at that! She can carry a simple tune, I'm so impressed! (How I ever got saddled with this troupe of fools, I will never know.)~

== KORGANJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Alright so the lass is done with 'er bloody music! Let's get back to the killin'!~
== MINSCJ IF ~IsValidForPartyDialog("Minsc")~ THEN ~Boo loves your singing! We want to hear more!~
== HAERDAJ IF ~IsValidForPartyDialog("HaerDalis")~ THEN ~A fine display, my little bird. It was heartsome and lovely. You struck all the right notes.~
== KELDORJ IF ~IsValidForPartyDialog("Keldorn")~ THEN ~This is truly a treat for weary bones, Imoen. Thank you for performing tonight.~
== MAZZYJ IF ~IsValidForPartyDialog("Mazzy")~ THEN ~The lyrics are striking. Very sad indeed.~
== ANOMENJ IF ~IsValidForPartyDialog("Anomen")~ THEN ~I enjoyed that very much. You are a girl of many talents.~
END IMOEN2J MRCampfireMusic8


APPEND IMOEN2J
	IF ~~ THEN BEGIN MRCampfireMusic8
		SAY ~(Imoen looks at you nervously, She is expecting some kind of opinion from you.)~

		++ ~(Simply keep looking at her, stunned. This has touched you beyond words.)~ GOTO MRCampfireMusic8Stun
		++ ~You're gifted, Imoen. Agile, deft with magic, and now music? Amazing.~ GOTO MRCampfireMusic8Gift

		++ ~It was good, but, you know, you should work on those high notes.~ GOTO MRCampfireMusic8High
		++ ~(Shrug) Well, how about some food, now.~ GOTO MRCampfireMusic8Shrug
		++ ~Glad that's over with. If I cringe any more, my face will get stuck this way.~ GOTO MRCampfireMusic8Cringe

	END

	IF ~~ THEN BEGIN MRCampfireMusic8Stun
		SAY ~(Imoen laughs) Hey, <CHARNAME>! You're still awake, right? Hello?~
		=
		~Haha, I'm gonna take that as a compliment.~
		IF ~~ THEN GOTO MRCampfireMusic9
	END

	IF ~~ THEN BEGIN MRCampfireMusic8Gift
		SAY ~Aww, jeez... (Imoen is blushing) it's not great. I could never make a livin' out of it, that's for sure.~

		=
		~But that's real nice to hear, <CHARNAME>. Thank you.~

		IF ~~ THEN GOTO MRCampfireMusic9
	END

	IF ~~ THEN BEGIN MRCampfireMusic8High
		SAY ~(She sighs) I know, I know... I try, but I'm no bard. There's no way I could make a livin' out of it.~


		IF ~~ THEN GOTO MRCampfireMusic9
	END

	IF ~~ THEN BEGIN MRCampfireMusic8Shrug
		SAY ~Yeesh, alright, I can take a hint. Not that it was subtle in any way...~

		IF ~~ THEN GOTO MRCampfireMusic9
	END

	IF ~~ THEN BEGIN MRCampfireMusic8Cringe
		SAY ~(Imoen's lips curve down in the most disillusioned face you've ever witnessed) Jeez. Okay. I knew it wasn't that good, but... jeez.~
         =~I'll put this thing away, you don't have to worry about it anymore.~
		IF ~~ THEN GOTO MRCampfireMusic9
	END
END

CHAIN IMOEN2J MRCampfireMusic9
~(The night goes on in a friendly, cheerful mood, Imoen's music gradually allowing other topics to surface.)~

== IMOEN2J IF ~NumInPartyGT(2)~ THEN ~(Everyone enjoys the night in their own way, regardless of their different beliefs and personalities. The opportunity to take a break from everything that is going on around you and your party doesn't come often.)~
== IMOEN2J IF ~NumInPartyGT(2)~ THEN ~(Topics wander from reminiscence of the past to future plans until the fire is reduced to embers, always avoiding the present. For tonight, Irenicus and Bodhi are replaced by mundane stories, heated discussions or lighthearted jokes, making all the tension and worry about your present situation fade away.)~
== IMOEN2J IF ~NumInPartyGT(2)~ THEN ~(Finally, the time to rest comes, and everyone retires to their respective bedroll. Imoen prepares hers a ways from the rest... then she lies on her back, gazing the stars until she falls asleep.)~
== IMOEN2J IF ~!NumInPartyGT(2)~ THEN ~(Soon enough Imoen is laughing lightheartedly at recounted stories from happier times in Candlekeep, and you spend the night talking about past and future alike until the fire is reduced to embers, always avoiding the present.)~
== IMOEN2J IF ~!NumInPartyGT(2)~ THEN ~(For tonight, Irenicus and Bodhi are replaced by mundane tales and lighthearted jokes, making all the tension and worry about your present situation fade away.)~
== IMOEN2J IF ~!NumInPartyGT(2)~ THEN ~(Somehow you end up lying on the turf resting on your backs, talking about anything and everything while you gaze at the countless stars that populate the firmament, until she falls asleep.)~
END IMOEN2J MRCampfireMusic10

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRCampfireMusic10
		SAY ~(With the background of the crickets' song and the soft zephyr passing through the branches overhead, the peaceful ambiance slowly lulls you into restful sleep.)~
			IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player2)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3a")~ EXIT
		
		IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player3)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3b")~ EXIT
		
		IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player4)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3c")~ EXIT
		
		IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player5)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3d")~ EXIT
		
		IF ~Global("ImoenRomanceActive","GLOBAL",1) Name("Imoen2",Player6)~ THEN DO ~ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe3e")~ EXIT
		IF ~!Global("ImoenRomanceActive","GLOBAL",1)~ THEN DO ~StartCutSceneMode() StartCutScene("Cut34a")~ EXIT
	END

	// *** Act 4 ***
	//loveme3.baf

	IF ~Global("MRCampfireMusic","GLOBAL",3)~ THEN BEGIN MRCampfireMorning
		SAY ~WAKE UP, <CHARNAME>!~ [ MRImRom4 ]
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",4) ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRCampfireMorning2
	END

	IF ~~ THEN BEGIN MRCampfireMorning2
		SAY ~*SShhwhoooosshh*~

		IF ~~ THEN EXTERN PLAYER1 MRCampfireMorning2
	END
END

APPEND PLAYER1
	IF ~~ THEN BEGIN MRCampfireMorning2
	SAY ~(You pry one eye open just in time to see a wall of water heading straight at your face.)~
        = ~(Frigid water splashes all over your half-dormant body, shocking your senses. With a shout, you roll out of the soaked bedroll.)~


	IF ~~ THEN EXTERN IMOEN2J MRCampfireMorning3
	END
END

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRCampfireMorning3
		SAY ~YES! GOTCHA! The almighty Bhaalspawn <CHARNAME> caught defenseless by the great Imoen, hahaha!~
		=
		~(Imoen breaks in peals of laughter, empty bucket hanging from limp fingers.)~
		++ ~(Just look at her in shock) Why would you do that? What did I ever do to you!~ GOTO MRCampfireMorning3Why


		++ ~Grrargh! Come here you! (You're going to catch this scoundrel and tickle her to death.)~ GOTO MRCampfireMorning3Catch
		++ ~Grrargh! Come here you! (You're going to catch this harlot and pummel her to death for what she's done.)~ GOTO MRCampfireMorning3Catch
		++ ~You brat, look at what you've done!~ GOTO MRCampfireMorning3Bitch
		++ ~(You might be wet, but your dignity is intact. Ignore Imoen, pick up your belongings, and start getting ready for the day.)~ GOTO MRCampfireMorning3Why4
	END

	IF ~~ THEN BEGIN MRCampfireMorning3Why
		SAY ~(Your expression only makes her laugh harder. She doubles over, bracing her belly with both hands.)~
		++ ~I thought you were my friend. I trusted you. I'd never do this to you, Imoen.~ GOTO MRCampfireMorning3Why2
		++ ~Grrargh! Come here you! (You're going to catch this scoundrel and tickle her to death.)~ GOTO MRCampfireMorning3Catch


		++ ~Grrargh! Come here you! (You're going to catch this harlot and pummel her to death for what she's done.)~ GOTO MRCampfireMorning3Catch
		++ ~You... you brat! You're such a nuisance!~ GOTO MRCampfireMorning3Bitch
		++ ~(You shake your head and simply ignore her, gathering your belongings and getting ready for the day.)~ GOTO MRCampfireMorning3Why4
	END

	IF ~~ THEN BEGIN MRCampfireMorning3Why2
		SAY ~(She laughs a bit more, then it starts to die down.)~

		=
		~C'mon, <CHARNAME>! (She giggles) It was just a joke!~
		++ ~(Shake your head) This isn't a joke. This is just an insult. I'm so humiliated right now.~ GOTO MRCampfireMorning3Why3
		++ ~Grrargh! Come here you! (You're going to catch this scoundrel and tickle her to death.)~ GOTO MRCampfireMorning3Catch
		++ ~Grrargh! Come here you! (You're going to catch this harlot and pummel her to death for what she's done.)~ GOTO MRCampfireMorning3Catch


		++ ~You're a brat, that's what you are! A nuisance!~ GOTO MRCampfireMorning3Bitch
		++ ~(You are rather annoyed. You grunt as you gather the little bit of dignity you have left and begin to dry yourself. You pick up your belongings and proceed to ignore Imoen completely.)~ GOTO MRCampfireMorning3Why4
	END

	IF ~~ THEN BEGIN MRCampfireMorning3Why3
		SAY ~(She approaches and lays a hand on your shoulder, worry taking over her features) Aaww, c'mon, c'mon, it was just a joke, a bad prank! I didn't think you'd take it that way. Forgive me? Please?~
		++ ~(Your charade has been successful. Now's your chance to get some playful revenge) Hahah, COME HERE! (Grab at her wrist, try to pin her down.)~ GOTO MRCampfireMorning3Catch
		++ ~(Shake your head in disgust) Just leave me alone. (Ignore her and pick up your things.)~ GOTO MRCampfireMorning3Why4
	END

	IF ~~ THEN BEGIN MRCampfireMorning3Why4
		SAY ~Okay, jeez, fine... yer such a sourpuss.~
                = ~You'll get over it, I know you will. You always do!~
                IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7) SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
         END

	IF ~~ THEN BEGIN MRCampfireMorning3Bitch
		SAY ~Aww, poor <CHARNAME>, needs to resort to name-callin' 'cause the Mighty Imoen got the best of <PRO_HIMHER>. Aaaawwwww!~
		++ ~Just wait 'til I catch you! (Leap after her, anticipating to tickle her until she begs.)~ GOTO MRCampfireMorning3Catch
		++ ~Grrargh! Come here you! (Leap after her, anticipating all the kicks and punches she'll suffer at your hand.)~ GOTO MRCampfireMorning3Catch
		++ ~(There is no getting through to her. You simply ignore her and gather your things.)~ GOTO MRCampfireMorning3Why4


	END

	IF ~~ THEN BEGIN MRCampfireMorning3Catch
		SAY ~(You stand up and attempt to grab her, but she jumps out of reach too quickly.)~
		=
		~Hahahah, yer too clumsy for me, slowpoke! (She sticks out her tongue at you and carries on laughing.)~

		++ ~(Leap after her and give chase.)~ GOTO MRCampfireMorning3Chase
		++ ~Fine, let's see what happens next time you're sleeping...~ GOTO MRCampfireMorning3Revenge
	END

	IF ~~ THEN BEGIN MRCampfireMorning3Revenge
		SAY ~Hahah, well then I guess I'll have to cast some contingency spells on myself tonight! You won't have a chance!~
		++ ~Just wait 'til I catch you! (Leap after her, anticipating to tickle her until she begs.)~ GOTO MRCampfireMorning3Catch

		++ ~(Out of options, you'll have to chase her if you want to teach her a lesson.)~ GOTO MRCampfireMorning3Chase
		++ ~You know what? Forget about it. I'm sick of this nonsense. (Simply ignore her and gather your things.)~ GOTO MRCampfireMorning3Why4
	END

	IF ~~ THEN BEGIN MRCampfireMorning3Chase
		SAY ~WHOAH! (Alert and fleet of foot, Imoen is already running) Try if you want, you won't catch me, heeheeee!~
		IF ~~ THEN DO ~
		ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe4")
		~ EXIT
	END
END

// *** Act 5 ***
//LoveMe4

APPEND PLAYER1
	IF ~Global("MRCampfireMusic","GLOBAL",4)~ THEN BEGIN MRCampfireMorning3Chase
	SAY ~(After the short chase, you are lucky enough to catch the hem of her clothes and drag her to the mossy ground. She tries to roll away from you, but she only sends you both tumbling together on the grass.)~  [ IRQUIET ]
	=
	~(As you wrestle with her in the soft turf, she cannot stop laughing. The dizzying whirls finally stop when you manage to roll on top of her.)~
	=
	~(She still laughs as she playfully battles so you won't pin her to the ground, but you sit astride her thighs, not letting her escape. Still struggling under your body, she is unable to restrain her giggling and tosses her head back, the gentle lawn serving as a soft, fresh pillow.)~


	IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",5)~ EXTERN IMOEN2J MRCampfireMorning4
	END
END

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRCampfireMorning4
		SAY ~Hahahahahah... hahahah... (She keeps giggling uncontrollably. It's been years since you last saw Imoen like this.)~ [ MRImRom1 ]
		++ ~(Forget about what she did and just keep looking at Imoen. The sight of her unbridled joy is such a rare treasure.)~ DO ~ActionOverride(Player1,SetDialog("Player1"))~GOTO MRCampfireMorning4Tickle2
		++ ~Now you'll see, I'll have my revenge! (Start the tickling onslaught.)~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRCampfireMorning4Tickle
		++ ~Stop struggling already! (You stare daggers into her eyes) I won't warn you again, Imoen. Don't you EVER do something like that to me. Understand?~ GOTO MRCampfireMorning4Anger
		++ ~(Sigh and stand up) You're harder to pin down than a greased hog. I've had enough, and it's time to keep going, so let's go!~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRCampfireMorning4Quit
	END

	IF ~~ THEN BEGIN MRCampfireMorning4Anger
	   SAY ~(It takes her a moment to realize you weren't being playful at all. Her laughter stops dead.)~
           = ~What... yes, yes, I get it. I get it, <CHARNAME>. Please let go of me. I'm sorry.~
           = ~(She hurriedly composes herself once you release her. Imoen's darted glances are full of fear.)~
           = ~I won't do it again.~
           = ~(She walks away, rattled and red-faced.)~
           IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7) SetGlobal("ImoenRomanceActive","GLOBAL",3)~ EXIT
        END

	IF ~~ THEN BEGIN MRCampfireMorning4Quit
		SAY ~Hahahah... ooh, alright... now that I was having some real fun...~
		=
		~(She sighs) But guess you're right, of course. Let's get my soul back, <CHARNAME>!~
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7) SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfireMorning4Tickle
		SAY ~Aaah, no, no! (She laughs hysterically, twisting and struggling from your well-directed tickles; sometimes she manages to utter some breathless words between laughs.)~
		=
		~Stop it, STOP IT, aahahahahaah! You're killing me!~
		IF ~~ THEN GOTO MRCampfireMorning4Tickle2
	END

	IF ~~ THEN BEGIN MRCampfireMorning4Tickle2
		SAY ~(Imoen's eyes and cheeks are wet with joyful tears. The soft light of dawn reflects off of them, her face tenderly caressed by the faint rays slipping through the canopy above.)~

		=
		~(Imoen's body trembles beneath you with her dying laughter. The giggles stop, leaving a warm smile on her lips.)~
                =
                ~(You lock gazes. The smile slowly fades.)~
                =
		~<CHARNAME>... (A fresh breeze carries her whisper. Cherry locks of hair titillate around her face.)~ [ MRImRom3 ]
		++ ~(This is your chance. Begin to undress her.)~ GOTO MRCampfirePivotFondle
		++ ~Aah, we really should get moving.~ GOTO MRCampfirePivotStand
		++ ~(Stroke her cheek, drying her tears with your thumb. Then slowly lower your head and touch your lips to hers.)~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRCampfirePivotKiss
		++ ~(Remain silent and motionless, uncertain about what to do.)~ GOTO MRCampfirePivotDelay
		++ ~Imoen, I...~ GOTO MRCampfirePivotSpeak
	END

	IF ~~ THEN BEGIN MRCampfirePivotSpeak
		SAY ~Y-yeah?~

		++ ~(Say nothing and begin to undress her.)~ GOTO MRCampfirePivotFondle
		++ ~Aah, we really should get moving.~ GOTO MRCampfirePivotStand
		++ ~(Gently caress her hair off her forehead. Cup her jaw, then slowly lower your head and touch your lips to hers.)~ DO ~ActionOverride(Player1,SetDialog("Player1"))~ GOTO MRCampfirePivotKiss
		++ ~(Remain silent and motionless, uncertain about what to do.)~ GOTO MRCampfirePivotDelay
	END



	IF ~~ THEN BEGIN MRCampfirePivotKiss
		SAY ~(Your lips come together. Though uncertain at first, Imoen responds with tender passion, inviting you in, thirsting, longing. Her breath leadens, its weight pulling at your senses like an inescapable tide.)~
		=~(Your mouths part, only to be rejoined. Her arms wrap around you, one hand on your back, the other at the back of your head.)~
        IF ~~ THEN GOTO MRCampfirePivotKissNext
	END
END

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRCampfirePivotDelay
		SAY ~(You let time pass. The breeze stops, the sun fades, the birds fall silent.)~
		=
		~<CHARNAME>... you are hurting my leg!~
		=~Better if we, um... better if we get going. (She quickly stands up, seemingly cheerful as always) We have some souls to get back, lil' <PRO_BROTHERSISTER>!~
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7)
		SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfirePivotStand
		SAY ~(As you stand up the breeze stops, the sunlight fades, the birds fall silent.)~
		=
		~Better if we, um... better if we get going. (She quickly stands up, seemingly cheerful as always) We have some souls to get back, lil' <PRO_BROTHERSISTER>!~
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7) SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfirePivotFondle
		SAY ~(Imoen watches as you begin to undress her. For a moment she look at you longingly, scant-breathed, heavy-lidded. Then she shakes her head. Her hands find yours and put a stop to your efforts.)~
                = ~N-no, <CHARNAME>. This isn't right.~
                = ~We have a precious friendship. Let's not ruin it like this... alright?~
                = ~Better if we... better if we just get going. (She quickly stands up, seemingly cheerful as always) We have some souls to get back, lil' <PRO_BROTHERSISTER>!~
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7)
		SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfirePivotKissNext
		SAY ~What are we doing... <CHARNAME>, what are we doing...~
		= ~(Though she expresses doubt, her kisses lose none of their luster.)~
		= ~We can't do this...~
		IF ~~ THEN REPLY ~It's okay. It's alright. I love you, Imoen. I love you.~ GOTO MRCampfirePivotYes
		++ ~I can't hold back anymore... I love you... I want you.~ GOTO MRCampfirePivotYes
		IF ~~ THEN REPLY ~(Say nothing. Let your tender ministrations do the talking.)~ GOTO MRCampfirePivotYes
		++ ~(Kiss her mouth once more. Begin to undress her with subtle care.)~ GOTO MRCampfirePivotYes
        ++ ~You're right. You're right... we can't do this. (Move away from her, gently.)~ GOTO MRCampfirePivotNo
	END


	IF ~~ THEN BEGIN MRCampfirePivotYes
	SAY ~Nhh...~
	= ~(Imoen shivers in your arms. Her lips travel down your jawline, to your neck) I... I want it. I want *you*.~
	= ~I want you...~
	IF ~~ THEN DO ~ClearAllActions()
	FaceObject(Player1)
	StartCutSceneMode()
	StartCutScene("LoveMe5")~
	EXIT
 END


	IF ~~ THEN BEGIN MRCampfirePivotNo
		SAY ~(You part reluctantly, roll off to one side, stand up. For a moment she looks at you longingly, breath scant, heavy lidded. Soon she's shaking her head.)~
		=
		~Thank you, <CHARNAME>... I think... I don't think I could have done that. We have a precious friendship. Let's keep it that way, huh?~
		=
		~(She stands up too, fixing her messy hair and clothes, looking a bit embarrassed. Smiling at you, Imoen gives you a peck on your cheek.) Let's get going.~
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",7)
		SetGlobal("ImoenRomanceActive","GLOBAL",4)~ EXIT
	END
END

// *** Act 6: The messy interlude ***
//loveme5.baf

APPEND PLAYER1
	IF ~Global("MRCampfireMusic","GLOBAL",5)~ THEN BEGIN MRCampfireAftermath
		SAY ~(You awaken to find that Imoen is no longer lying by your side. She stands a few paces from where you lie, looking up at nesting birds. She's lost in thought.)~ [ MRImRom6 ]
		=
		~(You quietly approach her.)~
		IF ~~ THEN DO ~SetGlobal("MRCampfireMusic","GLOBAL",6) SetGlobal("MRSleptImoen","GLOBAL",1) SetGlobalTimer("MRPartyReactionTimer","GLOBAL",ONE_DAY)
		ClearAllActions()
		StartCutSceneMode()
		StartCutScene("LoveMe5b")~ EXIT
	END
END

//loveme5a.baf
APPEND IMOEN2J
	IF ~Global("MRCampfireMusic","GLOBAL",6)~ THEN BEGIN MRCampfireAftermath
		SAY ~(Imoen senses your approach, then half-turns toward you. Her eyes are fastened to the ground, her stance distant, defensive.)~ [ IRQUIET ]
                = ~(She opens her mouth as if to speak, then closes it and looks elsewhere. Her breath is shallow. Her lips tremble.)~
                = ~(You notice her hand clenching into a fist. She looks at you briefly, only for half an instant.)~
                = ~I can't do this, <CHARNAME>.~
                = ~(It's barely a whisper. She shakes her head, walks away.)~
                = ~I can't do this.~
                = ~(She steps into the camp and starts gathering her things.)~
				= ~(It seems Imoen needs some time to sort out her emotions...)~
                IF ~~ THEN DO ~
			SetGlobal("MRCampfireMusic","GLOBAL",7)
			RunAwayFromNoInterrupt(Player1,30)~ EXIT
	END
END