//exitting underdark, first talk

ADD_TRANS_ACTION C6ELHAN2
BEGIN 54 63 END
BEGIN 0 END
~RealSetGlobalTimer("MRExitCommentTimer","GLOBAL",5)~

APPEND IMOEN2J

	IF ~Global("MRExitComment","AR2500",1)  GlobalGT("MRLoveTalk","GLOBAL",9)~ THEN BEGIN MRCampfire
		SAY ~I can't believe we are finally outta that hellhole, ugh... (She takes a deep breath) About time we got rid of that awful musty smell.~ [ MRImRom3 ]
		IF ~~ THEN DO ~SetGlobal("MRExitComment","AR2500",2) SetGlobal("MRCampPrompt","GLOBAL",5)~ GOTO MRCampfire2
	END
	
	IF ~Global("MRExitComment","AR2500",1)  !GlobalGT("MRLoveTalk","GLOBAL",9)~ THEN BEGIN MRCampfire
		SAY ~Finally out of that hellhole! I've had enough giant spiders to last me seven lifetimes. (Imoen takes in a deep breath.)~
		 =~Mmh, that's so nice. In the stories they never say just how bad the Underdark smells.~ [ IRQUIET ]
		IF ~~ THEN DO ~SetGlobal("MRExitComment","AR2500",2)~ GOTO MRGladeN
	END
	
	IF ~~ THEN MRGladeN
	SAY ~This glade sure is a welcome sight after all the gross darkness. I could spend the whole day just walking among the trees, it's so nice here.~
	= ~Oh well. Maybe later, when things aren't so crazy.~
	IF ~~ THEN EXIT
END
END


CHAIN IMOEN2J MRCampfire2
	~Y'know <CHARNAME>, I'd really enjoy resting somewhere green and beautiful for a change... wouldn't you?~
	==JAHEIRAJ IF ~IsValidForPartyDialog("Jaheira")~ THEN ~I fully agree, <CHARNAME>. It seems so long since I was last in contact with pure nature that I had forgotten its scent.~
	==AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~Ahh, yes, of course! This place is so peaceful, it reminds me of the forest of my youth. Let's stay all night, please!~
	==CERNDJ IF ~IsValidForPartyDialog("Cernd")~ THEN ~The peace of the forest is always welcome. Taking a break from what seems to be a never-ending quest might be a wise option to refresh both our minds and bodies.~
	==NALIAJ IF ~IsValidForPartyDialog("Nalia")~ THEN ~Great idea I'd say! I need some time to relax after this whole drow experience.~
END IMOEN2J MRCampfire3

APPEND IMOEN2J
	IF ~~ THEN BEGIN MRCampfire3
		SAY ~I think... hmm. (Imoen looks around her) This seems quite a neat spot, huh?~
		=
		~So, what if we spend a night here 'fore we go get this 'Lanthorn' thing? After all we've done, we can wait a few hours longer before we set off after Bodhi, right?~
		IF ~IsValidForPartyDialog("Viconia")~ THEN REPLY ~Let's do it. I'm exhausted after all that darkness and cruelty and drow deceit. No offense intended, Viconia.~ EXTERN VICONIJ MRCampfire3
		IF ~!IsValidForPartyDialog("Viconia")~ THEN REPLY ~Let's do it. I'm exhausted after all that darkness and cruelty and drow deceit.~ GOTO MRCampfireYes
		++ ~Alright, let's spend the night here.~ GOTO MRCampfireYes
		++ ~I don't think so. I'd prefer to get to Bodhi, and *then* we can do whatever you want to do.~ GOTO MRCampfireNo
		++ ~Haven't I told you that when you have an idea, you should tell it to the nearest rock and leave ME alone?~ GOTO MRCampfireCruel
	END
END

APPEND ~VICONIJ~
	IF ~~ THEN BEGIN MRCampfire3
		SAY ~I would never take offense from one such as *you*, kivvil. You are too far beneath my notice for me to care.~
		IF ~~ THEN EXTERN IMOEN2J MRCampfireYes
	END
END

APPEND IMOEN2J

	IF ~~ THEN BEGIN MRCampfireCruel
		SAY ~Yeah, but I thought you were babbling stupidly as always. How could I know it was the first time you were actually aware of what you were saying?~
		= ~... Jerk.~
		IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",3)~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfireNo
		SAY ~(She shrugs) If you insist. But I think yer losin' a great opportunity...~
		IF ~~ THEN DO ~SetGlobal("MRThinkCampAfterBodhi","GLOBAL",1) SetGlobal("MRCampPrompt","GLOBAL",5)~ EXIT
	END

	IF ~~ THEN BEGIN MRCampfireYes
		SAY ~Great! This is gonna be awesome!~
		IF ~~ THEN DO ~SetGlobal("MRCampfire","GLOBAL",1) ~
		EXIT
	END
END

APPEND IMOEN2J
IF  ~Global("MRCampPrompt","GLOBAL",3)~ THEN MRArrivedAtGlade
	SAY ~Ooh, I love this place. It's great to be here again.~
	= ~There's a real nice spot where we can set up camp when yer ready. Just say the word!~
	IF ~~ THEN DO ~SetGlobal("MRCampPrompt","GLOBAL",4)~ EXIT
END
END

