BEGIN BSLASSAL

IF ~See(Player1)
Gender(Player1,FEMALE)
Global("BodhiStrongholdPledged","LOCALS",0)
Global("BodhiStronghold","GLOBAL",2)~ THEN BEGIN pledgeMaster1F
   SAY ~I will serve you, my mistress!~
IF ~~ THEN DO ~SetGlobal("BodhiStrongholdPledged","LOCALS",1)~ EXIT
END

IF ~See(Player1)
!Gender(Player1,FEMALE)
Global("BodhiStrongholdPledged","LOCALS",0)
Global("BodhiStronghold","GLOBAL",2)~ THEN BEGIN pledgeMaster1M
   SAY ~I will serve you, my master!~
IF ~~ THEN DO ~SetGlobal("BodhiStrongholdPledged","LOCALS",1)~ EXIT
END


IF ~See(Player1)
  Gender(Player1,FEMALE)
  Global("LassalResurrected","GLOBAL",1)~
THEN BEGIN greetingStartF
   SAY ~It's you! I have failed because of you! Why did you resurrect me?~
   ++ ~I will let you live, if you will serve to me!~ + briefingNV1
   ++ ~I have a weakness for men.~ + briefingNV1   
   ++ ~I wanted to kill you this time for pleasure.~ + briefing3f
END


IF ~See(Player1)
!Gender(Player1,FEMALE)
  Global("LassalResurrected","GLOBAL",1)~
THEN BEGIN greetingStart
   SAY ~It's you! Why did you resurrect me?~
   ++ ~I want you to serve me. Or to die.~ + briefingNV1
   ++ ~I have a weakness for vampires.~ + briefingNV1
   ++ ~I wanted to kill you this time for pleasure.~ + briefing3f
END


IF ~~ briefingNV1
  SAY ~I am too ancient to serve one-day king as you. But I don't want to die yet.~
  ++ ~Then join my party or die.~ + briefing2
  ++ ~You are free to go. I release you.~ + briefing3
  ++ ~Die, conspirator!~ + briefing3f
END



IF ~~ briefing2
  SAY ~Fine, I will be serving you. I have no choice.~ 
  IF ~~ THEN DO ~
  MakeGlobal()
  SetGlobal("LassalResurrected","GLOBAL",2)
  DestroyItem("VVHLASAL")
  DestroyItem("MINHP1")
  GiveItemCreate("VVCASKET",Myself,1,1,0) // Empty Casket		
  JoinParty()
  ~ EXIT
END

IF ~~ briefing3f
  SAY ~I will defend myself!~
  IF ~~ THEN DO ~SetGlobal("LassalResurrected","GLOBAL",2)
  SetGlobal("LassalLeft","GLOBAL",1)
Enemy()
~ EXIT
END

IF ~~ briefing3
  SAY ~Goodbye, <CHARNAME>. I will return to my mountain tomb.~
  IF ~~ THEN DO ~RunAwayFromNoInterrupt(Player1,50)
  SetGlobal("LassalResurrected","GLOBAL",2)
DestroySelf()
~ EXIT
END

//when thrown out
IF ~Gender(Player1,MALE)
!Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVManB1
SAY ~Do you need me, <CHARNAME>?~ 
 ++ ~Come with me, Lassal, I need your skills.~ + notparty1
 ++ ~Stay here, Lassal, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3 
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ notparty2
SAY ~Okay, master!~
IF ~~ THEN DO ~~ EXIT
END

IF ~Gender(Player1,FEMALE)
!Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVFemB1
SAY ~Do you need me, <CHARNAME>?~ 
 ++ ~Return, Lassal, I need you, my servant.~ + notparty1
 ++ ~Stay here, Lassal, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3 
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVFemB1
SAY ~Do you need me, <CHARNAME>?~ 
 ++ ~Return, Lassal, I need you, my servant.~ + notparty1
 ++ ~Go to our Stronghold in Grave Yard District. I will find you there, if it will be needed.~ + notpartGoST
 ++ ~Stay here, Lassal, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3 
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,MALE)
Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVMaleB1
SAY ~Do you need me, <CHARNAME>?~ 
 ++ ~Return, Lassal, I need you, my servant.~ + notparty1
 ++ ~Go to our Stronghold in Grave Yard District. I will find you there, if it will be needed.~ + notpartGoST
 ++ ~Stay here, Lassal, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3 
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ notparty1m
  SAY ~Let's crush some bones..~
  IF ~~ THEN DO ~
  DestroyItem("MINHP1")
		JoinParty()~ EXIT
END

IF ~~ notparty1
  SAY ~Let's crush some bones.~
  IF ~~ THEN DO ~  DestroyItem("MINHP1")
		JoinParty()~ EXIT
END

IF ~~ notpartGoST
   SAY ~I will return there.~
   IF ~~ THEN DO ~LeaveParty()
   RunAwayFromNoInterrupt(Player1,40)
   MoveBetweenAreas("AR0808",[1263.913],N)~ EXIT
 END  

// talk in party

IF ~Gender(Player1,MALE)
InParty(Myself)
Race(Player1,VAMPIRE)~ THEN BEGIN GreetingManV1
SAY ~My master, do you need something?~ 
 ++ ~Are you hungry? You can drink my blood, Lassal.~ + suckblood
 ++ ~Tell me your story, Lassal.~ + talkLassalM
 ++ ~No, nothing, sorry, Lassal.~ + byesilent
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
InParty(Myself)
Race(Player1,VAMPIRE)~ THEN BEGIN GreetingFemV1
SAY ~My mistress, do you need something?~ 
 ++ ~Are you hungry? You can drink my blood, Lassal.~ + suckblood
 ++ ~Tell me your story, Lassal.~ + talkLassalF
 ++ ~No, nothing, sorry, Lassal.~ + byesilent
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,MALE)
InParty(Myself)
!Race(Player1,VAMPIRE)~ THEN BEGIN GreetingMan1
SAY ~<CHARNAME>, do you need something?~ 
 ++ ~Are you hungry? You can drink my blood, Lassal.~ + suckblood
 ++ ~Make me a vampire, Lassal.~ + vampconvm
 ++ ~Tell me your story, Lassal.~ + talkLassalM
 ++ ~No, nothing, sorry, Lassal.~ + byesilent
   ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
InParty(Myself)
!Race(Player1,VAMPIRE)~ THEN BEGIN GreetingFem1
SAY ~<CHARNAME>, do you need something?~ 
 ++ ~Are you hungry? You can drink my blood, Lassal.~ + suckblood
 ++ ~Make me a vampire, Lassal.~ + vampconvf 
 ++ ~Tell me your story, Lassal.~ +   talkLassalM
 ++ ~No, nothing, sorry, Lassal.~ + byesilent
   ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ byesilent
SAY ~Fine.~
  IF ~~ THEN DO ~~ EXIT
END


IF ~~ talkLassalM
  SAY ~I am a noble count. At least I was him three hundred years ago. I have very big tomb in mountains guarded by trolls and orcs. One day Bodhi's messenger showed up and proposed a treat. I will help Bodhi with sizing control of Ahkatla and helping our kind get proper place in food chain.~
  IF ~~ THEN GOTO talkLassalM2
END

IF ~~ talkLassalM2
  SAY ~I agreed and walked here. All was too easy. Then you have shown up, and now all is a mess.~
  IF ~~ THEN GOTO talkLassalM3
END

IF ~~ talkLassalM3
  SAY ~I hope you will help our kind to preserve successes gained by Bodhi and to show living who there true leaders must be.~
  IF ~~ THEN EXIT
END


IF ~~ talkLassalF
  SAY ~I am a noble count. At least I was him three hundred years ago. I have very big tomb in mountains guarded by trolls and orcs. One day Bodhi's messenger showed up and proposed a treat. I will help Bodhi with sizing control of Ahkatla and helping our kind get proper place in food chain.~
  IF ~~ THEN GOTO talkLassalF2
END

IF ~~ talkLassalF2
  SAY ~I agreed and walked here with your pretty ass and bouncing breasts. All was too easy. Then you have shown up, and now all is a mess.~
  IF ~~ THEN GOTO talkLassalF3
END

IF ~~ talkLassalF3
   SAY ~I hope you will help our kind to preserve successes gained by Bodhi and to show living who there true leaders must be.~
  IF ~~ THEN EXIT
END




IF ~~ suckblood
  SAY ~I always like blood.~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckblood2
END

IF ~~ suckbloodNo
  SAY ~I will not drink this poison!~
  IF ~~ THEN DO ~~ EXIT
END


IF ~~ suckblood2
  SAY ~Oooh, like a good booze!~
  IF ~~ THEN DO ~ApplyDamagePercent(Player1,90,MAGIC)
  SetGlobalTimer("BloodlustTimer","LOCALS",ONE_DAY)
		ApplySpell(Myself,RESTORE_FULL_HEALTH)~ EXIT 
END

IF ~~ vampconvm
  SAY ~(Lassal gets closer.)~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO vampconv2
END


IF ~~ vampconvf
  SAY ~(Lassal's teeth go out and brutally bite you in your neck.)~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO vampconv2
END

IF ~~ vampconv2
  SAY ~(Suddently you feel his teeths have pierced your skin and gone to carotid vein. Blood flow is distracted and becomes pulsating. You feel that your blood flows into Lassal.)~
IF ~~ GOTO vampconv3
END

IF ~~ vampconv3
  SAY ~(Soon you feel great weakness, your throuths are clouded. And you loose consciousness.)~
IF ~~ GOTO vampconv4
END

IF ~~ vampconv4
  SAY ~(...You open your eyes. World around you have changed. You have changed. You feel coldness of your body and immediately you feel all-consuming hunger growing in you.)~
IF ~~ GOTO vampconv5
END

IF ~~ vampconv5
  SAY ~(You are now undead, as you wished. Now you feel presence of Lassal and his throughts about ruling the world.)~

  IF ~~ THEN DO ~  ActionOverride(Player1,SetGlobal("ActorVampirisedLevel","LOCALS",2))
		ChangeStat(Player1,CON,2,ADD)
		ChangeStat(Player1,STR,2,ADD)
		ChangeStat(Player1,WIS,-2,ADD)
		ChangeStat(Player1,INT,-2,ADD)
		

		SetGlobal("LassalVampirized","GLOBAL",1)	
	~ EXIT
END


