BEGIN wlsbnw01

IF ~Global("wl_oublek_escort","GLOBAL",2)~ THEN BEGIN wl_oublek_escort1 SAY ~Hello. Can I help you?~
	++ ~Oublek sent me. I'm here to escort you to Baldur's Gate.~ DO ~SetGlobal("wl_oublek_escort","GLOBAL",4)~ + wl_oublek_escort2
	++ ~Sorry to bother you.~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_escort2 SAY ~Oh, that is wonderful! I had been stuck in this town since the poor guards my father hired were killed by bandits. You seem much more capable, I'm sure the local riffraff will be no match for you! Are we ready to go?~
	++ ~Yes, follow me.~ DO ~
		SetInterrupt(FALSE)
		ChangeEnemyAlly(Myself, FAMILIAR)
		AddFamiliar()
		SetGlobal("wl_oublek_escort","GLOBAL",5)
		AddJournalEntry(@31,QUEST)
		ForceRandomEncounterEntry("wlsbar01","ExitS")
		SetInterrupt(TRUE)~ EXIT
	++ ~Not yet, I'll be back shortly.~ EXIT
END

IF ~Global("wl_oublek_escort","GLOBAL",4)~ THEN BEGIN wl_oublek_escort2a SAY ~You're back! Are we ready to go?~
	++ ~Yes, follow me.~ DO ~
		SetInterrupt(FALSE)
		ChangeEnemyAlly(Myself, FAMILIAR)
		AddFamiliar()
		SetGlobal("wl_oublek_escort","GLOBAL",5)
		AddJournalEntry(@31,QUEST)
		ForceRandomEncounterEntry("wlsbar01","ExitS")
		SetInterrupt(TRUE)~ EXIT
	++ ~Not yet, I'll be back shortly.~ EXIT
END

IF ~AreaCheck("AR0900")
	Global("wl_oublek_escort","GLOBAL",6)~ THEN BEGIN wl_oublek_escort3 SAY ~We have arrived! Thank you so much for keeping me safe, I'll be fine on my own from here.~
		++ ~The pleasure was all mine, milady.~ DO ~
			SetInterrupt(FALSE)
			RemoveFamiliar()
			ChangeEnemyAlly(Myself, NEUTRAL)
			SetGlobal("wl_oublek_escort","GLOBAL",3)
			AddJournalEntry(@32,QUEST)
			MoveToPoint([3880.3125])
			DestroySelf()
			SetInterrupt(TRUE)~ EXIT
		++ ~Good riddance.~ DO ~
			SetInterrupt(FALSE)
			RemoveFamiliar()
			ChangeEnemyAlly(Myself, NEUTRAL)
			SetGlobal("wl_oublek_escort","GLOBAL",3)
			AddJournalEntry(@32,QUEST)
			MoveToPoint([3880.3125])
			DestroySelf()
			SetInterrupt(TRUE)~ EXIT
END