IF
  See(NearestEnemyOf(Myself))
  !StateCheck(Myself,STATE_INVISIBLE)
  Global("Shield","LOCALS",0)
THEN
  RESPONSE #100
    ApplySpell(Myself,WIZARD_FIRE_SHIELD_RED)
    SetGlobal("Shield","LOCALS",1)
END

IF
  See(NearestEnemyOf(Myself))
  StateCheck(Myself,STATE_INVISIBLE)
  Global("EfreetiFireball","LOCALS",0)
THEN
  RESPONSE #100
    ReallyForceSpell(NearestEnemyOf(Myself),WIZARD_FIREBALL)
    SetGlobal("EfreetiFireball","LOCALS",1)
END

IF
  See(NearestEnemyOf(Myself))
  !StateCheck(Myself,STATE_INVISIBLE)
  GlobalLT("EfreetiInvisibility","LOCALS",3)
THEN
  RESPONSE #100
    IncrementGlobal("EfreetiInvisibility","LOCALS",1)
    ForceSpell(Myself,WIZARD_INVISIBILITY)
    Wait(1)
END

IF
  See(NearestEnemyOf(Myself))
  Global("arrow","LOCALS",0)
THEN
  RESPONSE #100
    ForceSpell(NearestEnemyOf(Myself),WIZARD_FLAME_ARROW)
    SetGlobal("arrow","LOCALS",1)
END

IF
  See(NearestEnemyOf(Myself))
  Global("strike","LOCALS",0)
THEN
  RESPONSE #100
    ForceSpell(NearestEnemyOf(Myself),CLERIC_FLAME_STRIKE)
    SetGlobal("strike","LOCALS",1)
END

IF
  See(NearestEnemyOf(Myself))
THEN
  RESPONSE #100
    AttackReevaluate(NearestEnemyOf(Myself),15)
END

