BEGIN BSPARISA


IF ~See(Player1)
Gender(Player1,FEMALE)
Global("BodhiStrongholdPledged","LOCALS",0)
Global("BodhiStronghold","GLOBAL",2)~ THEN BEGIN pledgeMaster1F
   SAY ~I will serve you, my mistress!~
IF ~~ THEN DO ~SetGlobal("BodhiStrongholdPledged","LOCALS",1)~ EXIT
END

IF ~See(Player1)
!Gender(Player1,FEMALE)
Global("BodhiStrongholdPledged","LOCALS",0)
Global("BodhiStronghold","GLOBAL",2)~ THEN BEGIN pledgeMaster1M
   SAY ~I will serve you, my master!~
IF ~~ THEN DO ~SetGlobal("BodhiStrongholdPledged","LOCALS",1)~ EXIT
END



IF ~See(Player1)
  Gender(Player1,FEMALE)
  Global("ParisaResurrected","GLOBAL",1)~
THEN BEGIN greetingStartF
   SAY ~It's you! Why did you resurrect me? Answer, or feel my wraith!~
   ++ ~Calm down, Parisa, I don't want to kill you again.~ + briefingNV1
   ++ ~I will let you live, if you will serve me!~ + briefingNV1
   ++ ~Die, wicked monster!~ + briefing3f
END


IF ~See(Player1)
!Gender(Player1,FEMALE)
  Global("ParisaResurrected","GLOBAL",1)~
THEN BEGIN greetingStart
   SAY ~It's you! Why did you resurrect me? Answer, or feel my wraith!~
   ++ ~Calm down, Parisa, I don't want to kill you again.~ + briefingNV1
   ++ ~I will let you live, if you will serve me!~ + briefingNV1
   ++ ~Die, wicked monster!~ + briefing3f
END


IF ~~ briefingNV1
  SAY ~Don't know. Bodhi is defeated. Who will command me whom to tear apart? Do you have a guts to command me?~
  ++ ~You can join me and get to know this by yourself.~ + briefing2
  ++ ~You are free to go. I release you.~ + briefing3
  ++ ~Die, wicked monster!~ + briefing3f
END



IF ~~ briefing2
  SAY ~Just don't forget that I like tearing and dismembering.~
  IF ~~ THEN DO ~
  MakeGlobal()
  SetGlobal("ParisaResurrected","GLOBAL",2)
  DestroyItem("VVHPARIS")
  GiveItemCreate("VVCASKET",Myself,1,1,0) // Empty Casket		
  JoinParty()
  ~ EXIT
END

IF ~~ briefing3f
  SAY ~I'll have your entrails for dinner!~
  IF ~~ THEN DO ~SetGlobal("ParisaResurrected","GLOBAL",2)
Enemy()
Berserk()
~ EXIT
END

IF ~~ briefing3
  SAY ~Fine, if you don't need me, maybe some serial murderer would.~
  IF ~~ THEN DO ~RunAwayFromNoInterrupt(Player1,50)
  SetGlobal("ParisaResurrected","GLOBAL",2)
DestroySelf()
~ EXIT
END

//when thrown out
IF ~Gender(Player1,MALE)
!Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVManB1
SAY ~Do you need my power, my master?~ 
 ++ ~Come with me, Parisa, I need your skills.~ + notparty1
 ++ ~Stay here, Parisa, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3 
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ notparty2
SAY ~Okay, master!~
IF ~~ THEN DO ~~ EXIT
END

IF ~Gender(Player1,FEMALE)
!Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVFemB1
SAY ~Do you need my power, my mistress?~ 
 ++ ~Come with me, Parisa, I need you, my servant.~ + notparty1
 ++ ~Stay here, Parisa, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3  
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVFemB1
SAY ~Do you need my power, my mistress?~ 
 ++ ~Come with me, Parisa, I need you, my servant.~ + notparty1
 ++ ~Go to our Stronghold in Grave Yard District. I will find you there, if it will be needed.~ + notpartGoST
 ++ ~Stay here, Parisa, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3  
 ++ ~I decided to end your life.~ + briefing3f
END


IF ~Gender(Player1,MALE)
Global("BodhiStronghold","GLOBAL",2)
!InParty(Myself)~ THEN BEGIN GreetingVMAleB1
SAY ~Do you need my power, my master?~ 
 ++ ~Come with me, Parisa, I need you, my servant.~ + notparty1
 ++ ~Go to our Stronghold in Grave Yard District. I will find you there, if it will be needed.~ + notpartGoST
 ++ ~Stay here, Parisa, I will return.~ + notparty2
  ++ ~You are free to go. I release you.~ + briefing3  
 ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ notparty1m
  SAY ~Let the bloodbath begins!~
  IF ~~ THEN DO ~
	//	DestroyItem("VVParisa")
	//	DestroyItem("MONHP1")
		JoinParty()~ EXIT
END

IF ~~ notparty1
  SAY ~Let the blood spits!~
  IF ~~ THEN DO ~
		JoinParty()~ EXIT
END

IF ~~ notpartGoST
   SAY ~Bye bye!~
   IF ~~ THEN DO ~LeaveParty()
   RunAwayFromNoInterrupt(Player1,40)
   MoveBetweenAreas("AR0808",[555.704],S)~ EXIT
 END  

// talk in party

IF ~Gender(Player1,MALE)
InParty(Myself)
Race(Player1,VAMPIRE)~ THEN BEGIN GreetingManV1
SAY ~My master, do you need something from me?~ 
 ++ ~Are you hungry? You can suck my blood, Parisa.~ + suckblood
 ++ ~Tell me your story, Parisa.~ + talkParisaM
 ++ ~No, nothing right now, Parisa.~ + byesilent
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
InParty(Myself)
Race(Player1,VAMPIRE)~ THEN BEGIN GreetingFemV1
SAY ~My mistress, do you need something from me?~ 
 ++ ~Are you hungry? You can suck my blood, Parisa.~ + suckblood
 ++ ~Tell me your story, Parisa.~ + talkParisaF
 ++ ~No, nothing right now, Parisa.~ + byesilent
  ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,MALE)
InParty(Myself)
!Race(Player1,VAMPIRE)~ THEN BEGIN GreetingMan1
SAY ~<CHARNAME>, do you need something from me?~ 
 ++ ~Are you hungry? You can suck my blood, Parisa.~ + suckblood
 ++ ~Make me a vampire, Parisa.~ + vampconvm
 ++ ~Tell me your story, Parisa.~ + talkParisaM
 ++ ~No, nothing right now, Parisa. Sorry.~ + byesilent
   ++ ~I decided to end your life.~ + briefing3f
END

IF ~Gender(Player1,FEMALE)
InParty(Myself)
!Race(Player1,VAMPIRE)~ THEN BEGIN GreetingFem1
SAY ~<CHARNAME>, do you need something from me?~ 
 ++ ~Are you hungry? You can suck my blood, Parisa.~ + suckblood
 ++ ~Make me a vampire, Parisa.~ + vampconvf 
 ++ ~Tell me your story, Parisa.~ +   talkParisaM
 ++ ~No, nothing right now, Parisa. Sorry for disturbance.~ + byesilent
   ++ ~I decided to end your life.~ + briefing3f
END

IF ~~ byesilent
SAY ~Rrrr!~
  IF ~~ THEN DO ~~ EXIT
END


IF ~~ talkParisaM
  SAY ~I am from barbarian tribe of the Windspear Hills. I grown very quick and our tribe made some successful raids. We made our last raid on a village, when Bodhi's coven stayed for a night. This was our last mistake.~
  IF ~~ THEN GOTO talkParisaM2
END

IF ~~ talkParisaM2
  SAY ~All of our people were butchered. Just I remained alive and managed to defeat three Bodhi's girls. That I was proposed to join Bodhi and gain eternity. I was the last of our tribe, so I chose to get into new tribe, not to go to worms.~
  IF ~~ THEN GOTO talkParisaM3
END

IF ~~ talkParisaM3
  SAY ~So I am here, ready to fight and tear apart.~
  IF ~~ THEN EXIT
END


IF ~~ talkParisaF
  SAY ~I am from barbarian tribe of the Windspear Hills. I grown very quick and our tribe made some successful raids. We made our last raid on a village, when Bodhi's coven stayed for a night. This was our last mistake.~
  IF ~~ THEN GOTO talkParisaF2
END

IF ~~ talkParisaF2
  SAY ~ When a dwarven mine was found, I was transferred here. This was so boring, and that bitch Natasha mocked me for my Zent accent. But then you came and stormed through the mine. You killed me, and Night Counsil agent made me into vampire.~
  IF ~~ THEN GOTO talkParisaF3
END

IF ~~ talkParisaF3
  SAY ~So I am here, ready to fight and tear apart.~
  IF ~~ THEN EXIT
END



IF ~~ suckblood
  SAY ~You proposed it yourself!~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckblood2
END

IF ~~ suckbloodNo
  SAY ~Hey, your blood is not a blood!~
  IF ~~ THEN DO ~~ EXIT
END


IF ~~ suckblood2
  SAY ~I will drink it all!~
  IF ~~ THEN DO ~ApplyDamagePercent(Player1,95,MAGIC)
  SetGlobalTimer("BloodlustTimer","LOCALS",ONE_DAY)
		ApplySpell(Myself,RESTORE_FULL_HEALTH)~ EXIT 
END

IF ~~ vampconvm
  SAY ~(Parisa fall you to the ground and jumps over you.)~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO vampconv2
END


IF ~~ vampconvf
  SAY ~(Parisa's teeth go out and tear your neck. Blood is everywhere.)~
  IF ~!Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO suckbloodNo  
  IF ~Global("Player1RaceBlood","GLOBAL",4)~ THEN GOTO vampconv2
END

IF ~~ vampconv2
  SAY ~(Suddently you feel her teeths have pierced your skin and gone to carotid vein. Blood flow is distracted and becomes pulsating. You feel that your blood flows into Parisa.)~
IF ~~ GOTO vampconv3
END

IF ~~ vampconv3
  SAY ~(Soon you feel great weakness, your throuths are clouded. And you loose consciousness.)~
IF ~~ GOTO vampconv4
END

IF ~~ vampconv4
  SAY ~(...You open your eyes. World around you have changed. You have changed. You feel coldness of your body and immediately you feel all-consuming hunger growing in you.)~
IF ~~ GOTO vampconv5
END

IF ~~ vampconv5
  SAY ~(You are now undead, as you wished. Now you feel presence of Parisa. She is smiling and licking her hands. She sure liked your blood and waits for more.)~

  IF ~~ THEN DO ~  ActionOverride(Player1,SetGlobal("ActorVampirisedLevel","LOCALS",2))
		ChangeStat(Player1,CON,3,ADD)
		ChangeStat(Player1,STR,2,ADD)
		ChangeStat(Player1,WIS,-3,ADD)
		ChangeStat(Player1,INT,-2,ADD)
		

		SetGlobal("ParisaVampirized","GLOBAL",1)	
	~ EXIT
END


