// If Imoen's soul hasn't been retrieved and you are not at the Elven Glade already

CHAIN IMOEN2J MRLetsCampN
	~I keep thinkin' about the elven glade and how nice it felt to be there. I saw a beautiful spot where we could maybe camp for the night and have a great relaxing time. Dunno about you, but I sure could use it.~
	== JAHEIRAJ IF ~IsValidForPartyDialog("Jaheira")~ THEN ~I fully agree, <CHARNAME>. A peaceful night surrounded by nature would be an excellent way to let go of the weariness taking hold of my bones.~
	== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~Yes! We could toast marshmellows and- and sing around a campfire! It would be delightful.~
	== KELDORJ IF ~IsValidForPartyDialog("Keldorn")~ THEN ~While this sounds like a fine idea, I don't know if we should neglect our mission so. It is your decision, of course.~
	== KORGANJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Pfeh! If it ain't killin', pissin' or eatin', it ain't worth doin'!~
	== IMOEN2J IF ~IsValidForPartyDialog("Korgan")~ THEN ~Oh, hush your mouth, you. You'll pass out drunk before we even have time to sit down.~
END 
  IF ~!Global("BodhiDead","GLOBAL",1)~ EXTERN IMOEN2J MRLetsCampQ
   IF ~Global("BodhiDead","GLOBAL",1)~EXTERN IMOEN2J MRLetsCampQ2
  
APPEND IMOEN2J
	IF  ~Global("MRCampPrompt","GLOBAL",1) !Global("BodhiDead","GLOBAL",1)~ THEN MRLetsCamp
		SAY ~Hey, <CHARNAME>. I know we're supposed to go storm a den full of vampires and get that Lanthorn thingie and hopefully grind Bodhi to dust, but... ya think maybe we could take a break before that?~ [ MRImRom3 ]
		IF ~~ THEN DO ~SetGlobal("MRCampPrompt","GLOBAL",2)~ GOTO MRLetsCampN
	END
END


APPEND IMOEN2J
	IF ~~ THEN MRLetsCampQ
		SAY ~Whaddya say, <CHARNAME>?~
		++ ~Yes, I think you have the right idea. We'll head over there soon.~ + MRLetsCampYes
		++ ~I don't think so. I'd prefer to get to Bodhi, then Irenicus, and *then* we can do whatever you want to do.~ + MRLetsCampMaybe 
		++ ~Getting your soul back is my top priority. We can have a good relaxing time after that.~ + MRLetsCampAfter
		++ ~I'd like to, but it would be quite the journey right now. I'm sure our path will take us there again soon.~ + MRLetsCampAfter2
		++ ~That sounds like a massive waste of time. It's not going to happen.~ + MRLetsCampNo
	END	
		
	IF ~~ THEN MRLetsCampYes
		SAY ~Great! I know just the spot, you'll see. Can't wait to get there.~
		IF ~~ THEN DO ~SetGlobal("MRCampfire","GLOBAL",1)~  EXIT
	END

	IF ~~ THEN MRLetsCampMaybe
		SAY ~Aw. Yeah, makes sense, alright...~
		= ~But... ya think maybe do it before going to face Irenicus? I... I don't know, what if we don't make it? I'd like to at least have one last night enjoying myself.~
		= ~Dunno, food for thought, it's up to you. One way or another, if we get there again, I swear you won't regret it if you choose to spend the night.~
		IF ~~ THEN DO ~SetGlobal("MRCampfire","GLOBAL",1)~   EXIT
	END

	IF ~~ THEN MRLetsCampAfter
		SAY ~(She gives you a thankful smile.) That's sweet of you. Don't run yourself ragged, though. It's okay to stop and have a good time now and then.~
		= ~Alright, well, let's do what you feel is best, but I tell ya - if we get there again, I swear you won't regret it if you choose to spend the night.~
		IF ~~ THEN DO ~SetGlobal("MRCampfire","GLOBAL",1)~  EXIT
	END

	IF ~~ THEN MRLetsCampAfter2
		SAY ~True, makes sense. We have to return there to give them back the Lanthorn, right? We could do it then, if you feel like it.~
		= ~I'd love to, at any rate. I swear you won't regret it if you choose to spend the night once we get there.~
		IF ~~ THEN DO ~SetGlobal("MRCampfire","GLOBAL",1)~   EXIT
	END

	IF ~~ THEN MRLetsCampNo
		SAY ~Jeez, I'm so sorry. I just feel we're running ourselves ragged, we could use some down time in a beautiful place.~
		= ~But hey, you're the boss. The idea is still there if you change yer mind, though.~
		IF ~~ THEN DO ~SetGlobal("MRCampfire","GLOBAL",1)~  EXIT
	END
END


APPEND IMOEN2J
	IF  ~Global("MRCampPrompt","GLOBAL",1) Global("BodhiDead","GLOBAL",1)~   THEN MRLetsCamp2
		SAY ~Hey, <CHARNAME>. I know we're supposed to go face Irenicus and get all this mess over with one way or another, but... ya think maybe we could take a break before that?~ [ MRImRom3 ]
			IF ~~ THEN DO ~SetGlobal("MRCampPrompt","GLOBAL",2)~ GOTO MRLetsCampN
	END
END


APPEND IMOEN2J
	IF ~~ THEN MRLetsCampQ2
		SAY ~Whaddya say, <CHARNAME>?~
		++ ~Yes, I think you have the right idea. We'll head over there soon.~ + MRLetsCampYes
		++ ~I don't think so. I'd prefer to get to Irenicus, and *then* we can do whatever you want to do.~ + MRLetsCampMaybe
		++ ~I see how it is. You get your soul back and suddenly there's no need to hurry anymore.~ + MRLetsCampAss2
		++ ~I'd like to, but it would be quite the journey right now. I'm sure our path will take us there again soon.~ + MRLetsCamp2After2
		++ ~That sounds like a massive waste of time. It's not going to happen.~ + MRLetsCampNo
	END	
		

	IF ~~ THEN MRLetsCampAss2
		SAY ~No, no no no, I didn't mean it like that! I'm so grateful to have it back, and I wanted you to enjoy a bit of a break. Maybe I'd even... do something special for you.~
		= ~But I'm with ya no matter what you wanna do, always. Just think about it, okay? I swear you won't regret it if you choose to spend the night there.~
		IF ~~ THEN DO ~SetGlobal("MRCampfire","GLOBAL",1)~  EXIT
	END

	IF ~~ THEN MRLetsCamp2After2
		SAY ~True, makes sense. I don't want it to sound like suddenly I'm not in a hurry anymore since I got my soul back. I just wanted you to enjoy a bit of a break. Maybe I'd even... do something special for you.~
		= ~Anyway, hope we go there soon. I swear you won't regret it if you choose to spend the night there.~
		IF ~~ THEN DO ~SetGlobal("MRCampfire","GLOBAL",1)~  EXIT
	END
END