BEGIN ~RU_AZURE~

IF ~Global("RU_AZURE_TALK","LOCALS",1)~ THEN BEGIN RU_AZURE_0
  SAY @0
  IF ~~ THEN DO ~SetGlobal("RU_AZURE_TALK","LOCALS",2)~ EXTERN ~RU_ASIM~ RU_ASIM_0
END

IF ~Global("RU_AZURE_TALK","LOCALS",2)
    NumInPartyGT(1)~ THEN BEGIN RU_AZURE_1
  SAY @7
  IF ~~ THEN DO ~SetGlobal("RU_AZURE_TALK","LOCALS",3)~ EXTERN ~RU_CLOZE~ RU_CLOZE_1
END

IF ~Global("RU_AZURE_TALK","LOCALS",2)
    !NumInPartyGT(1)~ THEN BEGIN RU_AZURE_2
  SAY @8
  IF ~~ THEN DO ~SetGlobal("RU_AZURE_TALK","LOCALS",3)~ EXTERN ~RU_CLOZE~ RU_CLOZE_1
END

IF ~~ THEN BEGIN RU_AZURE_3
  SAY @14
  IF ~~ THEN EXTERN ~RU_CLOZE~ RU_CLOZE_2
END

IF ~~ THEN BEGIN RU_AZURE_4
  SAY @18
  IF ~~ THEN REPLY @11 GOTO RU_AZURE_3
  IF ~~ THEN REPLY @13 GOTO RU_AZURE_5
END

IF ~~ THEN BEGIN RU_AZURE_5
  SAY @19
  IF ~~ THEN EXTERN ~RU_ASIM~ RU_ASIM_3
END


APPEND RU_ASIM
IF ~~ THEN BEGIN RU_ASIM_0
  SAY @1
  IF ~~ THEN EXTERN ~RU_CLOZE~ RU_CLOZE_0
END

IF ~~ THEN BEGIN RU_ASIM_1
  SAY @6
  IF ~~ THEN DO ~ClearAllActions()
                 StartCutSceneMode()
                 StartCutScene("RU_CUTS4")~ EXIT
END

IF ~~ THEN BEGIN RU_ASIM_2
  SAY @10
  IF ~~ THEN REPLY @11 EXTERN ~RU_AZURE~ RU_AZURE_3
  IF ~~ THEN REPLY @12 EXTERN ~RU_LIME~ RU_LIME_1
  IF ~~ THEN REPLY @13 EXTERN ~RU_AZURE~ RU_AZURE_5
END

IF ~~ THEN BEGIN RU_ASIM_3
  SAY @20
  IF ~~ THEN EXTERN ~RU_MONIC~ RU_MONIC_2
END
END

APPEND RU_CLOZE
IF ~~ THEN BEGIN RU_CLOZE_0
  SAY @2
  IF ~~ THEN EXTERN ~RU_LIME~ RU_LIME_0
END

IF ~~ THEN BEGIN RU_CLOZE_1
  SAY @9
  IF ~~ THEN EXTERN ~RU_ASIM~ RU_ASIM_2
END

IF ~~ THEN BEGIN RU_CLOZE_2
  SAY @15
  IF ~~ THEN EXTERN ~RU_MONIC~ RU_MONIC_1
END

IF ~~ THEN BEGIN RU_CLOZE_3
  SAY @22
  IF ~~ THEN EXTERN ~RU_LIME~ RU_LIME_2
END
END

APPEND RU_MONIC
IF ~~ THEN BEGIN RU_MONIC_0
  SAY @4
  IF ~~ THEN EXTERN ~RU_MAXIM~ RU_MAXIM_0
END

IF ~~ THEN BEGIN RU_MONIC_1
  SAY @16
  IF ~~ THEN DO ~ClearAllActions()
                 StartCutSceneMode()
                 StartCutScene("RU_CUTS5")~ EXIT
END

IF ~~ THEN BEGIN RU_MONIC_2
  SAY @21
  IF ~~ THEN EXTERN ~RU_CLOZE~ RU_CLOZE_3
END
END

APPEND RU_LIME
IF ~~ THEN BEGIN RU_LIME_0
  SAY @3
  IF ~~ THEN EXTERN ~RU_MONIC~ RU_MONIC_0
END

IF ~~ THEN BEGIN RU_LIME_1
  SAY @17
  IF ~~ THEN EXTERN ~RU_AZURE~ RU_AZURE_4
END

IF ~~ THEN BEGIN RU_LIME_2
  SAY @23
  IF ~~ THEN DO ~ActionOverride("CUTSPY",DestroySelf())
                 Shout(ALERT)
                 Enemy()~ EXIT
END
END

APPEND RU_MAXIM
IF ~~ THEN BEGIN RU_MAXIM_0
  SAY @5
  IF ~~ THEN EXTERN ~RU_ASIM~ RU_ASIM_1
END
END