/* Contents:
// Meeting
// Imoen initiating dialogue with Cespenar
*/ 
ADD_TRANS_TRIGGER BOTSMITH 146 ~OR(4) !InParty("Imoen2") !See("Imoen2") StateCheck("Imoen2",CD_STATE_NOTVALID) !Global("IRTImIntroCesp","GLOBAL",0)~ 147 DO 0 1 2

EXTEND_BOTTOM BOTSMITH 146
 IF ~InParty("Imoen2") See("Imoen2") !StateCheck("Imoen2",CD_STATE_NOTVALID) Global("IRTImIntroCesp","GLOBAL",0)~ THEN EXTERN IMOEN25J ImCesp1
END

EXTEND_BOTTOM BOTSMITH 147
 IF ~InParty("Imoen2") See("Imoen2") !StateCheck("Imoen2",CD_STATE_NOTVALID) Global("IRTImIntroCesp","GLOBAL",0)~ THEN EXTERN IMOEN25J ImCesp1
END


ADD_TRANS_TRIGGER BOTSMITH 152 ~ OR(2)!Name("Imoen2",LastTalkedToBy) Global("TalkedToBotsmith","GLOBAL",0)~ DO 0


CHAIN IMOEN25J ImCesp1
	~Right. Bhaal had *you* for a butler.~ DO ~SetGlobal("IRTImIntroCesp","GLOBAL",1)~
	== BOTSMITH ~Oh yes! Great Bhaal liked to kick Cespenar! Kicked no one but I, Bhaal did, oh yes!~
	== IMOEN25J ~I cannot imagine why.~
	== BOTSMITH ~*Sniff!* Oooo! *Sniff sniff!* You be great one too! Well, kind of. Not as great. Phoo-eey.~
	== IMOEN25J ~Uh, you can *smell* my being a Bhaalspawn? Actually, never mind. Please, do tell us all about your shiny ones.~
	== BOTSMITH ~Yes oh yes! (The imp turns to talk to you again.) Call on me you may. Use my recipes for you will I, make the shiny ones. Have not done this for some time, no... no new master have I.~ [BOTSM17]
END BOTSMITH 2


// Imoen initiating dialogue with Cespenar
// Verify item name is correct

CHAIN IF WEIGHT #-1 ~IsGabber("Imoen2") GlobalGT("TalkedToBotsmith","GLOBAL",0) PartyHasItem("MRIMRIN1") Global("IRTCespenarBracelet","GLOBAL",0)~ THEN BOTSMITH ImCespBra1
	~Oooo! What is that? Shiiiiiny...~ [IRQUIET]
	== IMOEN25J ~Hey, hey get yer mitts off my bracelet, you nutty imp!~ DO ~SetGlobal("IRTCespenarBracelet","GLOBAL",1)~
	== BOTSMITH ~YEEOUCH!~
	== IMOEN25J ~What the-?~
	== BOTSMITH ~Evil thing! It zapped Cespenar!~
	== IMOEN25J ~Huh. That's... interesting.~
	== BOTSMITH ~It doesn't likes Cespenar, it is eeeeeevil!~
	== IMOEN25J ~Serves you right. Maybe you shouldn't go touching every shiny thing you see!~
	== IMOEN25J ~Whaddya know... Bob zaps demons. Wonder what else it can do.~
	== BOTSMITH ~Oh well. Cespenar can't improves shiny ones that Cespenar can't touch. A shame, it is!~
	== IMOEN25J ~Don't think I'd trust ya with it anyway, sorry to say...~
EXIT

CHAIN IF WEIGHT #-1 ~IsGabber("Imoen2") RandomNum(5,1) GlobalGT("TalkedToBotsmith","GLOBAL",0)~ THEN BOTSMITH ImCesp2
	~Not-so-great Great One is back! Cespenar is good butler, oh yes!~ [IRQUIET]
	== IMOEN25J ~Such a mouthful. You could just call me Imoen.~
	== BOTSMITH ~Oooo, no no no no.  You'se not-so-great Great One, I'se call you not-so-great Great one!~
	== IMOEN25J ~Alright, fine, have it your way, ya kooky imp.~
	== BOTSMITH ~I am Cespenar! Is not-so-great Great One dense or something? Hard of hearing, maybe? Cespenar! C-E-S-P... N... R!~
	== IMOEN25J ~Yes, yes. Sorry. My mistake.~ DO ~ActionOverride("BOTSMITH",RunAwayFrom("Imoen2",45))~
EXIT

CHAIN IF WEIGHT #-1 ~IsGabber("Imoen2") RandomNum(5,2) GlobalGT("TalkedToBotsmith","GLOBAL",0)~ THEN BOTSMITH ImCesp2
	~Ooo, not-so-great Great One! Cespenar good butler, yes?~ [IRQUIET]
	== IMOEN25J ~That depends. Can you go fetch me a sandwich?~
	== BOTSMITH ~"Sand Witch"? There be no sand witches in the Abyss, no no no. They'se only in deserts. Maybe I bring a big Balor for you, yes?~
	== IMOEN25J ~Um, no, that won't be necessary, don't bother. You're a nice butler, Cespenar.~ DO ~ActionOverride("BOTSMITH",RunAwayFrom("Imoen2",45))~
EXIT

APPEND BOTSMITH
IF WEIGHT #-1 ~IsGabber("Imoen2") RandomNum(5,3) GlobalGT("TalkedToBotsmith","GLOBAL",0)~ THEN BEGIN ImCesp4
	SAY ~You gots Shiny Ones for Cespenar, not-so-great Great One?~ [IRQUIET]
	IF ~RandomNum(3,1)~ THEN EXTERN IMOEN25J ImCesp4cha1
	IF ~RandomNum(3,2)~ THEN EXTERN IMOEN25J ImCesp4cha2
	IF ~RandomNum(3,3) Global("IRTwa2robe","GLOBAL",0) PartyHasItem("WA2ROBE")~ THEN DO ~SetGlobal("IRTwa2robe","GLOBAL",1)~ EXTERN IMOEN25J ImCesp4cha5
	IF ~RandomNum(3,3) OR(2) !PartyHasItem("WA2ROBE") Global("IRTwa2robe","GLOBAL",1)~ THEN EXTERN IMOEN25J ImCesp4cha6
END
END

CHAIN IMOEN25J ImCesp4cha1
	~Sure, uh... what can you do with this, umm... this jade ring?~
	== BOTSMITH ~Oooo! I'se can throws it into the dark pit over there, oh yes!~
END IMOEN25J ImCesp4chaex1

APPEND IMOEN25J
IF ~~ THEN BEGIN ImCesp4chaex1
	SAY ~Great, then do it! Thanks, Cespenar!~
	IF ~~ THEN DO ~ActionOverride("BOTSMITH",RunAwayFrom("Imoen2",45))~ EXIT
END
END

CHAIN IMOEN25J ImCesp4cha2
	~Maybe, let's see... what about this flashy, uh, jasper gem?~
	== BOTSMITH ~Oooo! I'se can throws it into the dark pit over there, oh yes!~
END IMOEN25J ImCesp4chaex1

CHAIN IMOEN25J ImCesp4cha5
	~Hmm... lemme see... oh, I know! This dirty Robe of Vecna no one uses.~
	== BOTSMITH ~Oooo! I'se can throws it into the dark pit over there, oh yes!~
	== IMOEN25J ~Great, do it then! Thanks, Cespenar!~
	= ~Uh, no, no, wait. I better keep that, <CHARNAME> might be mad if I let you throw it.~ DO ~ActionOverride("BOTSMITH",RunAwayFrom("Imoen2",45))~
EXIT

CHAIN IMOEN25J ImCesp4cha6
	~Hmm... lemme see... oh, I know! This neat aquamarine gem.~
	== BOTSMITH ~Oooo! I'se can throws it into the dark pit over there, oh yes!~
END IMOEN25J ImCesp4chaex1

CHAIN IF WEIGHT #-1 ~IsGabber("Imoen2") RandomNum(5,4) GlobalGT("TalkedToBotsmith","GLOBAL",0)~ THEN BOTSMITH ImCesp5
	~Cespenar is busy, not-so-great Great One! Lots of thingies to clean, lots to collect!~ [IRQUIET]
	== IMOEN25J ~Don't you think this place is clean enough? For how long have you been cleaning, anyway?~
	== BOTSMITH ~Not long enough, no no no! I'se back to cleaning, bye bye now.~
	== IMOEN25J ~Bye, I suppose!~ DO ~ActionOverride("BOTSMITH",RunAwayFrom("Imoen2",45))~
EXIT

CHAIN IF WEIGHT #-1 ~IsGabber("Imoen2") RandomNum(5,5) GlobalGT("TalkedToBotsmith","GLOBAL",0)~ THEN BOTSMITH ImCesp6
	~Cespenar only serves the Great One- Ooo! It is you, not-so-great Great One!~ [IRQUIET]
	== IMOEN25J ~How ya doin', you doofus?~
	== BOTSMITH ~I have founds three golden round shiny ones! Not-so-great Great One likes round shiny ones, yes?~
	== IMOEN25J ~Oh, absolutely. I accept your generous and gracious gift, Almighty Cespenar.~
	== BOTSMITH ~'Tis only Cespenar. Not-so-great Great One hard of hearing, I'se knows. Anyways, back to cleaning now!~ DO ~GiveGoldForce(3) RunAwayFrom("Imoen2",45)~
EXIT
