// Contents:
// Imoen talks about the first time you sleep in the pocket plane

CHAIN IF WEIGHT #0 ~Global("IRTRestedInPocketPlane","GLOBAL",1)~ THEN IMOEN25J Poc
	~(Imoen takes a deep breath while stretching.) Y'know- (A huge yawn interrupts her.)~ [IRQUIET] DO ~SetGlobal("IRTRestedInPocketPlane","GLOBAL",2)~
	= ~Whew. You know, I thought I wouldn't sleep well, but... you coulda paraded a troupe of drunk gnomes with trombones through here and I wouldn't have noticed. I feel so refreshed.~
	== AERIE25J IF ~InParty("Aerie")~ THEN ~How can you say that? I was barely able to enter trance. It feels like those statues are constantly watching me.~
	== JAHEI25J IF ~InParty("Jaheira")~ THEN ~It must be part of your heritage, Imoen. This cocoon plane... it is not a pleasant realm. I have a feeling we will have to get used to it, however.~
	== IMOEN25J ~It's just... cozy, here. The green sky is hypnotic, and this low humming sound that runs through the place renders you to sleep easily. The statues feel like guardians, watching over us.~
	= ~I know the place is hideous, but I still felt at home. How about you?~
END
	++ ~It felt like my room in Candlekeep. I have missed that feeling of complete safety.~ + Poc1
	+ ~Global("ImoenRomanceActive","GLOBAL",2)~ + ~I always feel at home with you in my arms, Imoen.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1)~ + Poc2
	++ ~I don't know what you're talking about. It's terrible here. This is out of necessity, nothing more.~ + Poc3
	++ ~(Shrug.) It's alright. A place to rest like any other.~ + Poc4
	+ ~!Global("ImoenRomanceActive","GLOBAL",3)~ + ~You talk far too much.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-2)~ + Poc5
	+ ~Global("ImoenRomanceActive","GLOBAL",3)~ + ~I have told you not to talk to me unless it's strictly necessary. Shut up and get ready.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-2)~ + Poc6
	
APPEND IMOEN25J
	IF ~~ THEN Poc1
		SAY ~Yeah! Oh gosh, yes. Exactly like that, it's uncanny. I might as well have been listening to the tavern's sounds above.~
		= ~Creepy, huh? Dunno if I'm entirely comfortable with it. It's obviously our divine souls getting drawn to their natural home. This dreadful place shouldn't feel so cozy.~
		= ~But it does, and dammit, I'm gonna enjoy it. About time the Taint did something nice for me.~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN Poc2
		SAY ~Ooh, smooth. You silver-tongued devil... (Imoen comes close and puts her arms around your waist.) Wish I'd thought of that one.~
		= ~I sleep better next to you, but there was something else here. A sense of belonging I haven't felt since... well, since Candlekeep.~
		++ ~I know what you mean. It felt like being back in my room, safe in the knowledge that nothing would come attacking.~ + Poc1
		++ ~I can't say the same for myself. It's terrible here. Our stay in this place is out of necessity, nothing more.~ + Poc3
		++ ~(Shrug.) It's a place to rest like any other. I didn't feel anything special.~ + Poc4
	END
		

	IF ~~ THEN Poc3	
		SAY ~Oh, really? I thought... huh. That's strange, then. Wonder why I feel so at home. Now it's gonna creep me out even more.~
		= ~Can't argue with the fact that it's a dreadful place. I just need to work on hating it more. That's too bad, I was thinking it was about time the Taint did something nice for me...~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN Poc4
		SAY ~Oh, really? I thought... huh. That's strange, then. Wonder why I feel so at home. Now it's gonna creep me out even more.~
		= ~It sure is a dreadful place. Maybe I just need to work on hating it more. That's too bad, I was thinking it was about time the Taint did something nice for me...~
		IF ~~ THEN EXIT
	END
		
	IF ~~ THEN Poc5
		SAY ~Jeez, sor-ry <PRO_SIRMAAM>! Just making a bit of conversation while getting ready. I'll keep to myself, then...~
		IF ~~ THEN EXIT
	END

	IF ~~ THEN Poc6
		SAY ~(Imoen's mouth puckers into a small oval. A long pause ensues.)~
		= ~Yes, boss.~
		IF ~~ THEN EXIT
	END
END

