BEGIN BSDURST

IF ~See(Player1)
Gender(Player1,FEMALE)
Global("BodhiStrongholdPledged","LOCALS",0)
Global("BodhiStronghold","GLOBAL",2)~ THEN BEGIN pledgeMaster1F
   SAY ~I will serve you, my mistress!~
IF ~~ THEN DO ~SetGlobal("BodhiStrongholdPledged","LOCALS",1)~ EXIT
END

IF ~See(Player1)
!Gender(Player1,FEMALE)
Global("BodhiStrongholdPledged","LOCALS",0)
Global("BodhiStronghold","GLOBAL",2)~ THEN BEGIN pledgeMaster1M
   SAY ~I will serve you, my master!~
IF ~~ THEN DO ~SetGlobal("BodhiStrongholdPledged","LOCALS",1)~ EXIT
END


IF ~See(Player1)
  Gender(Player1,FEMALE)
  Global("DurstResurrected","GLOBAL",1)~
THEN BEGIN greetingStartF
   SAY ~It's you! Why did you resurrect me?~
   ++ ~I will let you live, if you will serve to me!~ + briefingNV1
   ++ ~I have a weakness for aged men.~ + briefingNV1   
   ++ ~I wanted to kill you once more.~ + briefing3f
END


IF ~See(Player1)
!Gender(Player1,FEMALE)
  Global("DurstResurrected","GLOBAL",1)~
THEN BEGIN greetingStart
   SAY ~It's you! Why did you resurrect me?~
   ++ ~I want you to serve me. Or to die.~ + briefingNV1
   ++ ~I have a weakness for vampires.~ + briefingNV1
   ++ ~I wanted to kill you once more.~ + briefing3f
END


IF ~~ briefingNV1
  SAY ~Don't know. I am an aristocrate. What will people say if I will change a master so quickly?~
  ++ ~Then join my party or die.~ + briefing2
  ++ ~You are free to go anywhere you like. I release you.~ + briefing3
  ++ ~Die, world eater!~ + briefing3f
END



IF ~~ briefing2
  SAY ~I don't know of any other place to serve. I will join you, even if my pride is itching.~
  IF ~~ THEN DO ~
  MakeGlobal()
  SetGlobal("DurstResurrected","GLOBAL",2)
  DestroyItem("VVHDURST")
  GiveItemCreate("VVCASKET",Myself,1,1,0) // Empty Casket		
  JoinParty()
  ~ EXIT
END

IF ~~ briefing3f
  SAY ~I will defend myself!~
  IF ~~ THEN DO ~SetGlobal("DurstResurrected","GLOBAL",2)
 SetGlobal("DurstLeft","GLOBAL",1) 
Enemy()
~ EXIT
END

IF ~~ briefing3
  SAY ~Goodbye, <CHARNAME>. I will try to find some haunted mansion.~
  IF ~~ THEN DO ~RunAwayFromNoInterrupt(Player1,50)
  SetGlobal("DurstResurrected","GLOBAL",2)
DestroySelf()
~ EXIT
END

//when thrown out
IF ~Gender(Player1,MALE)
!Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVManB1
SAY ~Do you need me, my master?~ 
 ++ ~Come with me, Durst, I need your skills.~ + notparty1
 ++ ~Stay here, Durst, I will return.~ + notparty2
  ++ ~You are free to go. I release you from your duties.~ + briefing3 
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ notparty2
SAY ~Okay, master!~
IF ~~ THEN DO ~~ EXIT
END

IF ~Gender(Player1,FEMALE)
!Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVFemB1
SAY ~Do you need me, my mistress?~ 
 ++ ~Return, Durst, I need you, my servant.~ + notparty1
 ++ ~Stay here, Durst, I will return.~ + notparty2
  ++ ~You are free to go. I release you from your duties.~ + briefing3 
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVFemB1
SAY ~Do you need me, my mistress?~ 
 ++ ~Return, Durst, I need you, my servant.~ + notparty1
 ++ ~Go to our Stronghold in Grave Yard District. I will find you there, if it will be needed.~ + notpartGoST
 ++ ~Stay here, Durst, I will return.~ + notparty2
  ++ ~You are free to go. I release you from your duties.~ + briefing3 
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,MALE)
Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVMaleB1
SAY ~Do you need me, my master?~ 
 ++ ~Return, Durst, I need you, my servant.~ + notparty1
 ++ ~Go to our Stronghold in Grave Yard District. I will find you there, if it will be needed.~ + notpartGoST
 ++ ~Stay here, Durst, I will return.~ + notparty2
  ++ ~You are free to go. I release you from your duties.~ + briefing3 
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ notparty1m
  SAY ~I was starting to get bored.~
  IF ~~ THEN DO ~
	//	DestroyItem("VVDurst")
	//	DestroyItem("MONHP1")
		JoinParty()~ EXIT
END

IF ~~ notparty1
  SAY ~I was starting to get bored.~
  IF ~~ THEN DO ~
		JoinParty()~ EXIT
END

IF ~~ notpartGoST
   SAY ~As you command!~
   IF ~~ THEN DO ~LeaveParty()
   RunAwayFromNoInterrupt(Player1,40)
   MoveBetweenAreas("AR0808",[1263.913],N)~ EXIT
 END  

// talk in party

IF ~Gender(Player1,MALE)
InParty(Myself)
Race(Player1,VAMPIRE)~ THEN BEGIN GreetingManV1
SAY ~My master, do you need something?~ 
 ++ ~Are you hungry? You can drink my blood, Durst.~ + suckblood
 ++ ~Tell me your story, Durst.~ + talkDurstM
 ++ ~No, nothing, sorry, Durst.~ + byesilent
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
InParty(Myself)
Race(Player1,VAMPIRE)~ THEN BEGIN GreetingFemV1
SAY ~My mistress, do you need something?~ 
 ++ ~Are you hungry? You can drink my blood, Durst.~ + suckblood
 ++ ~Tell me your story, Durst.~ + talkDurstF
 ++ ~No, nothing, sorry, Durst.~ + byesilent
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,MALE)
InParty(Myself)
!Race(Player1,VAMPIRE)~ THEN BEGIN GreetingMan1
SAY ~<CHARNAME>, do you need something?~ 
 ++ ~Are you hungry? You can drink my blood, Durst.~ + suckblood
 ++ ~Make me a vampire, Durst.~ + vampconvm
 ++ ~Tell me your story, Durst.~ + talkDurstM
 ++ ~No, nothing, sorry, Durst.~ + byesilent
   ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
InParty(Myself)
!Race(Player1,VAMPIRE)~ THEN BEGIN GreetingFem1
SAY ~<CHARNAME>, do you need something?~ 
 ++ ~Are you hungry? You can drink my blood, Durst.~ + suckblood
 ++ ~Make me a vampire, Durst.~ + vampconvf 
 ++ ~Tell me your story, Durst.~ +   talkDurstM
 ++ ~No, nothing, sorry, Durst.~ + byesilent
   ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ byesilent
SAY ~As you want!~
  IF ~~ THEN DO ~~ EXIT
END


IF ~~ talkDurstM
  SAY ~I am a descendant of noble family in Suldanesselar. When Bodhi moved from Suldanesselar, she made me into vampire to get a hold of my assets.~
  IF ~~ THEN GOTO talkDurstM2
END

IF ~~ talkDurstM2
  SAY ~But this doesn't mean she robed me. I liked her style and she gave me this new life. Days in Suldanesselar were boring. I wanted to change my life, and it happened.~
  IF ~~ THEN GOTO talkDurstM3
END

IF ~~ talkDurstM3
  SAY ~I hope you will be better master than Bodhi and will not send me on suicide missions.~
  IF ~~ THEN EXIT
END


IF ~~ talkDurstF
  SAY ~I am a descendant of noble family in Amn. I am not from Ahkatla, I'm from other place. When Bodhi moved from Suldanesselar, she met me and made me into vampire to get a hold of my assets.~
  IF ~~ THEN GOTO talkDurstF2
END

IF ~~ talkDurstF2
  SAY ~But this doesn't mean she robed me. I liked her style and she gave me this new life. Days in mansion were boring. I wanted to change my life, and it happened.~
  IF ~~ THEN GOTO talkDurstF3
END

IF ~~ talkDurstF3
   SAY ~I hope you will be better mistress than Bodhi and will not send me on suicide missions.~
  IF ~~ THEN EXIT
END



IF ~~ suckblood
  SAY ~I always like a good drink.~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckblood2
END

IF ~~ suckbloodNo
  SAY ~This is not a drink I like, for sure!~
  IF ~~ THEN DO ~~ EXIT
END


IF ~~ suckblood2
  SAY ~Oooh, like a good old vine!~
  IF ~~ THEN DO ~ApplyDamagePercent(Player1,90,MAGIC)
  SetGlobalTimer("BloodlustTimer","LOCALS",ONE_DAY)
		ApplySpell(Myself,RESTORE_FULL_HEALTH)~ EXIT 
END

IF ~~ vampconvm
  SAY ~(Durst gets closer.)~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO vampconv2
END


IF ~~ vampconvf
  SAY ~(Durst's teeth go out and brutally bite you in your neck.)~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO vampconv2
END

IF ~~ vampconv2
  SAY ~(Suddently you feel his teeths have pierced your skin and gone to carotid vein. Blood flow is distracted and becomes pulsating. You feel that your blood flows into Durst.)~
IF ~~ GOTO vampconv3
END

IF ~~ vampconv3
  SAY ~(Soon you feel great weakness, your throuths are clouded. And you loose consciousness.)~
IF ~~ GOTO vampconv4
END

IF ~~ vampconv4
  SAY ~(...You open your eyes. World around you have changed. You have changed. You feel coldness of your body and immediately you feel all-consuming hunger growing in you.)~
IF ~~ GOTO vampconv5
END

IF ~~ vampconv5
  SAY ~(You are now undead, as you wished. Now you feel presence of Durst and his peaceful throughts.)~

  IF ~~ THEN DO ~  ActionOverride(Player1,SetGlobal("ActorVampirisedLevel","LOCALS",2))		

		SetGlobal("DurstVampirized","GLOBAL",1)	
	~ EXIT
END


