//saradush inn keeper

EXTEND_BOTTOM SARBAR02 0
	+ ~IsValidForPartyDialog("Imoen2") Global("ImoenRomanceActive","GLOBAL",2) Global("IRTQTSaradush","GLOBAL",0)~ + ~(Rest at this inn and spend some quality time with Imoen.)~ DO ~ SetGlobal("IRTQTSaradush","GLOBAL",1) StartCutSceneMode() StartCutScene("IQTCUT")~ EXIT
END


APPEND IMOEN25J
IF ~Global("IRTQTSaradush","GLOBAL",1)~ THEN 1QT
	SAY ~(After you made known your intentions to stay, Imoen appropriated a table toward the back of the inn. Her pack lies by her feet, while her weapon is leaning against the corner, close at hand. She is rummaging through her belongings as you approach.)~
	[IRYayRom]
	= ~Hey, <CHARNAME>. I'm starving, ya think they have anything good left? Don't think they'll let us use their kitchen to cook our own rations...~
	++ ~Let's give them a chance. They might have a hot stew brewing somewhere.~  DO ~SetGlobal("IRTQTSaradush","GLOBAL",2)~ + 1QT1
	++ ~With the siege, the best we can hope for is old cheese and stale bread. Does that sound appealing to you?~  DO ~SetGlobal("IRTQTSaradush","GLOBAL",2)~ + 1QT2
	++ ~I want you to eat light, we might need to take off at any moment.~  DO ~SetGlobal("IRTQTSaradush","GLOBAL",2)~ + 1QT3
	++ ~I don't care, I'm not hungry. Order something, if you feel adventurous.~ DO ~SetGlobal("IRTQTSaradush","GLOBAL",2)~ + 1QT4
	++ ~I'm not hungry for food, Imoen. Let's go to our room so I can show you what I'm hungry for.~  DO ~SetGlobal("IRTQTSaradush","GLOBAL",2)~+ 1QT5
END

IF ~~ THEN 1QT1
	SAY ~Hah, I admire your optimism. Let's go for it. Waitress!~
	IF ~~ THEN GOTO 1QTOrder
END

IF ~~ THEN 1QT2
	SAY ~Aw, they might have something extra if we ask nicely. I say we should go for it.~
	++ ~Alright, sounds good.~ + 1QT2a
	++ ~I'll pass. That kitchen looks filthy, anyway.~ + 1QT4
END

IF ~~ THEN 1QT2a
	SAY ~Let's hope it's the right choice. Waitress!~
	IF ~~ THEN GOTO 1QTOrder
END

IF ~~ THEN 1QT3
	SAY ~Aw, you mean I can't make a pig out of myself like I always do? You know how I like to gobble down that lard like it's lemonade.~
	= ~Pfah. I *always* eat light, like a proper lady, thank you very much.~
	++ ~Right, sure. I've never seen you loosen your breeches because you stuffed yourself too much, nope.~ + 1QT3a
	++ ~How crass of me to suggest otherwise. Go ahead and order.~ + 1QT3b
	++ ~Regardless, I don't want to eat anything. Knock yourself out.~ + 1QT4
END

IF ~~ THEN 1QT3a
	SAY ~(There's an amused twinkle in Imoen's eye.) There's a reason I wear only robes now, dontcha know...~
	= ~Let's give the food here a try. Waitress!~
	IF ~~ THEN GOTO 1QTOrder
END

IF ~~ THEN 1QT3b
	SAY ~That's right, all kinds of crass. Waitress!~
	IF ~~ THEN GOTO 1QTOrder
END

IF ~~ THEN 1QT4
	SAY ~Aw, c'mon, you should eat something. Gotta keep healthy an' all that.~
	++ ~Alright, let's see what they have.~ + 1QT4a
	++ ~I'm fine, mom. You go ahead, if you're done nagging.~ + 1QT4c
END

IF ~~ THEN 1QT4a
	SAY ~Wise choice. Waitress!~
	IF ~~ THEN GOTO 1QTOrder
END

IF ~~ THEN 1QT4c
	SAY ~Hey, *somebody* has to take care of you, 'cuz obviously you aren't gonna do it on your own.~
	= ~Suit yerself, then. I tried. Waitress!~
	IF ~~ THEN GOTO 1QTSolo
END

IF ~~ THEN 1QT5
	SAY ~(Imoen giggles incredulously.) My goodness, you don't mess around. Didya ever hear of wining and dining? My stomach is rumbling, <PRO_MANWOMAN>, fill me up if you wanna have a good time.~
	= ~Um... that came out all wrong. What I mean is, I wanna eat. Actual food, I mean! Jeez.~
	= ~Waitress!~
	IF ~~ THEN GOTO 1QTOrder
END
END

CHAIN IMOEN25J 1QTOrder
	~(After some wheeling and dealing with the staff, Imoen procures a small meal that could qualify as hearty. The old cheese and stale bread are indeed a part of it, but there are also bowls of stew - the meat in it seems to be salted venison - as well as dried apples, a few strips or jerky and spiced baked potatoes, with mulled wine to go with it all. Not a feast fit for kings, but you've had far worse in your travels.)~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",2)~
	== IMOEN25J IF ~!NumInPartyGT(2)~ THEN ~(You eat close together, sharing over the food intimate conversations that range from your current state of affairs to the unsatisfactory state of Imoen's spare undergarments. She spends a fair amount of time making up implausible origin stories for every patron in the inn, sniggering quietly all the while. Whenever she doesn't need it for eating, her left hand rarely leaves your arm, or leg, or whichever part of you is closest. By the time the meal is over, she doesn't even flinch when a new catapult impact lands nearby.)~
	== IMOEN25J IF ~NumInPartyGT(2)~ THEN ~(You eat close together, not minding the rest of the group. Over the food you share intimate conversations that range from your current state of affairs to the unsatisfactory state of Imoen's spare undergarments. She spends a fair amount of time making up implausible origin stories for every other patron in the inn, sniggering quietly all the while. Whenever she doesn't need it for eating, her left hand rarely leaves your arm, or leg, or whichever part of you is closest. By the time the meal is over, she doesn't even flinch when a new catapult impact lands nearby.)~
	= ~(Imoen pushes her plate away.) Mmm, y'know, that was surprisingly good. Worth the stay in a sieged city, maybe. Though I think the company made it so much better.~
END IMOEN25J 1QTEnd
	
CHAIN IMOEN25J 1QTSolo
	~(After some wheeling and dealing with the staff, Imoen procures a small meal that could qualify as hearty. The old cheese and stale bread are indeed a part of it, but there are also bowls of stew - the meat in it seems to be salted venison - as well as dried apples, a few strips or jerky and spiced baked potatoes, with mulled wine to go with it all. Not the worst you've seen in your travels.)~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1)~
	== IMOEN25J IF ~!NumInPartyGT(2)~ THEN ~(You sit close together, and while she eats you share intimate conversations that range from your current state of affairs to the unsatisfactory state of Imoen's spare undergarments. She spends a fair amount of time making up implausible origin stories for every other patron in the inn, sniggering quietly all the while. Whenever she doesn't need it for eating, her left hand rarely leaves your arm, or leg, or whichever part of you is closest. By the time the meal is over, she doesn't even flinch when a new catapult impact lands nearby.)~
	== IMOEN25J IF ~NumInPartyGT(2)~ THEN ~(You sit close together, not minding the rest of the group. While she eats you share intimate conversations that range from your current state of affairs to the unsatisfactory state of Imoen's spare undergarments. She spends a fair amount of time making up implausible origin stories for every other patron in the inn, sniggering quietly all the while. Whenever she doesn't need it for eating, her left hand rarely leaves your arm, or leg, or whichever part of you is closest. By the time the meal is over, she doesn't even flinch when a new catapult impact lands nearby.)~
	= ~(Imoen pushes her plate away.) Mmm, y'know, that was surprisingly good. Worth the stay in a sieged city, maybe. Too bad you didn't wanna join me.~
END IMOEN25J 1QTEnd

APPEND IMOEN25J	
IF ~~ THEN 1QTEnd
	SAY ~(Her hand is caressing your thigh.) If you still wanna stay here... I'm definitely ready for dessert. (She winks at you.) Though I must warn you, I've a bit of a sweet tooth...~
	++ ~(Smile appreciatively.) We can certainly indulge. There is so much to taste.~ + 1QTEnd1
	++ ~Tempting, but I must admit staying here makes me nervous. A catapult shot might crash upon our heads.~ + 1QTEnd2
	++ ~I've been waiting for this. I could tear off your clothes right this moment.~ + 1QTEnd3
	++ ~(Kiss her fingers and wordlessly drag her to your room.)~ + 1QTEnd4
	++ ~I'm far too tired, Imoen. All I want is to sleep in a proper bed.~ + 1QTEnd5
	++ ~I doubt they have any good desserts here.~ + 1QTEnd6
END

IF ~~ THEN 1QTEnd1
	SAY ~(There is mischief is her eyes as she runs her fingers over your skin.) Let's get outta here and into our room. Something tells me we'll forget the siege is even happening.~
	IF ~~ THEN GOTO 1QTLast
END

IF ~~ THEN 1QTLast
	SAY ~(Imoen takes your hand and drags you away among giggles, her fleeting touches a promise of what is to come...)~
	IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) ClearAllActions()  StartCutSceneMode() StartCutScene("IQT1Cut")~ EXIT
END

IF ~~ THEN 1QTEnd2
	SAY ~Oh. Yeah, you're right, but... (her gaze shines with mischief) some might say that such a thing makes it all even more... exciting?~
	++ ~Huh. Yes, it sure does. I'm in the market for some excitement.~ + 1QTEnd2a
	++ ~I've had my fill of excitement for quite a while. We better get out of here.~ + 1QTEnd2b 
END

IF ~~ THEN 1QTEnd2a
	SAY ~Mmm, if yer buyin', I'm sellin'...~
	IF ~~ THEN GOTO 1QTLast
END

IF ~~ THEN 1QTEnd2b
	SAY ~Aw, phooey. Yeah, yer probably right. (imoen sighs, looking you up and down.) That's too bad, though...~
	IF ~~ THEN DO ~StartCutSceneMode() StartCutScene("IQT2Cut")~ EXIT
END

IF ~~ THEN 1QTEnd3
	SAY ~(Her expression becomes one of mischief as she runs her fingers over your skin.) I can tell. The way you've been looking at me is making me smolder. And you know that, don't you.~
	= ~Let's get outta here and into our room... something tells me we'll forget the siege is even happening.~
	IF ~~ THEN GOTO 1QTLast
END

IF ~~ THEN 1QTEnd4
	SAY ~(Imoen follows you willingly, giggling all the way. Her kisses and fleeting touches make an enticing promise of what's to come...)~
	IF ~~ THEN DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",1) ClearAllActions() StartCutSceneMode() StartCutScene("IQT1Cut")~ EXIT
END

IF ~~ THEN 1QTEnd5
	SAY ~Aw, you poor thing, of course. Tellya what, I'll tidy up over here, you go get some rest and I'll join you soon.~
	= ~(Imoen sighs, looking you up and down.) That's too bad, though...~
	IF ~~ THEN DO ~StartCutSceneMode() StartCutScene("IQT2Cut")~ EXIT
END	

IF ~~ THEN 1QTEnd6
	SAY ~Ha ha, no, dummy. (Her fingers tingle the inside of your thigh, going farther up.) A very special kind of dessert. In our bedroom.~
	++ ~Ooh, I see. Suddenly I feel hungry all over again.~ + 1QTEnd1
	++ ~Oh, hah, alright. It's tempting, but a catapult shot might crash upon our heads.~ + 1QTEnd2
	++ ~I was hoping that's what you meant, because I could tear off your clothes right this moment.~ + 1QTEnd3
	++ ~Oh, that. I'm far too tired, Imoen. All I want is to sleep in a proper bed.~ + 1QTEnd5
END
END

// In the Amkethran Inn

EXTEND_BOTTOM AMBAR01 0
	+ ~IsValidForPartyDialog("Imoen2") Global("ImoenRomanceActive","GLOBAL",2) Global("IRTQTAmkethran","GLOBAL",0)~ + ~(Rest at this inn and spend some quality time with Imoen.)~  DO ~ SetGlobal("IRTQTAmkethran","GLOBAL",1)~ EXTERN IMOEN25J 3QT
END

EXTEND_BOTTOM AMBAR01 20
	+ ~IsValidForPartyDialog("Imoen2") Global("ImoenRomanceActive","GLOBAL",2) Global("IRTQTAmkethran","GLOBAL",0)~ + ~(Rest at this inn and spend some quality time with Imoen.)~  DO ~ SetGlobal("IRTQTAmkethran","GLOBAL",1)~ EXTERN IMOEN25J 3QT
END

EXTEND_BOTTOM AMBAR01 40
	+ ~IsValidForPartyDialog("Imoen2") Global("ImoenRomanceActive","GLOBAL",2) Global("IRTQTAmkethran","GLOBAL",0)~ + ~(Rest at this inn and spend some quality time with Imoen.)~  DO ~ SetGlobal("IRTQTAmkethran","GLOBAL",1)~ EXTERN IMOEN25J 3QT
END


APPEND IMOEN25J
IF ~~ THEN 3QT
	SAY ~(Imoen looks around with a critical eye.) Two tables and a common room crowded with mercenaries and angry people. Somehow we managed to find a worse place to stay than Saradush.~
	= ~Suddenly the accommodations in the pocket plane seem far more inviting...~
	++ ~There are private rooms in the basement. The innkeep showed me the staircase down.~ + 3QT5
	++ ~You know what? You're right. Let's get out of here.~ + 3QT1
	++ ~It's a good thing you walked in, then. The place feels brighter already.~ + 3QT2
	++ ~Yeah, yeah, can we skip the talking and get to the part where you take off your clothes?~ + 3QT3
	++ ~This is what we must do if we want to sleep in a bed.~ + 3QT4

END

IF ~~ THEN 3QT1
	SAY ~Yup. Feels wrong to say it, but we've earned a little bit of comfort now and then, dammit.~
	= ~That's too bad, though I can't say I had very high hopes when we entered town...~
	IF ~~ THEN EXIT
END

IF ~~ THEN 3QT2
	SAY ~Ha ha, yer so full of crap. I'm sweaty, covered in dust, hungry, and my definition of heaven right now is a wash basin. But hey, thanks for the compliment anyways.~
	= ~There's no way I'm washin' up in a gross common room, though. I'm not that desperate yet.~
	++ ~There are private rooms in the basement, actually. The innkeep showed me the staircase down.~ + 3QT5
	++ ~You're right, let's get out of here. We'll rest elsewhere.~ + 3QT2a
	++ ~So I guess that means no getting it on here, huh?~ + 3QT3
	++ ~A common room bed is still better than a bedroll. We'll make it work.~ + 3QT4

END

IF ~~ THEN 3QT2a
	SAY ~Yeah, let's. I'd suggest camping by the oasis we passed, if it weren't for all the bodies we left behind.~
	IF ~~ THEN EXIT
END
	
IF ~~ THEN 3QT3
	SAY ~Hah! Wow. Such mastery of romance, <CHARNAME>. Makes a girl go wild.~
	= ~Sorry to say, that's only happening in yer dreams this time around.~
	++ ~What if I told you there's private rooms in the basement?~ + 3QT5
	++ ~Oh. No point resting here, then. Let's go elsewhere.~ + 3QT2a
	++ ~At least we'll snuggle real close in one of the common room beds...~ + 3QT4
END

IF ~~ THEN 3QT4
	SAY ~Can't disagree with ya there! Well, it depends on the bed, actually. There better not be bedbugs or other nasties crawling around.~
	= ~I keep tellin' ya, get to work on controlling what happens in the pocket plane. From here to having a magical luxury suite, just a couple steps.~
	= ~For now, icky desert inns it is...~
	IF ~~ THEN DO ~RestParty()~ EXIT
END	
	
IF ~~ THEN 3QT5
	SAY ~Oh, really? I didn't notice a downstairs. Ya think it's any good down there? I bet it's cooler, at least...~
	++ ~For the price he asked, there better be gilded cabinets and manservants down below.~ + 3QT5a
	++ ~It won't be a palace, but it has to be better than the upstairs area.~ + 3QT5b
	++ ~(Smile suggestively.) All I care about is the "private" bit.~ + 3QT5c
	++ ~Only one way to find out.~ + 3QTGoDown
END

IF ~~ THEN 3QT5a
	SAY ~I'd settle for a tiny room with a door on it. I just want to wash up and feel like a lady again.~
	IF ~~ THEN GOTO 3QTGoDown
END

IF ~~ THEN 3QT5b
	SAY ~Not that hard to pull off; an abandoned troll den might be better than this, hah. Um, hope the innkeeper didn't hear that...~
	IF ~~ THEN GOTO 3QTGoDown
END

IF ~~ THEN 3QT5c
	SAY ~Pfah. Get me outta this heat and dust and into fresh underwear and then we'll talk about your private bits...~
	IF ~~ THEN GOTO 3QTGoDown
END

IF ~~ THEN 3QTGoDown
	SAY ~Alrighty then, let's see what we find down there.~
	IF ~~ THEN DO ~SetGlobal("IRT3QTDownstairs","GLOBAL",1) ClearAllActions()  StartCutSceneMode() StartCutScene("3QTCut")~ /*Small cutscene moving the party to downstairs area: a suitably small inn area recycled from one of the many inn maps in the game or even from BG1. Imoen starts dialogue after a fade in and a slow pan of the area */ EXIT
END
END

CHAIN IF WEIGHT #-5 ~Global("IRT3QTDownstairs","GLOBAL",1)~ THEN IMOEN25J 3QTDown
	~(It is much cooler down one floor. Under the dim oil lamplight you see rugs and tapestries, wooden laminate and modestly ornate furnishings. Imoen's eyes wander with mild interest, not quite excited but visibly pleased by what she sees.)~
	=~(Imoen's features suddenly light up.) Sweet Mystra's rack, are those bathtubs?~ DO ~SetGlobal("IRT3QTDownstairs","GLOBAL",2)~
/*	= ~<CHARNAME>, get me a bath and you can wreck my vag for as long as you like.~ */
/* Hmm, maybe phrase that differently. */
END IMOEN25J 3QTDownN

APPEND IMOEN25J
IF ~~ THEN 3QTDownN
	SAY ~(She turns to you, delight sparkling in her eyes.) <CHARNAME>... get us a bath and I will melt into a puddle.~ [IRYayRom]
	++ ~I'll make arrangements right away.~ + 3QTD1
	++ ~Let's hope those tubs aren't just for decoration, right?~ + 3QTD2
	++ ~That's irresponsible. I doubt water comes easy around here.~ + 3QTD3
	++ ~That would take time that we don't have. We need to rest and prepare for the challenges ahead, not soak in a bathtub for hours.~ + 3QTD4
	++ ~Knock yourself out. I'm off to sleep, I'm exhausted.~ + 3QTD5
END

IF ~~ THEN 3QTD1
	SAY ~Aw yeah! Let's get ahold of that innkeeper. This is going to be great.~
	IF ~~ THEN GOTO 3QTDFill
END	

IF ~~ THEN 3QTD2
	SAY ~I'm far too excited about this, don't even joke about it! Let's get ahold of that innkeeper so we can make this happen...~
	IF ~~ THEN GOTO 3QTDFill
END

IF ~~ THEN 3QTD3
	SAY ~Ogh, please... the town won't go dry, they gotta have druids or priests on hand. They can make water without problems. B'sides, they wouldn't have these here if they didn't want guests to use them, right?~
	IF ~~ THEN GOTO 3QTD3Mud
END

IF ~~ THEN 3QTD3Mud
	SAY ~C'mon, don't be such a stick in the mud...~
	++ ~It's not happening. Be happy we get these rooms at all.~ + 3QTD3a
	++ ~You have a point. Let's do it.~ + 3QTD1
END

IF ~~ THEN 3QTD3a
	SAY ~Pfeh. You can be such a warthog sometimes.~
	= ~Alright, well, then... business as usual it is, I suppose. I hope at least I get a lousy wash basin.~
	IF ~~ THEN DO ~ClearAllActions()  StartCutSceneMode() StartCutScene("3QTCuta")~ EXIT /*  Cutscene: transport the party back upstairs. */
END
	
IF ~~ THEN 3QTD4
	SAY ~But, but... I can study my spells while IN the bathtub! It'll hardly make a difference at all, you'll see.~
	IF ~~ THEN GOTO 3QTD3Mud
END

IF ~~ THEN 3QTD5
	SAY ~Aw. Not gonna join me?~
	++ ~No, thanks.~ + 3QTD5a
	++ ~On second thought, I'd be a fool not to.~ + 3QTD5b
END

IF ~~ THEN 3QTD5a
	SAY ~Pfeh. You can be such a warthog sometimes. Fine, then, more room for me.~
	= ~(Imoen scampers off, no doubt gone to find the innkeeper so she can make arrangements. You shrug and head off to bed.)~
	IF ~~ THEN DO ~ClearAllActions()  StartCutSceneMode() StartCutScene("3QTCuta")~ EXIT /*  Cutscene: transport the party back upstairs. */
END

IF ~~ THEN 3QTD5b
	SAY ~That's absolutely right! Let's get ahold of that innkeeper. This is going to be great.~
	IF ~~ THEN GOTO 3QTDFill
END	
END 

CHAIN IMOEN25J 3QTDFill
	~(Upstairs, the obsequious barkeep affably explains it will take about one hour to draw your baths, as pre-hauled water needs to be tapped from the cisterns and heated up. With poorly-disguised mischievous glances at you, Imoen insists you will only need one tub to be prepared.)~ DO ~IncrementGlobal("IRTLoveMeter","GLOBAL",2)~
	= ~(You fill the time sorting through the contents of your packs, making routine preparations for the coming threats ahead, having conversations about optimal spell selections, weapon maintenance and other minutiae inherent to the high-risk, high-stakes life you carry. An hour hardly seems to pass before you are notified that the water is ready.)~
	= ~(Imoen races ahead of you into the cozy bathing room. Her clothes are half-way off by the time you get there; you watch her disrobe, then peel off her undershirt and pants, then shed every last bit of clothing left on her person.)~
	= ~(With a coquettish glance at you she steps out of her panties and stands by the tub. Delicately she dips her toes, then carefully steps inside. The expression of delight on her face as she lowers her body into the steaming water is one you don't often see these days.)~
	= ~Mmmmmh...~
	== IMOEN25J IF ~Gender(Player1,MALE)~ THEN ~(She settles in, her shoulders shrugging this way and that. The hollows of her collarbones draws enticing shadows upon her skin.) Oh Gods above, I've died and gone to paradise. (She looks at you and smiles.) Whatcha waiting for, handsome? Come over here and wash my back. I'm... ever so dirty.~
	== IMOEN25J IF ~Gender(Player1,FEMALE)~ THEN ~(She settles in, her shoulders shrugging this way and that. The hollow of her collarbones draws enticing shadows upon her skin.) Oh Gods above, I've died and gone to paradise. (She looks at you and smiles.) Whatcha waiting for, gorgeous? Come over here and wash my back. I'm... ever so dirty.~
	== IMOEN25J ~(Her smile widens.) Lock the door and get rid of all those pesky clothes...~ 
END
     IF ~~ THEN DO ~ StartCutSceneMode() StartCutScene("3QTCutb")~ EXIT
