//Alignment-Based Interjections

APPEND BIMOEN2
	IF ~Global("MRAlignGoodEvil","LOCALS",0)
	InPartySlot(LastTalkedToBy,0) 
		!StateCheck(Player1,CD_STATE_NOTVALID)
		!StateCheck(Myself,CD_STATE_NOTVALID)
		GlobalGT("Chapter","GLOBAL",%bg2_chapter_3%)
		InParty("Imoen2")
		See(Player1)
		!ActuallyInCombat()~ THEN BEGIN MRGoodEvilAlignTalk
		SAY ~Hey, <CHARNAME>. Don't take this wrong, but...~
		IF ~OR(3) Alignment(Player1,LAWFUL_GOOD) Alignment(Player1,NEUTRAL_GOOD) Alignment(Player1,CHAOTIC_GOOD)~THEN DO ~SetGlobal("MRAlignGoodEvil","LOCALS",1)~ GOTO MRGoodEvilGood
		IF ~OR(3) Alignment(Player1,LAWFUL_NEUTRAL) Alignment(Player1,NEUTRAL) Alignment(Player1,CHAOTIC_NEUTRAL)~THEN DO ~SetGlobal("MRAlignGoodEvil","LOCALS",1)~ GOTO MRGoodEvilNeu
		IF ~OR(3) Alignment(Player1,LAWFUL_EVIL) Alignment(Player1,NEUTRAL_EVIL) Alignment(Player1,CHAOTIC_EVIL)~THEN DO ~SetGlobal("MRAlignGoodEvil","LOCALS",1)~ GOTO MRGoodEvilEvil
	END

	IF ~~ THEN BEGIN MRGoodEvilGood
		SAY ~Don't you ever get sick of being such a goodie-goodie?~
		=
		~I mean, you're always helping people out and stuff - but they never really seem grateful. They just say 'thanks, how about you build me a new house while you're at it?'~
		=
		~They never get enough. Doesn't it frustrate you?~
		++ ~Of course it does. No one has an unlimited supply of patience and energy, not even me.~ GOTO MRGoodEvilGood-Yes
		++ ~No. I love helping people, and knowing I've made a positive change in the world is reward enough.~ GOTO MRGoodEvilGood-No
		IF ~Gender(Player1, MALE)~ THEN REPLY ~Now is not the time for a moral debate, Imoen.~ GOTO MRGoodEvilGoodEndMale
		IF ~Gender(Player1, FEMALE)~ THEN REPLY ~Now is not the time for a moral debate, Imoen.~ GOTO MRGoodEvilGoodEndFemale
		IF ~Gender(PLAYER1,FEMALE)~ THEN REPLY ~Only about once a month.~ GOTO MRGoodEvilGood-Period
	END
	IF ~~ THEN BEGIN MRGoodEvilGood-Yes
		SAY ~Hah. That's good to hear, actually. I mean, that you're not some kinda saint or something.~
		= ~I don't see how you do it. I'd be tellin' people to go solve their own damn problems. Sure, there's good people out there that need help, but after all we've seen?~
		= ~Most of the time they're just lazy or con men or something like that.~
			++ ~Most of them, maybe. But some of them are sincere.~ GOTO MRGoodEvilGood-Maybe
			++ ~Imoen, don't be harsh. You can't condemn everyone because of a few scoundrels.~ GOTO MRGoodEvilGood-Scoundrel
			IF ~Gender(Player1, MALE)~ THEN REPLY ~I don't want to discuss this right now.~ GOTO MRGoodEvilGoodEndMale
			IF ~Gender(Player1, FEMALE)~ THEN REPLY ~I don't want to discuss this right now.~ GOTO MRGoodEvilGoodEndFemale
	END

	IF ~~ THEN BEGIN MRGoodEvilGood-Maybe
		SAY ~Some of them, yeah. Like... a tenth of them.~
		= ~I guess I shouldn't let it make me bitter, though. It's just hard sometimes to have faith in people when they're such jerks all the time.~
		= ~C'mon, let's go. This conversation is depressing me.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilGood-Scoundrel
		SAY ~I guess you're right. It's just hard sometimes to have faith in people when they're such jerks all the time.~
		= ~Maybe some of your patience'll rub off on me. Otherwise I'm gonna end up punching some poor sod one of these days.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilGood-No
		SAY ~(She sighs dramatically) See what I mean? You're some kinda saint or something, I swear!~
		= ~I don't see how you do it. I'd be tellin' people to go solve their own damn problems. Sure, there's good people out there that need help, but after all we've seen?~
		= ~Most of the time they're just lazy or con men or something like that.~
			++ ~You're exaggerating. The vast majority of these people sincerely need our help.~ GOTO MRGoodEvilGood-Scoundrel
			++ ~Imoen, don't be harsh. You can't condemn everyone because of a few scoundrels.~ GOTO MRGoodEvilGood-Scoundrel
			IF ~Gender(Player1, MALE)~ THEN REPLY ~I don't want to discuss this right now.~ GOTO MRGoodEvilGoodEndMale
			IF ~Gender(Player1, FEMALE)~ THEN REPLY ~I don't want to discuss this right now.~ GOTO MRGoodEvilGoodEndFemale
	END

	IF ~~ THEN BEGIN MRGoodEvilGoodEndMale
		SAY ~Gah. I try to have *one* deep conversation with you...~
		= ~Forget it. I'll just stick with 'Please, sir' and 'Thank you, sir.'~
		IF ~~ THEN EXIT
	END
	
	IF ~~ THEN BEGIN MRGoodEvilGoodEndFemale
		SAY ~Gah. I try to have *one* deep conversation with you...~
		= ~Forget it. I'll just stick with "Please, ma'am" and "Thank you, ma'am."~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilGood-Period
		SAY ~Hah! No kidding, huh? I know how you feel.~
		= ~Seriously, though. The other three weeks of the month... does it bother you?~
		++ ~Of course it does. No one has an unlimited supply of patience and energy, not even me.~ GOTO MRGoodEvilGood-Yes
		++ ~No. I love helping people, and knowing I've made a positive change in the world is reward enough.~ GOTO MRGoodEvilGood-No
		IF ~Gender(Player1, MALE)~ THEN REPLY~Now is not the time for a moral debate, Imoen.~GOTO MRGoodEvilGoodEndMale
		IF ~Gender(Player1, FEMALE)~ THEN REPLY~Now is not the time for a moral debate, Imoen.~GOTO MRGoodEvilGoodEndFemale
	END	

	IF ~~ THEN BEGIN MRGoodEvilNeu
		SAY ~I can't figure out if you're wishy-washy, or if you just genuinely can't make up your mind.~
		++ ~What do you mean?~ GOTO MRGoodEvilNeu-Huh
		IF ~Gender(PLAYER1,MALE)~ THEN REPLY ~Wishy-washy? Are you implying that I'm gay?~ GOTO MRGoodEvilNeu-Gay
		++ ~I'm wishy-washy. Or... wait... no. Oh, heck, I can't decide!~ GOTO MRGoodEvilNeu-Joke
		++ ~You're one to talk. You change your mind more often than most people change their underwear!~ GOTO MRGoodEvilNeu-Joke
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-Joke
		SAY ~Oh, har har, see how hard I laugh. C'mon, I'm being serious.~ 
		IF ~~ THEN GOTO MRGoodEvilNeu-Huh
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-Gay
		SAY ~What? No! I said 'wishy', not 'swishy'! And c'mon, I'm being serious here!~ 
		IF ~~ THEN GOTO MRGoodEvilNeu-Huh
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-Huh
		SAY ~Sometimes you can be the most helpful, nice, considerate person in Faerun...~
		= ~And then turn around and let some poor sod die when you coulda saved them. What gives?~
		++ ~Oh, it just depends on my mood. A good breakfast can make the difference between life and death.~ GOTO MRGoodEvilNeu-Joke2
		IF ~IsValidForPartyDialog("Jaheira")~ THEN REPLY ~It's balance, Imoen. For every good there must be an evil, and vice versa. Sometimes one person must play both roles.~ GOTO MRGoodEvilNeu-JahYes
		IF ~!IsValidForPartyDialog("Jaheira")~ THEN REPLY ~It's balance, Imoen. For every good there must be an evil, and vice versa. Sometimes one person must play both roles.~ GOTO MRGoodEvilNeu-JahNo
		++ ~Huh. Didn't realize I did that, actually.~ GOTO MRGoodEvilNeu-Huh2
		++ ~I don't sit around weighing good versus evil, Im. I just do whatever seems appropriate at the time.~ GOTO MRGoodEvilNeu-Neu
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-Joke2
		SAY ~Maybe we should hire a cook then! Not that trail rations aren't delicious... every day... of every week... for the last two months...~
		= ~Ugh, now my stomach is growling. See what you did? (She lightly smacks your shoulder, giving you a stern look) No teasing the tummy!~
		= ~C'mon, let's go find something to eat. Something that isn't trail rations, bugs, weeds, or acorns.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-Neu
		SAY ~Heh. Well, that's good to hear, actually. I mean, that you're still just a regular person like the rest of us.~
		= ~I was kinda afraid that all this prophecy-this and Bhaal-that stuff had started to go to your head.~
		= ~Glad to hear you're still just normal ol' <CHARNAME>. Very glad indeed!~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-Huh2
		SAY ~Well, you do. So there's no particular reason or rationale behind it?~
		++ ~Oh, it just depends on my mood. A good breakfast can make the difference between life and death.~ GOTO MRGoodEvilNeu-Joke2
		IF ~IsValidForPartyDialog("Jaheira")~ THEN REPLY ~It's balance, Imoen. For every good there must be an evil, and vice versa. Sometimes one person must play both roles.~ GOTO MRGoodEvilNeu-JahYes
		IF ~!IsValidForPartyDialog("Jaheira")~ THEN REPLY ~It's balance, Imoen. For every good there must be an evil, and vice versa. Sometimes one person must play both roles.~ GOTO MRGoodEvilNeu-JahNo
		++ ~I don't sit around weighing good versus evil. I just do whatever seems appropriate at the time.~ GOTO MRGoodEvilNeu-Neu
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-JahNo
		SAY ~Agh, you're starting to sound like Jaheira. Minus the incessant nagging, that is.~
			++ ~Jaheira had the right idea. In fact, I really admire both the Harpers and the Druids.~ GOTO MRGoodEvilNeu-Admire
			++ ~Hah, well... I'll try to tone it down a little, then. But balance is still a good idea.~ GOTO MRGoodEvilNeu-Idea
			++ ~Gods forbid! I shall immediately begin rescuing cats down trees and kissing babies! Goodness must prevail!~ + MRGoodEvilNeu-Dork
			++ ~Gods forbid! I shall immediately begin kicking puppies and robbing old ladies! Evil is supreme!~ + MRGoodEvilNeu-Dork
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-JahYes
		SAY ~Agh, you're starting to sound like Jaheira. Minus the incessant nagging, that is.~
		= ~Crap, she didn't hear me, did she?~
			IF ~IsValidForPartyDialog("Jaheira")~ THEN REPLY ~Doesn't look like it. Want me to call her over here?~ GOTO MRGoodEvilNeu-Jah2
			++ ~Jaheira had the right idea. In fact, I really admire both the Harpers and the Druids.~ GOTO MRGoodEvilNeu-Admire
			++ ~Hah, well... I'll try to tone it down a little, then. But balance is still a good idea.~ GOTO MRGoodEvilNeu-Idea
			++ ~Gods forbid! I shall immediately begin rescuing cats down trees and kissing babies! Goodness must prevail!~+ MRGoodEvilNeu-Dork
			++ ~Gods forbid! I shall immediately begin kicking puppies and robbing old ladies! Evil is supreme!~ + MRGoodEvilNeu-Dork
	END
	
	IF ~~ THEN BEGIN MRGoodEvilNeu-Jah2
		SAY ~What? No! Are you *trying* to get me killed?~
		= ~And yes, a two hour lecture about balance is just as bad as death. Let's just forget I asked and keep moving.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-Admire
		SAY ~Well, as long as you don't become as obnoxiously self-important as they do.~
		= ~I can understand 'balance' and all, I guess. At least I know why you're so freakin' random sometimes.~
		= ~Anyways... I'll think about it. Sorry for botherin' ya.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-Idea
		SAY ~Heh. I'd appreciate that, actually. I mean, I can understand 'balance' and all, but sometimes people like you-know-who just go overboard and get all bossy about it.~
		= ~And I'd hate to have to remind you that you don't, in fact, know everything. (She winks at you.)~
		= ~Anyways... thanks for sharin', and sorry for botherin' ya. Let's keep going.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilNeu-Dork
		SAY ~Haha, yeah, right! You're such a dork sometimes. But it is nice to see you haven't lost your sense of humor with everything that's been going on.~
		= ~Just keep bein' you - I like that just fine as it is.~
		IF ~~ THEN EXIT
	END


	/* Evil - Done */

	IF ~~ THEN BEGIN MRGoodEvilEvil
		SAY ~Why're you always such a jerk to everyone?~
		= ~Sometimes you're seriously a bastard, y'know? I mean, sure, you're nice enough to me, but I'm the exception.~
		IF ~CheckStatGT(Player1,12,WIS)~ THEN REPLY ~Some people are born as wolves, some are born as sheep. Do you call a wolf evil because it does to sheep what nature intended?~ GOTO MRGoodEvilSheep
		IF ~CheckStatGT(Player1,14,INT)~ THEN REPLY ~ Eh. I wouldn't be so mean if people weren't so stupid.~ GOTO MRGoodEvilStupidSmart
		IF ~CheckStatLT(Player1,10,INT)~ THEN REPLY ~ Eh. I wouldn't be so mean if people weren't so stupid.~ GOTO MRGoodEvilStupidDumb
		IF ~CheckStatGT(Player1,9,INT) CheckStatLT(Player1,15,INT)~ THEN REPLY ~ Eh. I wouldn't be so mean if people weren't so stupid.~ GOTO MRGoodEvilStupidNeu
		++ ~They have it coming. Those that interfere with my goals deserve what they get.~ GOTO MRGoodEvilStupidNeu
		++ ~I'm not bad, I'm just misunderstood.~ GOTO MRGoodEvilBad
		++ ~This isn't the time for a moral debate, Imoen.~ GOTO MRGoodEvilEndNormal
	END

	IF ~~ THEN BEGIN MRGoodEvilStupidSmart
		SAY ~People aren't stupid, <CHARNAME> - you're just an egghead.~ 
		IF ~~ THEN GOTO MRGoodEvilStupidNeu
	END

	IF ~~ THEN BEGIN MRGoodEvilStupidDumb
		SAY ~Psht. Says the <PRO_RACE> with the brains of a ochre jelly.~ 
		IF ~~ THEN GOTO MRGoodEvilStupidNeu
	END

	IF ~~ THEN BEGIN MRGoodEvilStupidNeu
		SAY ~Just 'cause people are annoying sometimes or get in your way, doesn't give you the right to abuse them, y'know.~
		IF ~CheckStatGT(Player1,16,CHR)~ THEN REPLY ~We are Bhaalspawn. Demi-gods, Imoen... half-divine! We are nothing like the common rabble around us.~ GOTO MRGoodEvilCor1
		IF ~CheckStatLT(Player1,16,CHR)~ THEN REPLY ~I'm half-god. You really think I'm the same as these weaklings?~ GOTO MRGoodEvilLosers
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEndCor
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEnd
		++ ~I'm not bad. I'm just misunderstood.~ GOTO MRGoodEvilBad
	END

	IF ~~ THEN BEGIN MRGoodEvilBad
		SAY ~(She raises an eyebrow at you) 'Misunderstood'? That's a joke, right? How is threatening people and killing them 'misunderstood'?~
		++ ~It just does! See, you don't understand me either! No one understands me!~ GOTO MRGoodEvilBad2
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEndCor
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEnd
		IF ~CheckStatGT(Player1,14,INT)~ THEN REPLY ~ Eh. I wouldn't be so mean if people weren't so stupid.~ GOTO MRGoodEvilStupidSmart
		IF ~CheckStatLT(Player1,10,INT)~ THEN REPLY ~ Eh. I wouldn't be so mean if people weren't so stupid.~ GOTO MRGoodEvilStupidDumb
		IF ~CheckStatGT(Player1,9,INT) CheckStatLT(Player1,15,INT)~ THEN REPLY ~ Eh. I wouldn't be so mean if people weren't so stupid.~ GOTO MRGoodEvilStupidNeu
		++ ~They have it coming. Those that interfere with my goals deserve what they get.~ GOTO MRGoodEvilStupidNeu
	END

	IF ~~ THEN BEGIN MRGoodEvilBad2
		SAY ~Right. Okay. I'm sorry I asked.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilSheep
		SAY ~Well, no... but that's different! You're a person, just like the people you hurt.~
		IF ~CheckStatGT(Player1,16,CHR)~ THEN REPLY ~We are Bhaalspawn. Demi-gods, Imoen... half-divine! We are nothing like the common rabble around us.~ GOTO MRGoodEvilCor1
		IF ~CheckStatLT(Player1,16,CHR)~ THEN REPLY ~I'm half-god. You really think I'm the same as these losers?~ GOTO MRGoodEvilLosers
		IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~(Grin at her suggestively) What, I'm not wolfish enough for you?~ GOTO MRGoodEvilCorWolf
		IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~I'm a predator; these people are prey. That we look the same on the outside is only coincidence.~ GOTO MRGoodEvilCor2
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEndCor
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEnd
	END

	IF ~~ THEN BEGIN MRGoodEvilCorWolf
		SAY ~Hah! Don't even go there, <CHARNAME> - you aren't charming your way outta this conversation!~
		IF ~CheckStatGT(Player1,16,CHR)~ THEN REPLY ~We are Bhaalspawn. Demi-gods, Imoen... half-divine! We are nothing like the common rabble around us.~ GOTO MRGoodEvilCor1
		IF ~CheckStatLT(Player1,16,CHR)~ THEN REPLY ~I'm half-god. You really think I'm the same as these losers?~ GOTO MRGoodEvilLosers
		IF ~!Global("ImoenRomanceActive","GLOBAL",2)~ THEN REPLY ~I'm a predator; these people are prey. That we look the same on the outside is only coincidence.~ GOTO MRGoodEvilCor2
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEndCor
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEnd
	END

	IF ~~ THEN BEGIN MRGoodEvilLosers
		SAY ~Since when does being a 'mere mortal' make someone a loser? What about Gorion, or Puffguts, or Jaheira?~
		++ ~Losers. All of them.~ GOTO MRGoodEvilLosersEnd
		++ ~Well, I suppose there are some exceptions.~ GOTO MRGoodEvilLosers2
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEndCor
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEnd
	END

	IF ~~ THEN BEGIN MRGoodEvilEndCor
		SAY ~Yes I do! I just... well... I dunno. You make sense, kinda.~
		=
		~(She frowns) Maybe I should get my head checked.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilLosers2
		SAY ~Hmph. Yeah, there better be some exceptions!~
		= ~Look, let's just move on before you make an even bigger ass of yourself.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilLosersEnd
		SAY ~Y'know, it's funny. I can only think of one loser so far - a stuck-up <PRO_RACE> with the brain of a toad.~
		= ~Let's move on before you make an even bigger ass of yourself.~
		IF ~~ THEN EXIT
	END


	IF ~~ THEN BEGIN MRGoodEvilCor1
		SAY ~That's... well, okay, that's true, but still. Can't you just... I dunno... be strong *and* be nice?~
		++ ~It doesn't work that way, Im. Everyone's biting and clawing to work their way up in this world. You have to be able to defend yourself.~ GOTO MRGoodEvilCor2
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~No! Haven't you been listening to *anything* I've said?~ GOTO MRGoodEvilEndListenCor
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~No! Haven't you been listening to *anything* I've said?~ GOTO MRGoodEvilEndListen
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand~ GOTO MRGoodEvilEndCor
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand~ GOTO MRGoodEvilEnd
	END

	IF ~~ THEN BEGIN MRGoodEvilEndListenCor
		SAY ~Yes, I have! I just, well... I dunno. You make sense, kinda, but...~
		= ~(She frowns) Maybe I should get my head checked.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilEndListen
		SAY ~Yes, I have! But it doesn't make any sense!~
		= ~You should listen to yourself sometime, maybe then you'd realize how daft you are.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilEnd
		SAY ~Y'know what? You're right. I don't.~
		IF ~~ THEN EXIT
	END


	IF ~~ THEN BEGIN MRGoodEvilCor2
		SAY ~I don't buy that. I mean, sure, life's rough and all, but that doesn't mean you gotta go around being a sourpuss all the time.~
		IF ~CheckStatGT(Player1,12,WIS)~ THEN REPLY ~Some people are born as wolves, some are born as sheep. Do you call a wolf evil because it does to sheep what nature intended?~ GOTO MRGoodEvilSheep
		IF ~CheckStatGT(Player1,14,INT)~ THEN REPLY ~ Eh. I wouldn't be so mean if people weren't so stupid.~ GOTO MRGoodEvilStupidSmart
		IF ~CheckStatLT(Player1,10,INT)~ THEN REPLY ~ Eh. I wouldn't be so mean if people weren't so stupid.~ GOTO MRGoodEvilStupidDumb
		IF ~CheckStatGT(Player1,9,INT) CheckStatLT(Player1,15,INT)~ THEN REPLY ~ Eh. I wouldn't be so mean if people weren't so stupid.~ GOTO MRGoodEvilStupidNeu
		++ ~They have it coming. Anyone who gets in my way deserves what they get.~ GOTO MRGoodEvilStupidNeu
		++ ~I'm not bad, I'm just misunderstood.~ GOTO MRGoodEvilBad
		IF ~CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEndCor
		IF ~!CheckStatGT(Player1,13,CHR)~ THEN REPLY ~(sigh) This is pointless. You don't *want* to understand.~ GOTO MRGoodEvilEnd
	END


	IF~~ THEN BEGIN MRGoodEvilEndNormal
		SAY ~Gah. I try to have *one* deep conversation with you...~
		=
		~Forget it. I'll stick with one-styllable words from now on. Y'know, like "GO!" and "KILL!" and "SIT!"~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN BEGIN MRGoodEvilApo
		SAY ~ Ooooh no, you're not getting out of this that easily!~
		=
		~Just you wait. Just you wait!~
		=
		~(She jabs you in the chest with her finger before striding away with an indignant 'hmph'. That sounded... omnious.)~
		IF ~~ THEN EXIT
	END
END