CHAIN
IF ~Global("MRLilarcor","GLOBAL",1)~ THEN IMOEN2J MRLilarcorTalk //// Changes: basic punctuation
	~<CHARNAME>, I never did ask about Lilarcor. How-~
	== MRLILCOR ~If you have a question, I can hear and talk, you know.~
	== IMOEN2J ~How can you hear and talk?~
	== MRLILCOR ~Swords can talk! Most just don't have much to say! And we're always listening.~
	== MRLILCOR ~And when we hear about killing something, we get all excited! I feel so riled up now! Hahaha!~
	== IMOEN2J ~Okay, Lilarcor... why are you called 'Lilarcor'?~
 == MRLILCOR ~Because that's my *name*, duh.~
	== IMOEN2J ~But what about the name of the sword your spirit was enchanted into?~
	== MRLILCOR ~It was just some random sword. Not every sword has a cool name like me, y'know.~
	== IMOEN2J ~Do you have a last name?~
	== MRLILCOR ~I told you! It's Lilarcor.~
	== IMOEN2J ~Then what's your first name?~
	== MRLILCOR ~None of your business. What's *your* last name?~
	== IMOEN2J ~Er...~
	DO ~SetGlobal("MRLilarcor","GLOBAL",2) RealSetGlobalTimer("MRLilarcorTimer","GLOBAL",500)~
END MRLILCOR MRLastFirstTalk

APPEND MRLILCOR

	IF ~~ THEN BEGIN MRLastFirstTalk
		SAY ~See? C'mon, I'm tired of this chatting, let's just go kill something!~
		IF ~~ THEN DO ~DestroySelf()~ EXTERN IMOEN2J MRLastFirstTalk2
	END
END

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRLastFirstTalk2
		SAY ~Uh, sure, I guess.~
		IF ~~ THEN EXIT
	END
END

/* Second talk -- check to make sure that Lilarcor is still equipped first */

APPEND MRLILCOR
	IF ~Global("MRLilarcor","GLOBAL",3)~ THEN BEGIN MRLilarcorTalk2
		SAY ~It's Lawrence.~
			IF ~~ THEN REPLY ~What's Lawrence?~ DO ~SetGlobal("MRLilarcor","GLOBAL",4)~ EXTERN MRLILCOR MRLilarcorTalk22
	END
END


CHAIN MRLILCOR MRLilarcorTalk22
	~It's Lawrence... My first name.~
	== IMOEN2J ~Really? Wow, no wonder you didn't mention it before.~
	== MRLILCOR ~Oh, COME ON! What's *your* last name, then?~
	== IMOEN2J ~Hmm... I guess it would have to be after the man whom raised me. Puffguts?~
	== MRLILCOR ~And you laughed at *my* name? Hahaha!~
	== IMOEN2J ~Oh yeah? Well, Lawrence, I happen to be a very proud Puffgut. I'm going to use my *hands* to cover my *ears*. When you don't want to listen to someone, you should do that too. Oh, wait-~
END MRLILCOR MRLast2Talk


APPEND MRLILCOR
 IF ~~ THEN BEGIN MRLast2Talk
		SAY ~Shut up! I'm in the mood to kill. C'mon, let's tear the head off a drow or something!~
		IF ~~ THEN DO ~DestroySelf()~ EXIT
	END
END