///////////////////////////////////////////////////////////////////
// Dialogue for Xan
///////////////////////////////////////////////////////////////////
BEGIN MOXAN1

IF ~Global("bd_xan_followup","GLOBAL",0)
AreaCheck("bd1000")~ THEN BEGIN 0
  SAY @9001
  IF ~~ THEN REPLY @9002 GOTO 3  // I've little interest in your dour nature. Leave me.
  IF ~~ THEN REPLY @9003 GOTO 1  // Dreadful as these circumstances may be, we march to put a stop to Caelar's aggression.
END

IF ~~ THEN BEGIN 1
  SAY @9004 = @9005 
  IF ~~ THEN REPLY @9006 GOTO 3 // It's hard enough trying to keep our hopes up without you to bring them down. I'd rather you didn't join us.
  IF ~~ THEN REPLY @9007 GOTO 2 // I'd feel more comfortable facing down the impossible with a skilled mage at my side. Join with me.
END

IF ~~ THEN BEGIN 2
  SAY @9009
  IF ~~ THEN DO ~SetGlobal("bd_xan_followup","GLOBAL",1) 
JoinParty()~ EXIT
END

IF ~~ THEN BEGIN 3
  SAY @9008
  IF ~~ THEN DO ~SetGlobal("bd_xan_followup","GLOBAL",1)~ EXIT
END

IF ~Global("bd_xan_followup","GLOBAL",1)
!InParty("xan")~ THEN BEGIN 4
  SAY @9010
  IF ~~ THEN REPLY @9011 GOTO 3 // On second thought, I think our spirits would be higher without your assistance.
  IF ~~ THEN REPLY @9012 GOTO 2 // Yes, I require a skilled magic wielder at my side.
END