// This is a conversation initiated through PID by a male protagonist
// who wants to talk children with a romanced Imoen.
// Available after first of Senda/Abazigal dead and solar talk


// Trigger global: IRTPregnancyTalk = 1
// A global is set here that is taken into account for epilogues if the main character is male
// "IRTInSyncChildren","GLOBAL",1
// It's only set if the player and Imoen have the same views on the issue

/*
PID option:
+ ~Global("IRTPregnancyTalk","GLOBAL",1)~ + ~Could we talk for a minute? What do you think about ever having children?~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) SetGlobal("IRTPregnancyTalk","GLOBAL",2)~ GOTO Preg1
*/


APPEND IMOEN25J
IF ~~ Preg1
   SAY ~Whoa. Um... y- you wanna do this now?~
   = ~I kinda... well, I figured we shouldn't even worry about that stuff until we get the Bhaal nonsense sorted out.~
   + ~CheckStatGT(Player1,10,INT)~ + ~Ah. You have a point there. Why worry about the future when the present is in constant flux?~ + PregEnd2
   + ~!CheckStatGT(Player1,10,INT)~ + ~Ah. Makes sense. We should decide once we survive this mess.~ + PregEnd2
   ++ ~I see. You're worried I might go on to become a god, leaving you behind to raise our child alone?~ + PregWorry
   ++ ~I like to plan for the future anyway. I would like to raise children with you.~ + PregYes
   ++ ~I like to plan for the future anyway. I don't think I want children in our life.~ + PregNo
   ++ ~I like to plan for the future anyway, and I can't make up my mind. How do you feel about it?~ + PregDoubt
   ++ ~Works for me. Let's get to work, then.~ + PregEnd
END

IF ~~ PregEnd
   SAY ~(Imoen nods, clear acceptance on her face.)~
   IF ~~ THEN EXIT
END

IF ~~ PregEnd2
   SAY ~(Imoen nods.) My thoughts exactly.~
   IF ~~ THEN EXIT
END

IF ~~ PregDoubt
   SAY ~(There is clear relief on Imoen's features.) It's up to me? Thank Mystra.~
   IF ~~ THEN DO ~SetGlobal("IRTInSyncChildren","GLOBAL",1)~ GOTO PregAgree
END

IF ~~ PregNo
   SAY ~(There is clear relief on Imoen's features.) Oh, thank Mystra. For a while I was worried you'd be all into that, and it'd turn into this big, fat argument that'd break us apart...~
   IF ~~ THEN DO ~SetGlobal("IRTInSyncChildren","GLOBAL",1)~ GOTO PregAgree
END

IF ~~ PregYes
   SAY ~(Imoen cringes at your words.) Ah, y'see... there's, um. There's a bit of a problem with that.~
   IF ~~ THEN GOTO PregDisagree
END

IF ~~ PregAgree
   SAY ~I don't want children, <CHARNAME>. I really, *really* don't want children.~
   ++ ~Great! We're on the same page, then. No need to ever bring it up again.~ + PregAgree5
   ++ ~I'm glad. I want to adventure, travel and have fun, and a child would only get in the way of that.~ + PregAgree4
   ++ ~I can see why. Our child would only be a target, and a way to get to us. We couldn't afford it.~ + PregAgree3
   ++ ~Good. I despise children.~ + PregAgree2
   ++ ~That's a lot of conviction about it. Why do you feel so strongly?~ + PregAgree1
   ++ ~(Shrug.) I'm fine either way, really.~ + PregAgree0
END

IF ~~ PregAgree0
   SAY ~I'm so glad. After all we've seen, it's hard to imagine why anyone would *want* kids.~
   IF ~~ THEN GOTO PregReasonAgree
END

IF ~~ PregAgree1
   SAY ~Oh boy, besides the obvious, I guess yer askin'? Well, after all we've seen, it's hard to imagine why anyone would *want* kids.~
   IF ~~ THEN GOTO PregReasonAgree
END

IF ~~ PregAgree2
   SAY ~Hah, well, I wouldn't go that far, but... it's just- just not my thing. Awesome Aunty Imoen? Sure. Dearest mommy? (Imoen shudders, her lower lip curling involuntarily.) Yeugh, no thanks.~
   IF ~~ THEN GOTO PregReasonAgree
END

IF ~~ PregAgree3
   SAY ~Yeah, well said. I hadn't even considered that.~
   IF ~~ THEN GOTO PregReasonAgree
END

IF ~~ PregAgree4
   SAY ~Oh, Gods, YES. I'm so happy you feel the same way.~
   IF ~~ THEN GOTO PregReasonAgree
END

IF ~~ PregAgree5
   SAY ~Wow, that was so easy. (Imoen leans in and gives you a quick kiss.) I love you, <CHARNAME>.~
   = ~Now let's go get some work done!~
   IF ~~ THEN EXIT
END

IF ~~ PregReasonAgree
   SAY ~Y'know what I think every time I see parents all worried about their children, goin' out of their way to keep them safe and all that? I think, "what an awful burden to have." I think, "you'll never see me tied up to a kid like that."~
   = ~It's not that I don't like them or anything, it's just... motherhood? Yeugh. Not for me.~
   = ~(Imoen smiles at you with complicity.) Wow, that was so easy! (She leans in for a kiss.) I love you, <CHARNAME>.~
   = ~Now let's go get some work done!~
   IF ~~ THEN EXIT
END

IF ~~ PregReasonDisagree
   SAY ~Y'know what I think every time I see parents all worried about their children, goin' out of their way to keep them safe and all that? I think, "what an awful burden to have." I think, "you'll never see me tied up to a kid like that."~
   = ~It's not that I don't like them or anything, it's just... motherhood? Yeugh. Not for me.~
   ++ ~That's so selfish. I didn't realize you were such a selfish person.~ + PregReasonArg2
   ++ ~It doesn't have to be like that. We can raise a child on the road, educate him or her right, and there's no question that we'll be able to protect them easily.~ + PregReasonArg1
   ++ ~You believe that now, but you'll change your mind in the future, I guarantee you.~ + PregBioClock
   ++ ~You clearly feel very strongly about this, and I understand. I can live without children, as long as it's with you.~ + PregDisagree3
   ++ ~But having children is a woman's mission in life. How could you not want that?~ + PregDisagree2
   ++ ~That's outrageous. I want a family, but you don't? Imoen, we... we're clearly not compatible.~ + PregDisagree1
END

IF ~~ PregBioClock
   SAY ~Oh, is that so? Gee, yer so full of insight on the way my mind works. Clearly you've figured out exactly how I'm supposed to feel, so I guess I don't have to work at it anymore.~
   = ~I'm not sayin' all this on a whim, <CHARNAME>. I've known for some time, and I just *know* I'll always feel this way.~
   = ~I... am *not*... mother material. It's just not happening.~
   ++ ~But that's so selfish! I didn't realize you were such a selfish person.~ + PregReasonArg2
   ++ ~You imagine the worst case scenario, though. We can raise a child on the road, educate him or her right, and there's no question that we'll be able to protect them easily.~ + PregReasonArg1
   ++ ~You clearly feel very strongly about this, and I understand. I can live without children, as long as it's with you.~ + PregDisagree3
   ++ ~That's outrageous. I want a family, but you don't? Imoen, we... we're clearly not compatible.~ + PregDisagree1
END

IF ~~ PregReasonArg1
   SAY ~Y- yeah! (Her reply is laced with mirthless laughter.) Yeah, and the boy will learn Celestial and sing powerful ballads to kings and queens! He'll be the spittin' image of his daddy, make'im proud on all things and never talk back!~
   = ~(Imoen snorts.) Yer livin' in a fantasy land if you think it'd be so easy. That kid will be a major pain in my arse for ten years, then become a bratty teenager that will always know better than us, and then go off in some hare-brained adventure and get him or herself killed - if it doesn't get *us* killed before then.~
   = ~No. No, there's no way I'd want that in my future. Even in the best case scenario you envision, it's a huge hassle that I don't have the stomach for.~
   ++ ~But that's so selfish! I didn't realize you were such a selfish person.~ + PregReasonArg2
   ++ ~A hassle? It's rearing a child, Imoen. A grand challenge, but extremely rewarding. Part of our legacy for the future.~ + PregReasonArg3
   ++ ~You clearly feel very strongly about this. I understand, Imoen. I can live without children, as long as it's with you.~ + PregDisagree3
   ++ ~That's outrageous. I want a family, but you don't? Imoen, we... we're clearly not compatible.~ + PregDisagree1
END

IF ~~ PregReasonArg2
   SAY ~(Her eyes widen with amused disbelief.) Selfish? Why is it selfish? The kid isn't born, it's not like I'm mistreating the damn thing. Why is having children such an obligation in your head?~
   = ~Or, wait - I guess it's selfish toward you? Like, I'm being selfish with my life by not ruining it with a fifteen-year-long-plus burden?~
   = ~I've given you my life, <CHARNAME>. And you gave it back to me in Amn. I think we'll be even by the time the Bhaal business is over with. I won't owe you a damn thing if we survive, and *definitely* will not owe you any offspring.~
   IF ~~ THEN GOTO PregUltimatum
END

IF ~~ PregReasonArg3
   SAY ~It might sound rewarding to some, to you - but not me. I've a very clear idea of what I want my life to be if we survive, and a child in that life is a burden, a risk and a liability. I'll build my legacy with my own two hands, thank you - and my hands won't be able to do that if they're carryin' a poop factory.~
   = ~<CHARNAME>, I get it. I get that this is what you want. I'm just tryin' to tell you... that's not what *I* want.~
   IF ~~ THEN GOTO PregUltimatum
END

IF ~~ PregDisagree
   SAY ~I don't want children, <CHARNAME>. I really, *really* don't want children.~
   ++ ~What? Why?~ + PregDisagree4
   ++ ~Oh, alright. It's not set in stone, you know. I can live without children, as long as it's with you.~ + PregDisagree3
   ++ ~But having children is a woman's mission in life. How could you not want that?~ + PregDisagree2
   ++ ~That's outrageous. I want a family, but you don't? Imoen, we... we're clearly not compatible.~ + PregDisagree1
END

IF ~~ PregDisagree1
   SAY ~(Imoen knits her brow, tiny creases of worry appearing above the bridge of her nose.)~
   = ~I didn't want to make an issue about it. I love you, <CHARNAME>. I don't want this to end, I really don't. But I can't expect you to change your mind on this, and I sure as Hell won't.~
   IF ~~ THEN GOTO PregUltimatum
END

IF ~~ PregUltimatum
   SAY ~It's... it's a problem for us. I know. I don't know what to say.~
   ++ ~Really? There's nothing I can say to change your mind? This... this can't be the end of what we have.~ + PregUlti5
   ++ ~No, wait, back up a bit. It's not set in stone. If the choice is either children or you, I choose you.~ + PregUlti4
   ++ ~Can't you make this sacrifice for the sake of our relationship?~ + PregUlti3
   ++ ~(Sigh.) So be it. It was great while it lasted, but I'm sure we can agree that there is no future for us together.~ + PregUlti2
   ++ ~I can't believe it! You should have told me earlier! Everything we've done, all the work we put into our relationship - all for nothing!~ + PregUlti1
END

IF ~~ PregUlti1
   SAY ~(Imoen seems to shrink at your words.) I'm sorry. If it's a dealbreaker for you... I'm sorry.~
   ++ ~Are you *sure* there's nothing I can say to change your mind?~ + PregUlti1Loop
   ++ ~Let's... let's cool down and think about it. I don't want to lose you, Imoen. If the choice is either children or you, I choose you.~ + PregUlti4
   ++ ~(Sigh.) So be it. It was great while it lasted, but I'm sure we can agree that there is no future for us together.~ + PregUlti2
END

IF ~~ PregUlti1Loop
   SAY ~(There is honest sorrow in her gaze.) It's not the life I want. I can't do it.~
   ++ ~Let's... let's cool down and think about it. I don't want to lose you, Imoen. If the choice is either children or you, I choose you.~ + PregUlti4
   ++ ~(Sigh.) So be it. It was great while it lasted, but I'm sure we can agree that there is no future for us together.~ + PregUlti2
END


IF ~~ PregUlti2
   SAY ~(She stares at the ground, eyes bright with moisture, distant. Her mouth curls in a pained grimace.) I... guess. I didn't... I didn't want to talk about it until after.~
   = ~(A few tears start flowing, and with one hand she wipes at her face.) But you're right, there's just... no point. It's best this way. It was too good to be true.~
   = ~I'm sure we can be friends again. Right now I... I need a moment. Excuse me.~
   IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4) RunAwayFrom(Player1,50)~ EXIT
END

IF ~~ PregUlti3
   SAY ~(Imoen's frown is a mixture of dread and disgust.) You... you want me to be miserable for years, just so you can fulfil this fantasy of yours?~
   = ~No. No, I'm sorry, but... no.~
   ++ ~Really? There's nothing I can say to change your mind? This... this can't be the end of what we have.~ + PregUlti5
   ++ ~I see. Well, I'd never force anything on you. If the choice is either children or you, I choose you.~ + PregUlti4
   ++ ~(Sigh.) So be it. It was great while it lasted, but I'm sure we can agree that there is no future for us together.~ + PregUlti2
END

IF ~~ PregUlti4
   SAY ~(She lifts her gaze from the ground, regarding you with quickly tempered hope.)~
   IF ~~ THEN GOTO PregReversal
END

IF ~~ PregReversal
   SAY ~Are you sure? Are you *absolutely* sure? I'd need you to be completely okay with it. I can't take your dreams away, just like you don't want to take away mine.~
   = ~*Please* be certain this is what you want, please...~
   ++ ~Yes, I'm sure. There is no contest between the two. It's like choosing between something nice, and something wonderful.~ + PregReversal3
   ++ ~I won't lie, I'm not certain. But I think I can get used to the idea.~ + PregReversal2
   ++ ~Does it even matter? We might be dead tomorrow. Forget about the whole thing and let's live day by day.~ + PregReversal1
   ++ ~No. No, I can't. I want a family, Imoen. I'm sorry.~ + PregUlti5a
END

IF ~~ PregReversal1
   SAY ~(Her expression is hard to read. It's ambiguous between agreement and reluctance.) That's definitely true. I'm fine with that. It was my point to begin with...~
   = ~Let's just... get some work done, then. Off to adventure we go.~
   IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-5)~ EXIT
END

IF ~~ PregReversal2
   SAY ~(Her expression is hard to read. It's ambiguous between relief and reluctance.) Well, it's... it's a start. I don't want this to end. I'm willing to give that a chance.~
   = ~(Imoen leans in and gives you a quick kiss.) I love you, <CHARNAME>.~
   = ~Now let's go get some work done!~
   IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-5)~ EXIT
END

IF ~~ PregReversal3
   SAY ~(She appears mostly relieved, but there's a hint of reluctance underneath.) That's a lovely way to put it. Hopefully we can do enough crazy things together to fill that "gotta have children" void.~
   = ~Huh. That line came out way dirtier than it sounded in my head. (Imoen leans in and gives you a quick kiss.) I love you, <CHARNAME>.~
   = ~Now let's go get some work done!~
   IF ~~ THEN EXIT
END

IF ~~ PregUlti5
   SAY ~(Dread haunts her gaze, but conviction prevails on her brow.) I'm so sorry, <CHARNAME>. I know it's not what you wanted...~
   = ~I can't have children. I won't. I'm sorry.~
   ++ ~I see. Well, I'd never force anything on you. If the choice is either children or you, I choose you.~ + PregUlti4
   ++ ~(Sigh.) So be it. It was great while it lasted, but I'm sure we can agree that there is no future for us together.~ + PregUlti2
   ++ ~You SHOULD be sorry! All the work we put into our relationship, all the hardship and angst! Was that all for nothing?~ + PregUlti5a
END

IF ~~ PregUlti5a
   SAY ~(Imoen shrinks away from your words.) I'm so sorry... (She stares at the ground, eyes bright with moisture, distant. Her mouth is curled in a pained grimace.) I didn't... I didn't want to talk about it until after.~
   = ~(A few tears start flowing, and with one hand she wipes at her face.) But it's true, there's just... no point. It's best this way. It was too good to be true.~
   = ~I hope we can be friends again. Right now I... I need a moment. Excuse me.~
   IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4) RunAwayFrom(Player1,50)~ EXIT
END

IF ~~ PregDisagree2
   SAY ~Wow. You really believe that? Please tell me you don't really believe that.~
   ++ ~Why wouldn't I? If I had the power to create life within me, I'd be delighted to fulfil that potential.~ + PregDisagree2d
   ++ ~Of course I do! Women belong in a home, rearing children and cooking my meals. You'll get there, eventually.~ + PregDisagree2c
   ++ ~No, you silly. I just wanted to see what kind of face you'd make if I said that.~ + PregDisagree2b
   ++ ~What's wrong with it?~ + PregDisagree2a
END

IF ~~ PregDisagree2a
   SAY ~What's wrong with it? What if I said that about you? Is every man's mission in life to punch everyone in the face, just because they have the equipment to do it?~
   = ~Some women are content with takin' care of a family, and that's fine, but it's not like that for everyone. It's *definitely* not like that for me.~
   ++ ~I didn't mean it like that, and it's not the same, anyway. If I had the power to create life within me, I'd be delighted to fulfil that potential.~ + PregDisagree2d
   ++ ~Ha ha, that's such nonsense! Women belong in a home, rearing children and cooking my meals. You'll get there, eventually.~ + PregDisagree2c
   ++ ~You believe that now, but you'll change your mind in the future, I guarantee you.~ + PregBioClock
   ++ ~(Burst out laughing.) Your face is priceless right now! I can't believe you took me seriously.~ + PregDisagree2b
   ++ ~Well, damn. Sorry. I understand now, when you put it like that.~ + PregDisagree2a1
END

IF ~~ PregDisagree2a1
   SAY ~Well... good. That's good. There's hope for you yet. But... we've got a problem here, love.~
   IF ~~ THEN GOTO PregDisagree1
END

IF ~~ PregDisagree2b
   SAY ~(There's a moment of confusion, then of incredulity - then Imoen shoves your shoulder.) Yer such a donkey's arse! I can't believe I fell for it!~
   = ~You made me all worried for nothing, shame on you. Ya better make up for that now by saying exactly what I wanna hear.~
   ++ ~It's such a relief you don't want kids. We're on the same page, then. No need to ever bring it up again.~ + PregAgree5
   ++ ~Well, I want to adventure, travel and have fun, and a child would only get in the way of that.~ + PregAgree4
   ++ ~We agree, Imoen. Our child would only be a target, and a way to get to us. We couldn't afford it.~ + PregAgree3
   ++ ~I despise children.~ + PregAgree2
   ++ ~Oh, I still want to have a family. You know, with you, my equal partner.~ + PregDisagree2b1
END

IF ~~ PregDisagree2b1
   SAY ~(Her expression falls.) Oh. Well, darn. Yer in for a bit of a disappointment, then...~
   IF ~~ THEN GOTO PregReasonDisagree
END

IF ~~ PregDisagree2c
   SAY ~What.~
   = ~I'm going to give you one more chance to reveal you were jokin' all along.~
   ++ ~I'm absolutely serious. How is this so hard to understand?~ + PregDumb
   ++ ~(Burst out laughing.) Your face is priceless right now! I can't believe you took me seriously.~ + PregDisagree2b
END

IF ~~ PregDumb
   SAY ~(Imoen blinks and stares, perhaps taking a few more moments to read your expression and body language, making sure you're not kidding.)~
   = ~If you believe that, then I've been insanely deluded and there's no way I'd ever want to stay in a relationship with you.~
   = ~Please tell me you're just very, very committed to this prank. Last chance before you break my heart and we stop being a thing, <CHARNAME>.~
   ++ ~Why are you this outraged? Are you not aware of the natural order of things? Women tend to their men and rear their children. Men provide for their women. What's so bad about that?~ + PregDumbN
   ++ ~(Lie.) Your face is priceless right now! I can't believe you took me seriously, I got you good!~ + PregDisagree2b
   ++ ~(You can't hold it anymore; burst out laughing.) Your face is priceless right now! I can't believe you took me seriously, I got you good!~ + PregDisagree2b
END

IF ~~ PregDumbN
   SAY ~(Her features transition through a gamut of emotions. Incredulity, into dread, into anger, into... disappointment.)~
   = ~How you've managed to keep this from me until now, I'll never know. We were way too hasty getting together, I'm seein' that much.~
   = ~(Tears come to her eyes.) I don't know if I even wanna be friends with someone that thinks that way. I... I need some time to think.~
   = ~Excuse me.~
   IF ~~ THEN DO ~SetGlobal("ImoenRomanceActive","GLOBAL",4) RunAwayFrom(Player1,50)~ EXIT
END

IF ~~ PregDisagree2d
   SAY ~Well, then, that's *your* preference, isn't it? I get your point of view, though. It's a good point, worthy. I'm not arguing that.~
   IF ~~ THEN GOTO PregReasonArg3
END

IF ~~ PregDisagree3
   SAY ~(Her eyes widen in pleased surprise.) Really?~
   IF ~~ THEN GOTO PregReversal
END

IF ~~ PregDisagree4
   SAY ~Oh boy, besides the obvious, I guess yer askin'? Well, after all we've seen, it's hard to imagine why anyone would *want* kids.~
   IF ~~ THEN GOTO PregReasonDisagree
END

IF ~~ PregWorry
   SAY ~No, not really, because there's no way you could get a child in my belly until I let ya. But you raise a huge concern that I've been tryin' not to even think about.~
   = ~I don't think we should discuss it at all. The other thing, I mean, the... the godhood thing. It's obvious what I want, I can't pretend I don't want you to stay, but I want it to be your decision, if that decision ever comes. Nothin' noble about it, either, y'know - I just don't want you blaming me for missed opportunities, years down the road. If you stay, it needs to be because you *want* to.~
   = ~Anyway, that's not what we're talkin' about, is it? You wanna know about kids.~
   ++ ~Nah, you're right, let's not worry about it for the time being. We might not even survive the day.~ + PregEnd2
   ++ ~Yes, of course. I very much plan to stick around and raise children with you.~ + PregYes
   ++ ~Yes, of course. The truth is, I don't think I want children in our life.~ + PregNo
   ++ ~Yes, of course. I can't make up my mind on the matter. I was wondering, how do you feel about it?~ + PregDoubt
   ++ ~Wait, wait a moment. What do you mean with that? "Can't do it until I let you"?~ + PregCC
END

IF ~~ PregCC
   SAY ~(Imoen rolls her eyes.) Contraceptives. D'uh.~
   = ~You didn't think we've been takin' our chances all this time, didja? Frendan pushed a bunch of nararoot into my hands as soon as I... well, y'know. "Became a real, proper young lady."~
   = ~Still keep a pouch of the stuff, even though a simple cantrip does the trick, nowadays.~
   ++ ~You've been doing *that* all this time, without consulting me? Why didn't I have say in the matter?~ + PregCC3
   ++ ~Oh, thank Sune. So there's nothing wrong with my boys, then. What a relief.~ + PregCC2
   ++ ~Aah, so that's what you meant. Alright, I was just confused for a moment.~ + PregCC1
END

IF ~~ PregCC1
   SAY ~Yup. I'm a responsible girl after all. What a shocker, huh?~
   = ~So, yeah. No unplanned kids here. Move along.~
   ++ ~How about planned kids, then? I would love to start a family with you.~ + PregYes
   ++ ~Not ever, I hope. I really don't want any children in my life.~ + PregNo
   ++ ~How do you feel about kids in general? I can't make up my mind.~ + PregDoubt
   ++ ~And move along we will.~ + PregEnd
END

IF ~~ PregCC2
   SAY ~Hah hah! No, not that I know of, you can put that worry to rest.~
   ++ ~How about planned kids, then? I would love to start a family with you.~ + PregYes
   ++ ~Well, go ahead and keep doing what you're doing. I really don't want any children in my life.~ + PregNo
   ++ ~Good to know. But how do you feel about having kids in general? I can't make up my mind.~ + PregDoubt
   ++ ~That's great. We better focus on what's happening right now, then, and worry about these issues if we survive.~ + PregEnd
END

IF ~~ PregCC3
   SAY ~(Imoen blinks a few times at you.) I'm goin' to pretend you didn't spill that bucket-full of slops just now, let ya think about it and give you a do-over. Because I'm nice like that.~
   = ~So, kids, huh. I was hopin' this topic wouldn't come up until after we survive all this Bhaal crap.~
   ++ ~No, I'm serious! Why wouldn't you let me have a say on the matter? It's my choice, too.~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",-3)~ + PregCCDumb
   ++ ~I like to plan for the future anyway. I very much want to raise children with you.~ + PregYes
   ++ ~I like to plan for the future anyway. I don't think I want children in our life.~ + PregNo
   ++ ~I like to plan for the future anyway, and I can't make up my mind. How do you feel about it?~ + PregDoubt
   ++ ~Works for me. Let's get to work, then.~ + PregEnd
END

IF ~~ PregCCDumb
   SAY ~(Her eyes widen in exasperation. Imoen takes a deep breath and lets it out slowly before answering.)~
   = ~It really is not, unless you've magically found a way to carry this kid in your belly for almost a year, put up with all the horrible pregnancy sickness and then push out the thing through your winkie - because that's just what childbirth will feel like, you know. Pushing out a melon through yer pecker. Wouldja like me to decide whether you get to push out a melon through your pecker?~
   = ~That's rhetorical, and so this conversation is over.~
   IF ~~ THEN EXIT
END


END















