// These should trigger if IRTAerImFriend = 1, on a standard timer unless otherwise stated. They all need to be implemented.
// If IRTAerImFriend = 2, they're still friends but they're quiet about it because the player has expressed annoyance
// Name of the global keeping track of banter progress: IRTImAerTalks
// If Imoen is not romanced by the player, there are two more conversations about Imoen and Aerie.
// I figured the mod wouldn't be nearly as saturated if you're not romancing Imoen, so it shouldn't feel like she talks too much.

// If Global("IRTImAerWishYes","GLOBAL",1) then Aerie's epilogue doesn't display and Imoen's epilogue shows their story together as a romantic couple.
// If !Global("IRTImAerWishYes","GLOBAL",1) and IRTAerImFriend > 0, then Aerie's epilogue doesn't display and Imoen gets the friendship epilogue.






// ~~ 1st conversation ~~
// Should trigger pretty soon. In pocket plane after talking heads and Illasera?


CHAIN IF WEIGHT #21 ~Global("IRTImAerTalks","GLOBAL",1)~ THEN AERIE25J AE1
~Imoen?~ [IRAerie] DO ~SetGlobal("IRTImAerTalks","GLOBAL",2) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~
	== IMOEN25J ~Yeah?~
	== AERIE25J ~Are we... are we friends?~
	== IMOEN25J ~Um, yeah? I should hope so, at any rate. We sure have killed enough people together. Why?~
	== AERIE25J ~That's... what? How is that a metric for friendship?~
	== IMOEN25J ~(Imoen shrugs.) Some people have lunch together. You and I, we fireball things. Monsters and bad guys, preferably.~
	== AERIE25J ~Is this a bad time? You are being needlessly bleak again.~
	== IMOEN25J ~No, no, I just... I've some stuff in my head, never you mind. Why the silly question, Aerie? Of course we're friends.~
	= ~Uh, right? You don't suddenly hate me or nuthin'...~
	== AERIE25J ~N- no, of course not. The complete opposite - I think the world of you!~
	== IMOEN25J ~Aww, that's awful sweet of you. And... somewhat awkward. Whatcha tryin' to get at? It isn't my cookie stash yer after, is it? 'Cause you can forget about that.~
	== AERIE25J ~I was just... thinking. I've never had a friend. A *real* friend. I realized you are my first.~
	== IMOEN25J ~Aw, c'mon, that's such a sad thing to say. How about your Uncle Quayle, or whoever you knew before... y'know. *Before*.~
	== AERIE25J ~I love Uncle Quayle. He was nice to me, sweet and caring, but... not a friend, not quite. Just somebody that took pity on me. Adoptive family.~
	= ~And my life before I was captured... I don't even see it as real anymore. I was a child, and what few friends I had were little more than play mates. It's different with you.~
	== IMOEN25J ~Huh.~
	== AERIE25J ~Huh? What do you mean, "huh"?~
	== IMOEN25J ~Well, I just never thought when we met that you'd ever go from "I've got no wings, my life's over" to "I care so little that I feel like it never happened."~
	= ~Or that you'd ever go whole sentences without stammering, for that matter.~
	== AERIE25J ~Oh. (Aerie falls silent for a moment.)~
	= ~Huh.~
	== IMOEN25J ~Yeah! Huh indeed.~
	== AERIE25J ~I- I guess... I guess seeing what you and <CHARNAME> have faced, quite literally going to Hell and back... it gave me a bit of perspective, perhaps. Some... confidence?~
	= ~We have done so much. I used to feel small and powerless, but I don't feel that anymore. I've... found new wings, in a way.~
	== IMOEN25J ~That's right! The wings of MAGIC! To fireball people with!~
	== AERIE25J ~Y- yes, or, maybe, you know, powerful prayers to protect my allies and heal the wounded?~
	== IMOEN25J ~Pfah. The voices in my head don't care about such things.~
	== AERIE25J ~I'm sorry?~
	== IMOEN25J ~What?~
	== AERIE25J ~W- What?~
	== IMOEN25J ~Exactly.~
EXIT





// ~~ 2nd conversation: Imoen - Aerie original game banter, which needs to be heavily changed if they are friends. It becomes the second banter they have befriended each other. ~~

CHAIN IF WEIGHT #20 ~Global("IRTImAerTalks","GLOBAL",3)~ THEN AERIE25J Friend71
~I keep wondering how could you stand being sheltered inside Candlekeep all of your youth, Imoen. I mean, you are so, ah... what's the word?~ [IRAerie] DO ~SetGlobal("IRTImAerTalks","GLOBAL",4) SetGlobal("ExpBaerie11","LOCALS",1) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~
	== IMOEN25J ~Awesome?~
	== AERIE25J ~Restless.~
	== IMOEN25J ~Are you saying I'm not awesome?~
	== AERIE25J ~No, it just doesn't have anything to do with what I'm trying to-~
	== IMOEN25J ~So you think I'm boring! Oh, oh my, I feel so betrayed, and I thought you were my friend!~
	== AERIE25J ~B- but I've never said you were-~
	== IMOEN25J ~You think I'm boring and stupid and ugly! You think I should be burned at the stake for my horrible, horrible face! I can't stand the pain, you've just stabbed my heart with your cruel words. I disown you, I disown you forever!~
	== AERIE25J ~(Aerie furrows her brow, pursing her lips and looking at Imoen's hurt face with irritation.)~
	== IMOEN25J ~...~
	== AERIE25J ~...~
	== IMOEN25J ~What?~
	== AERIE25J ~Must you always make fun of my honest attempts at conversation?~
	== IMOEN25J ~Must you always be SO EASY to make fun of? Really, the lack of a challenge makes it almost boring.~
	== IMOEN25J ~Almost.~
	== AERIE25J ~Well that makes TWO of us getting tired of your constant mockery.~
	== IMOEN25J ~Yeesh, alright, I'll be nice, I promise.~
	== AERIE25J ~(Aerie huffs lightly.) It feels stupid now to ask the same question. You just ruined the whole thing.~
	== IMOEN25J ~Aww, c'mon, "hyperactive" is another word you coulda used.~
	== AERIE25J ~Yes, very much so. Those poor Candlekeep monks, imprisoned within the same walls as the little red-haired devil. You must have been so bored, my heart goes out to them.~
	== IMOEN25J ~Oh boy, speaking of, I used to play this great game: see how many heart attacks I could cause to the older monks in one month, and then see if I could beat my own record. It was harder every time, since a lot of them kept dying on me.~
	== AERIE25J ~Imoen! That is monstrous! How could you-~
	== IMOEN25J ~I'm joking, yeesh! It wasn't that bad. They did hate to be called "monkeys", though. I was always climbing the walls just to drive the monks up them. And well, there was <CHARNAME> too, who was my privileged number one victim and accomplice rolled into one. You can frame the same person of this or that mischief only so many times.~
	== AERIE25J IF ~Alignment(Player1,MASK_EVIL) OR(2) CheckStatGT(Player1,14,WIS) CheckStatGT(Player1,14,INT)~ THEN ~<CHARNAME> doesn't strike me as someone who would easily make light of your practical jokes, Imoen.~
	== IMOEN25J IF ~Alignment(Player1,MASK_EVIL) OR(2) CheckStatGT(Player1,14,WIS) CheckStatGT(Player1,14,INT)~ THEN ~The more annoyed <PRO_HESHE> was, the more fun I got!~
	== AERIE25J IF ~!Alignment(Player1,MASK_EVIL) OR(2) CheckStatGT(Player1,14,WIS) CheckStatGT(Player1,14,INT)~ THEN ~<CHARNAME> doesn't strike me as someone so easily fooled, Imoen.~
	== IMOEN25J IF ~!Alignment(Player1,MASK_EVIL) OR(2) CheckStatGT(Player1,14,WIS) CheckStatGT(Player1,14,INT)~ THEN ~Yer right, it was a challenge, really. But the more difficult, the more fun it is!~
	== AERIE25J ~Now I understand why <CHARNAME> can cope with so much and not collapse under the burden. <PRO_HESHE> grew up with you.~
== IMOEN25J ~Aw, you hurt me so! I didn't get up to that much trouble, honest. Winthrop taught me well to weasel out of problems. Though... lately I'm not following his advice too well.~
	== AERIE25J ~(Aerie smiles sadly.) Right. But Winthrop? I thought your tutor was Gorion.~
	== IMOEN25J ~Officially, yeah. But I liked to stick with ol' Puffguts more. He... he kinda *got* me, y'know? I think he even... loved me. I think. When he wasn't bossin' me around to do the chores, that is. Sometimes, I caught him looking at me with this strange look in his eyes, like... like, y'know, a proud look. Like he was proud of me.~
	== IMOEN25J ~I can't say the same for Gorion. I don't think he ever felt anything close to being proud of me. Mister G was distant most of time, really. <CHARNAME> was his true ward; I just stuck around.~
	== AERIE25J ~Oh.~
	== IMOEN25J ~Aw, don't feel bad, that sounded worse than I intended. He... he must've known I was a Bhaalspawn. He probably didn't want me to get tangled up with that whole mess, and keeping his distance was the best he could do to shield me. Anyway, Winthrop was good enough for me. He was more a friend than a parent - well, as friends as an adult can be with a little girl. I miss him.~
	== AERIE25J ~He... he's still alive, yes?~
	== IMOEN25J ~As far as I know, yeah. I sure hope so. When all this ends, I'd love to go see him. It'd be nice to visit Gorion's resting place, too. We never got a chance to do that.~
	== AERIE25J ~I'd love to go with you and meet Winthrop, if... if you don't mind, I mean.~
	== IMOEN25J ~Why, really? That'd be great. We can go visit then, for sure. (She smiles cheerily.) If we're still alive, that is!~
	== AERIE25J ~We can only hope.~
EXIT




// 3rd Conversation


CHAIN IF WEIGHT #19 ~Global("IRTImAerTalks","GLOBAL",5)~ THEN IMOEN25J ImAerChain3
	~Shut up, shut up already!~ [ IRQUIET ] DO ~SetGlobal("IRTImAerTalks","GLOBAL",6) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~
	= ~(Imoen's eyes are squeezed shut, as if cringed closed after a sudden jolt of pain. Slowly she opens them and looks around.)~
	= ~Uh, sorry. Didn't realize I said that out loud.~
	== AERIE25J ~Are you well?~
	== IMOEN25J ~Y- yeah, yeah, I'm fine. Forget about it.~
	== AERIE25J ~Is it... is it the Taint? Whispering?~
	== IMOEN25J ~I don't care to talk about it, okay? Just leave me alone, I'll be fine.~
	== AERIE25J ~(Aerie's mouth quirks at the corner, her brow crinkling in an expression of worry.) Of course, Imoen.~
EXIT


//// 4th Conversation (Make the timer shorter for this one)

CHAIN IF WEIGHT #18 ~Global("IRTImAerTalks","GLOBAL",7)~ THEN IMOEN25J ImAerChain4
	~Hey, Aerie. I'm sorry about earlier.~ [IRAerie] DO ~SetGlobal("IRTImAerTalks","GLOBAL",8) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ 
	== AERIE25J ~There is nothing to apologize for. I know what you are dealing with.~
	= ~Well, I don't *know*, truly - I wish I did. But I know sometimes you are... not yourself.~
	== IMOEN25J ~Gosh, you really *don't* wish you did, believe me. But that's such an accurate way to put it, though. Not myself.~
	= ~That's exactly how I feel sometimes. Like there's this... presence, eatin' away at what makes me *me*. Makes me wanna poke a knife into my head and dig it out.~
	== AERIE25J ~Isn't that what Irenicus attempted? He didn't meet with much success.~
	== IMOEN25J ~Well, d'uh. I'm not gonna *do* it, I'm not that crazy yet.~
	== AERIE25J ~(Aerie smiles.) But you are getting there?~
	== IMOEN25J ~Yeah. Yeah, I'm gettin' there.~
	== AERIE25J ~Well... would you like to know my opinion?~
	== IMOEN25J ~How could I stop ya, when you're so polite about it?~
	== AERIE25J ~I think that you are far stronger than whatever power this influence can wield. You have endured far too much and vanquished too many demons to be taken down now by a simple divine curse.~
	= ~Nothing can break you, Imoen. Least of all a dead god.~
	== IMOEN25J ~Hah, wow. That's some vote of confidence right there. I'm feelin' the pressure now, really hope I don't disappoint ya.~
	== AERIE25J ~You have yet to do that, and I don't think you will start any time soon. You will get through it, Imoen.~
	== IMOEN25J ~Boy. I'm coming to you any time I need a pep talk. You sure know what to say to make things feel a little less terrible.~
	== AERIE25J ~I am just making sure you don't see it coming when I stab you abominable Bhaalspawn in the middle of the night.~
	== IMOEN25J ~(Imoen is startled for a moment, then bursts out laughing.) You little imp! You had me going for a moment, you and your perfectly straight face!~
	== AERIE25J ~(Aerie giggles and curtsies.) I've learned from the master.~
	== IMOEN25J ~Yeah, well. I'm sleepin' with one eye open from now on, missy. Just in case.~
	== AERIE25J ~As well you should.~
EXIT


// 5th Conversation: Imoen approaches the player, but only if she is either romanced or friendly.
// Skip to next if she's fighting with the player

/* branch a) Imoen is romanced */

APPEND IMOEN25J
IF WEIGHT #800 ~Global("ImoenRomanceActive","GLOBAL",2) Global("IRTImAerTalks","GLOBAL",9)~ THEN IAR1
   SAY ~<CHARNAME>, got a moment? Maybe we could talk?~ [IRAerie]
   = ~(Imoen is nearly whispering. She clearly wants to be discreet.)~
   ++ ~What's on your mind?~ DO ~SetGlobal("IRTImAerTalks","GLOBAL",10)~ + IAR1Next
   ++ ~If you make it quick.~ DO ~SetGlobal("IRTImAerTalks","GLOBAL",10)~ + IAFRQuick
   ++ ~Sorry, I don't have time.~ DO ~SetGlobal("IRTImAerTalks","GLOBAL",10)~ + IAFEnd
   ++ ~Leave me alone.~ DO ~SetGlobal("IRTImAerTalks","GLOBAL",10)~ + IAFEnd2
END

IF ~~ IAFRQuick
   SAY ~Oh, no, no, it's not even important, don't mind me if yer in a hurry right now.~
   ++ ~Fine. What's on your mind?~ + IAR1Next
   ++ ~Sorry then, I don't have the time.~ + IAREnd
END

IF ~~ IAREnd
   SAY ~That's fine. Onwards to adventure we go.~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~EXIT
END

IF ~~ THEN IAR1Next
   SAY ~Well, I just wanted to discuss Aerie with ya. I've been spendin' a lot of time with her lately, and I wanna make sure yer alright with that. Don't mean to make you feel neglected or nothin'...~
   ++ ~She's your friend, Imoen. Of course I don't mind.~ + IAR1d
   ++ ~You two can be annoying at times, but I'll manage.~ + IAR1c
   ++ ~I do feel you spend a bit too much time with her.~ + IAR1b
   ++ ~I've been meaning to ask you. Stop talking to Aerie. I can't stand her.~ + IAR1a
END

IF ~~ IAR1a
   SAY ~Aw. (Imoen blinks a few times.) Really? But...~
   = ~Really?~
   ++ ~Every time she opens her mouth I want to stab her face.~ + IAR1a4
   ++ ~She's just too feeble-minded. She drags everyone down, including you.~ + IAR1a3
   ++ ~She's stealing you from me. I want you all for myself.~ + IAR1a2
   ++ ~Alright, fine, do whatever you please, don't look at me like that.~ + IAR1a1
END

IF ~~ IAR1a1
   SAY ~Hah, puppy eyes to the rescue. Phew. Alright.~
   = ~We can keep things quiet, now that I know it annoys you. I'd rather keep the peace. Last thing I wanna do is get her kicked out...~
   = ~Alright then, let's stop talkin' about Aerie and get to bashin' some heads.~
   IF ~~ THEN DO ~SetGlobal("IRTAerImFriend","GLOBAL",2) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAR1a2
   SAY ~Pfah hah hah! Are you serious? You can't be serious.~
   = ~Alright, yer serious. You've nothing to worry about, dummy! I'd never betray you like that, and she's got *zero* interest in girls, believe me. You'd be surprised about the comments she's made on some of the guys we've encountered...~
   = ~Can't believe yer jealous of Aerie, of all people. She's harmless like a cuddly-sweet kitten.~
   = ~A prayer-wielding, fireball-lobbin' kitten...~
   ++ ~No. Stop talking to her. That's final.~ + IAR1a2b
   ++ ~I don't feel comfortable with it, Imoen. Please, I would like it to stop.~ + IAR1a2a
   ++ ~Alright, fine, do whatever you please, don't look at me like that.~ + IAR1a1
END

IF ~~ IAR1a2a
   SAY ~(Imoen purses her lips at you. The emotion in her features isn't as much anger as it is... disappointment.)~
   = ~Fine, you win. I'll explain to her and we'll be quiet from now on. I won't even put the blame on you or anything spiteful like that. I'd rather keep the peace and move along, because I know what's at stake, and I know what's important.~
   = ~But if we survive all this? We'll have some words, you and I. A bit of jealousy is understandable, even flattering, but... you can't expect me not to have any friends.~
   = ~Anyway, let's just move on, shall we?~
   IF ~~ THEN DO ~SetGlobal("IRTAerImFriend","GLOBAL",2) IncrementGlobal("IRTLoveMeter","GLOBAL",-15) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAR1a2b
   SAY ~Whoa, hey, watch it. I'll talk to whoever I please. You're not in charge of that, understand? That's not the <PRO_MANWOMAN> I fell in love with.~
   = ~That being said, I *will* explain to her and be quiet from now on. I'd rather keep the peace and move along, because I know what's at stake, and I know what's more important.~
   = ~So let's move on, shall we?~
   IF ~~ THEN DO ~SetGlobal("IRTAerImFriend","GLOBAL",2) IncrementGlobal("IRTLoveMeter","GLOBAL",-20) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAR1a3
   SAY ~What? Aerie's tough! Yer still thinking of the whiny little girl you picked up at the circus. She's become a tough, hardy woman that just so happens to be soft-spoken and really care about yer feelings and whatnot.~
   = ~But hey, if you feel that way, we'll just keep things quiet from now on. I'd rather keep the peace and move along, because I know what's at stake, and I know what's more important.~
   = ~I sure do wish you'd reconsider, though...~
   IF ~~ THEN DO ~SetGlobal("IRTAerImFriend","GLOBAL",2) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAR1a4
   SAY ~Yikes! That's some strong feelings right there. I'm surprised you've kept her around this long, if you feel that way... I guess she's just too useful to kick her out?~
   = ~Alright, well, Aerie and I can just be quiet about our things from now on. I'd rather keep the peace and not make a fuss about it, I know what's at stake. And I know she'll understand, because, despite yer misguided feelings, Aerie is awesome.~
   = ~That's too bad, though...~
   IF ~~ THEN DO ~SetGlobal("IRTAerImFriend","GLOBAL",2) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAR1b
   SAY ~Aww, really? I... I guess I can see your point. I'll make extra-sure yer getting your rightful share of Imoen-time, I know it's in high demand nowadays. (She winks at you.)~
   IF ~~ THEN GOTO IAR1bN
END

IF ~~ IAR1bN
   SAY ~I just... I really like her, y'know? And before you say a thing, I like her *strictly* as a friend. Don't you be getting jealous or anything weird like that.~
   = ~Well, then, I don't think yer gonna like the next question. Y'see...~
   IF ~~ THEN GOTO IARFond
END

IF ~~ IAR1c
   SAY ~Ha ha, yeah, well, I can't say I blame ya. We've been a bit obnoxious sometimes, guilty as charged. I'll make extra-sure yer getting your rightful share of Imoen-time, I know it's in high demand nowadays. (She winks at you.)~
   IF ~~ THEN GOTO IAR1bN
END

IF ~~ IAR1d
   SAY ~Aw, it's great that you feel that way. Yer such a sweet pumpkin pie. (She lands a quick peck on your nose.)~
   IF ~~ THEN GOTO IARFond
END

IF ~~ IARFond
   SAY ~I've grown real fond of her. I'd love it if she sticks around for the long term, if she wants. How wouldja feel about that? Us three, traveling together for years to come?~
   ++ ~I do like Aerie, and I like seeing you happy. She's welcome for as long as she wants to travel with us.~ + IARHappy
   ++ ~I find her abilities invaluable. I would never want to do without them.~ + IARSkills
   ++ ~I don't like her much, but I'm willing to put up with her for your sake.~ + IARSake
   ++ ~You know I can't stand her, though. I was hoping to get rid of her soon.~ + IARGetRid
   ++ ~Imoen... that's too much. I want to be alone with you at some point. We don't need a sidekick.~ + IARSide
   ++ ~We'll see. I don't think we should plan beyond Bhaal's Throne.~ DO ~SetGlobal("IRTImoenWarnedAboutLeaving","GLOBAL",1)~ + IARPlan
END

IF ~~ IARHappy
   SAY ~That's great! You're the sweetest thing. I'll let her know. (Imoen startles as if she just realized something.) Oh, by the way, she didn't put me up to this or anything. I'm just doing some preemptive research, y'see.~
   = ~(She pats your arm and chuckles.) Not that the plan matters much. She'll probably get sick of me within a year and we'll end up lobbin' fireballs at each other's heads.~
   = ~Good times! Lookin' forward to it.~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IARSkills
   SAY ~That's right! Aerie's all kinds of mighty. Between you and me, and dontcha ever dare tell her... I don't think I could take her in a straight fight. I'll run out of spells before she's even winded.~
   = ~Anyway, that sounds great. (She pats your arm and chuckles.) Not that the plan matters much. She'll probably get sick of me within a year and we'll end up lobbin' fireballs at each other's heads.~
   = ~Good times! Lookin' forward to it.~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IARSake
   SAY ~Hey, maybe she'll grow on ya! I'm telling you, Aerie's not who she used to be. Maybe you'll change yer mind, eventually.~
   = ~Anyway, that sounds great. (She pats your arm and chuckles.) Don't worry too much, probably we'll get sick of each other within a year and end up lobbin' fireballs at each other's heads.~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IARGetRid
   SAY ~Aw, c'mon... I wish you'd see her like I do. She's changed so much. If only you'd give her a chance...~
   IF ~~ THEN GOTO IARNoAerieEnd
END

IF ~~ IARSide
   SAY ~Aw, she wouldn't be a sidekick, just a friend! Y'know, like Khalid and Jaheira when we started.~
   IF ~~ THEN GOTO IARNoAerieEnd
END

IF ~~ IARNoAerieEnd
   SAY ~But I guess I see your point. I can't expect ya to travel with people you don't like after all this stuff is over. Aerie and I will... figure something out.~
   = ~Well, then, I suppose that's settled. Might as well get on with the Bhaal business.~
   IF ~~ THEN DO ~SetGlobal("IRTEpilogueNoAerie","GLOBAL",1) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IARPlan
   SAY ~Oh. I... I see. Yeah, I understand. No point talking about these things when we might be dead in a couple days.~
   = ~Well, then, glad that's settled for now. Might as well get on with the Bhaal business!~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

/* branch b) Imoen isn't romanced */

IF WEIGHT #800 ~!Global("ImoenRomanceActive","GLOBAL",2) Global("IRTImAerTalks","GLOBAL",9)~ THEN IAF1
   SAY ~<CHARNAME>, got a moment? Maybe we could talk? It's about Aerie.~ [IRAerie]
   = ~(Imoen is nearly whispering. She clearly wants to be discreet.)~
   ++ ~What's the matter?~ DO ~SetGlobal("IRTImAerTalks","GLOBAL",10)~ + IAF2
   ++ ~If you make it quick.~ DO ~SetGlobal("IRTImAerTalks","GLOBAL",10)~ + IAF2Quick
   ++ ~Sorry, I don't have time.~ DO ~SetGlobal("IRTImAerTalks","GLOBAL",10)~ + IAFEnd
   ++ ~Leave me alone.~ DO ~SetGlobal("IRTImAerTalks","GLOBAL",10)~ + IAFEnd2
END

IF ~~ IAFEnd
   SAY ~Aw. Alright. It wasn't important anyway, I'll figure it out.~
   IF ~~ THEN DO ~SetGlobal("IRTAerieIgnoreSexualTension","GLOBAL",1) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAFEnd2
   SAY ~Yeesh, alright, alright...~
   IF ~~ THEN DO ~SetGlobal("IRTAerieIgnoreSexualTension","GLOBAL",1) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAF2
   SAY ~Okay, now, bear with me because I feel pretty spooked about this. I'd really appreciate it if you don't give me weird looks, and don't act all shocked, and *especially* don't burst out laughing. You ready?~
   = ~Um, what if I told ya that, um...~
   = ~What if I were developing certain... feelings... for Aerie?~
   = ~Like, you know. *Feelings*. Of the romantic kind.~
   ++ ~Are you serious?~ + IAFSerious
   ++ ~Well, I saw that coming from miles away.~ + IAFSaw
   ++ ~(Burst out laughing.)~ + IAFLaugh
   ++ ~That's none of my business, Imoen. Just do as you please.~ + IAFDismiss
   ++ ~(Yell at the top of your lungs.) You like Aerie romantically? That's fascinating!~ + IAFYell
END

IF ~~ IAF2Quick
   SAY ~Oh, um, sure. I was gonna dither and dance around the topic, but since yer in a hurry I'll just blurt it out. Ready?~
   = ~I might be developing romantic feelings for Aerie. What do you think I should do?~
   ++ ~Whoa. Are you serious?~ + IAFSerious
   ++ ~Well, I saw that coming from miles away.~ + IAFSaw
   ++ ~(Burst out laughing.)~ + IAFLaugh
   ++ ~That's none of my business, Imoen. Just do as you please.~ + IAFDismiss
   ++ ~(Yell at the top of your lungs.) You like Aerie romantically? That's fascinating!~ + IAFYell
END

IF ~~ IAFYell
   SAY ~(Imoen freezes for a panicked moment, her eyes somehow mixing shock and murderous intent. Then she starts laughing as if you just said the zaniest thing, looking back and forth from you to Aerie. The elf has a quizzical eyebrow raised.)~
    = ~Yer such a skid mark, trying to weird out Aerie like that! Where did that even come from? I was only askin' to stop for a bite some time, jeez!~
   = ~I better leave you alone now, who knows what kind of madness you'll start spoutin' next time I ask for a pee break...~
   = ~(Imoen walks over to Aerie. You can see her rolling her eyes and pointing at her head, twirling her finger as if to say that you are one hundred percent mad.)~
   IF ~IsValidForPartyDialog("Aerie")~ THEN DO ~SetGlobal("IRTAerieTalkSexualTension","GLOBAL",1) MoveToObject("Aerie") RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
   IF ~!IsValidForPartyDialog("Aerie")~ THEN DO ~SetGlobal("IRTAerieTalkSexualTension","GLOBAL",1) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAFDismiss
   SAY ~Yeesh, okay. Way to appreciate me trusting ya with deeply personal stuff.~
   = ~Fine, then, off to adventure we go. I'll figure things out.~
   IF ~~ THEN DO ~SetGlobal("IRTAerieTalkSexualTension","GLOBAL",1) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAFLaugh
   SAY ~(Imoen has crossed her arms and is tapping her foot. She's looking at you like she wouldn't mind seeing you fall off a cliff right this moment.)~
   = ~Fine, laugh it up. I was such a fool to hope for some advice. I'll just figure it out on my own...~
   ++ ~(Hold it back.) No, no, wait. Let's talk about it.~ + IAFLaugh1
   ++ ~(Keep laughing.)~ + IAFLaugh2
END

IF ~~ IAFLaugh1
   SAY ~(She eyes you with skepticism for a moment, then heavily breathes out.)~
   IF ~~ THEN GOTO IAFAdvice
END

IF ~~ IAFLaugh2
   SAY ~(Imoen huffs and stomps away.)~
   IF ~~ THEN DO ~SetGlobal("IRTAerieTalkSexualTension","GLOBAL",1) RunAwayFrom(Player1,40) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAFSaw
   SAY ~(Imoen blinks a few times.) Oh. Really? Do ya... d'ya think she knows, then? No, no, of course she doesn't. She'd get all weird. You just saw it coming because we're always talkin' and giggling and stuff, of course you'd get ideas...~
   = ~(She stops herself and exhales a sigh.)~
   IF ~~ THEN GOTO IAFAdvice
END

IF ~~ IAFSerious
   SAY ~(Imoen gives a nervous chuckle.) I know, it's real weird! It's been building for a while, I think. And then last night, we were poring over her spellbook - didja know it's covered in unicorns and fairies? I swear, it's the cutest thing - and it kinda just hit me, I was like... I could kiss her right now. It was a very strange moment.~
   = ~(Imoen's cheeks are flushed a deep shade of pink. She runs a hand through her hair.)~
   IF ~~ THEN GOTO IAFAdvice
END

IF ~~ IAFAdvice
   SAY ~This is tough for me, <CHARNAME>. I don't know what to do.~
   ++ ~If you love her, you should tell her.~ + IAFAdvice5
   ++ ~You realize Aerie isn't attracted to women, right?~ + IAFAdvice4
   ++ ~You shouldn't do a thing about this. It's simple infatuation and it will pass.~ + IAFAdvice3
   ++ ~I'm baffled. What could you possibly see in Aerie?~ + IAFAdvice22
   ++ ~I didn't even know you liked women.~ + IAFAdvice2
   ++ ~This is disgusting and I don't ever want to hear a word about it. I will be majorly aggravated if I see any kind of unseemly behavior.~ + IAFAdvice1
END

IF ~~ IAFAdvice1
   SAY ~(It takes Imoen a moment to understand what you're saying. She takes a step back, and a deep chasm seems to open between you.)~
   = ~Alright. Sorry I brought this to you.~
   = ~(She steps away, shaking her head.)~
   IF ~~ THEN DO ~SetGlobal("IRTAerImFriend","GLOBAL",2) SetGlobal("ImoenRomanceActive","GLOBAL",3) RunAwayFrom(Player1,40) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAFAdvice2
   SAY ~I, uh. (Her cheeks redden further.) I- I guess I do? If I'm perfectly honest... some people I find attractive regardless of gender. It's all about the person.~
   = ~And the midriff. Aerie has an amazing midriff.~
   ++ ~If you love her, you should tell her.~ + IAFAdvice5
   ++ ~You realize Aerie isn't attracted to women, right?~ + IAFAdvice4
   ++ ~You shouldn't do a thing about this. It's simple infatuation and it will pass.~ + IAFAdvice3
   ++ ~I'm baffled. Midriff aside, what could you possibly see in Aerie?~ + IAFAdvice22
   ++ ~This is disgusting and I don't ever want to hear a word about it. I will be majorly aggravated if I see any kind of unseemly behavior.~ + IAFAdvice1
END

IF ~~ IAFAdvice22
   SAY ~Aw, I know you don't like her much, but... I really wish you'd reconsider. Aerie is sweet, honest, always eager to help, and real funny if she's comfortable enough. (She tries to restrain a giggle.) She's cracked some real dirty jokes, ya never expect them to come out of that pouty little mouth...~
   IF ~~ THEN GOTO IAFAdviceGush
END

IF ~~ IAFAdvice3
   SAY ~You... you think so? It could be. I mean, I don't think I'd call this, um. The L word. Right? It doesn't work that way. Not that I have any experience in the matter...~
   IF ~~ THEN GOTO IAFAdviceLike
END

IF ~~ IAFAdvice4
   SAY ~I know, I *know* that! That's why this is so complicated for me. Maybe, y'know... maybe she'd give it a chance. If you go by some of the stories in Candlekeep, most women are open to... umm. Anyway.~
   IF ~~ THEN GOTO IAFAdviceLike
END

IF ~~ IAFAdviceLike
   SAY ~I just really like her, y'know? Aerie is sweet, honest, she's always eager to help, and real funny if she's comfortable enough. (Imoen tries to restrain a giggle.) She's cracked some real dirty jokes, ya never expect them to come out of that pouty little mouth...~
   IF ~~ THEN GOTO IAFAdviceGush
END

IF ~~ IAFAdvice5
   SAY ~(Her cheeks redden further.) L- love? I- I don't know if it goes that far, I mean... it doesn't work that way, right? Suddenly, love? Not that I have any experience in the matter.~
   IF ~~ THEN GOTO IAFAdviceLike
END

IF ~~ IAFAdviceGush
   SAY ~Oh Gods. I'm gushing, aren't I?~
   = ~I'm positively gushing. This... this might be worse than I thought.~
   ++ ~It sounds like you need to talk about this with her.~ DO ~SetGlobal("IRTAerieTalkPlayerAdvice","GLOBAL",1) SetGlobal("IRTAerieTalkSexualTension","GLOBAL",1)~ + IAFRes5
   ++ ~It sounds like you need to keep this to yourself. You'll only get hurt if you try anything.~ DO ~SetGlobal("IRTAerieIgnoreSexualTension","GLOBAL",1)~ + IAFRes4
   ++ ~Seduce her, Imoen. She won't resist you.~ DO ~SetGlobal("IRTAerieKissSexualTension","GLOBAL",1)~ + IAFRes3
   ++ ~Don't you dare drag Aerie into that kind of relationship. You will ruin her, Imoen.~ DO ~SetGlobal("IRTAerieIgnoreSexualTension","GLOBAL",1)~ + IAFRes2
   ++ ~I really don't know what you should do.~ DO ~SetGlobal("IRTAerieIgnoreSexualTension","GLOBAL",1)~ + IAFRes1
END

IF ~~ IAFRes1
   SAY ~You an' me both, then. It's alright, I didn't expect you to. I just wanted to talk about it.~
   = ~Thanks a lot for listening to my teenage drama, <CHARNAME>. Hey, look at that! At least not everything is a life or death dilemma, huh?~
   = ~I guess we'll wait and see...~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~EXIT
END

IF ~~ IAFRes2
   SAY ~Whoa, okay. I'm not that bad an influence, you know? I've helped her a lot, she tells me all the time! Maybe I can make her happy like that. Maybe I'm just what she needs, what do *you* know?~
   = ~(Imoen pauses for a moment. Her defensive stance deflates under the weight of second thoughts.) Or maybe I'd drag her into all of my Bhaal bullshit and end up hurting her somehow. Or freak her out and throw our friendship in the trash.~
   = ~Maybe I can just... get over this whole thing.~
   = ~Thanks, <CHARNAME>.~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAFRes3
   SAY ~Whoa, haha, okay. I dunno if I can do *that*, but thanks for the vote of confidence. I knew I could count on ya to make me feel not-so-awkward about this.~
   = ~Maybe I'll just up and kiss her. That should solve all my problems, yup...~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAFRes4
   SAY ~(She seems to deflate more with every word you say.)~
   = ~Yeah... yeah, you're probably right.~
   = ~I'll get over it. I know I can get over it. I wish I didn't feel this way, though.~
   = ~Thanks, <CHARNAME>.~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAFRes5
   SAY ~(She bites her lip.) I was afraid you'd say that. D'ya know how awkward that's gonna be? "Oh, hey Aerie, did ya know I wanna kiss you? Whatcha think about that?"~
   = ~I can see her already, staring with those giant blue eyes, making me feel like a damn fool, way too polite to show she's all grossed out.~
   = ~I just need to be real careful about it. I don't wanna lose her as a friend, y'know.~
   = ~(Imoen sighs.) Thanks a lot for listening to my teenage drama, <CHARNAME>. Hey, look at that! At least not everything is a life or death dilemma, huh?~
   = ~Wish me luck, I guess.~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END
END




// 6th Conversation

// If Imoen is romanced, this is their final conversation

CHAIN IF WEIGHT #800 ~Global("IRTImAerTalks","GLOBAL",11) OR(3) Global("IRTAerieTalkSexualTension","GLOBAL",1) Global("IRTAerieKissSexualTension","GLOBAL",1) Global("ImoenRomanceActive","GLOBAL",2)~ THEN IMOEN25J IA6Chain
	~So what are your plans for when this is all over, Aerie?~ [IRAerie] DO ~SetGlobal("IRTImAerTalks","GLOBAL",12) ~
	== AERIE25J ~Plans? I... I don't know if we should even make them, honestly.~
	== IMOEN25J ~Oh, c'mon, we should be optimistic! Everything will turn out easy-breezy and we'll come out rich and famous. The world will be our playground!~
	== AERIE25J ~But what of your Bhaal heritage? What of <CHARNAME>'s birthright? I can't imagine how we can come out the other end with a lust for adventure.~
	== IMOEN25J ~Yer such a downer, Aerie! Weren't you encouraging *me* a while ago? Well, I took it to heart, don't you see? Things will work out. They always do. Even when there's a whole bunch of torture and death in-between.~
	== AERIE25J ~(Aerie laughs half-heartedly.) It still baffles me that you can make light of everything you went through. I've yet to joke about... well, you know.~
	== IMOEN25J ~Have ya tried? It's real easy, honest. As easy as getting stabbed in the brain and traumatized for life!~
	== AERIE25J ~Well... w- well, at least now I don't have to worry about... um.~
	= ~(Aerie thinks for a moment.) I hope at least some posh old lady out there enjoys having my feathers on their fancy bonnet.~
	== IMOEN25J ~(Imoen snorts a chuckle.) Pretty lame, but that's the spirit.~
	== AERIE25J ~I can do better! How about...~
	= ~I'm glad my wings are gone. I can finally lie down without getting tickled all the time.~
	== IMOEN25J ~Pfff!~
	== AERIE25J ~I'm going to start shooting down every bird I see, collect all their feathers and glue them to my back. Do you think it will solve my self-esteem issues?~
	== IMOEN25J ~(The joke finally gets an honest laugh out of Imoen. Aerie's voice is laced with titters.)~
	== AERIE25J ~You know what the best part of flying was? Pooping on merchants' heads.~
	== IMOEN25J ~Pffhah hah hah, WH- WHAT?~
	== AERIE25J ~They clipped my wings, Imoen! Sit down so I can spend the next four hours telling you all about it!~
	== IMOEN25J ~(Imoen laughs lightheartedly.) You weren't *that* bad, c'mon...~
	== AERIE25J ~For future reference, you can tell I'm excited whenever my stumps wiggle.~
	== IMOEN25J ~Who-ho-hoah, that's *dark*, Aerie! Oh Gods, what have I done? I've unleashed a monster!~
END
	IF ~Global("IRTAerieKissSexualTension","GLOBAL",1)~ THEN EXTERN AERIE25J IA6KissChain
	IF ~Global("IRTAerieTalkSexualTension","GLOBAL",1)~ THEN EXTERN AERIE25J IA6RomChain
	IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN EXTERN AERIE25J IA6RomChain



// This chain is for when IRTAerieTalkSexualTension = 1 or ImoenRomanceActive = 2

CHAIN AERIE25J IA6RomChain
	~They might have caged me for months, but... but at least... (Aerie can't stop giggling, mirth coming in short bursts between quickly drawn breaths. She gives in to the laughter, and soon she's tossed her head back, one hand on her chest. Imoen is simply looking at her, a huge smile on her lips.)~
	= ~Oh, oh Baervar, please... (Her laughter dies down, though her shoulders still shake.) I'm not saying that one out loud.~
	== IMOEN25J ~Kinda glad yer not! That got a bit scary for a moment...~
	== AERIE25J ~This feels great! It is so liberating. It's as if- as if part of me was still in that cage all this time, letting the old, rotten memory atrophy and fester. (She grins, eyebrows arching up in sweet innocence.) You know, like my wings did? Before they lopped them off?~
	== IMOEN25J ~Hah! Alright, okay, you can stop now, it's getting creepy...~
	== AERIE25J ~(Aerie simply smiles for a moment, mischief turning to affection. She steps forward and hugs Imoen close.)~
	== IMOEN25J ~Ooof. You're way too strong for a skinny elf, ya know that?~
	== AERIE25J ~Thank you, Imoen. You are the best friend anyone could hope for. I love you.~
END
	IF ~Global("IRTAerieTalkSexualTension","GLOBAL",1)~ THEN EXTERN IMOEN25J IA6TalkChain
	IF ~Global("ImoenRomanceActive","GLOBAL",2)~ THEN EXTERN IMOEN25J IA6RomChain2



// This chain is for when ImoenRomanceActive = 2

CHAIN IMOEN25J IA6RomChain2
	~Aw, jeeez... yer gonna make me cry now.~ DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~
	= ~I love you too, Airy-head.~
	== BVICON25 IF ~IsValidForPartyDialog("Viconia")~ THEN ~This is more than I can stand. I am about to retch.~
	== BEDWIN25 IF ~IsValidForPartyDialog("Edwin")~ THEN ~Have you no concept of what is appropriate to do in public? Save it for camp, where I won't have to listen to this saccharine drivel!~
	== BKORGA25 IF ~IsValidForPartyDialog("Korgan")~ THEN ~Aye, 'urry up and get on with the kissin' now, lasses. Put on a good show ta make up fer all this bloody lovey-dovey nonsense.~
	== BSAREV25 IF ~IsValidForPartyDialog("Sarevok")~ THEN ~This is the most grievous torture I've ever had to endure.~
	== AERIE25J ~(Aerie takes a deep breath, daintily wiping tears from her cheeks. There's a faint smile on her lips and a sparkling cheer to her eyes.)~
EXIT


// This chain is for when IRTAerieKissSexualTension = 1

CHAIN AERIE25J IA6KissChain
	~They might have caged me for months, but... but at least... (Aerie can't stop giggling, laughter coming in short bursts between quickly drawn breaths. She gives in to it, and soon she's tossed her head back, one hand on her chest. Imoen is simply looking at her, an adoring smile on her lips.)~ DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~
	== IMOEN25J ~(As if in a trance, Imoen steps forward. Her fingertips delicately touch Aerie's hair, then graze the Avariel's cheek. Her hand slips behind Aerie's nape. The elf looks at her friend through laugh-squinted eyes, still rapt in mirth.)~
	= ~(Imoen leans in and joins her lips to Aerie's.)~
	== AERIE25J ~(Aerie's eyes widen. At first there is confusion, then it turns to distress. She places her hands on Imoen's shoulders and gently, tactfully pushes away.)~
	== IMOEN25J ~(Imoen seems startled, taking a few, tiny steps back. She meets Aerie's eyes, then looks away.) Uh-~
	== AERIE25J ~Imoen? What...~
	== IMOEN25J ~Oh sweet Tymora. (Imoen looks flustered beyond description.) That didn't just happen. This isn't happening.~
	== AERIE25J ~Imoen, I'm... I'm sorry.~
	== IMOEN25J ~Oh Gods. *I'm* so sorry. (She turns away.) It won't happen again. Please forgive me.~
	== AERIE25J ~(Aerie's hand reaches out, almost touches Imoen's shoulder, stops. The hand falls limp to her side.) Imoen...~
	== IMOEN25J ~That was really weird and I'm really, really sorry. I'll leave you alone now.~
	== AERIE25J ~No, wait...~
	== IMOEN25J ~(Imoen walks away, staying as far from Aerie as party dynamics will allow. Aerie doesn't try to follow.)~ DO ~RunAwayFrom("Aerie",40)~
	== BJAHEI25 IF ~IsValidForPartyDialog("Jaheira")~ THEN ~(Jaheira is shaking her head.) Foolish, foolish girl.~
	== BNALIA25 IF ~IsValidForPartyDialog("Nalia")~ THEN ~Well, *that* went to unexpected places...~
	== BMAZZY25 IF ~!IsValidForPartyDialog("Nalia") IsValidForPartyDialog("Mazzy")~ THEN ~Well, *that* went to unexpected places...~
	== BEDWIN25 IF ~IsValidForPartyDialog("Edwin")~ THEN ~Have you no concept of what is appropriate in public? Save it for camp, where I won't have to bear witness to this foolishness!~
	== BVICON25 IF ~IsValidForPartyDialog("Viconia")~ THEN ~This is more than I can stand. I am about to retch.~
	== BKORGA25 IF ~IsValidForPartyDialog("Korgan")~ THEN ~Come on, 'urry up and chase 'er and get on with the kissin' now, lasses. Put on a good show ta make up fer all this bloody nonsense.~
	== BSAREV25 IF ~IsValidForPartyDialog("Sarevok")~ THEN ~This is the most grievous torture I've ever had to endure.~
EXIT


// This chain is for when IRTAerieTalkSexualTension = 1

CHAIN IMOEN25J IA6TalkChain
	~(Imoen's face suddenly flusters all the way to her hairline. Her breath quickens.)~ DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~
	= ~F- friend, huh?~
	== AERIE25J ~I'm sorry?~
	== IMOEN25J IF ~NumInPartyGT(3)~ THEN ~(Imoen's gaze darts everywhere but back at Aerie. Her lips press together.) Alright, so... I got something to tell you. I kinda wanted to do it in private, but whatever, there's no point. Nothing stays private for long in this group, anyway.~
	== IMOEN25J IF ~!NumInPartyGT(3)~ THEN ~(Imoen's gaze darts everywhere but back at Aerie. Her lips press together.) Alright, so... I got something to tell you. I kinda wanted to do it in private, but whatever, there's no point. <CHARNAME> already knows and <PRO_HESHE> has a way of finding things out, anyway.~
	== IMOEN25J IF ~Global("IRTAerieTalkPlayerAdvice","GLOBAL",1)~ THEN ~But I've got this speech, and I gotta get through it, okay? And if you don't like it, you can blame <CHARNAME>, because <CHARNAME> told me I should tell you.~
	== IMOEN25J IF ~!Global("IRTAerieTalkPlayerAdvice","GLOBAL",1)~ THEN ~But I've got this speech, and I gotta get through it, okay? And if you don't like it, well, you can blame <CHARNAME>, because <CHARNAME> refused to give any useful advice.~
	== AERIE25J ~All... right? Th- this is a bit scary. What is it?~
	== IMOEN25J ~No, it's nothing bad! Well, not... not really. You might think it's bad, but it really is not, and I'd never let it- (Imoen interrupts herself with a cringe and looks up.)~
	= ~To Hell with it. Look, I'm... I'm attracted to you. As more than a friend. How do you feel about that? Just be honest.~
	== AERIE25J ~(Aerie's eyes widen. Briefly there is confused shock, but soon it turns to distress.) Oh, Imoen... I thought... I thought I was imagining things. I was afraid you would say this...~
	== IMOEN25J ~Hah. Afraid, huh.~
	== AERIE25J ~I'm so sorry. I just... I don't *feel* that way about women. In a way, I- I wish I did. You are everything to me, I think *so* highly of you. Only... not that way. I can't reciprocate that kind of attraction, I'm so, so sorry...~
	== IMOEN25J ~M- maybe if... if you tried it?~
	== AERIE25J ~N- no, no. I'm- I'm certain, believe me. I wish it weren't so, I really do.~
	== IMOEN25J ~Oh.~
	== IMOEN25J ~Well. This is awkward, huh.~
	== AERIE25J ~(Aerie's voice becomes a fearful whisper.) Is this... going to be a problem between us?~
	== IMOEN25J ~No, no, absolutely not! Yeah, it'll be really awkward for a while, but I don't ever want to lose your friendship, okay? Everything can go back to normal, I'll totally, definitely get over it, and we can be happy friends forever. Pleeease tell me I didn't just gross you out and throw it all away. Please?~
	== AERIE25J ~"Grossed out"? I'm... flattered, if anything. I just feel so bad for... for disappointing you.~
	== IMOEN25J ~Hey, it's alright, I'll get over it, like I said. Yer not that hot, anyway.~
	== AERIE25J ~(Aerie laughs softly.) You can resort to as many lies as you want, I won't hold it against you.~
	== IMOEN25J ~As gracious as ever. (Imoen shuffles uncomfortably.) Well, alright, then... then I guess we should get going.~
	= ~See? Look at that. Not awkward at all.~
	== AERIE25J ~(Aerie squeezes Imoen's shoulder and walks past. Imoen follows with her eyes, then shakes her head.)~
	== BNALIA25 IF ~IsValidForPartyDialog("Nalia")~ THEN ~Well, *that* went to unexpected places...~
	== BMAZZY25 IF ~!IsValidForPartyDialog("Nalia") IsValidForPartyDialog("Mazzy")~ THEN ~Well, *that* went to unexpected places...~
	== BEDWIN25 IF ~IsValidForPartyDialog("Edwin")~ THEN ~Idiot wenches! Save it for camp, where I won't have to bear witness to this foolishness!~
	== BVICON25 IF ~IsValidForPartyDialog("Viconia")~ THEN ~That was revolting. I am about to retch.~
	== BKORGA25 IF ~IsValidForPartyDialog("Korgan")~ THEN ~Oi, not even some kissin'? Come on, 'urry up and chase 'er, lass. Put on a good show ta make up fer all this bloody nonsense.~
	== BSAREV25 IF ~IsValidForPartyDialog("Sarevok")~ THEN ~This is the most grievous torture I've ever had to endure.~
EXIT



// This is an independent chain that happens when IRTAerieIgnoreSexualTension = 1

CHAIN IF WEIGHT #800 ~Global("IRTImAerTalks","GLOBAL",11)  Global("IRTAerieIgnoreSexualTension","GLOBAL",1)~ THEN IMOEN25J IA6IgnoreChain
	~Imoen? Are you well?~ [IRAerie] DO ~SetGlobal("IRTImAerTalks","GLOBAL",12) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~
	== IMOEN25J ~Y- yeah, I'm fine. Why?~
	== AERIE25J ~You have been so quiet lately. Did I upset you, m- maybe?~
	== IMOEN25J ~What? No, of course not, don't be silly. I just have a buncha stuff in my head.~
	== AERIE25J ~Ah. Nightmares and whispers?~
	== IMOEN25J ~(Imoen huffs out a bitterly amused breath.) Among other things...~
	== AERIE25J ~I'm a bit surprised it's affecting you so much, Imoen. I thought you were used to having voices in your head before all this happened.~
	== IMOEN25J ~(Imoen arches an eyebrow and blinks. Finally her lips curve into a smile.) How long were you holdin' on to that one?~
	== AERIE25J ~Far too long! I've been waiting for you to come complaining about the Taint, like you used to. You... you've been avoiding me, and I'd love to know why.~
	== IMOEN25J ~Aerie, I... I can't talk about it. It's nothing. I'll be back to pestering you as normal in no time. Promise.~
	== AERIE25J ~(The Avariel's mouth quirks down at the corner.) You are worrying me now. I thought we could tell each other everything.~
	== IMOEN25J ~It's nothing, really! Aw, c'mon, stop giving me the puppy eyes, it's not fair and you know it.~
	== AERIE25J ~(Aerie's brow creases with hurt. Her lips tremble slightly.) I thought you were my friend...~
	== IMOEN25J ~I can't believe yer doin' this to me! *I* perfected that look, missy! I *taught you* that look, stop it!~
	== AERIE25J ~(Aerie blinks and tips her head to one side, visibly shaken. Actual tears brim over her eyelids and stream down her cheeks.)~
	== IMOEN25J ~Sweet Tymora's rack, how do you even *do* that! FINE, fine, I'll just tell you and get it over with, okay? I'm attracted to you. Okay? There, I said it. I want to kiss you *so bad* right now.~
	== AERIE25J ~(Aerie's hurt expression vanishes, replaced by wide eyes and agape mouth. She absentmindedly wipes the tears off with her hand.)~
	== IMOEN25J ~So... there. Let the awkward begin.~
	== AERIE25J ~Imoen...~
	== IMOEN25J ~You... you don't need to say anything, Aerie. I can see it all on your face.~
	== AERIE25J ~(Aerie cringes in distress. She steps forward to take Imoen's hand, but stops short at the last moment.)~
	== AERIE25J ~Imoen, I'm so sorry, please believe me. I love you more than I've ever loved anyone, but... as a friend. I'm so sorry, but I just... I don't feel *that way* about women. I wish- I wish I did, right now.~
	== AERIE25J ~Am I... am I going to lose you because of this?~
	== IMOEN25J ~No, no, absolutely not. Yeah, it'll be really awkward for a while, but I don't ever want to lose what we already have. It's what I was workin' on before your damn interrogation - I'll totally, definitely get over it, everything'll go back to normal, and we can be happy friends forever.~
	= ~Pleeease tell me I didn't just gross you out and throw it all away. Please?~
	== AERIE25J ~"Grossed out"? I'm... flattered, if anything. I just feel so bad for... for disappointing you.~
	== IMOEN25J ~It's... it's alright. I'll be alright. I'll get over it, like I said. (Imoen smiles.) Yer not that hot, anyway.~
	== AERIE25J ~(Aerie laughs softly.) You can resort to as many lies as you want, I won't hold it against you.~
	== IMOEN25J ~As gracious as ever. (Imoen shuffles uncomfortably.) Well, alright, then... I'm glad that's over. Let's never mention it again, ever. So... we can get goin' now.~
	= ~See? Look at that. Not awkward at all.~
	== AERIE25J ~(Aerie squeezes Imoen's shoulder and walks past. Imoen follows with her eyes, then shakes her head.)~
	== BNALIA25 IF ~IsValidForPartyDialog("Nalia")~ THEN ~Well, *that* went to unexpected places...~
	== BMAZZY25 IF ~!IsValidForPartyDialog("Nalia") IsValidForPartyDialog("Mazzy")~ THEN ~Well, *that* went to unexpected places...~
	== BEDWIN25 IF ~IsValidForPartyDialog("Edwin")~ THEN ~Idiot wenches! Save it for camp, where I won't have to bear witness to this foolishness!~
	== BVICON25 IF ~IsValidForPartyDialog("Viconia")~ THEN ~That was revolting. I am about to retch.~
	== BKORGA25 IF ~IsValidForPartyDialog("Korgan")~ THEN ~Oi, not even some kissin'? Come on, 'urry up and chase 'er, lass. Put on a good show ta make up fer all this bloody nonsense.~
	== BSAREV25 IF ~IsValidForPartyDialog("Sarevok")~ THEN ~This is the most grievous torture I've ever had to endure.~
EXIT



// 7th Conversation
// Only happens if Imoen is not romanced
// Triggers right before resting, or perhaps after displaying the animation but not getting the actual rest yet. The talk actually happens in the *middle* of rest.


APPEND IMOEN25J
IF WEIGHT #800 ~Global("IRTImAerTalks","GLOBAL",13)~ IAEavesdrop
   SAY ~(The sound of hushed voices wakes you. It takes your keen senses only a moment to understand there is no danger; it is simply Imoen, speaking barely above a whisper.)~ [ IRQUIET ]
   IF ~~ THEN DO ~SetGlobal("IRTImAerWishYes","GLOBAL",1) SetGlobal("IRTImAerTalks","GLOBAL",14)~ GOTO IAEavesdropN
END

IF ~~ IAEavesdropN
   SAY ~(A different voice replies, Aerie's. The elf seems demure, while Imoen sounds impatient. You could listen in, if you strained hard enough to make out the words.)~
   ++ ~(You do your best to eavesdrop effectively.)~ DO ~SetGlobal("IRTImAerEavesdrop","GLOBAL",1)~ + IAEaveChain
   ++ ~(Eugh, not again. You roll on to your other side, get the pillow over your head and get back to sleep.)~ + IAEaveNot
END

IF ~~ THEN IAEaveNot
   SAY ~(Imoen's almost-harsh reply fades from your conscious thoughts, and soon restful, dreamless sleep claims you.)~
   IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",300) RestParty()~ EXIT
END
END

CHAIN IMOEN25J IAEaveChain
~... just nuts. It's too dangerous, let alone frivolous. What would <CHARNAME> say if I wasted that kind of spellpower on this?~ [IRAerie] DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",300)~
== AERIE25J ~I- I don't think it's frivolous. It's our lives. Our future.~
== IMOEN25J ~Our future will be full of fun and adventure regardless. I'm not gonna take the risk just so I can have icing on the cake.~
== AERIE25J ~(There is a brief pause.) So I'm icing on a cake? You are trying to seduce me already.~
== IMOEN25J ~(Imoen breathes out harshly.) Yer not gonna cute-talk me into this one. I can't believe yer even suggesting this.~
== AERIE25J ~(Another, longer pause.)~
= ~I want you to be happy.~
== IMOEN25J ~I *am* happy. Y'know what would make me real miserable, though? You turning into a drooling vegetable 'cause you felt too guilty to turn me down. Like I said, I'll get over it.~
== AERIE25J ~That's... that's a lie, Imoen.~
== IMOEN25J ~Wow, aren't you one conceited little minx.~
== AERIE25J ~No, what I mean is... you are in love with me. You can't simply ignore that. I know I couldn't...~
== IMOEN25J ~N- no, no, wait, whoa. In love? I wouldn't say so much, I just... y'know, I'm just really... y'know.~
== AERIE25J ~In love?~
== IMOEN25J ~No! That's not what's happening here, okay? I just... I fancy you, that's all. It'll pass. It will.~
== AERIE25J ~Look me in the eyes, then. Look me in the eyes and say you don't want us together. Tell me you don't want to spend your life loving me.~
= ~(There is only silence for a while.)~
= ~Say to my eyes that you don't want it just as much as I want to love you back.~
== IMOEN25J ~What's with this fascination with the eyes! Look, it's a moot point, 'cause yer not into the ladies, and there's no way I'd use a freakin' Wish spell on you, so this conversation is over.~
== AERIE25J ~I don't know why you are so concerned. We won't rush into it. We will do the research and make sure we are getting everything right.~
== IMOEN25J ~You don't understand! It's not within the tried and true parameters, it falls on crapshot territory. Who knows what might happen to you? To us all? Reality is a devious thing. Try to reshape it all willy-nilly and yer just asking for all sorts of disaster.~
== AERIE25J ~You know, I will eventually catch up to your skill in magic. I could cast it myself, then.~
== IMOEN25J ~The risk is the same! Aren't you listening? Why aren't you listening to me?~
== AERIE25J ~I am listening, Imoen. I simply think the risk is worth it.~
== IMOEN25J ~What *I* think is that yer a stubborn fairy-faced lummox.~
== AERIE25J ~Remember what we talked about? Becoming old maidens, always waiting for that perfect knight in shining armor?~
= ~Well... you are my knight. Who is going to come into my life and sweep me off my feet? They all pale in comparison to you. But I can't feel that attraction you feel, I just can't. So I want to fix it.~
== IMOEN25J ~(More silence.)~
= ~Damn you and your silver tongue. (Imoen's voice sounds slightly choked.) It was much easier to argue with you when you were a shy little butterfly.~
== AERIE25J ~You taught me better. You let me find myself, become the person I always wished I could be. And now that you told me the way you feel, the more I think about it...~
= ~There is this chance we could become much more than friends, and... I want that. Or rather, I *want* to want that. So I am willing to take a risk for it.~
== IMOEN25J ~(There is a long stretch of silence, broken only by the soft rustling of clothes. Finally, you hear a sniff.)~
= ~(Imoen's whisper is so quiet that you can barely hear it.)~
= ~I love you, Aerie. I could never forgive myself if something went wrong. Messing with your free will... it has "bad idea" written all over it.~
== AERIE25J ~(More rustling of clothes.)~
= ~It's not affecting my free will. I won't wish to fall in love with you. I wish to *be able* to feel the same way you do.~
= ~We're no fools, Imoen. Every day we wield life and death in our hands. We will wait until all this is over, and then... we will be careful.~
== IMOEN25J ~(Imoen remains quiet.)~
== AERIE25J ~Will you think about it?~
== IMOEN25J ~...~
= ~I'll think about it, you silver-tongued temptress.~
== AERIE25J ~Look who's talking...~
== IMOEN25J ~Just go get some rest. You won't get four hours before your turn on watch at this rate, and I'm not letting you off the hook again. I might kick you into consciousness, just to teach ya a lesson.~
== AERIE25J ~(You hear the telling sounds of someone getting up from a sitting position.)~
= ~I'm glad we talked. Don't... don't get over me yet. With luck, you won't have to.~
== IMOEN25J ~Just go do your trance thing, Aerie.~
= ~(For a while there's only the noises of someone quietly moving around, disrobing, handling blankets. You've almost drifted back to sleep when Imoen's whisper reaches your ears, soft and doleful.)~
= ~I don't think I can...~
END
 IF ~~ THEN DO ~RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",300) RestParty()~ EXIT



// 8th Conversation
// Imoen approaches you for more advice.

APPEND IMOEN25J
IF WEIGHT #800 ~Global("IRTImAerTalks","GLOBAL",15) !Global("ImoenRomanceActive","GLOBAL",2)~ IAWish
   SAY ~Can I bug you again, <CHARNAME>?~ [ IRQUIET ]
   IF ~~ THEN DO ~SetGlobal("IRTImAerTalks","GLOBAL",16)~ GOTO IAWishN
END

IF ~~ IAWishN
   SAY ~Aerie's driving me insane.~ [IRAerie]
   ++ ~Any time, Imoen.~ + IAWishYes2
   + ~Global("IRTImAerEavesdrop","GLOBAL",1)~ + ~Using a Wish spell to make her attracted to women? Quite the idea.~ + IAWishEave
   ++ ~If you must. The babysitting never ends.~ + IAWishYes1
   ++ ~No, absolutely not. I'm done with your drama.~ + IAWishNo
END

IF ~~ IAWishNo
   SAY ~Hah! Y'know what? I'd normally get upset but I really can't blame ya.~
   = ~S'alright, we'll figure it out one way or another. *Quietly*.~
   IF ~~ THEN DO ~SetGlobal("IRTImAerWishYes","GLOBAL",1) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAWishYes1
   SAY ~Hah! Y'know what? I'd normally give you some attitude but I really can't blame ya.~
   IF ~~ THEN GOTO IAWishEx
END

IF ~~ IAWishYes2
   SAY ~Of course you'd say that.~
   IF ~~ THEN GOTO IAWishEx
END

IF ~~ IAWishEave
   SAY ~How'd you- oh, you sneaky troll ears!~
   = ~I tellya, nothing stays private 'round here. Might as well talk in front of everyone all the time.~
   IF ~~ THEN GOTO IAWishOpinion
END

IF ~~ THEN IAWishEx
   SAY ~Alright, so... this one's pretty crazy. I'm pretty much counting on you laughin' me off here. I'll even join ya.~
   = ~So she knows I... y'know. Fancy her. So, I'm standing watch a while ago, she comes over, I'm all like, great, here comes the speech - "Imoen, I can't do this, it's too weird, blah blah blah."~
   = ~But it's not like that. She's all shy, asking me to do something for her. Ya wanna know what? Get ready.~
   = ~She asks me if I could cast a Wish spell, and wish for her to be attracted to women so we can be together. Just like that. Can you believe it?~
   = ~It's crazy, right? Well, you wouldn't suspect how persuasive that elven vixen is. I'm, hah hah... I'm mighty tempted, considering. Of course, we'd do it after... y'know, all the Bhaal business. If we *were* to do it. I'd actually appreciate it if, uh... if you talked me out of it?~
   IF ~~ THEN GOTO IAWishOpinion
END

IF ~~ IAWishOpinion
   SAY ~So what's your take, then?~
   ++ ~(Burst out laughing.)~ + IAWishOp5
   ++ ~Well, what are the risks, exactly?~ + IAWishInfo
   ++ ~I'd have never thought about it. It's genius, Imoen.~ + IAWishOp6
   ++ ~It's smart, and it sounds like it would work. You should do it.~ + IAWishOp4
   ++ ~I don't know, it's quite risky. You shouldn't do it.~ + IAWishOp3
   ++ ~It's the most deranged, reckless and ridiculous idea I ever heard. Under no circumstance should you let this happen.~ + IAWishOp2
   ++ ~It's your lives. You need to decide for yourself in this.~ + IAWishOp1
END

IF ~~ IAWishInfo
   SAY ~The risks? Well, a Wish spell is crazy complicated, and deceptively simple at the same time. You basically wish for whatever you want, and make reality bend to your will. If you wish for simple material things, or for things that have to do with the magic you know, there's no real risk. You can travel back in time and undo a recent mistake, too. Pretty nifty.~
   = ~If you go out of those parameters, though... oh! Y'know the story about the street urchin that finds a lamp and rubs it and gets three wishes? That's perfect to explain.~
   = ~Think of reality as a really, really twisted djinni that resents you for pestering her. If you ask for something weird or out of the normal purview, she'll try to screw you over any way she can. You have to know *exactly* what you want, and leave no wiggle room at all, or your wish will be twisted against you.~
   = ~I... I don't know if I have that kind of focus. There are SO many stories and actual accounts of Wish spells gone wrong. I don't wanna add to them.~
   IF ~~ THEN GOTO IAWishFinal
END

IF ~~ IAWishFinal
   SAY ~So... yeah. I've my doubts. Aerie makes a compelling argument, though. Her and her stupid lithe midriff...~
   ++ ~It's a clever idea and it sounds like it would work. You should do it.~ + IAWishOp4
   ++ ~I don't know, it's quite risky. You shouldn't do it.~ + IAWishOp3
   ++ ~This is the most deranged, reckless and ridiculous idea I could think of. Under no circumstance should you let this happen.~ + IAWishOp2
   ++ ~It's your lives. You need to decide for yourself in this.~ + IAWishOp1
END

IF ~~ IAWishOp1
   SAY ~Ooogh, come on, I'm looking for an easy way out here! If things go wrong, I can always blame you for talking me into it, dontcha see?~
   = ~Fine, okay. Bleurgh. Somehow I knew you'd say something like that...~
   = ~Thanks for listening anyway, lil' <PRO_BROTHERSISTER>. I really do appreciate it. We'll figure it out ourselves... *quietly*.~
   IF ~~ THEN DO ~SetGlobal("IRTImAerWishYes","GLOBAL",1) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAWishOp2
   SAY ~Wow. That's... very final of you.~
   IF ~~ THEN GOTO IAWishOpNo
END

IF ~~ IAWishOpNo
   SAY ~Y'know, I must be dumb, because I feel disappointed to hear that. Part of me wanted to hear it was okay to take such a stupid risk, it seems.~
   = ~But you're absolutely right. It's crazy. It could ruin her life or outright kill her. There's no way I'd go for it.~
   = ~Thanks a lot for being honest and talkin' me out of it, <CHARNAME>. I knew I could count on you.~
   = ~I'll talk it over with her... *quietly*.~
   IF ~~ THEN DO ~SetGlobal("IRTImAerWishYes","GLOBAL",2) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAWishOp3
   SAY ~Yeah... yeah, you're right.~
   IF ~~ THEN GOTO IAWishOpNo
END

IF ~~ IAWishOp4
   SAY ~Really? You think so?~
   IF ~~ THEN GOTO IAWishOpYes
END

IF ~~ IAWishOpYes
   SAY ~Y'know, I must be dumb, because right now I'm so glad you feel that way. I just... I *really* want to be with her, and it's making me stupid. The more she talked yesterday, the more I realized I'm completely screwed. I... I love her, <CHARNAME>. I'm in love with her.~
   = ~Damn that elf and her clever little mouth. I used to run circles around her, I've no idea what happened. Anyway, thanks for listening, and thanks for believing in me. In us.~
   = ~Wish me luck, lil' <PRO_BROTHERSISTER>. I'll talk it over with her... *quietly*.~
   IF ~~ THEN DO ~SetGlobal("IRTImAerWishYes","GLOBAL",1) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAWishOp5
   SAY ~(Imoen blows out her breath in a horse-like chortle as you laugh.) I can't even get mad here. Go ahead, let it all out. I don't blame ya.~
   = ~I'm gonna go out on a limb and assume you don't think it's the best idea ever.~
   ++ ~No, actually, I find it brilliant! But all the drama around it really makes me laugh.~ + IAWishLaugh4
   ++ ~It's the most ridiculous, reckless idea I ever heard! For a moment I thought it was one of your pranks.~ + IAWishLaugh3
   ++ ~I don't know about the idea - I just find it hilarious that she wants to turn gay for you.~ + IAWishLaugh2
   ++ ~Alright, let me get a hold of myself. What are the risks, exactly?~ + IAWishInfo
   ++ ~(Simply walk away, still laughing and shaking your head.)~ + IAWishLaugh1
END

IF ~~ IAWishLaugh1
   SAY ~(Imoen sighs, watching you step away from her.)~
   = ~Yeah, okay. I get it.~
   IF ~~ THEN DO ~SetGlobal("IRTImAerWishYes","GLOBAL",2) RealSetGlobalTimer("IRTAerieImoenTimer","GLOBAL",1200)~ EXIT
END

IF ~~ IAWishLaugh2
   SAY ~Hah. I suppose I should be... flattered? She's weird, you know. I doubt anyone else would even consider stuff like this.~
   IF ~~ THEN GOTO IAWishFinal
END

IF ~~ IAWishLaugh3
   SAY ~I wish it were. Only a month ago I could've never imagined I'd be in this situation.~
   IF ~~ THEN GOTO IAWishOpNo
END

IF ~~ IAWishLaugh4
   SAY ~Ha ha, brilliant? Dunno if I'd go that far...~
   IF ~~ THEN GOTO IAWishOpYes
END

IF ~~ IAWishOp6
   SAY ~Ha ha, genius? Dunno if I'd go that far...~
   IF ~~ THEN GOTO IAWishOpYes
END
END


// Misc: If the player ever breaks off the relationship with Imoen

//// Triggers after a while (5 real minutes?) of IRTImoenDumped = 1
//might leave this as banter triggerable for now
CHAIN IF WEIGHT #800 ~Global("IRTImoenDumped","GLOBAL",1) Global("IRTAerieComfortsDumpedImoen","GLOBAL",1)~ THEN AERIE25J IAConfortChain
	~Imoen, I'm so sorry. Can I... can I do anything?~ [ IRQUIET ] DO ~SetGlobal("IRTAerieComfortsDumpedImoen","GLOBAL",2)~
	== IMOEN25J ~I'll be fine. I'll get over it.~
	== AERIE25J ~You can't simply get over something like this. Talk to me.~
	== IMOEN25J ~Just... stop looking at me like that, please. I can't do this right now. I need to keep together, get things done. I can't think about it or I'll fall apart, understand?~
	== AERIE25J ~Y- yes, of course. Sorry.~
	= ~But... any time at all, Imoen. Wake me up if you have to.~
	== IMOEN25J ~Okay. Okay...~
EXIT

