BEGIN wlsbmn01
IF ~TRUE()~ THEN BEGIN wl_oublek_miner1 SAY ~WE WON'T WORK! WE WON'T WORK! WE WO... Eh? What do you want? Can't you see I'm busy?~
	++ ~What are you busy with if you won't work?~ + wl_oublek_miner1a
	++ ~I want you to go back to work.~ + wl_oublek_miner2
END

IF ~~ THEN wl_oublek_miner1a SAY ~Striking, obviously! Sheesh, adventurers these days are getting thicker...~
	IF ~~ THEN DO ~DisplayStringHead(myself,@1001)~ EXIT
END

IF ~~ THEN wl_oublek_miner2 SAY ~Is your helmet on too tight? We're ON STRIKE! That means we're not going back to work until our demands are met!~
	++ ~Okay then, what are your demands?~ + wl_oublek_miner2a
	IF ~CheckStatGT(Player1,17,STR)~ THEN REPLY ~Get back to work before I strike YOU!~ +wl_oublek_miner3a
	IF ~CheckStatLT(Player1,18,STR)~ THEN REPLY ~Get back to work before I strike YOU!~ +wl_oublek_miner3b
END

IF ~~ THEN wl_oublek_miner2a SAY ~Some kind of new monstrosity is stalking the lower levels of the mine! We're not going back to work unless it's chased off!~
	++ ~Alright, I'll deal with it for you.~ DO ~SetGlobal("wl_oublek_miners","GLOBAL",4) AddJournalEntry(@9,QUEST)~ EXIT
	++ ~Will 100 gold pieces make you lot go back to work? Call it hazard pay.~ + wl_oublek_miner2b
	IF ~CheckStatGT(Player1,17,STR)~ THEN REPLY ~Get back to work before I strike YOU!~ +wl_oublek_miner3a
	IF ~CheckStatLT(Player1,18,STR)~ THEN REPLY ~Get back to work before I strike YOU!~ +wl_oublek_miner3b
END

IF ~~ THEN wl_oublek_miner2b SAY ~100 pieces of gold? You've got yourself a deal, <SIRMAAM>!~ 
	IF ~TRUE()~ THEN DO ~IncrementGlobal("wl_oublek_count","GLOBAL",1) SetGlobal("wl_oublek_miners_disperse","GLOBAL",1) TakePartyGold(100) EscapeArea()~ EXIT
END

IF ~~ THEN wl_oublek_miner3a SAY ~EEEK! Please don't hurt us, we'll go back to work right now!~
	IF ~TRUE()~ THEN DO ~IncrementGlobal("wl_oublek_count","GLOBAL",1) SetGlobal("wl_oublek_miners_example","GLOBAL",1) EscapeArea()~ EXIT
END

IF ~~ THEN wl_oublek_miner3b SAY ~I'm not afraid of you! Who's going to go dig in that hellhole if you hurt me, you? Don't make me laugh!~ 
	IF ~~ THEN DO ~DisplayStringHead(myself,@1001)~ EXIT
END