IF
      Die()
THEN
      RESPONSE #100
	  ReallyForceSpellDeadRES("ru_stna2",Myself)
END

IF
        Global("RU_STAGE_OVER","GLOBAL",1)
THEN
	RESPONSE #100
                ReallyForceSpellRES("ru_disap",Myself)
                Wait(2)
                DestroySelf()
END

IF
	See(NearestEnemyOf(Myself))
        !GlobalTimerNotExpired("ResistDelayTimer","LOCALS")
THEN
	RESPONSE #100
                SetGlobalTimer("ResistDelayTimer","LOCALS",60)
                ReallyForceSpellRES("SPCL907",Myself)
END

IF
	!See(NearestEnemyOf(Myself))
        Global("BATTLESTART","LOCALS",1)
THEN
	RESPONSE #100
                SetGlobal("BATTLESTART","LOCALS",0)
END

IF
	See(NearestEnemyOf(Myself))
        Global("BATTLESTART","LOCALS",0)
THEN
	RESPONSE #100
                SetGlobal("BATTLESTART","LOCALS",1)
                Continue()
END

IF
        Global("BATTLESTART","LOCALS",1)
        !GlobalTimerNotExpired("SUMMON_DELAY","LOCALS")
        !GlobalTimerNotExpired("RU_SKEB_TIMER","LOCALS")

THEN
	RESPONSE #100
                SetGlobalTimer("SUMMON_DELAY","LOCALS",3)
                SetGlobalTimer("RU_SKEB_TIMER","LOCALS",60)
                DisplayStringHead(Myself,@158) // 슬픔에 절규하는 자들이여. 내가 감싸 안으리니...
                ReallyForceSpellRES("ru_c6s1a",Myself)
END

IF
        Global("BATTLESTART","LOCALS",1)
        !GlobalTimerNotExpired("SUMMON_DELAY","LOCALS")
        !GlobalTimerNotExpired("RU_SKES_TIMER","LOCALS")

THEN
	RESPONSE #100
                SetGlobalTimer("SUMMON_DELAY","LOCALS",3)
                SetGlobalTimer("RU_SKES_TIMER","LOCALS",90)
                DisplayStringHead(Myself,@159) // 현실에 절망하는 자들이여. 내가 감싸 안으리니...
                ReallyForceSpellRES("ru_c6s2a",Myself)
END

IF
        Global("BATTLESTART","LOCALS",1)
        !GlobalTimerNotExpired("SUMMON_DELAY","LOCALS")
        !GlobalTimerNotExpired("RU_SKEW_TIMER","LOCALS")

THEN
	RESPONSE #100
                SetGlobalTimer("SUMMON_DELAY","LOCALS",3)
                SetGlobalTimer("RU_SKEW_TIMER","LOCALS",120)
                DisplayStringHead(Myself,@160) // 안식을 찾는 기사들이여. 내가 감싸 안으리니...
                ReallyForceSpellRES("ru_c6s3a",Myself)
END

IF
        Global("BATTLESTART","LOCALS",1)
        !GlobalTimerNotExpired("SUMMON_DELAY","LOCALS")
        !GlobalTimerNotExpired("RU_SKEM_TIMER","LOCALS")

THEN
	RESPONSE #100
                SetGlobalTimer("SUMMON_DELAY","LOCALS",3)
                SetGlobalTimer("RU_SKEM_TIMER","LOCALS",160)
                DisplayStringHead(Myself,@161) // 눈물로 탄식하는 현자들이여. 내가 감싸 안으리니...
                ReallyForceSpellRES("ru_c6s4a",Myself)
END

IF
        Global("BATTLESTART","LOCALS",1)
	Gender([ANYONE],SUMMONED)
        OR(2)
          NumCreatureLT([ANYONE],10)
          !GlobalTimerNotExpired("RU_SKEB_TIMER","LOCALS")
        !GlobalTimerNotExpired("SUMMON_DELAY","LOCALS")
        InMyGroup([ANYONE])

THEN
	RESPONSE #25
                SetGlobalTimer("SUMMON_DELAY","LOCALS",3)
                SetGlobalTimer("RU_SKEB_TIMER","LOCALS",60)
                DisplayStringHead(Myself,@158) // 슬픔에 절규하는 자들이여. 내가 감싸 안으리니...
                ReallyForceSpellRES("ru_c6s1a",Myself)
        RESPONSE #75
                Continue()
END

IF
        Global("BATTLESTART","LOCALS",1)
	Gender([ANYONE],SUMMONED)
        OR(2)
          NumCreatureLT([ANYONE],8)
          !GlobalTimerNotExpired("RU_SKES_TIMER","LOCALS")
        !GlobalTimerNotExpired("SUMMON_DELAY","LOCALS")
        InMyGroup([ANYONE])

THEN
	RESPONSE #25
                SetGlobalTimer("SUMMON_DELAY","LOCALS",3)
                SetGlobalTimer("RU_SKES_TIMER","LOCALS",90)
                DisplayStringHead(Myself,@159) // 현실에 절망하는 자들이여. 내가 감싸 안으리니...
                ReallyForceSpellRES("ru_c6s2a",Myself)
        RESPONSE #75
                Continue()
END

IF
        Global("BATTLESTART","LOCALS",1)
	Gender([ANYONE],SUMMONED)
        OR(2)
          NumCreatureLT([ANYONE],6)
          !GlobalTimerNotExpired("RU_SKEW_TIMER","LOCALS")
        !GlobalTimerNotExpired("SUMMON_DELAY","LOCALS")
        InMyGroup([ANYONE])

THEN
	RESPONSE #25
                SetGlobalTimer("SUMMON_DELAY","LOCALS",3)
                SetGlobalTimer("RU_SKEW_TIMER","LOCALS",120)
                DisplayStringHead(Myself,@160) // 안식을 찾는 기사들이여. 내가 감싸 안으리니...
                ReallyForceSpellRES("ru_c6s3a",Myself)
        RESPONSE #75
                Continue()
END

IF
        Global("BATTLESTART","LOCALS",1)
	Gender([ANYONE],SUMMONED)
        OR(2)
          NumCreatureLT([ANYONE],6)
          !GlobalTimerNotExpired("RU_SKEM_TIMER","LOCALS")
        !GlobalTimerNotExpired("SUMMON_DELAY","LOCALS")
        InMyGroup([ANYONE])

THEN
	RESPONSE #25
                SetGlobalTimer("SUMMON_DELAY","LOCALS",3)
                SetGlobalTimer("RU_SKEM_TIMER","LOCALS",160)
                DisplayStringHead(Myself,@161) // 눈물로 탄식하는 현자들이여. 내가 감싸 안으리니...
                ReallyForceSpellRES("ru_c6s4a",Myself)
        RESPONSE #75
                Continue()
END

IF
        See(NearestEnemyOf(Myself))
        !GlobalTimerNotExpired("SongTimer","LOCALS")
        NumCreatureGT([ANYONE],2)
	Gender([ANYONE],SUMMONED)
        InMyGroup([ANYONE])
THEN
	RESPONSE #100
                SetGlobalTimer("SongTimer","LOCALS",30)
                DisplayStringHead(Myself,@162) // 짐은 왕이도다.
                ReallyForceSpellRES("RU_MUMSH",Myself)
                ScreenShake([20.20],3)
                Shout(201)
END

IF
	See(NearestEnemyOf(Myself))
        ActionListEmpty()
THEN
	RESPONSE #20
                DisplayStringHead(Myself,@163) // 죽음만이 영원한 정의를 외친다.
                ReallyForceSpellRES("SPCL901",Myself)
                AttackReevaluate(NearestEnemyOf(Myself),30)
	RESPONSE #20
                DisplayStringHead(Myself,@164) // 무지의 간격을 죽음이 메우는가.
                ReallyForceSpellRES("SPCL901",Myself)
                AttackReevaluate(NearestEnemyOf(Myself),30)
	RESPONSE #60
                ReallyForceSpellRES("SPCL901",Myself)
                AttackReevaluate(NearestEnemyOf(Myself),30)
END