BEGIN wlsbbp01

IF ~Global("wl_oublek_bpimp","GLOBAL",2)~ THEN BEGIN wl_oublek_bpimp0 SAY ~This is a private room,  what do you want?~
	++ ~I'm here for the documents you stole from Oublek.~ + wl_oublek_bpimp1
	++ ~Sorry to bother you, I'll leave.~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_bpimp1 SAY ~Stole? We didn't steal anything! The fat weasel sent us into a trap, no doubt hoping we'd perish, and then refused to pay us when we made it back! We were owed compensation and we took it!~
	+ ~CheckStatGT(Player1Fill,19,STR)
		OR(2)
			ReputationGT(Player1,16)
			ReputationLT(Player1,5)~ + ~I care not for your excuses! Surrender the documents or draw your blades!~ + wl_oublek_bpimp_intimidated
	+ ~CheckStatLT(Player1Fill,20,STR)~ + ~I care not for your excuses! Surrender the documents or draw your blades!~ + wl_oublek_bpimp_fight
	+ ~CheckStatGT(Player1Fill,19,STR)
		ReputationGT(Player1,4)
		ReputationLT(Player1,17)~ + ~I care not for your excuses! Surrender the documents or draw your blades!~ + wl_oublek_bpimp_fight
	+ ~CheckStatGT(Player1Fill,15,CHR)
		OR(2)
			CheckStatGT(Player1Fill,15,WIS)
			CheckStatGT(Player1Fill,15,INT)~ + ~I can sympathize as I've had jobs go bad myself. But if you don't return the documents, you'll never be able to do business in Nashkel again. Is this really worth it?~ + wl_oublek_bpimp_convinced
	+ ~CheckStatGT(Player1Fill,9,CHR)~ + ~I can sympathize as I've had jobs go bad myself. How about I buy the documents off you?~ + wl_oublek_bpimp_bribe0
	++ ~I believe you. Keep the documents, I'll tell Oublek you had already left town by the time I got here.~ DO ~
		SetGlobal("wl_oublek_bpimp","GLOBAL",99)
		AddJournalEntry(@38,QUEST)~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_bpimp_intimidated SAY ~We are still not fully recovered from that deathtrap Oublek sent us in, I'll not risk another confrontation. Here, take the blasted papers! Come friends, time to leave.~
	IF ~TRUE()~ THEN DO ~
		SetGlobal("wl_oublek_bpimp","GLOBAL",3)
		AddJournalEntry(@37,QUEST)
		GiveItemCreate("wlsbms01",Player1,0,0,0)~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_bpimp_convinced SAY ~I can see the wisdom in your words. Very well, take the papers. Come friends, time to leave.~
	IF ~TRUE()~ THEN DO ~
		SetGlobal("wl_oublek_bpimp","GLOBAL",3)
		AddJournalEntry(@37,QUEST)
		GiveItemCreate("wlsbms01",Player1,0,0,0)~ EXIT
END
	
IF ~~ THEN BEGIN wl_oublek_bpimp_bribe0 SAY ~You want to buy them? Hmm...~ 
	IF ~CheckStatGT(Player1Fill,9,CHR)
		CheckStatLT(Player1Fill,12,CHR)~ THEN DO ~~ + wl_oublek_bpimp_bribe1
	IF ~CheckStatGT(Player1Fill,11,CHR)
		CheckStatLT(Player1Fill,14,CHR)~ THEN DO ~~ + wl_oublek_bpimp_bribe2
	IF ~CheckStatGT(Player1Fill,13,CHR)
		CheckStatLT(Player1Fill,16,CHR)~ THEN DO ~~ + wl_oublek_bpimp_bribe3
	IF ~CheckStatGT(Player1Fill,15,CHR)
		CheckStatLT(Player1Fill,18,CHR)~ THEN DO ~~ + wl_oublek_bpimp_bribe4
	IF ~CheckStatGT(Player1Fill,18,CHR)~ THEN DO ~~ + wl_oublek_bpimp_bribe5
END

IF ~~ THEN BEGIN wl_oublek_bpimp_bribe1 SAY ~II will take no less than 500gp. Agreed?~
	+ ~PartyGoldGT(499)~ + ~Agreed.~ DO ~
		TakePartyGold(500)
		SetGlobal("wl_oublek_bpimp","GLOBAL",3)
		AddJournalEntry(@37,QUEST)
		GiveItemCreate("wlsbms01",Player1,0,0,0)~ EXIT
	++ ~I see there's no reasoning with you. Draw your weapons.~ DO ~SetGlobal("wl_oublek_bpimp","GLOBAL",4)~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_bpimp_bribe2 SAY ~I will take no less than 400gp. Agreed?~
	+ ~PartyGoldGT(399)~ + ~Agreed.~ DO ~
		TakePartyGold(400)
		SetGlobal("wl_oublek_bpimp","GLOBAL",3)
		AddJournalEntry(@37,QUEST)
		GiveItemCreate("wlsbms01",Player1,0,0,0)~ EXIT
	++ ~I see there's no reasoning with you. Draw your weapons.~ DO ~SetGlobal("wl_oublek_bpimp","GLOBAL",4)~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_bpimp_bribe3 SAY ~I will take no less than 300gp. Agreed?~
	+ ~PartyGoldGT(299)~ + ~Agreed.~ DO ~
		TakePartyGold(300)
		SetGlobal("wl_oublek_bpimp","GLOBAL",3)
		AddJournalEntry(@37,QUEST)
		GiveItemCreate("wlsbms01",Player1,0,0,0)~ EXIT
	++ ~I see there's no reasoning with you. Draw your weapons.~ DO ~SetGlobal("wl_oublek_bpimp","GLOBAL",4)~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_bpimp_bribe4 SAY ~I will take no less than 200gp. Agreed?~
	+ ~PartyGoldGT(199)~ + ~Agreed.~ DO ~
		TakePartyGold(200)
		SetGlobal("wl_oublek_bpimp","GLOBAL",3)
		AddJournalEntry(@37,QUEST)
		GiveItemCreate("wlsbms01",Player1,0,0,0)~ EXIT
	++ ~I see there's no reasoning with you. Draw your weapons.~ DO ~SetGlobal("wl_oublek_bpimp","GLOBAL",4)~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_bpimp_bribe5 SAY ~I will take no less than 100gp. Agreed?~
	+ ~PartyGoldGT(99)~ + ~Agreed.~ DO ~
		TakePartyGold(100)
		SetGlobal("wl_oublek_bpimp","GLOBAL",3)
		AddJournalEntry(@37,QUEST)
		GiveItemCreate("wlsbms01",Player1,0,0,0)~ EXIT
	++ ~I see there's no reasoning with you. Draw your weapons.~ DO ~SetGlobal("wl_oublek_bpimp","GLOBAL",4)~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_bpimp_fight SAY ~Don't you know who we are? We shall not be robbed by the likes of you! TO ARMS, FRIENDS!~
	IF ~TRUE()~ THEN DO ~
		SetGlobal("wl_oublek_bpimp","GLOBAL",4)~ EXIT
END