BEGIN wlsbnw02

IF ~Global("wl_oublek_escort","GLOBAL",2)~ THEN BEGIN wl_oublek_escort1 SAY ~Hello. Can I help you?~
	++ ~Oublek sent me. I'm here to escort you to Baldur's Gate.~ DO ~SetGlobal("wl_oublek_escort","GLOBAL",4)~ + wl_oublek_escort2
	++ ~Sorry to bother you.~ EXIT
END

IF ~~ THEN BEGIN wl_oublek_escort2 SAY ~Oh, that is wonderful! I had been stuck in this town since the poor guards my father hired were killed by bandits. You seem much more capable, I'm sure the local riffraff will be no match for you! Are we ready to go?~
	++ ~Yes, follow me.~ DO ~
		SetInterrupt(FALSE)
		ChangeEnemyAlly(Myself, FAMILIAR)
		AddFamiliar()
		SetGlobal("wl_oublek_escort","GLOBAL",7)
		AddJournalEntry(@31,QUEST)
		ForceRandomEncounterEntry("wlsbar01","ExitS")
		SetInterrupt(TRUE)~ EXIT
	++ ~Not yet, I'll be back shortly.~ EXIT
END

IF ~Global("wl_oublek_escort","GLOBAL",4)~ THEN BEGIN wl_oublek_escort2a SAY ~You're back! Are we ready to go?~
	++ ~Yes, follow me.~ DO ~
		SetInterrupt(FALSE)
		ChangeEnemyAlly(Myself, FAMILIAR)
		AddFamiliar()
		SetGlobal("wl_oublek_escort","GLOBAL",7)
		AddJournalEntry(@31,QUEST)
		ForceRandomEncounterEntry("wlsbar01","ExitS")
		SetInterrupt(TRUE)~ EXIT
	++ ~Not yet, I'll be back shortly.~ EXIT
END

IF ~AreaCheck("wlsbar01")
	Global("wl_oublek_escort","GLOBAL",8)~ THEN BEGIN wl_oublek_escort3 SAY ~We have arrived at our final destination. Well, YOUR final destination anyway. Time to pay for the sins of your father, ward of Gorion!~
		++ ~What the...?!~ DO ~
			SetInterrupt(FALSE)
			RemoveFamiliar()
			ChangeEnemyAlly(Myself, ENEMY)
			ChangeAIScript("WTASIGHT",DEFAULT)
			Polymorph(HAG_NIGHT)
			CreateVisualEffectObject("sppolymp",Myself)
			SetName(@2000)
			SetGlobal("wl_oublek_escort","GLOBAL",9)
			SetInterrupt(TRUE)~ EXIT
END