BEGIN BSDEL

IF ~See(Player1)
Gender(Player1,FEMALE)
Global("BodhiStrongholdPledged","LOCALS",0)
Global("BodhiStronghold","GLOBAL",2)~ THEN BEGIN pledgeMaster1F
   SAY ~I will serve you, my mistress!~
IF ~~ THEN DO ~SetGlobal("BodhiStrongholdPledged","LOCALS",1)~ EXIT
END

IF ~See(Player1)
!Gender(Player1,FEMALE)
Global("BodhiStrongholdPledged","LOCALS",0)
Global("BodhiStronghold","GLOBAL",2)~ THEN BEGIN pledgeMaster1M
   SAY ~I will serve you, my master!~
IF ~~ THEN DO ~SetGlobal("BodhiStrongholdPledged","LOCALS",1)~ EXIT
END


IF ~See(Player1)
  Gender(Player1,FEMALE)
  Global("DelResurrected","GLOBAL",1)~
THEN BEGIN greetingStartF
   SAY ~Why did you resurrect me, a pretty girl? I was your rival.~
   ++ ~I will let you live, if you will serve me.~ + briefingNV1
   ++ ~I have a weakness for women.~ + briefingNV1   
   ++ ~Die, harpy!~ + briefing3f
END


IF ~See(Player1)
!Gender(Player1,FEMALE)
  Global("DelResurrected","GLOBAL",1)~
THEN BEGIN greetingStart
   SAY ~Why did you resurrect me, a pretty boy? I was your rival back then.~
   ++ ~I almost get lost in your beauty.~ + briefingNV1
   ++ ~I have a weakness for women.~ + briefingNV1
   ++ ~Die, harpy!~ + briefing3f
END


IF ~~ briefingNV1
  SAY ~I am not just a silly girl. I am able to fight and able to cast magic. Do you really returned me because of my natural beauty?~
  ++ ~Join my party, you will be one of shining diamonds in it.~ + briefing2
  ++ ~Join my party, your skills need practice.~ + briefing2
  ++ ~You are free to go, beauty. I release you.~ + briefing3
  ++ ~Die, harpy!~ + briefing3f
END



IF ~~ briefing2
  SAY ~I don't have anywhere else to go.~
  IF ~~ THEN DO ~
  MakeGlobal()
  SetGlobal("DelResurrected","GLOBAL",2)
  DestroyItem("VVHLANA")
  GiveItemCreate("VVCASKET",Myself,1,1,0) // Empty Casket		
  JoinParty()
  ~ EXIT
END

IF ~~ briefing3f
  SAY ~I am too beautiful to die!~
  IF ~~ THEN DO ~SetGlobal("DelResurrected","GLOBAL",2)
  SetGlobal("DelLeft","GLOBAL",1)
Enemy()
~ EXIT
END

IF ~~ briefing3
  SAY ~Goodbye, <CHARNAME>. I must search for place in this world.~
  IF ~~ THEN DO ~RunAwayFromNoInterrupt(Player1,50)
  SetGlobal("DelResurrected","GLOBAL",2)
DestroySelf()
~ EXIT
END

//when thrown out
IF ~Gender(Player1,MALE)
!Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVManB1
SAY ~Do you need me, my master?~ 
 ++ ~Return, Del, I need your skills.~ + notparty1
 ++ ~Stay here, Del, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3 
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ notparty2
SAY ~Okay, master!~
IF ~~ THEN DO ~~ EXIT
END

IF ~Gender(Player1,FEMALE)
!Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVFemB1
SAY ~Do you need me, my mistress?~ 
 ++ ~Return, Del, I need you, my servant.~ + notparty1
 ++ ~Stay here, Del, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3  
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVFemB1
SAY ~Do you need me, my mistress?~ 
 ++ ~Return, Del, I need you, my servant.~ + notparty1
 ++ ~Go to our Stronghold in Grave Yard District. I will find you there, if it will be needed.~ + notpartGoST
 ++ ~Stay here, Del, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3  
 ++ ~I decided to end your life.~ + briefing3f
END


IF ~Gender(Player1,MALE)
Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVMAleB1
SAY ~Do you need me, my master?~ 
 ++ ~Return, Del, I need you, my servant.~ + notparty1
 ++ ~Go to our Stronghold in Grave Yard District. I will find you there, if it will be needed.~ + notpartGoST
 ++ ~Stay here, Del, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3  
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ notparty1m
  SAY ~Okay, okay!~
  IF ~~ THEN DO ~
	DestroyItem("VVHLANA")
		JoinParty()~ EXIT
END

IF ~~ notparty1
  SAY ~With pleasure!~
  IF ~~ THEN DO ~DestroyItem("VVHLANA")
		JoinParty()~ EXIT
END

IF ~~ notpartGoST
   SAY ~As you command!~
   IF ~~ THEN DO ~LeaveParty()
   RunAwayFromNoInterrupt(Player1,40)
   MoveBetweenAreas("AR0808",[143.829],SE)~ EXIT
 END  

// talk in party

IF ~Gender(Player1,MALE)
InParty(Myself)
Race(Player1,VAMPIRE)~ THEN BEGIN GreetingManV1
SAY ~My master, do you need something from me?~ 
 ++ ~Are you hungry? You can suck my blood, Del.~ + suckblood
 ++ ~Tell me your story, Del.~ + talkDelM
 ++ ~No, nothing right now, Del.~ + byesilent
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
InParty(Myself)
Race(Player1,VAMPIRE)~ THEN BEGIN GreetingFemV1
SAY ~My mistress, do you need something from me?~ 
 ++ ~Are you hungry? You can suck my blood, Del.~ + suckblood
 ++ ~Tell me your story, Del.~ + talkDelF
 ++ ~No, nothing right now, Del.~ + byesilent
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,MALE)
InParty(Myself)
!Race(Player1,VAMPIRE)~ THEN BEGIN GreetingMan1
SAY ~<CHARNAME>, do you need something from me?~ 
 ++ ~Are you hungry? You can suck my blood, Del.~ + suckblood
 ++ ~Make me a vampire, Del.~ + vampconvm
 ++ ~Tell me your story, Del.~ + talkDelM
 ++ ~No, nothing right now, Del. Sorry.~ + byesilent
   ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
InParty(Myself)
!Race(Player1,VAMPIRE)~ THEN BEGIN GreetingFem1
SAY ~<CHARNAME>, do you need something from me?~ 
 ++ ~Are you hungry? You can suck my blood, Del.~ + suckblood
 ++ ~Make me a vampire, Del.~ + vampconvf 
 ++ ~Tell me your story, Del.~ +   talkDelM
 ++ ~No, nothing right now, Del. Sorry for disturbance.~ + byesilent
   ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ byesilent
SAY ~To next time!~
  IF ~~ THEN DO ~~ EXIT
END


IF ~~ talkDelM
  SAY ~I was a licenced mage of Cowled Wizards. I was so young and went by myself to check stories about vampires in Grave Yard District.~
  IF ~~ THEN GOTO talkDelM2
END

IF ~~ talkDelM2
  SAY ~Tales were true. I have opposed Bodhi and lost. But she was generous, my skills impressed her, so now I am vampire. But I like the smell of blood, the taste of it on my lips. And my beauty is preserved. I will not slowly wither.~
  IF ~~ THEN GOTO talkDelM3
END

IF ~~ talkDelM3
  SAY ~If you feel lonely, come talk to me. I like to talk with men.~
  IF ~~ THEN EXIT
END


IF ~~ talkDelF
   SAY ~I was a licenced mage of Cowled Wizards. I was so young and went by myself to check stories about vampires in Grave Yard District.~
  IF ~~ THEN GOTO talkDelF2
END

IF ~~ talkDelF2
  SAY ~Tales were true. I have opposed Bodhi and lost. But she was generous, my skills impressed her, so now I am vampire. But I like the smell of blood, the taste of it on my lips. And my beauty is preserved. I will not slowly wither.~
  IF ~~ THEN GOTO talkDelF3
END

IF ~~ talkDelF3
 SAY ~If you feel lonely, come talk to me. I like to talk with women.~
  IF ~~ THEN EXIT
END




IF ~~ suckblood
  SAY ~I will be gentle!~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckblood2
END

IF ~~ suckbloodNo
  SAY ~Hey, are you trying to poison me?~
  IF ~~ THEN DO ~~ EXIT
END

IF ~~ suckblood2
  SAY ~Aaahhhh! Ooohhhh!~
  IF ~~ THEN DO ~ApplyDamagePercent(Player1,80,MAGIC)
  SetGlobalTimer("BloodlustTimer","LOCALS",ONE_DAY)
		ApplySpell(Myself,RESTORE_FULL_HEALTH)~ EXIT 
END

IF ~~ vampconvm
  SAY ~(Del firmly embraces you by neck and gets closer.)~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO vampconv2
END


IF ~~ vampconvf
  SAY ~(Del's teeth go out and gently bite you in your neck.)~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO vampconv2
END

IF ~~ vampconv2
  SAY ~(Suddently you feel her teeths have pierced your skin and gone to carotid vein. Blood flow is distracted and becomes pulsating. You feel that your blood flows into Del.)~
IF ~~ GOTO vampconv3
END

IF ~~ vampconv3
  SAY ~(Soon you feel great weakness, your throuths are clouded. And you loose consciousness.)~
IF ~~ GOTO vampconv4
END

IF ~~ vampconv4
  SAY ~(...You open your eyes. World around you have changed. You have changed. You feel coldness of your body and immediately you feel all-consuming hunger growing in you.)~
IF ~~ GOTO vampconv5
END

IF ~~ vampconv5
  SAY ~(You are now undead, as you wished. Now you feel presence of Del and her spontaneous throughts. You feel, that Del has reserved some human part in her mind.)~

  IF ~~ THEN DO ~  ActionOverride(Player1,SetGlobal("ActorVampirisedLevel","LOCALS",2))
		ChangeStat(Player1,CON,-2,ADD)
		ChangeStat(Player1,STR,-1,ADD)
		ChangeStat(Player1,WIS,1,ADD)
		ChangeStat(Player1,INT,1,ADD)
	

		SetGlobal("DelVampirized","GLOBAL",1)	
	~ EXIT
END


