IF
  See([PC])
  NumTimesTalkedTo(0)
THEN
  RESPONSE #100
    MoveToObject([PC])
    StartDialogueNoSet([PC])
END

IF
  Global("SUDryadHostile","GLOBAL",1)
THEN
  RESPONSE #100
    SetGlobal("SUDryadHostile","GLOBAL",2)
    SetGlobalTimer("Round2","LOCALS",6)
    PlaySound("CRE_P01")
    CreateVisualEffectObject("SPGFLSH1",Myself)
    CreateCreatureObjectOffset("wolfdr01",Myself,[-10. -10])
    CreateCreatureObjectOffset("wolfdi01",Myself,[15. -10])
    CreateCreatureObjectOffset("smound01",Myself,[20. -25])
END

IF
  Global("SUDryadHostile","GLOBAL",2)
  GlobalTimerExpired("Round2","LOCALS")
THEN
  RESPONSE #100
    CreateCreatureObjectDoor("sirine01",[PC],0,0,0)
    CreateCreatureObjectDoor("sirine01",[PC],0,0,0)
    SetGlobal("SUDryadHostile","GLOBAL",3)
END

IF
  AttackedBy([GOODCUTOFF],DEFAULT)
  Global("SUDryadHostile","GLOBAL",0)
THEN
  RESPONSE #100
    SetGlobal("SUDryadHostile","GLOBAL",1)
    Enemy()
END

IF
  See(NearestEnemyOf(Myself))
  HaveSpell(WIZARD_IMPROVED_INVISIBILITY)
THEN
  RESPONSE #100
    Spell(Myself,WIZARD_IMPROVED_INVISIBILITY)
END

IF
  See(NearestEnemyOf(Myself))
  HaveSpell(WIZARD_DIRE_CHARM)
THEN
  RESPONSE #100
    Spell(NearestEnemyOf(Myself),WIZARD_DIRE_CHARM)
END

IF
  See(NearestEnemyOf(Myself))
  HaveSpell(WIZARD_MAGIC_MISSILE)
THEN
  RESPONSE #100
    SpellNoDec(NearestEnemyOf(Myself),WIZARD_MAGIC_MISSILE)
END
